BEGIN YASRAENP



IF ~Global("YasraenaRescued","GLOBAL",1)
Global("YasraenaJoined","GLOBAL",1)
!Global("YasraenaArrested","GLOBAL",0)~ THEN BEGIN WelcomeBackYasraena
SAY ~Thank you for this, <CHARNAME>. You have saved me, and you have saved Divalir! Shall we continue together?~ [YASRA131]
 ++ ~Yes, let's go.~ GOTO WelcomeBackYasraena1a
 ++ ~No, we should go our separate ways.~ GOTO WelcomeBackYasraena2a
END

IF ~~ THEN BEGIN WelcomeBackYasraena1a
SAY ~Very well.~
IF ~~ THEN DO
~SetGlobal("YasraenaRescued","GLOBAL",2)
EraseJournalEntry(@5015)
EraseJournalEntry(@5018)
AddexperienceParty(20000)
JoinParty()~ SOLVED_JOURNAL @5020
EXIT
END

IF ~~ THEN BEGIN WelcomeBackYasraena2a
SAY ~I see. I must then continue my search for Divalir alone.~
IF ~~ THEN DO ~SetGlobal("YasraenaJoined","GLOBAL",0)
EraseJournalEntry(@5015)
EraseJournalEntry(@5018)
EscapeArea()~ SOLVED_JOURNAL @5021
EXIT
END



IF ~Global("YasraenaTeleport","GLOBAL",3)
Global("YasraenaJoined","GLOBAL",1)~ THEN BEGIN YSMeetAfterElhan
SAY ~I have successfully avoided detection by the Suldanessellar Elves.~
=
~It pains me to stoop to such subterfuge, but it is necessary.~
=
~Shall we continue together, <CHARNAME>?~
 ++ ~Yes, welcome back.~ GOTO YSMeetAfterElhan1
 ++ ~I'm sorry, Yasraena, but I do not require your services any longer.~ GOTO YSMeetAfterElhan2
END

IF ~~ THEN BEGIN YSMeetAfterElhan1
 SAY ~Very well.~
 IF ~~ THEN DO ~SetGlobal("YasraenaTeleport","GLOBAL",4)JoinParty()~
EXIT
END

IF ~~ THEN BEGIN YSMeetAfterElhan2
 SAY ~I understand. Thank you again for your aid, and may your journeys be safe.~
 IF ~~ THEN DO ~EscapeArea()~
EXIT
END



IF ~HappinessLT(Myself,-190)~ YasraenaSplits
SAY ~Divalir awaits, and I sully myself with you? No longer!~ [YASRA132]
IF ~~ DO ~LeaveParty() EscapeArea()~ EXIT
END



IF ~Global("YasraenaJoined","GLOBAL",1)~ THEN BEGIN YasraenaBoot
  SAY ~We must part company then?~ [YASRA133]
  ++ ~No, please don't go anywhere.~ DO ~JoinParty()~ EXIT
  ++ ~Yes, for now. Will you wait here?~ GOTO YasraenaBoot1a
  ++ ~I can travel no longer with a drow. It is too dangerous.~ GOTO YasraenaBoot2a
END

IF ~~ THEN BEGIN YasraenaBoot1a
  SAY ~I cannot. It is too dangerous for a drow to stand thus exposed.~
  =
  ~Divalir awaits, and I go to him. Fare you well.~
  IF ~~ THEN DO ~SetGlobal("YasraenaJoined","GLOBAL",0)EscapeArea()~
EXIT
END

IF ~~ THEN BEGIN YasraenaBoot2a
  SAY ~I understand. Thank you for what you have done for me. Divalir awaits, and I go to him now.~
  IF ~~ THEN DO ~SetGlobal("YasraenaJoined","GLOBAL",0)EscapeArea()~
EXIT
END
