BEGIN WILLYBJ



IF ~Global("WBMockWillie","GLOBAL",10)~ THEN BEGIN WilliePubQuest
SAY ~Faack's sake, <CHARNAME>! Can you believe some ponce wants ta shut down the pub?~
++ ~Come on, Willie. We haven't the time for this.~ DO ~SetGlobal("WBMockWillie","GLOBAL",11)~ GOTO WilliePubQuest1
++ ~What was that all about?~ DO ~SetGlobal("WBMockWillie","GLOBAL",11)~ GOTO WilliePubQuest1
++ ~You seem a bit forlorn, Willie.~ DO ~SetGlobal("WBMockWillie","GLOBAL",11)~ GOTO WilliePubQuest1
END

IF ~~ THEN BEGIN WilliePubQuest1
SAY ~...he hates pubs...~
++ ~Who exactly, Willie?~ GOTO WilliePubQuest2
++ ~So do I! Pubs are wretched hives of scum and villainy!~ GOTO WilliePubQuest3
++ ~Yeah, I know.~ GOTO WilliePubQuest4
END

IF ~~ THEN BEGIN WilliePubQuest2
SAY ~That Rupert ponce, whoever he is! We gotta sort him out!~
++ ~Details, Willie! Where is he?~ GOTO WilliePubQuest5
++ ~In due course, Willie. We've got other things to attend to first.~ GOTO WilliePubQuest6
++ ~Sorry, Willie, but a pub being shut down is not my concern.~ GOTO WilliePubQuest7
IF ~GlobalLT("Chapter","GLOBAL",4)~ THEN REPLY ~Certainly! This is clearly *far* more important than rescuing Imoen.~ GOTO WilliePubQuest8
END

IF ~~ THEN BEGIN WilliePubQuest3
SAY ~Ah! This is worse than me birthday!~
IF ~~ THEN DO ~GivePartyAllEquipment()EquipMostDamagingMelee()LeaveParty()Enemy()Attack(LastSeenBy())~ EXIT
END

IF ~~ THEN BEGIN WilliePubQuest4
SAY ~Well, then, let's sort out this pub-hating la-di-da!~
++ ~Details, Willie! Where is he?~ GOTO WilliePubQuest5
++ ~In due course, Willie. We've got other things to attend to first.~ GOTO WilliePubQuest6
++ ~Sorry, Willie, but a pub being shut down is not my concern.~ GOTO WilliePubQuest7
IF ~GlobalLT("Chapter","GLOBAL",4)~ THEN REPLY ~Certainly! This is clearly *far* more important than rescuing Imoen.~ GOTO WilliePubQuest8
END

IF ~~ THEN BEGIN WilliePubQuest5
SAY ~Erm, he's somefin ta do with some Sarles bloke. Let's look him up.~
++ ~All right, Willie. We'll look him up, but don't get impatient.~ GOTO WilliePubQuest6
++ ~In due course, Willie. We've got other things to attend to first.~ GOTO WilliePubQuest6
++ ~Sorry, Willie, but a pub being shut down is not my concern.~ GOTO WilliePubQuest7
IF ~GlobalLT("Chapter","GLOBAL",4)~ THEN REPLY ~Certainly! This is clearly *far* more important than rescuing Imoen.~ GOTO WilliePubQuest8
END

IF ~~ THEN BEGIN WilliePubQuest6
SAY ~Sure thing, mate.~
IF ~~ THEN DO ~AddJournalEntry(@5003,QUEST)~ EXIT
END

IF ~~ THEN BEGIN WilliePubQuest7
SAY ~Well, sod ya then! Yer no mate a' mine!~
IF ~~ THEN DO ~GivePartyAllEquipment()LeaveParty()EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN WilliePubQuest8
SAY ~Yeah, we'll deal with that slag later, init.~
++ ~That was sarcasm, Willie. Translation: your pub quest means nothing to me next to rescuing Imoen.~ GOTO WilliePubQuest7
++ ~All right, Willie. We'll look this Rupert up, but don't get impatient.~ GOTO WilliePubQuest6
++ ~In due course, Willie, we'll deal with this. But right now, we've got other things to attend to.~ GOTO WilliePubQuest6
END



