BEGIN BKINDREK



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
OR (5)
Global("KindrekLeaveOverEdwin","LOCALS",1)
Global("KindrekLeaveOverTsujatha","LOCALS",1)
Global("KindrekLeaveOverTashia","LOCALS",1)
Global("KindrekLeaveOverZaiya","LOCALS",1)
Global("KindrekLeaveOverKelsey","LOCALS",1)~ THEN BEGIN KindrekLeaveOverWizard
SAY ~<CHARNAME>! You have taken a wizard into our group! You will pay for disrespecting me!~  [KINDR053]
IF ~~ THEN DO ~EquipMostDamagingMelee()LeaveParty()Enemy()Attack(LastSeenBy())~ EXIT
END


IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Global("KindrekLeaveOverIrenicus","LOCALS",1)~ THEN BEGIN KindrekLeaveOverIrenicus
SAY ~<CHARNAME>! You have taken Irenicus, your chief enemy, into our group! You will pay for disrespecting me with this insult!~  [KINDR054]
IF ~~ THEN DO ~EquipMostDamagingMelee()LeaveParty()Enemy()Attack(LastSeenBy())~ EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Gender(Player1,FEMALE)
Global("KindrekPropositionPC","GLOBAL",0)~ THEN BEGIN KindrekPropositionPC
SAY ~<CHARNAME>! I find your shape appealing.  Come and share my bed!~  [KINDR155]
 ++ ~Kindrek, get the hell out of my group!~ DO ~SetGlobal("KindrekPropositionPC","GLOBAL",1)~ GOTO KindrekPropositionPC1a
 ++ ~You could benefit from a bit of manners!~ DO ~SetGlobal("KindrekPropositionPC","GLOBAL",1)~ GOTO KindrekPropositionPC2a
 ++ ~I thought you'd never ask.~ DO ~SetGlobal("KindrekPropositionPC","GLOBAL",1)~ GOTO KindrekPropositionPC3a
 ++ ~You disgusting scumbag! How dare you speak to me that way!~ DO ~SetGlobal("KindrekPropositionPC","GLOBAL",1)~ GOTO KindrekPropositionPC4a
END

IF ~~ THEN BEGIN KindrekPropositionPC1a
 SAY ~Fine! You don't know what you're missing!~
 =
 ~And don't come begging to me for it later.~
 IF ~~ THEN DO ~SetGlobal("KindrekDidNotDoPC","GLOBAL",1)GivePartyAllEquipment()LeaveParty()EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN KindrekPropositionPC2a
 SAY ~So is that a *yes*?~
 ++ ~No! By no means.~ GOTO KindrekPropositionPC2b
 ++ ~Sure, why not.~ GOTO KindrekPropositionPC2c
END

IF ~~ THEN BEGIN KindrekPropositionPC2b
 SAY ~Your loss.~
 IF ~~ THEN DO ~SetGlobal("KindrekDidNotDoPC","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN KindrekPropositionPC2c
 SAY ~All right! Let's set camp and spread the bedrolls!~
 IF ~~ THEN DO ~SetGlobal("KindrekDidPC","GLOBAL",1)RestParty()~ EXIT
END

IF ~~ THEN BEGIN KindrekPropositionPC3a
 SAY ~Seriously? Whoa. I mean, I know I'm sexy, but I didn't expect you to be so keen on bedding me!~
 ++ ~Well, the joke's on you, Kindrek. I would *never* bed you!~ GOTO KindrekPropositionPC2b
 ++ ~Enough talk. I want to get you in the sack!~ GOTO KindrekPropositionPC2c
END

IF ~~ THEN BEGIN KindrekPropositionPC4a
 SAY ~Very easily. You are a woman. I am a man.~
 =
 ~I would have thought the reason for my request was obvious!~
 ++ ~You are a filthy, foul-mouthed, dirty-minded slug!~  GOTO KindrekPropositionPC4b
 ++ ~The only thing that's obvious is your plentiful lack of wit and tact.~ GOTO KindrekPropositionPC4b
 ++ ~Yes, it is obvious. You're obviously a loser. Get out of my group!~ GOTO KindrekPropositionPC1a
 ++ ~Yes, it is obvious. I've never taken a berserker into my bed. Let's get it on!~ GOTO KindrekPropositionPC2c
END

IF ~~ THEN BEGIN KindrekPropositionPC4b
 SAY ~I'll take that as a *no*.~
 IF ~~ THEN DO ~SetGlobal("KindrekDidNotDoPC","GLOBAL",1)~ EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,FIGHTER_ALL)
!Class(Player1,MONK)
Global("KindrekFighterTalk","GLOBAL",0)~ THEN BEGIN KindrekFighter
SAY ~<CHARNAME>! Hacking people to tiny bits is fun, isn't it?~  [KINDR055]
 ++ ~How horrid! Kindrek, you are a beast!~ DO ~SetGlobal("KindrekFighterTalk","GLOBAL",1)~ GOTO KindrekFighter1a
 ++ ~Well, now that you mention it . . . yes!~ DO ~SetGlobal("KindrekFighterTalk","GLOBAL",1)~ GOTO KindrekFighter2a
 ++ ~Kindrek, can you please control yourself?~ DO ~SetGlobal("KindrekFighterTalk","GLOBAL",1)~ GOTO KindrekFighter3a
