BEGIN KINDREK



IF ~Global("KKButcherRejection","LOCALS",1)~ THEN BEGIN KKButcherRejection
SAY ~What? Oh, I see, a little butchery will now serve your turn? You hypocrite!~
++ ~What? Call me a hypocrite! Taste my wrath!~ GOTO KKButcherRejection1
++ ~Just shut up and get in the group.~ GOTO KKButcherRejection2
++ ~Look, sometimes principles must be compromised. You coming along or what?~ GOTO KKButcherRejection3
++ ~I have no need of you. Begone!~ GOTO KKButcherRejection4
++ ~Can you wait a little while longer?~ GOTO KKButcherRejection5
END

IF ~~ THEN BEGIN KKButcherRejection1
SAY ~How I have longed to dash your brains among the filth of these streets!~
IF ~~ THEN DO ~Enemy()EquipMostDamagingMelee()Attack(LastSeenBy())~
EXIT
END

IF ~~ THEN BEGIN KKButcherRejection2
SAY ~I will suffer no disrespect! I go for now, but mind your tongue, <CHARNAME>.~
IF ~~ THEN DO ~SetGlobal("KindrekJoined","LOCALS",1)JoinParty()~
EXIT
END

IF ~~ THEN BEGIN KKButcherRejection3
SAY ~Hah! You weak-willed fool! I will have no part in the quest of an indecisive, compromising child who cannot even cling to his own dear principles!~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN KKButcherRejection4
SAY ~With pleasure!~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN KKButcherRejection5
SAY ~For a while, but do not tarry long!~
IF ~~ THEN DO ~SetGlobal("KKButcherRejection","LOCALS",2)SetGlobal("KKNiceRejection","LOCALS",1)~ EXIT
END



IF ~NumTimesTalkedTo(0)~ THEN BEGIN KindrekMeet
 SAY ~Greetings. I am Kindrek. I see you are a group armed for battle. Do you do a lot of killing?~  [KINDR045]
 ++ ~Yes. We go to meet our trouble.~ GOTO KindrekMeet1a
 ++ ~Who are you accosting us in the city gate?~ GOTO KindrekMeet2a
 ++ ~That is none of your affair.~ GOTO KindrekMeet3a
 ++ ~Greetings, I am <CHARNAME>. We fight only when we must.~ GOTO KindrekMeet4a
 ++ ~Greetings, I am <CHARNAME>. We revel in the shedding of blood.~ GOTO KindrekMeet5a
END

IF ~~ THEN BEGIN KindrekMeet1a
 SAY ~The fashion of the world is to avoid cost, and you encounter it. I am looking for a band with which to travel. My halberd, Disruptor, has split many skulls and has spilled rivers of blood! Will you have me?~
 ++ ~Sure. Come aboard! We could use another eager blade!~ GOTO KindrekMeet1b
 ++ ~Wait. First I have some questions.~ GOTO KindrekMeet1c
 ++ ~No, I have no need of a savage butcher such as yourself.~ GOTO KindrekMeet1d
END

IF ~~ THEN BEGIN KindrekMeet1b
 SAY ~Excellent! And now let us see what this new world has for us! And let wizards tremble at our approach!~
 IF ~~ THEN DO ~SetGlobal("KindrekJoined","LOCALS",1)JoinParty()~
EXIT
END

IF ~~ THEN BEGIN KindrekMeet1c
 SAY ~Ask, and I will not refuse to answer.~
 ++ ~What are you? You have a dwarf's build, yet you are taller than any man.~ GOTO KindrekMeet1e
 ++ ~Why are you here? You are of no race I have ever encountered before.~ GOTO KindrekMeet1e
 ++ ~Why do you delight in killing?~ GOTO KindrekMeet1e
END

IF ~~ THEN BEGIN KindrekMeet1d
 SAY ~Your loss, fools! You will learn in time that *butchery* will serve your turn.~
 IF ~~ THEN DO ~SetGlobal("KKButcherRejection","LOCALS",1)~ EXIT
END

IF ~~ THEN BEGIN KindrekMeet1e
 SAY ~I am a Rahk! The origin of my race is a mystery. Some say we have both dwarf and human blood, while others think we were cross-bred with giants.~
