BEGIN YSMOM



CHAIN
IF ~InParty("Yasraena")
!StateCheck("Yasraena",STATE_SLEEPING)
InParty("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)~
THEN YSMOM RevengeYasraena1a
~We have found you, Yasraena! You thought to escape the hand of Lolth, but you cannot!~
=
~You will die here, and the House of Arkhenneld will return to Lolth's favor!~
== BYASRA25
~Matron Mother! (Yasraena spits the words.) I have longed for your death!~ [YASRA217]
== YSMOM
~It is you who shall die here, slain by the hand of Lolth's faithful!~
== BVICON25
~Yes, yathtallar. Take her! We surrender her to the will of Lolth!~
== YSMOM
~You are wise, og'elend, not to face our wrath!~
=
~She will die for her crimes!~
DO ~SetGlobal("AvengingDivalir","GLOBAL",1)
ClearAllActions()StartCutSceneMode()StartCutScene("YSBETRAY")~
EXIT



CHAIN
IF ~InParty("Yasraena")
!StateCheck("Yasraena",STATE_SLEEPING)
!InParty("Viconia")~
THEN YSMOM RevengeYasraena
~We have found you, Yasraena! You thought to escape the hand of Lolth, but you cannot!~
=
~You will die here, and the House of Arkhenneld will return to Lolth's favor!~
== BYASRA25
~Matron Mother! (Yasraena spits the words.) I have longed for your death!~ [YASRA217]
== YSMOM
~It is you who shall die here, slain by the hand of Lolth's faithful!~
END

++ ~We shall defend you, Yasraena!~ GOTO RevengeYasraena1
++ ~Whoa, whoa, whoa! This isn't *my* fight! Take her and leave me be.~ GOTO RevengeYasraena2

CHAIN YSMOM RevengeYasraena1
~Fool! You will not withstand our assault!~
=
~Arkhenneld! Attack!~
DO ~SetGlobal("YSFamilyFight","GLOBAL",1)
Enemy()~
EXIT

CHAIN YSMOM RevengeYasraena2
~You are wise, Bhaalspawn, not to face our wrath!~
=
~She will die for her crimes!~
DO ~SetGlobal("AvengingDivalir","GLOBAL",1)
ClearAllActions()StartCutSceneMode()StartCutScene("YSBETRAY")~
EXIT