END

IF ~~ THEN BEGIN KindrekFighter1a
 SAY ~Thanks.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekFighter2a
 SAY ~Ha! We'll make a butcher out of you yet, <CHARNAME>!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekFighter3a
 SAY ~I can. But restraining my tongue only serves to strengthen my arm in battle!~
 IF ~~ THEN EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,MONK)
Global("KindrekMonkTalk","GLOBAL",0)~ THEN BEGIN KindrekMonk
 SAY ~<CHARNAME>! You fight without the aid of weapons. I admire that.~  [KINDR056]
 ++ ~Thanks, Kindrek.~ DO ~SetGlobal("KindrekMonkTalk","GLOBAL",1)~ GOTO KindrekMonk1a
 ++ ~Why?~ DO ~SetGlobal("KindrekMonkTalk","GLOBAL",1)~ GOTO KindrekMonk1a
END

IF ~~ THEN BEGIN KindrekMonk1a
 SAY ~Relying upon raw skill is a sign of strength. Though you claim to be disciplined, you bludgeon people to death with your bare fists, and I find that delightfully savage!~
 IF ~~ THEN EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,PALADIN_ALL)
Global("KindrekPaladinTalk","GLOBAL",0)~ THEN BEGIN KindrekPaladin
 SAY ~<CHARNAME>! You are a warrior of light and right. Surely life's issues are not so black and white!~  [KINDR057]
 ++ ~Yes, they are. It is a pity that all you see is red.~ DO ~SetGlobal("KindrekPaladinTalk","GLOBAL",1)~ GOTO KindrekPaladin1a
 ++ ~You speak from ignorance. Those living in darkness have seen the light, but they cannot comprehend it.~ DO ~SetGlobal("KindrekPaladinTalk","GLOBAL",1)~ GOTO KindrekPaladin2a
END

IF ~~ THEN BEGIN KindrekPaladin1a
 SAY ~Hmmm. You are not easily provoked. I will say no more.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekPaladin2a
 SAY ~<CHARNAME>, I have light enough to kill by, and that is all I need!~
 IF ~~ THEN EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,RANGER_ALL)
Global("KindrekRangerTalk","GLOBAL",0)~ THEN BEGIN KindrekRanger
 SAY ~<CHARNAME>! You are a woodsman trained in wilderness survival as well as swordplay and combat. Why waste your time caring about dumb animals?~  [KINDR058]
 ++ ~My compassion for someone is not measured by my estimation of his intelligence!~ DO ~SetGlobal("KindrekRangerTalk","GLOBAL",1)~ GOTO KindrekRanger1a
 ++ ~Animals are as important to Faerun as the sentient races.~ DO ~SetGlobal("KindrekRangerTalk","GLOBAL",1)~ GOTO KindrekRanger2a
 ++ ~I am a warden of nature. This includes the natural environment and all its denizens.~ DO ~SetGlobal("KindrekRangerTalk","GLOBAL",1)~ GOTO KindrekRanger3a
END

IF ~~ THEN BEGIN KindrekRanger1a
 SAY ~Mine is. Wizards are always the smart ones, and I despise them the most!~
 ++ ~So you ought to like animals best of all.~ GOTO KindrekRanger1b
 ++ ~Yes, *we know*!~ GOTO KindrekRanger1c
END

IF ~~ THEN BEGIN KindrekRanger1b
 SAY ~ . . . . ~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekRanger1c
 SAY ~Just making sure you do not forget what I specialize in when we come across those spellchuckers.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekRanger2a
 SAY ~You understand how everything works together to achieve a balance?~
 ++ ~Kindrek, how do you understand these things?~ GOTO KindrekRanger2b
END

IF ~~ THEN BEGIN KindrekRanger2b
 SAY ~I don't. I've only heard you speak of such things. I care not. Killing is my business!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekRanger3a
 SAY ~Does nature need protection? People like you talk about the power of nature. Is it not powerful enough to take care of itself.~
 ++ ~Its power cannot be measured by your standards.~ EXIT
 ++ ~We have dominion over nature and a responsibility to defend it.~ GOTO KindrekRanger3b
 ++ ~The power of nature is stronger than you think. Without its grace, you starve.~ GOTO KindrekRanger3c
END

IF ~~ THEN BEGIN KindrekRanger3b
 SAY ~When one has dominion, one often forgets about responsibility.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekRanger3c
 SAY ~Then it is best I stay in *your* good graces as well!~
 IF ~~ THEN EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,THIEF_ALL)
Global("KindrekThiefTalk","GLOBAL",0)~ THEN BEGIN KindrekThief
 SAY ~<CHARNAME>! When you steal, do you also filch magic?~  [KINDR059]
 ++ ~Yes. That's the most valuable, so why wouldn't I?~ DO ~SetGlobal("KindrekThiefTalk","GLOBAL",1)~ GOTO KindrekThief1a
 ++ ~No, magic is evil, and I will not touch it!~ DO ~SetGlobal("KindrekThiefTalk","GLOBAL",1)~ GOTO KindrekThief2a
 ++ ~I do not use my skills for petty thievery.~ DO ~SetGlobal("KindrekThiefTalk","GLOBAL",1)~ GOTO KindrekThief3a