=
 ~Whatever the case, we do not care. We live only to destroy magic and those who wield it!~
 ++ ~You destroy magic?~ GOTO KindrekMeet1f
 ++ ~Well, but why are you here?~ GOTO KindrekMeet1f
 ++ ~Isn't a Roc a giant bird?~ GOTO KindrekMeet1g
END

IF ~~ THEN BEGIN KindrekMeet1f
 SAY ~You are no wizard, so there is nothing to fear! I require guides and friends in this strange land, so if you have me, you may rest assured that I will restrain myself from slaying any of your spellcasting companions.~
=
 ~The guards call this place Athkatla, but it is unknown to me. I was in the middle of killing a particularly wily wizard when I was sent here.~
=
 ~I can only guess it was accomplished by his magic. But fear not! I will have my revenge on Prenash!~
 ++ ~Prenash?~ GOTO KindrekMeet1h
 ++ ~You may travel with me. I need a wizard-slayer.~ GOTO KindrekMeet1b
END

IF ~~ THEN BEGIN KindrekMeet1g
 SAY ~????? Perhaps they are homonymns!~
 ++ ~Forget it. Whatever name you give your race, you are strange.~ GOTO KindrekMeet1i
 ++ ~I have no time to speak with one who is slow of speech.~ GOTO KindrekMeet1j
END

IF ~~ THEN BEGIN KindrekMeet1h
 SAY ~I hunt down wizards and slay them! They are anathema to me, and I glory in spilling their blood, in showing them that they cannot hide behind their pitiful magicks!~
=
 ~I had become so feared that cities trembled at my approach.~
=
 ~I had bathed in the blood of countless wizards, so they sent Prenash and his minions to eliminate me.~
 ++ ~Who sent Prenash?~ GOTO KindrekMeet1k
 ++ ~You are a fiend! I should strike you down here for your crimes!~ GOTO KindrekMeet1j
 ++ ~You despicable wretch! I will not speak with a murderer!~ GOTO KindrekMeet1d
 ++ ~Bathing in blood sounds nice. I could use someone like you!~ GOTO KindrekMeet1b
 ++ ~Continue with your tale. I would hear more.~ GOTO KindrekMeet1n
END

IF ~~ THEN BEGIN KindrekMeet1i
 SAY ~And in a strange land. Regardless, I require aid, and you are one of few who will even speak with me. You do not fear my scarred visage, my unkempt matted hair, nor the murderous lust glowing in my eyes! Will you have me?~
 ++ ~Sure. Come aboard! We could use another eager blade!~ GOTO KindrekMeet1b
 ++ ~Wait. First I have some questions.~ GOTO KindrekMeet1c
 ++ ~No, I have no need of a savage butcher such as yourself.~ GOTO KindrekMeet1d
END

IF ~~ THEN BEGIN KindrekMeet1j
 SAY ~The few who had the gall to speak to me in that way now lie in their graves! Soon you will join them!~
 IF ~~ THEN DO ~Enemy()EquipMostDamagingMelee()Attack(LastSeenBy())~
EXIT
END

IF ~~ THEN BEGIN KindrekMeet1k
 SAY ~All who had something to lose and everything to gain by my death gave Prenash the soldiers he needed to track me down and destroy me.~
=
 ~But I did not run. I did not hide. Prenash would fall by my halberd. I sought him and found him, and as my hands wrapped round his throat, as the neckbone cracked and was beginning to give way under the strength of my grip, I was overwhelmed by brilliant light. All sensation fell away, and then I found myself here.~
=
 ~I was awoken by the city guard. They said something to the effect of, *I am here to keep order.*~
 ++ ~You are skilled in battling wizards, then?~ GOTO KindrekMeet1l
END

IF ~~ THEN BEGIN KindrekMeet1l
 SAY ~I am.~
 ++ ~Then join me. I will give you many chances to hunt.~ GOTO KindrekMeet1b
 ++ ~It is a shame I have no room for you now. I might take you in later. Will you wait?~ GOTO KindrekMeet1m
END