IF ~Global("WBMockWillie","GLOBAL",7)~ THEN BEGIN WBWillyChain
SAY ~Good ol' Rover.  The most well 'ard mutt in these parts.~
IF ~~ THEN DO ~SetGlobal("WBMockWillie","GLOBAL",8)
EraseJournalEntry(@5000)EraseJournalEntry(@5001)~ SOLVED_JOURNAL @5002
EXIT
END



IF ~Global("WBRunAwayComment","GLOBAL",1)~ THEN BEGIN WBRunAwayComment
SAY ~So it was chavs wot done it! How dare they interfere with me ol'mum. As luck would have it, chavs can be counted on for one thing: they never stray far from where their mums spat 'em out.~
++ ~It's still a big city, mate. Can you narrow it down at all?~ DO ~SetGlobal("WBRunAwayComment","GLOBAL",2)~ GOTO WBRunAwayComment1
++ ~I'm not really following all of this, Willie.~ DO ~SetGlobal("WBRunAwayComment","GLOBAL",2)~ GOTO WBRunAwayComment1
END

IF ~~ THEN BEGIN WBRunAwayComment1
SAY ~Well, we'd do well to keep our eyes peeled round about really cheap inns or the dole office.~
IF ~~ THEN DO ~AddJournalEntry(@5001,QUEST)~ EXIT
END



IF ~Global("WBMumSpawns","GLOBAL",5)~ THEN BEGIN WBMumExplanation
SAY ~That was me ol' mum, <CHARNAME>.~
++ ~What was that all about, Willie?~ DO ~SetGlobal("WBMumSpawns","GLOBAL",6)~ GOTO WBMumExplanation1
++ ~I see speaking gibberish runs in the family.~ DO ~SetGlobal("WBMumSpawns","GLOBAL",6)~ GOTO WBMumExplanation1
END

IF ~~ THEN BEGIN WBMumExplanation1
SAY ~Okay, let me spell it out for ya: my pride and joy 'as been robbed by some rat-bag. Lucky for 'im that 'e didn't 'urt me dear ol' mum in the process.~
IF ~~ THEN DO ~AddJournalEntry(@5000,QUEST)~ EXIT
END



IF ~Global("WillieBruceSpellhold","GLOBAL",1)~ THEN BEGIN WillieBruceSpellhold
SAY ~We gonna find this Irenicus slag in here or what?~ [WILLY065]
IF ~~ THEN DO ~SetGlobal("WillieBruceSpellhold","GLOBAL",2)~
EXIT
END



IF ~Global("WillieBruceUnderdark","GLOBAL",1)~ THEN BEGIN WillieBruceUnderdark
SAY ~Faackin 'ell! I can't see a bloody fing dahn 'ere!~ [WILLY066]
IF ~~ THEN DO ~SetGlobal("WillieBruceUnderdark","GLOBAL",2)~
EXIT
END



IF ~IsGabber(Player1)
CombatCounter(0)~ THEN BEGIN WillieBruceChatsSOA
SAY ~(Willie Bruce is drinking again.)~
++ ~There's something wrong with you, Willie Bruce.~ + WBChatFixerSOA
END

IF ~~ THEN BEGIN WBChatFixerSOA
 SAY ~Faack me! So there is!~ [WILLY067]
 IF ~~ THEN DO ~StartCutScene("WBFIX")~ EXIT
END



CHAIN
IF ~Global("WBRUPERTRuns","GLOBAL",2)~ THEN WILLYBJ WBRupertShowdown
~Oi, mate! I wasn't finished when you legged it earlier!~
DO ~SetGlobal("WBRUPERTRuns","GLOBAL",3)~
== WBRUPERT
~You are on *my* property now! Do you mind escorting yourself away from me? Your stench is quite overwhelming.~
== WILLYBJ
~Let's just 'ave a couple a' pints and sort this out civil-like.~
== WBTYSON
~Yo, Jordan! Check dis! He's got a new bumchum wif a black blouse and makeup.~
== WBJORDAN
~Yeah, but no, but... gissa fag, mate!~
== WBRUPERT
~If tobacco will get you gone from my sight, then, here: take one!~
== WBTYSON
~Keep it livid! Giss one, too!~
== WBRUPERT
~Very well! Now begone, urchins!~
END
++ ~That's disgraceful, giving tobacco to children! Sort him out, Willie!~ GOTO WBRupertShowdown1
++ ~May cancer descend swiftly and mercilessly upon you all!!~ GOTO WBRupertShowdown2
++ ~Now, Rupert, will you please talk to Willie about this pub-closing nonsense to put an end to his whining.~ GOTO WBRupertShowdown3