END

IF ~~ THEN BEGIN KindrekThief1a
 SAY ~What?! <CHARNAME>, if it weren't for the guidance you're providing me . . . ~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekThief2a
 SAY ~That is what I want to hear! Together, you and I can put an end to the people's reliance on magic!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekThief3a
 SAY ~Indeed! What do you use them for?~
 ++ ~For insuring that the way is safe when we investigate dungeons and other hostile territories.~ GOTO KindrekThief3b
 ++ ~For sneaking up on my enemies unawares.~ GOTO KindrekThief3b
 ++ ~For ensnaring my foes in devious traps.~ GOTO KindrekThief3b
END

IF ~~ THEN BEGIN KindrekThief3b
 SAY ~That skill eludes warriors such as myself. But it serves you, and therefore all who follow you, well.~
 IF ~~ THEN EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,CLERIC)
Global("KindrekLathandarTalk","GLOBAL",0)~ THEN BEGIN KindrekCleric
 SAY~<CHARNAME>! Though I suffer priests to be near me, I will have none of your magic! Do not ever try to cast your healing spells on me.~  [KINDR060]
 ++ ~Fine. Bleed.~ DO ~SetGlobal("KindrekLathandarTalk","GLOBAL",1)~ GOTO KindrekCleric1a
 ++ ~But I cannot let you stay injured when I can aid you.~ DO ~SetGlobal("KindrekLathandarTalk","GLOBAL",1)~ GOTO KindrekCleric2a
 ++ ~Is that a threat?~ DO ~SetGlobal("KindrekLathandarTalk","GLOBAL",1)~ GOTO KindrekCleric3a
END

IF ~~ THEN BEGIN KindrekCleric1a
 SAY ~That is all I ask.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekCleric2a
 SAY ~You will, or I will bury Disruptor in your skull!~
 ++ ~I will not tolerate threats! Leave.~ GOTO KindrekCleric2b
 ++ ~Just try, and you will know real pain!~ GOTO KindrekCleric2c
 ++ ~Calm down, Kindrek. No one's impressed.~ GOTO KindrekCleric2d
END

IF ~~ THEN BEGIN KindrekCleric2b
 SAY ~Better to go alone than travel in your company!~
 IF ~~ THEN DO ~GivePartyAllEquipment()LeaveParty()EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN KindrekCleric2c
 SAY ~Saucy! So you *do* have a backbone! Perhaps you are in the wrong profession.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekCleric2d
 SAY ~I shall owe you an answer for that!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekCleric3a
 SAY ~A promise. Use no magic on me!~
 ++ ~I cannot do as you ask.~ GOTO KindrekCleric3b
 ++ ~I will use no magic on you, but you will stop making threats!~ GOTO KindrekCleric3c
END

IF ~~ THEN BEGIN KindrekCleric3b
 SAY ~Then we must part company.~
 IF ~~ THEN DO ~GivePartyAllEquipment()LeaveParty()EscapeArea()~ EXIT
END

IF ~~ THEN BEGIN KindrekCleric3c
 SAY ~I apologize. It's just that the mere thought of magic nearly drives me into a frenzy!~
 IF ~~ THEN EXIT
END



IF ~See(Player1)
!StateCheck(Player1,STATE_SLEEPING)
Class(Player1,DRUID_ALL)
Global("KindrekDruidTalk","GLOBAL",0)~ THEN BEGIN KindrekDruid
 SAY ~<CHARNAME>! How are you different from a ranger?~  [KINDR061]
 ++ ~I use magic to protect nature, whereas a ranger uses his fighting skills.~ DO ~SetGlobal("KindrekDruidTalk","GLOBAL",1)~ GOTO KindrekDruid1a
 ++ ~Though we strive toward the same goal, there are ideological differences.~ DO ~SetGlobal("KindrekDruidTalk","GLOBAL",1)~ GOTO KindrekDruid2a
 ++ ~In our hearts, there is no difference.~ DO ~SetGlobal("KindrekDruidTalk","GLOBAL",1)~ GOTO KindrekDruid3a
 ++ ~I understand Nature and the delicate balance that binds all things together in harmony better than any ranger.~ GOTO KindrekDruid4a
END

IF ~~ THEN BEGIN KindrekDruid1a
 SAY ~Then my hopes is with the rangers. Magic only destroys. It does not preserve!~
 ++ ~What do you mean?~ GOTO KindrekDruid1b
 ++ ~You're just prejudiced!~ GOTO KindrekDruid1c
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid1b
 SAY ~My people's ancient homeland was destroyed by two warring magic factions. The land was laid waste, stripped of all life, and my people were forced to find a new land in which to live.~
=
 ~But we were unwelcome wherever we went, and the *civilized* peoples of the earth would not suffer the presence of savages.~
