BEGIN BKINDR25



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
OR (5)
Global("KKLeaveOverEdwinTOB","LOCALS",1)
Global("KKLeaveOverTsujathaTOB","LOCALS",1)
Global("KKLeaveOverTashiaTOB","LOCALS",1)
Global("KKLeaveOverZaiyaTOB","LOCALS",1)
Global("KKLeaveOverKelseyTOB","LOCALS",1)~ THEN BEGIN KindrekLeaveOverWizardTOB
SAY ~<CHARNAME>! You have taken a wizard into our group! You will pay for disrespecting me!~  [KINDR053]
IF ~~ THEN DO ~LeaveParty()Enemy()EquipMostDamagingMelee()Attack(LastSeenBy())~ EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Global("KKLeaveOverIrenicusTOB","LOCALS",1)~ THEN BEGIN KindrekLeaveOverIrenicusTOB
SAY ~<CHARNAME>! You have taken Irenicus, your chief enemy, into our group! You will pay for disrespecting me with this insult!~  [KINDR054]
IF ~~ THEN DO ~LeaveParty()Enemy()EquipMostDamagingMelee()Attack(LastSeenBy())~ EXIT
END



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("AerieKindrekTOB","GLOBAL",0)~ THEN BAERIE25 KKAerieWicked
~You are a wicked man, Kindrek.~
DO ~SetGlobal("AerieKindrekTOB","GLOBAL",1)~
== BKINDR25
~I am no man. I am a Rahk! But, yes, I am wicked!~  [KINDR095]
== BAERIE25
~Have you no shame in what you have done, what you will do?~
== BKINDR25
~If you had seen my homeland, now affectionately referred to as *the Magic Wastes*, you would understand. You would know the true nature of magic, and it would be *you* who would be ashamed.~
EXIT



