APPEND CROBAR01
IF WEIGHT #-1 ~InParty("WillyB")Global("WBMockWillie","GLOBAL",11)~ THEN BEGIN CroBarSuccess
SAY ~Well, what have you found out about Rupert?~
++ ~Nothing yet.~ GOTO CroBarSuccess1
++ ~Nothing. We just want a room.~ GOTO CroBarSuccess2
END

IF ~~ THEN BEGIN CroBarSuccess1
SAY ~Well, I'm not sure if this is the best course of action, but Willie seems determined.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN CroBarSuccess2
SAY ~Not the fanciest lodging, but I'll lay a blanket in the stables for you if you need. It's more comfortable than it sounds.~
++ ~That will be fine if I stay. Let me see what else you've got first.~ GOTO CroBarSuccess3
++ ~No thank you. Some other time.~ GOTO CroBarSuccess4
END

IF ~~ THEN BEGIN CroBarSuccess3
SAY ~Sure thing.~
IF ~~ THEN DO ~StartStore("crobar01",LastTalkedToBy())~ EXIT
END

IF ~~ THEN BEGIN CroBarSuccess4
SAY ~Suit yourself. The door is always open if need be.~
IF ~~ THEN EXIT
END
END



CHAIN
IF WEIGHT #-1 ~InParty("WillyB")Global("WBMockWillie","GLOBAL",8)~ THEN CROBAR01 WillieLandlord
~Willie! You haven't been in here for a while. Got bad news, I'm afraid.~
== WILLYBJ
~What, did Terry try and nick the leg o' time again?~
== CROBAR01
~No, no. He left it behind the bar, just like you told him to. But I'm afraid it looks like we're going to be shut down.~
== WILLYBJ
~Ya havin' a laugh?~
== CROBAR01
~No, Willie! The fact is, this is a really crap inn, and we don't exactly make a lot of money.~
=
~Some rich fellow has made quite a generous offer for the property.~
== WILLYBJ
~But we can't leave the gate district with no place to get shit-faced in!~
== CROBAR01
~Well, apart from that, I'm getting old and can't be running this place anymore. As you know, the wife left me because I couldn't sow my seeds, so there's no one to take over.~
== WILLYBJ
~'old on! Y' mean to say the new landlord ain't gonna stay open?~
== CROBAR01
~No, Willie. I'm afraid not.~
== WILLYBJ
~But why?!~
== CROBAR01
~Actually, Willie, he hates pubs.~
== WILLYBJ
~(Shocked silence.)~
== CROBAR01
~Um, Willie?~
== WILLYBJ
~(Shocked silence.)~
== CROBAR01
~Willie? Willie!~
== WILLYBJ
~Do you know what "nemesis" means?!~
== CROBAR01
~I can't rightly say I do.~
== WILLYBJ
~I'm not much sure either, but I've always wanted to say that, and it seems 'bout right. Anyway, who is this bloke?~
== CROBAR01
~His name's Rupert. He's a rather successful artist or somesuch. He's often hanging around the high-ups in the Government District.~
=
~I think he mentioned someone by the name of Sarles.~
== WILLYBJ
~Well, I ain't gonna let this lie! I'll sort that pub-hating ponce out!~
== CROBAR01
~Well, thanks Willie, but I *do* need to make a living.~
== WILLYBJ
~Don't worry geeza! You'll not go without.~
DO ~SetGlobal("WBMockWillie","GLOBAL",9)~
EXIT