CHAIN WILLYBJ WBRupertShowdown1
~Luvly jubly, y've had this coming to ya, mate!~
== WBRUPERT
~Very well! I will enjoy ridding the earth of the surplus population!~
DO ~SetGlobal("WBRUPERTRuns","GLOBAL",4)SetGlobal("WBRupertKicksAss","GLOBAL",1)
EraseJournalEntry(@5006)
EraseJournalEntry(@5003)
AddJournalEntry(@5005,QUEST_DONE)ClearAllActions()StartCutSceneMode()StartCutScene("WBRUP")~
EXIT

CHAIN WILLYBJ WBRupertShowdown2
~Oooh, that's a bit much...~
== WBRUPERT
~*You* stay out of this, cretin!~
== WILLYBJ
~*You* stay outta my pub!~
== WBRUPERT
~Enough of this! I legally own this building, and it's time to teach you inferiors a lesson!~
DO ~SetGlobal("WBRUPERTRuns","GLOBAL",4)SetGlobal("WBRupertKicksAss","GLOBAL",1)
EraseJournalEntry(@5006)
EraseJournalEntry(@5003)
AddJournalEntry(@5005,QUEST_DONE)ClearAllActions()StartCutSceneMode()StartCutScene("WBRUP")~
EXIT

CHAIN WILLYBJ WBRupertShowdown3
~Futures, <CHARNAME>! Let's sort this out!~
== WBRUPERT
~What possible enticement could you give me to keep me from shutting down this rathole pub?~
== WILLYBJ
~Well, my mum would be proper grateful...~
== WBRUPERT
~*How* grateful?~
== WILLYBJ
~How's about 10 sessions?~
== WBRUPERT
~Mmmm, 10 sessions? I don't know... does your mum do bagpiping?~
== WILLYBJ
~I'm sure she wouldn't mind. And she's got luvly, flabby bingo wings.~
== WBRUPERT
~Oooh, 10 sessions with your flabby mum... mmm, I must confess that it is tempting.~
== WILLYBJ
~You don't seem convinced. I might be able to twist her arm and 'ave her bring along Aunt Mabel as well.~
== WBRUPERT
~Well... I guess that would be acceptable. I've always fancied "a bit a' rough" with an older lady.~ DO ~EscapeArea()~
== WILLYBJ
~Fine. It's a done deal. (Willie whirls on you.) Let's get outta here!~
END
++ ~What was that all about, Willie?~ DO ~SetGlobal("WBRUPERTRuns","GLOBAL",4)~ GOTO WBRupertShowdown4
++ ~I'm just going to pretend that I didn't hear that conversation.~ DO ~SetGlobal("WBRUPERTRuns","GLOBAL",4)~ GOTO WBRupertShowdown4
++ ~Well, since you're already passing your mum around...~ DO ~SetGlobal("WBRUPERTRuns","GLOBAL",4)~ GOTO WBRupertShowdown5

CHAIN WILLYBJ WBRupertShowdown4
~Nevermind, <CHARNAME>. Problem solved. Let's go.~
DO ~AddexperienceParty(25000)
EraseJournalEntry(@5006)
EraseJournalEntry(@5003)
AddJournalEntry(@5004,QUEST_DONE)~
== WBTYSON
~Yo, Jordan, whas bagpipin'?~ DO ~EscapeArea()~
== WBJORDAN
~No, but... Shut up! I don't know nuthin'.~ DO ~EscapeArea()~
EXIT

CHAIN WILLYBJ WBRupertShowdown5
~Shut it! SHUT it! SHUT IT!~
DO ~AddexperienceParty(25000)
EraseJournalEntry(@5006)
EraseJournalEntry(@5003)
AddJournalEntry(@5004,QUEST_DONE)~
== WBJORDAN
~Oooiiieeee, that's well sick, innit?~ DO ~EscapeArea()~
== WBTYSON
~Yeah, his mum is well mingin'!~ DO ~EscapeArea()~
EXIT