IF ~~ THEN BEGIN KindrekMeet1m
 SAY ~For a while, I can wait!~
 IF ~~ THEN DO ~SetGlobal("KKNiceRejection","LOCALS",1)~ EXIT
END

IF ~~ THEN BEGIN KindrekMeet1n
SAY ~There is little beyond this! Due to ineptitude of the wizard I was fighting, I was somehow transported here. Will you have me?~
 ++ ~Sure. Come aboard! We could use another eager blade!~ GOTO KindrekMeet1b
 ++ ~Wait. First I have some more questions.~ GOTO KindrekMeet1c
 ++ ~No, I have no need of a savage butcher such as yourself.~ GOTO KindrekMeet1d
END

IF ~~ THEN BEGIN KindrekMeet2a
 SAY ~Because I require a band with which to travel. My halberd, Disruptor, has split many skulls and has spilled rivers of blood! Will you have me?~
 ++ ~Sure. Come aboard! We could use another eager blade!~ GOTO KindrekMeet1b
 ++ ~Wait. First I have some questions.~ GOTO KindrekMeet1c
 ++ ~No, I have no need of a savage butcher such as yourself.~ GOTO KindrekMeet1d
END

IF ~~ THEN BEGIN KindrekMeet3a
 SAY ~No wizard leads this group. That is why I speak to you.~
 ++ ~Step aside. I cannot be delayed.~ GOTO KindrekMeet3b
 ++ ~Strange. Why do you fear wizards?~ GOTO KindrekMeet3c
END

IF ~~ THEN BEGIN KindrekMeet3b
 SAY ~Fare you well, then.~
 IF ~~ THEN DO ~SetGlobal("KKNiceRejection","LOCALS",1)~ EXIT
END

IF ~~ THEN BEGIN KindrekMeet3c
 SAY ~I did not say I fear them. I simply said this group is under the command of one who is not a wizard. I loathe wizards and will not speak to one. Indeed, it is best that he keeps clear of me if he values his life!~
 ++ ~So you hate wizards. What does this have to do with me?~ GOTO KindrekMeet1f
 ++ ~Move aside! I cannot waste any more time speaking with one as close-minded as you.~ GOTO KindrekMeet1j
END

IF ~~ THEN BEGIN KindrekMeet4a
 SAY ~A safe answer! I fight even when I shouldn't!~
=
 ~I am looking for a band with which to travel. My halberd, Disruptor, has split many skulls and has spilled rivers of blood! Will you have me?~
 ++ ~Sure. Come aboard! We could use another eager blade!~ GOTO KindrekMeet1b
 ++ ~Wait. First I have some questions.~ GOTO KindrekMeet1c
 ++ ~No, I have no need of a savage butcher such as yourself.~ GOTO KindrekMeet1d
END

IF ~~ THEN BEGIN KindrekMeet5a
 SAY ~Excellent! A good answer. Perhaps I have found the ones I have been looking for.~
=
 ~I am looking for a band with which to travel. My halberd, Disruptor, has split many skulls and has spilled rivers of blood! Will you have me?~
 ++ ~Sure. Come aboard! We could use another eager blade!~ GOTO KindrekMeet1b
 ++ ~Wait. First I have some questions.~ GOTO KindrekMeet1c
 ++ ~No, I have no need of a savage butcher such as yourself.~ GOTO KindrekMeet1d
END



IF ~Global("KKNiceRejection","LOCALS",1)~ THEN BEGIN KKNiceRejection
SAY ~What is it? Do you now wish to profit from my wizard-slaying skills?~
++ ~Yes, come along.~ GOTO KKNiceRejection1
++ ~No, not at the moment.~ GOTO KKNiceRejection2
++ ~I will never let you join my group!~ GOTO KKNiceRejection3
END

IF ~~ THEN BEGIN KKNiceRejection1
SAY ~Excellent! Let us hunt some spellcasters!~
IF ~~ THEN DO ~SetGlobal("KindrekJoined","LOCALS",1)JoinParty()~
EXIT
END

IF ~~ THEN BEGIN KKNiceRejection2
SAY ~Then do not bother me!~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KKNiceRejection3
SAY ~You fool! You will be crying my name when you come face to face with a demilich!~
=
~Nevermore shall you see Kindrek!~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END
