BEGIN YSNETHR



IF ~Global("TalkedToYSTMCPTN","GLOBAL",1)
Global("TalkedToNethrin","GLOBAL",0)
!InParty("Yasraena")~ THEN BEGIN NethrinGivesDivRing
SAY ~Greetings. Do you have business with me?~ 
 ++ ~Yes, you are Nethrin, are you not?~ DO ~SetGlobal("TalkedToNethrin","GLOBAL",1)~ GOTO NethrinGivesDivRing1a
 ++ ~Perhaps. What are you doing here?~ DO ~SetGlobal("TalkedToNethrin","GLOBAL",1)~ GOTO NethrinGivesDivRing2a
 ++ ~I need Divalir's ring immediately!~ DO ~SetGlobal("TalkedToNethrin","GLOBAL",1)~ GOTO NethrinGivesDivRing3a
END

IF ~~ THEN BEGIN NethrinGivesDivRing1a
SAY ~I am. Do I know you?~
 ++ ~Not really. I am a friend of Yasraena's.~ GOTO NethrinGivesDivRing1b
 ++ ~No, you don't. But I need Divalir's ring.~ GOTO NethrinGivesDivRing3a
 ++ ~Enough chit chat. Give me the ring, and no one gets hurt!~ GOTO NethrinGivesDivRing1c
END

IF ~~ THEN BEGIN NethrinGivesDivRing1b
SAY ~Yasraena! Then she is alive? I feared the worst when she did not return from Irenicus' dungeon.~
 ++ ~She is well, but she will not remain so for long if you do not give me Divalir's ring.~ GOTO NethrinGivesDivRing1d
 ++ ~Enough chit chat. Give me the ring and no one gets hurt!~ GOTO NethrinGivesDivRing1c
END

IF ~~ THEN BEGIN NethrinGivesDivRing1c
SAY ~What do you mean? Is she in danger?~
 ++ ~Yes. She has been accused of Divalir's murder, and she instructed me to get his ring from you to prove her innocence.~ GOTO NethrinGivesDivRing1e
 ++ ~Yes, and if you don't give me Divalir's ring, she is going to die!~ GOTO NethrinGivesDivRing1e
END

IF ~~ THEN BEGIN NethrinGivesDivRing1d
SAY ~What? Why do you need Divalir's ring? Is Yasraena in danger?~
 ++ ~Yes. She has been accused of Divalir's murder, and she instructed me to get his ring from you to prove her innocence.~ GOTO NethrinGivesDivRing1e
 ++ ~Yes, and if you don't give me Divalir's ring, she is going to die!~ GOTO NethrinGivesDivRing1e
END

IF ~~ THEN BEGIN NethrinGivesDivRing1e
SAY ~Then by all means take the ring. If it will save her life, then I freely give it to you. I will return to Suldanessellar to plead for her.~
IF ~~ THEN DO ~AddJournalEntry(@5018,QUEST)SetGlobal("GiveDivRing","GLOBAL",1)AddexperienceParty(10000)~ EXIT
END

IF ~~ THEN BEGIN NethrinGivesDivRing2a
SAY ~I am staying here in this inn. Is there anything wrong with this?~
++ ~No, of course not. Are you Nethrin?~ GOTO NethrinGivesDivRing1a
++ ~I don't know. It's not my business. But Yasraena *is* my business, and she needs your help!~ GOTO NethrinGivesDivRing1b
++ ~Enough talk. Give me the ring, and no one gets hurt!~ GOTO NethrinGivesDivRing1c
END

IF ~~ THEN BEGIN NethrinGivesDivRing3a
SAY ~Who are you? What do you know of Divalir?!~
++ ~I've never met Divalir, but I know that Yasraena will be executed for his murder if you don't give me that ring!~ GOTO NethrinGivesDivRing3b
++ ~I know that Yasraena stands accused of his murder, and she instructed me to get his ring from you to prove her innocence.~ GOTO NethrinGivesDivRing1e
END

IF ~~ THEN BEGIN NethrinGivesDivRing3b
SAY ~Executed? That must not be. By all means take the ring. If it will save her life, then I freely give it to you. I will return to Suldanessellar to plead for her.~
IF ~~ THEN DO ~AddJournalEntry(@5018,QUEST)SetGlobal("GiveDivRing","GLOBAL",1)AddexperienceParty(10000)~ EXIT
END