=
 ~Now we wander the land, living wherever we can, all because of magic!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid1c
 SAY ~Though I mistrust your magic, I do not hate it as I do a wizard's. My people's ancient homeland was destroyed by two warring magic factions. The land was laid waste, stripped of all life, and my people were forced to find a new land in which to live.~
=
 ~But we were unwelcome wherever we went, and the *civilized* peoples of the earth would not suffer the presence of savages.~
=
 ~Now we wander the land, living wherever we can, all because of magic!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid2a
 SAY ~Such as?~
 ++ ~Well, to rangers, the things nature has to offer are means to an end. If he grew up in a particular environment or has a natural proclivity for ranger skills, then he would find that the wilderness makes him particularly good at what he wants to do.~ GOTO KindrekDruid2b
 ++ ~Well, druids are the caretakers of nature. We revere the natural world and recognize it as good for what it is. It is not a tool but a Mother to us.~ GOTO KindrekDruid2b
END

IF ~~ THEN BEGIN KindrekDruid2b
 SAY ~Ummm. Okay. Sure, I understand that.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid3a
 SAY ~You are an inclusive person, I see. Hence the reason you allowed me into your group.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid4a
 SAY ~So you are better than a ranger?~
 ++ ~I did not say that. We have different strengths.~ GOTO KindrekDruid4b
 ++ ~Yes, I am!~ GOTO KindrekDruid4c
 ++ ~Rangers are far inferior to druids. They are bad imitations!~ GOTO KindrekDruid4d
END

IF ~~ THEN BEGIN KindrekDruid4b
 SAY ~You value variety in knowledge and skill. There is strength in diversity. Hence the reason for your motley crew.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid4c
 SAY ~Confidence becomes you!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekDruid4d
 SAY ~Ha! Do not speak your mind so loudly, lest you have a fight on your hands! But maybe you crave battle as I do.~
 IF ~~ THEN EXIT
END