CHAIN
IF ~InParty("Anomen")
See("Anomen")
!StateCheck("Anomen",STATE_SLEEPING)
Global("AnomenKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKAnomenUndead
~Anomen! I am pleased that you exercise great power over the undead, especially the vampires.~  [KINDR096]
DO ~SetGlobal("AnomenKindrekTOB","GLOBAL",1)~
== BANOME25
~Why? Do you fear them?~
== BKINDR25
~I fear nothing! But if given the choice, I would avoid their grave-cold touch.~
== BANOME25
~With faith, there is no fear. The undead fall before the glory of Helm.~
EXIT



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("CerndKindrekTOB","GLOBAL",0)~ THEN BCERND25 KKCerndDiscord
~Kindrek, you are a being in discord.~
DO ~SetGlobal("CerndKindrekTOB","GLOBAL",1)~
== BKINDR25
~And I spread my discord to all I can!~  [KINDR097]
== BCERND25
~You are like an infectious disease, threatening all you contact with your madness.~
== BKINDR25
~Would that I were as virulent as you claim! There would be no wizard living near me!~
EXIT



CHAIN
IF ~InParty("Haerdalis")
See("Haerdalis")
!StateCheck("Haerdalis",STATE_SLEEPING)
Global("HaerdalisKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKHaerSigil
~Haer'Dalis! You are quite skilled in many things. Why rely on magic? Do you not know that it corrupts and weakens?~  [KINDR098]
DO ~SetGlobal("HaerdalisKindrekTOB","GLOBAL",1)~
== BHAERD25
~On the contrary: it enobles and strengthens. Kindrek, your prejudice is so myopic that one can hardly engage in intelligent discourse with you.~
== BKINDR25
~Caution, spellsinger! You would not last two minutes against me!~
== BHAERD25
~And you, my bigoted berserker, would not last two minutes in Sigil.~
EXIT



CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
!StateCheck("Imoen2",STATE_SLEEPING)
Global("ImoenKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKImmySlayer
~Imoen! Why do you not give into your blood and become the Slayer? It would make you a terrifying power!~  [KINDR099]
DO ~SetGlobal("ImoenKindrekTOB","GLOBAL",1)~
== BIMOEN25
~Kindrek, is that all you think about? Death, murder, slaughter?~
== BKINDR25
~Mostly.~
== BIMOEN25
~Then we are fortunate that *you* are not one of Bhaal's children.~
EXIT



CHAIN
IF ~InParty("Jaheira")
See("Jaheira")
!StateCheck("Jaheira",STATE_SLEEPING)
Global("JaheiraKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKJaheiraPester
~Jaheira! Now that we have set off on a new set of adventures, perhaps you would like to reconsider my offer?~  [KINDR100]
DO ~SetGlobal("JaheiraKindrekTOB","GLOBAL",1)~
== BJAHEI25
~You still pester me, Kindrek? Surely you have learned your lesson. Do you want another tongue thrashing?~
== BKINDR25
~Ooooh. Tongue thrashing? I like the sound of that.~
== BJAHEI25
~Ugh. Incorrigible.~
EXIT



CHAIN
IF ~InParty("Keldorn")
See("Keldorn")
!StateCheck("Keldorn",STATE_SLEEPING)
Global("KeldornKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKKeldornWeary
~Keldorn! Surely your adventuring days are nearly done. You have built an impressive career. Why jeopardize it by accompanying <CHARNAME> to <PRO_HISHER> doom?~  [KINDR101]
DO ~SetGlobal("KeldornKindrekTOB","GLOBAL",1)~
== BKELDO25
~<CHARNAME> has done much for me. It is my duty to <PRO_HISHER> quest to completion.~
== BKINDR25
~Duty? How have you lived so long upholding duty?~
== BKELDO25
~What do you mean?~
== BKINDR25
~Duty drives one to a premature grave! Duty is merely a badge on one's chest; therefore I'll none of it.~
== BKELDO25
~Duty, honor, and sacrifice are all noble qualities in a warrior of conscience, Kindrek. It is not an outward sign but an inward stamp of righteousness.~
EXIT



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("KorganKindrekTOB","GLOBAL",0)~ THEN BKORGA25 KKKorganMeanStreak
~Kindrek, ye've a mean streak in ye an ocean wide!~
DO ~SetGlobal("KorganKindrekTOB","GLOBAL",1)~
== BKINDR25
~I am what I am. When compared to those with no backbone, I suppose I appear unnecessarily cruel.~  [KINDR102]
== BKORGA25
~But when compared to yer own kind, yer jes one o' the boys!~
== BKINDR25
~You assume much, Dwarf. There are none like me--not even you. I am a primal force, a living terror!~
=
~Were I to turn my countenance toward you, even you, mighty Korgan, would cower.~
== BKORGA25
~Ye're assuming much, Rahk.~
EXIT



CHAIN
IF ~InParty("Mazzy")
See("Mazzy")
!StateCheck("Mazzy",STATE_SLEEPING)
Global("MazzyKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKMazzyStature
~Mazzy! I once thought one's battle prowess was proportional to one's stature. But you have altered that perception.~  [KINDR103]
DO ~SetGlobal("MazzyKindrekTOB","GLOBAL",1)~
==BMAZZY25
~Thank you, Kindrek. Now, what is the punchline?~
==BKINDR25
~No punchline. I am completely serious in my praise of your martial skill.~
EXIT



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("MinscKindrekTOB","GLOBAL",0)~ THEN BMINSC25 KKMinscHeadButt
~Kindrek! Let's have a head-butting contest. The one left standing is the winner.~
DO ~SetGlobal("MinscKindrekTOB","GLOBAL",1)~
==BKINDR25
~A tempting offer. But you cannot appreciate just how thick a Rahk's skull is.~  [KINDR104]
=
~If you fall, you will not get up.~
EXIT



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("NaliaKindrekTOB","GLOBAL",0)~ THEN BNALIA25 KKNaliaBully
~Kindrek, you cannot deny that my magic has both aided <CHARNAME>'s quest and saved your life on many occasions.~
DO ~SetGlobal("NaliaKindrekTOB","GLOBAL",1)~
== BKINDR25
~Bah! Your magic is no help to me. Were it not for <CHARNAME>'s protection, your dried blood would be caked on my blade!~  [KINDR105]
== BNALIA25
~You cannot bully me! I won't allow it!~
== BKINDR25
~I have no desire to bully you. I just want to murder you! Say the word, and you die quickly.~
EXIT



CHAIN
IF ~InParty("Sarevok")
See("Sarevok")
!StateCheck("Sarevok",STATE_SLEEPING)
Global("SarevokKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKSarevokOpportunity
~Sarevok! I am pleased that <CHARNAME> has chosen to take you into <PRO_HISHER> group.~  [KINDR106]
DO ~SetGlobal("SarevokKindrekTOB","GLOBAL",1)~
==BSAREV25
~As am I. Traveling with <CHARNAME> presents many interesting opportunities.~
==BKINDR25
~And you intend to seize those opportunities when they present themselves.~
== BSAREV25
~Naturally. You, however, as I have been told, delight in only one thing: slaying mages.~
== BKINDR25
~Naturally. There is no greater thrill than annihilating magic!~
EXIT



CHAIN
IF ~InParty("Valygar")
See("Valygar")
!StateCheck("Valygar",STATE_SLEEPING)
Global("ValygarKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKValygarFuture
~Valygar! I have an offer for you.~  [KINDR107]
DO ~SetGlobal("ValygarKindrekTOB","GLOBAL",1)~
== BVALYG25
~What's that, Kindrek?~
== BKINDR25
~When <CHARNAME>'s quest is finished, and if we have survived, would you join me on my quest to eliminate magic wherever I find it?~
== BVALYG25
~I am no butcher, Kindrek. I cannot.~
== BKINDR25
~But you hate magic!~
== BVALYG25
~No, I distrust it. But I have, since my travels with <CHARNAME>, met many wizards that I would consider honorable and good.~
== BKINDR25
~So, you will not accompany me.~
== BVALYG25
~No. The road ahead for you is a lonely one.~
EXIT



CHAIN
IF ~InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("ViconiaKindrekTOB","GLOBAL",0)~ THEN BKINDR25 KKViconiaTesty
~Viconia! I--~  [KINDR108]
DO ~SetGlobal("ViconiaKindrekTOB","GLOBAL",1)~
== BVICON25
~--Silence, fool! I will not hear you!~
== BKINDR25
~Testy! The cliche, *you're so beautiful when you're angry*, does not begin to express my arousal at this moment!~
== BVICON25
~Shar! Take me away from this salacious troll!~
EXIT