INTERJECT PLAYER1 33 WillieBruceTreeofLife
== PLAYER1 IF ~InParty("WillyB")~ THEN
~(Willie Bruce couldn't give a damn if Irenicus lived or died, but since he's already here, he looks fairly keen.)~
END
++ ~Willie. You want to do this thing, or what?~ EXTERN WILLYBJ WillieBruceTreeofLife1

APPEND WILLYBJ
IF ~~ THEN BEGIN WillieBruceTreeofLife1
SAY ~Sure fing. Let's make it quick. I need to go to the bog.~ [WILLY068] COPY_TRANS PLAYER1 33
END
END



INTERJECT PLAYER1 5 WillieBruceSlayer
== PLAYER1 IF ~InParty("WillyB")~ THEN
~Faaack me! Y' scarier than me muva-in-law!~ [WILLY069]
END
++ ~This is no time for jests, Willie!~ EXTERN WILLYBJ WillieBruceSlayer1
++ ~That you're comparing me to her makes me *not* want to meet her, despite my power.~ EXTERN WILLYBJ WillieBruceSlayer2
++ ~Keep it up, Willie, and I'll show you "scary".~ EXTERN WILLYBJ WillieBruceSlayer3

APPEND WILLYBJ
IF ~~ THEN BEGIN WillieBruceSlayer1
SAY ~I wasn't jokin'. Me muva-in-law's a rite ol' slag!~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN WillieBruceSlayer2
SAY ~Indeed.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN WillieBruceSlayer3
SAY ~Easy geeza.~
IF ~~ THEN EXIT
END
END



INTERJECT_COPY_TRANS HellJon 7 WillieBruceHellJon1
== WILLYBJ IF ~InParty("WillyB")~ THEN
~If y' know what's good f' ya, y'll stay dahn, mate.~ [WILLY070]
END



INTERJECT_COPY_TRANS HellJon 10 WillieBruceHellJon2
== WILLYBJ IF ~InParty("WillyB")~ THEN
~If y' know what's good f' ya, y'll stay dahn, mate.~ [WILLY070]
END



INTERJECT_COPY_TRANS HellJon 9 WillieBruceHellJon3
== WILLYBJ IF ~InParty("WillyB")~ THEN
~If y' know what's good f' ya, y'll stay dahn, mate.~ [WILLY070]
END



INTERJECT_COPY_TRANS HellJon 8 WillieBruceHellJon4
== WILLYBJ IF ~InParty("WillyB")~ THEN
~If y' know what's good f' ya, y'll stay dahn, mate.~ [WILLY070]
END



INTERJECT_COPY_TRANS PLAYER1 25 WillieBruceInHell
== WILLYBJ IF ~InParty("WillyB")~ THEN
~Faack me! It stinks of Pakis down 'ere!~ [WILLY071]
END



INTERJECT TRGYP02 2 WillieBrucePikeys
== TRGYP02 IF ~!InPartySlot(LastTalkedToBy,0)
Name("WillyB",LastTalkedToBy)~ THEN
~You do not need a fortune teller. You live in a cloud of enebriation, and that bottle in your hand will soon be the death of you.~
DO ~SetGlobal("UselessGlobal","LOCALS",1)~ EXTERN WILLYBJ WillieBrucePikeys1

APPEND WILLYBJ
IF ~~ THEN BEGIN WillieBrucePikeys1
SAY ~Betta ta live shit-faced than to die sober, luv.~
IF ~~ THEN DO ~SetGlobal("UselessGlobal","LOCALS",1)~
EXTERN TRGYP02 WillieBrucePikeys2
END
END

APPEND TRGYP02
IF ~~ THEN BEGIN WillieBrucePikeys2
SAY ~Telling one's fortune rarely causes one to alter one's path.  I see that you are resolute and ready to die in your addiction. On your way, then.~
IF ~~ THEN DO ~SetGlobal("UselessGlobal","LOCALS",1)~ EXTERN WILLYBJ WillieBrucePikeys3
END
END

APPEND WILLYBJ
IF ~~ THEN BEGIN WillieBrucePikeys3
SAY ~Wot a load of old bollocks.  I fuckin' hate pikeys!~
IF ~~ THEN EXIT
END
END
