BEGIN KINDREKP



IF ~Global("KKLeftSpellhold","LOCALS",1)~ THEN BEGIN KindrekSated
SAY ~I have sated my bloodlust, <CHARNAME>, and am ready to rejoin your group. Shall we go?~
++ ~Actually, I don't need you anymore.~ GOTO KindrekSated1
++ ~You want me to take you back after you left me in my moment of need?~ GOTO KindrekSated2
++ ~Sure, I guess. Come on.~ GOTO KindrekSated3
++ ~Come with me, but if you leave me like that again, I'll hunt you down and kill you myself!~ GOTO KindrekSated4
END

IF ~~ THEN BEGIN KindrekSated1
SAY ~Fine. Then Disruptor will be my companion, and I will spill rivers of blood with it!~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN KindrekSated2
SAY ~<CHARNAME>! Understand that what I did was pure *mercy*! I could have slaughtered everyone in that damned nuthouse, but I did not... for your sake!~
++ ~Fine. Well, let's go, then.~ GOTO KindrekSated3
++ ~That's a pretty sorry excuse. If you can't control your urges, then I don't need you.~ GOTO KindrekSated1
END

IF ~~ THEN BEGIN KindrekSated3
SAY ~Excellent!~
IF ~~ THEN DO ~JoinParty()SetGlobal("KKLeftSpellhold","LOCALS",2)~ EXIT
END

IF ~~ THEN BEGIN KindrekSated4
SAY ~Ah! <CHARNAME>, I see my influence is having a positive influence on you! Let us go, then!~
IF ~~ THEN DO ~JoinParty()SetGlobal("KKLeftSpellhold","LOCALS",2)~ EXIT
END



IF ~Global("KindrekJoined","LOCALS",1)~ THEN BEGIN KindrekBoot
  SAY ~You're kicking me out?!~  [KINDR046]
  ++ ~No, it was a mistake. Please stay.~ DO ~JoinParty()~ EXIT
  ++ ~For the time being. Will you wait right here?~ GOTO KindrekBoot1a
END

IF ~~ THEN BEGIN KindrekBoot1a
  SAY ~I'll make my way back to the City Gates district in Athkatla.~
  =
  ~If you come up against an unbeatable wizard and need me, I'll be there.~
  IF ~~ THEN DO ~SetGlobal("KindrekJoined","LOCALS",0)SetGlobal("KindrekKickedOut","LOCALS",1)EscapeAreaMove("AR0020",869,395,7)~
EXIT
END



IF ~Global("KindrekJoined","LOCALS",0)
    Global("KindrekKickedOut","LOCALS",1)~ THEN BEGIN KindrekRejoin
  SAY ~Hello, again, <CHARNAME>! Do you need my services once again?~  [KINDR047]
  ++ ~Yes, Kindrek. Let's go.~ DO ~SetGlobal("KindrekJoined","LOCALS",1)JoinParty()~ EXIT
  ++ ~No, not yet.~ GOTO KindrekRejoin1a
END

IF ~~ THEN BEGIN KindrekRejoin1a
  SAY ~Very well. You know where I am if you need me.~
  IF ~~ THEN EXIT
END