CHAIN
IF ~InParty("Aerie")
See("Aerie")
!StateCheck("Aerie",STATE_SLEEPING)
Global("AerieKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKAerieFly
~Aerie! You could at one time fly?~  [KINDR062]
DO ~SetGlobal("AerieKindrekTalk","GLOBAL",1)~
== BAERIE
~Y-yes. I could soar near the clouds and among the eagles! But my wings were clipped.~
== BKINDREK
~I wish I could fly.~
== BAERIE
~You do? Why?~
== BKINDREK
~So I could catch all those wizards who fly away from me when I'm chasing them!~
EXIT

CHAIN
IF ~InParty("Aerie")
See("Aerie")
!StateCheck("Aerie",STATE_SLEEPING)
Global("AerieKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKAerieStrangle
~Aerie! Step away from me before I snap your pretty little neck!~  [KINDR063]
DO ~SetGlobal("AerieKindrekTalk","GLOBAL",2)~
== BAERIE
~Kindrek! You m-monster! Do not speak to me in such violent tones!~
== BKINDREK
~I suffer your spellcasting for <CHARNAME>'s sake. Do not tempt me by walking too near.~
== BAERIE
~Savage. Y-your stench will be more than enough to keep me at bay.~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("AerieKindrekTalk","GLOBAL",2)~ THEN BAERIE KKAerieBenefits
~Kindrek, by forsaking magic, you have foresworn all the benefits magic can bring.~
DO ~SetGlobal("AerieKindrekTalk","GLOBAL",3)~
== BKINDREK
~Magic has no benefit! It is destructive, and those who wield it lord it over those who don't!~  [KINDR064]
== BAERIE
~In your experience. But your knowledge of magic is limited.~
== BKINDREK
~I know enough about magic that if you question me further, your spell protections will do nothing to aid in you in defense against Disruptor!~
== BAERIE
~B-but I have non-magical protection as well: my friends who travel with us. By forsaking magic, you have forsaken friends. Your m-mission is a lonely one.~
EXIT



CHAIN
IF ~InParty("Anomen")
See("Anomen")
!StateCheck("Anomen",STATE_SLEEPING)
Global("AnomenKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKAnomenArrogant
~Anomen! You are arrogant. I like that!~  [KINDR065]
DO ~SetGlobal("AnomenKindrekTalk","GLOBAL",1)~
== BANOMEN
~I care not what you like or dislike. You are unworthy to travel with one such as I!~
== BKINDREK
~See.~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("AnomenKindrekTalk","GLOBAL",1)~ THEN BANOMEN KKAnomenMagic
~Kindrek, how can you deny the power I gain through magic? I use it effectively to supplement my fighting skills.~
DO ~SetGlobal("AnomenKindrekTalk","GLOBAL",2)~
== BKINDREK
~What you use is not magic. It is divine power. There is a difference.~  [KINDR066]
== BANOMEN
~What difference is there?~
== BKINDREK
~Power from the heavens is infused in you. You use something of the energy that the gods used to make the world. It is by definition creative.~
== BANOMEN
~And how is that different from arcane magic?~
== BKINDREK
~Wizards know only domination and destruction! How many more lives are lost in war when one man, protected by a line of infantry, is able to incinerate troops from a safe distance?~
== BANOMEN
~You see magic as a coward's path, then?~
== BKINDREK
~Yes. But none know just how cowardly wizards are until they find that their spells do not work against me. Then it is too late, and as I crush the life from them, they wet themselves in fear and beg for mercy! Cowards, all!~
EXIT

CHAIN
IF ~InParty("Anomen")
See("Anomen")
!StateCheck("Anomen",STATE_SLEEPING)
!Global("AnomenIsNotKnight","GLOBAL",1)
Global("AnomenKindrekTalk","GLOBAL",2)~ THEN BKINDREK KKAnomenOrder
~Anomen! By the way you talk and strut around, what do you need with the Order?~  [KINDR067]
DO ~SetGlobal("AnomenKindrekTalk","GLOBAL",3)~
== BANOMEN
~The Order is the source of all that is right! Through it, we crush evil.~
== BKINDREK
~You are better off without them.~
== BANOMEN
~Why do you say this?~
== BKINDREK
~You are powerful, but the Order imposes rules and regulations, codes and control. Without the Order, you can choose your own destiny! You choose whom to crush and whom to let live! The Order steals your strength, your initiative, your independence!~
== BANOMEN
~The world needs order. Being a vigilante, powerful or no, is no better than being a thug. Rules must be set and followed.~
== BKINDREK
~Must they?~
EXIT



CHAIN
IF ~InParty("Cernd")
See("Cernd")
!StateCheck("Cernd",STATE_SLEEPING)
Global("CerndKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKCerndShapeshift
~Cernd! You change your form to assume new shapes! What magic is this?~  [KINDR068]
DO ~SetGlobal("CerndKindrekTalk","GLOBAL",1)~
== BCERND
~It is the will of Nature that affords me this power.~
== BKINDREK
~Is Nature your god, then?~
== BCERND
~Nature is my Mother; she nurtures and teaches me. She is patient, and she gently rebukes me when I do wrong.~
== BKINDREK
~Huh?~
== BCERND
~Kindrek, our Mother cannot be brushed aside. Though we forsake her, yet she is always faithful, providing for us though we abuse her.~
== BKINDREK
~It's like your trying to tell me something. I know it. Your lips are moving, but I have no idea what you're saying.~
END



CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
!StateCheck("Imoen2",STATE_SLEEPING)
Global("ImoenKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKImmyRescue
~Imoen! <CHARNAME> has come far to rescue you!~  [KINDR069]
DO ~SetGlobal("ImoenKindrekTalk","GLOBAL",1)~
== IMOEN2J
~Yes, I know. <CHARNAME> is a true friend.~
== BKINDREK
~If I had known we were going through all that trouble to rescue a wizard, I would've never agreed!~
== IMOEN2J
~Yeah, life's full of little disappointments.~
== BKINDREK
~Watch your tongue, weak one!~
== IMOEN2J
~Sorry, I don't have the *magic* to do that.~
EXIT

CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
!StateCheck("Imoen2",STATE_SLEEPING)
Global("ImoenKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKImmySpellhold
~Imoen! Spellhold's got the right idea. They just need to take it a step further and exterminate the prisoners once they arrive!~  [KINDR070]
DO ~SetGlobal("ImoenKindrekTalk","GLOBAL",2)~
== IMOEN2J
~Don't talk about that place! It was horrible.~
== BKINDREK
~Yes, horrible that I could not tear off their heads and adorn my halberd with them.~
== IMOEN2J
~Yeah, yeah. Life's full of compromises. Get used to it.~
EXIT

CHAIN
IF ~InParty("Imoen2")
See("Imoen2")
!StateCheck("Imoen2",STATE_SLEEPING)
Global("ImoenKindrekTalk","GLOBAL",2)~ THEN BKINDREK KKImmyDisruptor
~Why are you looking at me that way, Imoen?~ [KINDR071]
DO ~SetGlobal("ImoenKindrekTalk","GLOBAL",3)~
== IMOEN2J
~Your halberd disrupts magical protections, right?~
== BKINDREK
~That is true.~
== IMOEN2J
~But the only way to achieve that effect is through magic. Isn't Disruptor therefore magical?~
== BKINDREK
~No! I can smell magic, and the stench of enchantment is not upon my blade!~
== IMOEN2J
~Then how do you explain how Disruptor does what it does?~
== BKINDREK
~I seek no explanation. I know what Disruptor can do, and I know it is not enchanted.~
=
~That is good enough for me!~
== IMOEN2J
~OK, then where did you get it?~
== BKINDREK
~I made it.~
== IMOEN2J
~You want me to believe that Disruptor is not magical, and that it does what it does simply because your forged something of your purpose into it?~
== BKINDREK
~I do not care what you believe! I am not here to convince you, nor have I any desire to justify myself to you.~
EXIT



CHAIN
IF ~InParty("Jaheira")
See("Jaheira")
!StateCheck("Jaheira",STATE_SLEEPING)
Global("JaheiraKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKJaheiraFallen
~Jaheira! Who is *the fallen*?~  [KINDR072]
DO ~SetGlobal("JaheiraKindrekTalk","GLOBAL",1)~
== BJAHEIR
~None of your business!~
== BKINDREK
~Then why advertise the existence of such a person or persons if you are unwilling to talk about it?~
== BJAHEIR
~I am unwilling to talk about it just with *you*.~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("JaheiraKindrekTalk","GLOBAL",1)~ THEN BJAHEIR KKJaheiraConfused
~I am one of <CHARNAME>'s oldest traveling companions, and I cannot figure out why <PRO_HESHE> allowed you to tag along.~
DO ~SetGlobal("JaheiraKindrekTalk","GLOBAL",2)~
== BKINDREK
~I do not tag along. <CHARNAME> uses my skill in battle to succeed in <PRO_HISHER> mission. Do not think that I do not also take advantage of our association.~  [KINDR073]
== BJAHEIR
~Do not worry. I will never make that mistake.~
EXIT

CHAIN
IF ~InParty("Jaheira")
See("Jaheira")
!StateCheck("Jaheira",STATE_SLEEPING)
Global("JaheiraKindrekTalk","GLOBAL",2)~ THEN BKINDREK KKJaheiraCompanion
~Jaheira! I finally understand why you are always snapping at people, why you are always in a sour mood.~  [KINDR074]
DO ~SetGlobal("JaheiraKindrekTalk","GLOBAL",3)~
== BJAHEIR
~Enlighten me.~
== BKINDREK
~You desire companionship. Come, I will share my bed with you!~
== BJAHEIR
~Insufferable presumption! (Jaheira's voice relaxes, and she smiles sweetly at Kindrek.) I might consider your offer were it not that I am a druid and therefore mindful of the feelings of your constant companions.~
== BKINDREK
~What companions? What are you talking about?~
== BJAHEIR
~Your fleas, Kindrek. They need sleeping space, too. I would not wish to crowd and upset them.~
EXIT



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("KeldornKindrekTalk","GLOBAL",0)~ THEN BKELDOR KKKeldornHealing
~Kindrek, I have heard you say that divine healing is not true magic, and therefore you do not despise it.~
DO ~SetGlobal("KeldornKindrekTalk","GLOBAL",1)~
== BKINDREK
~That is true.~  [KINDR071]
== BKELDOR
~Then why do you refuse healing?~
== BKINDREK
~Because I distrust it.~
== BKELDOR
~Born from the long habit of hunting wizards?~
== BKINDREK
~Possibly. Or perhaps it is because I feel that if I accept healing, then I may come to rely upon magic as well. The step is a small one.~
== BKELDOR
~And then you would become the very thing you detest.~
== BKINDREK
~You have a keen mind, Keldorn.~
EXIT

CHAIN
IF ~InParty("Keldorn")
See("Keldorn")
!StateCheck("Keldorn",STATE_SLEEPING)
Global("KeldornKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKKeldornDispel
~Keldorn! You have a remarkable ability to cancel magic!~  [KINDR075]
DO ~SetGlobal("KeldornKindrekTalk","GLOBAL",2)~
== BKELDOR
~Yes, but I use magic to do so.~
== BKINDREK
~Hmmm. Your motives are good, but your method needs revision!~
EXIT

CHAIN
IF ~InParty("Keldorn")
See("Keldorn")
!StateCheck("Keldorn",STATE_SLEEPING)
Global("KeldornKindrekTalk","GLOBAL",2)~ THEN BKINDREK KKKeldornScars
~Keldorn! The scars you bear are a testament to your victories.~  [KINDR076]
DO ~SetGlobal("KeldornKindrekTalk","GLOBAL",3)~
== BKELDOR
~Or defeats.~
== BKINDREK
~No, I have seen you in battle. You are formidable!~
== BKELDOR
~I will accept the compliment. But honor should be given to the one who strengthens my arm.~
== BKINDREK
~Now, if we can just make you love the smell of blood, you can become a true butcher!~
== BKELDOR
~Sharks and wild beasts hunger after blood. And madness comes with them.~
EXIT



CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("KorganKindrekTalk","GLOBAL",0)~ THEN BKORGAN KKKorganLittleKindrek
~You kinda look like me, Kindrek, only taller!~
DO ~SetGlobal("KorganKindrekTalk","GLOBAL",1)~
== BKINDREK
~You are a dwarf, Korgan. There are none of your kind where I come from.~  [KINDR077]
== BKORGAN
~And yer a giant, Kindrek. Me axe has felled many of yer kind!~
== BKINDREK
~Yeah, but why'd you want to raise your axe against someone as good looking as me?~
== BKORGAN
~Hey, thanks!~
EXIT

CHAIN
IF ~InParty("Korgan")
See("Korgan")
!StateCheck("Korgan",STATE_SLEEPING)
Global("KorganKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKKorganAxe
~Korgan! Do all dwarves wield the axe as well as you?~  [KINDR078]
DO ~SetGlobal("KorganKindrekTalk","GLOBAL",2)~
== BKORGAN
~Ye've a good eye, Kindrek. Ye know skill when ye see it!~
== BKINDREK
~The butchering you do with that axe is a thing of beauty!~
== BKORGAN
~We're a warrior race, a people who delve in the mountains for riches! We're as hard as stone, and we live to test the steel we forge 'gainst our foes.~
== BKINDREK
~I wish the rest of our party understood the necessity of gratuitous bloodshed!~
== BKORGAN
~Hear hear!~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("KorganKindrekTalk","GLOBAL",2)~ THEN BKORGAN KKKorganAle
~Kindrek! I've been noticing that ale ye've been carrying around.~
DO ~SetGlobal("KorganKindrekTalk","GLOBAL",3)~
== BKINDREK
~Wanna sip?~  [KINDR079]
== BKORGAN
~Atta boy! Toss that jug over here!~
== BKINDREK
~It's my homebrew. It knocks the skinny-folk on their backsides.~
== BKORGAN
~But we can handle it! We're solid rock.~
== BKINDREK
~Please tell me that was not your attempt at a pun.~
EXIT



CHAIN
IF ~InParty("Mazzy")
See("Mazzy")
!StateCheck("Mazzy",STATE_SLEEPING)
Global("MazzyKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKMazzyGourd
~Mazzy! I could crack you open like a gourd!~  [KINDR080]
DO ~SetGlobal("MazzyKindrekTalk","GLOBAL",1)~
== BMAZZY
~You might find me a tougher nut to crack than you suppose.~
== BKINDREK
~Nonsense! I have felled foes ten times your size!~
== BMAZZY
~Then why waste your talents on me? In what way do I threaten you?~
== BKINDREK
~Um . . . you don't! I . . . uh . . . I just like killing things!~
== BMAZZY
~Brilliant, Kindrek. Thankfully for us all you do not have an ambition for oratory.~
EXIT



CHAIN
IF ~InParty("Minsc")
See("Minsc")
!StateCheck("Minsc",STATE_SLEEPING)
Global("MinscKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKMinscButtkicking
~Minsc! Your *buttkicking for goodness* mantra has got to go!~  [KINDR081]
DO ~SetGlobal("MinscKindrekTalk","GLOBAL",1)~
== BMINSC
~What do you mean? Kicking butt in the name of goodness is what I do best.~
== BKINDREK
~You should be more indiscriminate in the butt you kick!~
== BMINSC
~You mean kick no one's butt?~
== BKINDREK
~No, kick everyone's butt! Everyone needs a buttkicking every now and then!~
=
~Do not worry about whether they deserve it or not! They do.~
EXIT

CHAIN
IF ~InParty("Minsc")
See("Minsc")
!StateCheck("Minsc",STATE_SLEEPING)
Global("MinscKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKMinscBerserk
~Minsc! You are a half-assed berserker!~  [KINDR082]
DO ~SetGlobal("MinscKindrekTalk","GLOBAL",2)~
== BMINSC
~No, both of my buttcheecks are firmly attached!~
== BKINDREK
~(Aside, to himself.) On the other hand, perhaps it is because he has half a brain. Who would've thought that an effective berserker would actually require intelligence?~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("MinscKindrekTalk","GLOBAL",2)~ THEN BMINSC KKMinscKillBoo
~Boo is convinced that you are giving us a bad name, Kindrek.~
DO ~SetGlobal("MinscKindrekTalk","GLOBAL",3)~
== BKINDREK
~A bad name?~  [KINDR083]
== BMINSC
~You succumb to the battle rage as Boo and I do, yet there is no honor in your fighting.~
== BKINDREK
~Boo berserks, too?~
== BMINSC
~Oh, yes! Boo is a terror on the field of battle. Death and ruin follow him!~
== BKINDREK
~Put him on the battlefield, and I will follow him to his death and ruin!~
== BMINSC
~You will not harm Boo! I will rip you apart!~
== BKINDREK
~That's the spirit!~
EXIT



CHAIN
IF ~InParty("Valygar")
See("Valygar")
!StateCheck("Valygar",STATE_SLEEPING)
Global("ValygarKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKValygarGreatMan
~Valygar! You are a great man.~  [KINDR084]
DO ~SetGlobal("ValygarKindrekTalk","GLOBAL",1)~
== BVALYGA
~Why do you say so?~
== BKINDREK
~Because you have forsaken your wizardly heritage! Bravo!~
== BVALYGA
~I have forsaken more than this. I had to kill my parents.~
== BKINDREK
~I never knew my parents. But if I had, I'm sure I would have killed them, too! Take comfort, Valygar. You are not alone!~
== BVALYGA
~(Sigh.) Splendid.~
EXIT

CHAIN
IF ~InParty("Valygar")
See("Valygar")
!StateCheck("Valygar",STATE_SLEEPING)
Global("ValygarKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKValygarCursed
~Valygar! You say your blood is cursed.~  [KINDR085]
DO ~SetGlobal("ValygarKindrekTalk","GLOBAL",2)~
== BVALYGA
~It is. It is cursed by dark, foul magic.~
== BKINDREK
~Yes. You are cursed. Sucks to be you!~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("ValygarKindrekTalk","GLOBAL",2)~ THEN BVALYGA KKValygarWhy
~Why do you hate magic, Kindrek?~
DO ~SetGlobal("ValygarKindrekTalk","GLOBAL",3)~
== BKINDREK
~Magic destroys all it touches! Even when it helps, eventually it harms!~  [KINDR086]
=
~And it weakens people, weakens the will! People grow dependent upon it.~
=
~Magic destroyed my homeland! Nothing will grow there!~
=
~Wizards are megalomaniacs, lording it over everyone!~
=
~Magic offends my nostrils!~
=
~Magic is a crutch!~
=
~Wizards are cowards who hide behind spellbooks! Grab one by the throat and squeeze, and watch how quickly he wets himself!~
== BVALYGA
~Sorry I asked.~
EXIT



CHAIN
IF ~InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("KindrekViconiaJealousy","GLOBAL",0)
OR (2)
Global("ViconiaRomanceActive","GLOBAL",1)
Global("ViconiaRomanceActive","GLOBAL",2)~ THEN BKINDREK KKViconiaJealousy
~Viconia! You reject my advances yet flirt shamelessly with <CHARNAME>!~  [KINDR087]
DO ~SetGlobal("KindrekViconiaJealousy","GLOBAL",1)~
== BVICONI
~Of course, you lout! <CHARNAME> is preferable to any woman of sense!~
== BKINDREK
~But why? What can he offer you that I cannot?~
== BVICONI
~A clean bed.~
EXIT

CHAIN
IF ~InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("ViconiaKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKViconiaProposition1
~Viconia! Your beauty arouses me--look! I want to taste your body.~  [KINDR088]
DO ~SetGlobal("ViconiaKindrekTalk","GLOBAL",1)~
== BVICONI
~You filth! I will cut out your tongue, and you will taste nothing but your lifeblood.~
== BKINDREK
~Quickly. I'll bump you to the front of the queue! I know you are an impatient woman and hate to be kept waiting.~
== BVICONI
~*You* may wait till you make your bed in hell!~
EXIT

CHAIN
IF ~InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("ViconiaKindrekTalk","GLOBAL",1)~ THEN BKINDREK KKViconiaProposition2
~Viconia! I sense that you are now ready. You will find pleasure in my bed!~  [KINDR089]
DO ~SetGlobal("ViconiaKindrekTalk","GLOBAL",2)~
== BVICONI
~Yes, just as much as you may find upon a knife's point.~
EXIT

CHAIN
IF ~InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("ViconiaKindrekTalk","GLOBAL",2)~ THEN BKINDREK KKViconiaProposition3
~Viconia! Come, I am freshly bathed!~  [KINDR090]
DO ~SetGlobal("ViconiaKindrekTalk","GLOBAL",3)~
== BVICONI
~You have not so much brain as earwax. I have refused you! Can you be so dull?~
== BKINDREK
~No, indeed! My rapier is keen and unsheathed!~
== BVICONI
~Keep up your bright sword, for the dew will rust it.~
EXIT




CHAIN
IF ~InParty("Yoshimo")
See("Yoshimo")
!StateCheck("Yoshimo",STATE_SLEEPING)
Global("YoshimoKindrekTalk","GLOBAL",0)~ THEN BKINDREK KKYoshimoSneaking
~Yoshimo! Your sneaking around is making me nervous!~  [KINDR091]
DO ~SetGlobal("YoshimoKindrekTalk","GLOBAL",1)~
== BYOSHIM
~My apologies, unwashed one.~
== BKINDREK
~Do not concern yourself with my hygiene. Just concentrate on keeping your fingers out of my purse!~
== BYOSHIM
~I take only things of value, Kindrek.~
EXIT

CHAIN
IF ~InParty("Kindrek")
See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("YoshimoKindrekTalk","GLOBAL",1)~ THEN BYOSHIM KKYoshimoOrigins
~Kindrek, where are you from?~
DO ~SetGlobal("YoshimoKindrekTalk","GLOBAL",2)~
== BKINDREK
~A wasteland.~  [KINDR092]
== BYOSHIM
~Indeed? A desert?~
== BKINDREK
~No, Yoshimo. A wasteland. A plain of parched, cracked earth, where even the smallest, toughest weed cannot be found.~
== BYOSHIM
~Then how did you survive there?~
== BKINDREK
~My people no longer live there, but there my heart will forever reside.~
EXIT

CHAIN
IF ~InParty("Yoshimo")
See("Yoshimo")
!StateCheck("Yoshimo",STATE_SLEEPING)
Global("YoshimoKindrekTalk","GLOBAL",2)~ THEN BKINDREK KKYoshimoBounty
~Yoshimo! You love the thrill of the hunt.~  [KINDR093]
DO ~SetGlobal("YoshimoKindrekTalk","GLOBAL",3)~
== BYOSHIM
~Why do you say that?~
== BKINDREK
~Because that is your profession, is it not? You hunt men for reward.~
== BYOSHIM
~I have not taken a bounty for some time.~
== BKINDREK
~Yet the hunt lives in your blood. You hear the call of the hunter's horn, calling you to the chase!~
== BYOSHIM
~Kindrek, you have plucked out the heart of my mystery.~
==BKINDREK
~Then hunt wizards with me. Together, we will track their scent of fear!~
EXIT
