BEGIN KIND25J



IF ~Global("KKLeaveOverPCMageTOB","LOCALS",1)~ THEN BEGIN KindrekPCMageTOB
SAY ~<CHARNAME>! You have taken up the mantle of a wizard! For that, you will surely die!~  [KINDR152]
IF ~~ THEN DO ~SetGlobal("KKLeaveOverPCMageTOB","LOCALS",2)LeaveParty()Enemy()EquipMostDamagingMelee()Attack(LastSeenBy())~
EXIT
END



IF ~Global("KKDestroyDisplacementCloakTOB","LOCALS",2)~ THEN BEGIN KindrekDestroyDisplacementTOB
SAY ~I can bear it no more! The magic of that cloak offends me so that I must take action!~  [KINDR049]
IF ~~ THEN DO ~TakePartyItem("clck03")DestroyItem("clck03")SetGlobal("KindrekDestroyDisplacementCloakTOB","LOCALS",3)~ EXIT
END



IF ~Global("KKDestroyReflectionCloakTOB","LOCALS",2)~ THEN BEGIN KindrekDestroyReflectionTOB
SAY ~I can bear it no more! The magic of that cloak offends me so that I must take action!~  [KINDR049]
IF ~~ THEN DO ~TakePartyItem("clck24")DestroyItem("clck24")SetGlobal("KindrekDestroyReflectionCloakTOB","LOCALS",3)~ EXIT
END



IF ~Global("KKDestroyMirroringCloakTOB","LOCALS",2)~ THEN BEGIN KindrekDestroyMirroringTOB
SAY ~I can bear it no more! The magic of that cloak offends me so that I must take action!~  [KINDR049]
IF ~~ THEN DO ~TakePartyItem("clck26")DestroyItem("clck26")SetGlobal("KindrekDestroyMirroringCloakTOB","LOCALS",3)~ EXIT
END



IF ~IsGabber(Player1)
CombatCounter(0)~ THEN BEGIN KindrekChatsTOB
SAY ~(Kindrek is brooding again.)~
+ ~RandomNum(4,1)~ + ~A copper for your thoughts, Kindrek.~ + KindrekCopperTOB1
+ ~RandomNum(4,2)~ + ~A copper for your thoughts, Kindrek.~ + KindrekCopperTOB2
+ ~RandomNum(4,3)~ + ~A copper for your thoughts, Kindrek.~ + KindrekCopperTOB3
+ ~RandomNum(4,4)~ + ~A copper for your thoughts, Kindrek.~ + KindrekCopperTOB4

+ ~RandomNum(4,1)~ + ~Why the sour face, Kindrek?~ + KindrekSourTOB1
+ ~RandomNum(4,2)~ + ~Why the sour face, Kindrek?~ + KindrekSourTOB2
+ ~RandomNum(4,3)~ + ~Why the sour face, Kindrek?~ + KindrekSourTOB3
+ ~RandomNum(4,4)~ + ~Why the sour face, Kindrek?~ + KindrekSourTOB4

+ ~RandomNum(4,1)~ + ~What are you thinking about, Kindrek?~ + KindrekThinkingTOB1
+ ~RandomNum(4,2)~ + ~What are you thinking about, Kindrek?~ + KindrekThinkingTOB2
+ ~RandomNum(4,3)~ + ~What are you thinking about, Kindrek?~ + KindrekThinkingTOB3
+ ~RandomNum(4,4)~ + ~What are you thinking about, Kindrek?~ + KindrekThinkingTOB4

+ ~RandomNum(4,1)~ + ~Kindrek! Tell me about a particularly memorable wizard you have slain.~ + KindrekMemoryTOB1
+ ~RandomNum(4,2)~ + ~Kindrek! Tell me about a particularly memorable wizard you have slain.~ + KindrekMemoryTOB2
+ ~RandomNum(4,3)~ + ~Kindrek! Tell me about a particularly memorable wizard you have slain.~ + KindrekMemoryTOB3
+ ~RandomNum(4,4)~ + ~Kindrek! Tell me about a particularly memorable wizard you have slain.~ + KindrekMemoryTOB4

+ ~RandomNum(4,1)~ + ~Anything wrong, Kindrek?~ + KindrekWrongTOB1
+ ~RandomNum(4,2)~ + ~Anything wrong, Kindrek?~ + KindrekWrongTOB2
+ ~RandomNum(4,3)~ + ~Anything wrong, Kindrek?~ + KindrekWrongTOB3
+ ~RandomNum(4,4)~ + ~Anything wrong, Kindrek?~ + KindrekWrongTOB4

++ ~There's something wrong with you, Kindrek.~ + KKChatFixerTOB
END

IF ~~ THEN BEGIN KindrekCopperTOB1
 SAY ~My thoughts are bloody.~  [KINDR132]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekCopperTOB2
 SAY ~Would that I were in your place, that I were a godchild! The rivers of Faerun would be as blood, and I would build my kingdom out of human bones!~  [KINDR133]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekCopperTOB3
 SAY ~You are Bhaalspawn, and death therefore follows you. It is good to be in your company!~  [KINDR134]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekCopperTOB4
 SAY ~Whom shall I slay this day?~  [KINDR135]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekSourTOB1
 SAY ~The days have been cheerful and sunny of late. Nice weather always puts me in a foul mood!~  [KINDR136]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekSourTOB2
 SAY ~I do not like how I am always being transported back to your pocket plane!~  [KINDR137]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekSourTOB3
 SAY ~The Solar in your pocket plane--I want to kill her! Perhaps next time we're there, you distract her while I sneak up from behind!~  [KINDR138]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekSourTOB4
 SAY ~This is my *happy* face!~  [KINDR139]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekThinkingTOB1
 SAY ~I was thinking about all the harlots we have seen in our travels. I would love to take some time out of adventuring and bed a few of them!~  [KINDR140]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekThinkingTOB2
 SAY ~Home.~  [KINDR141]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekThinkingTOB3
 SAY ~Will I ever return to my home? Or will I be forever exiled in this world?~  [KINDR142]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekThinkingTOB4
 SAY ~What I will do after we part company. This is still a strange world to me. When I am alone, where will I go?~  [KINDR143]
 =
 ~Where will fate lead me? . . . Of course, fate will show me where the wizards are, and I will fall upon them as wolves fall upon a lost and weary traveler!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekMemoryTOB1
 SAY ~I was once in the grand city of Norivea, and it was under siege by an army of giants. Now, the giants on my world are only about a foot or two taller than I am.~  [KINDR144]
 =
 ~They could not breach the city walls, for they were strongly fortified with men and magic. Well, all civilians had been evacuated when word of the approaching army reached the city.~
 =
 ~I, being a traveler and non-resident of the city, decided to stay. I did not fight but sat out in front of a particular tavern and drank large amounts of ale.~
 =
 ~There were many wizards in the city, helping with the war effort, but whenever one came strolling down the road where I sat out front, I snatched him, broke his neck, and tossed him in the nearby alley.~
 =
 ~This went on for days, and no one was the wiser! The bodies were really starting to pile up in the alley, and I thought for sure I would soon be discovered.~
 =
 ~But the giants breached Norivea soon thereafter! I think perhaps it was due to the lack of wizards. A lot of people died. Oops!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekMemoryTOB2
 SAY ~Well, this isn't exactly a story about a slain wizard, but it is memorable nonetheless!~  [KINDR145]
 =
 ~I sneaked into this party that some aristocrat was throwing in a city called Arinport. Arinport is a pirate-town, so it wasn't hard.~
 =
 ~I was snooping around the back rooms of the mansion, looking in the kitchen for something to eat. I was actually there to find a certain wizard who had been hiding from me, but I was hungry!~
 =
 ~Anyway, in the middle of my meal, in walked a serving girl. In her shock, she asked me what I was doing there. I said nothing, but walked over, snatched her up by her pretty hair, and snapped her neck.~
 =
 ~I couldn't risk discovery, so I snapped her body in two and stuffed her folded corpse into the cupboard.~
 =
 ~But then other servants came looking for the missing servant. I was able to kill a couple more before I was discovered. To get away, I took a girl hostage.~
 =
 ~The closest thing Arinport has to a town guard pursued me through the streets, and all the time this girl was screaming. I turned and decided to stand my ground.~
 =
 ~Not long after, the guards were upon me, and the girl was still screaming like an idiot! So, thought I, I'll use her as a human shield. That will shut her up.~
 =
 ~And it did. The guards hacked away at her trying to get to me. When my shield was no longer adequate protection, I tossed it aside and dealt severely with those rogues!~
 =
 ~Unfortunately, that wizard eluded me. I have not crossed his path since.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekMemoryTOB3
 SAY ~I once had to team up with some priests to destroy a vampire who was quite adept at spellcasting.~  [KINDR146]
 =
 ~I let them go first, of course, and we were all caught in a nasty illusion. I saw right through it, but my companions were doomed.~
 =
 ~When the vampire came out for us, I acted enthralled as my companions were. I wanted to strike, but I had to wait for the right moment.~
 =
 ~Of course, that opportune moment came when the fiend started feasting on one of the priests. I thought I should strike then, but then I reconsidered.~
 =
 ~There were three priests. I thought, why not wait until the vampire has killed the first two and is feasting on the third? That way, I don't have to share any of the booty with them!~
 =
 ~It was a brilliant plan! As the vampire was feasting upon the third priest, I struck, and Disruptor took his head! There was a lot of gold in the vampire's lair, and if I had had to share it, I would have been very depressed.~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekMemoryTOB4
 SAY ~I was chasing a wizard down the streets of Kaleni, but this guy was fast! I could not catch up with him, so I stopped at this bowyer's shop I was passing and snatched up a longbow.~  [KINDR147]
 =
 ~I took aim and fired off three arrows in quick succession. They struck the wizard and killed him instantly. But that's not the memorable part.~
 =
 ~The bowyer's wife came out of the house and started yelling at me. So I turned and put three arrows in her!~
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekWrongTOB1
 SAY ~Yes! Everything!~  [KINDR148]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekWrongTOB2
 SAY ~I think I accidentally used poison ivy last time I wiped!~  [KINDR149]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekWrongTOB3
 SAY ~Yes, that fact that you interrupt my reverie!~  [KINDR150]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KindrekWrongTOB4
 SAY ~No! I am all smiles and sparkles!~  [KINDR151]
 IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN KKChatFixerTOB
 SAY ~Says who? I guess I'll fix it anyway.~
 IF ~~ THEN DO ~StartCutScene("KKFIX")~ EXIT
END


INTERJECT_COPY_TRANS SARMEL01 46 KindrekYagaShura
== KIND25J IF ~InParty("Kindrek")~ THEN
~I have met many *invincible* opponents, Melly. Now they are no more. Just point me in Yaga's direction!~
== SARMEL01
~<CHARNAME>, is it wise to travel with one so brazen?~
END



INTERJECT 25SPELL 2 KindrekLazarusKill
== KIND25J IF ~InParty("Kindrekk")~ THEN
~Wrong, you spell-flinging fool! I can tolerate your continued existence no longer! <CHARNAME> and <PRO_HISHER> deals be damned! I will have my revenge on all wizards!~
== 25SPELL
~So be it, but here you meet your end!~ DO ~Enemy()~
END



INTERJECT_COPY_TRANS BALTH 24 KindrekBalthazar
== KIND25J IF ~InParty("Kindrek")~ THEN
~I'm not dying for anyone's sake!~
== BALTH
~You have taken part in <PRO_HISHER> quest, now share in <PRO_HISHER> death!~
END



INTERJECT_COPY_TRANS AMLICH01 0 KindrekVongoethe
== KIND25J IF ~InParty("Kindrek")~ THEN
~That does not matter, lich! I will scatter your bones across this cavern!~
== AMLICH01
~So this is the mighty wizard-slayer, the berserker Kindrek. This cavern shall entomb *your* bones along with mine!~
END



EXTEND_TOP SARVOLO 9
IF ~InParty("Kindrek")~ THEN REPLY ~Tell me about Kindrek.~ GOTO KindrekVolo
END

CHAIN SARVOLO KindrekVolo
~Kindrek is the most savage member of <PRO_LORDLADY> <CHARNAME>'s group. His only delight is in the butchering of weaker foes, in spilling their blood. He drinks in fear like a deer drinks water from a stream. Reports of his activities indicate that he despises wizards and slays them whenever possible. Some say this hatred even extends to items imbued with magical properties. Yet many are puzzled by Disruptor, a seemingly magical weapon cherished by Kindrek.~
== KIND25J IF ~InParty("Kindrek")~ THEN ~You know me well, historian! But say Disruptor is magical again, and I'll rip your throat out!~  [KINDR109]
EXTERN SARVOLO 9



EXTEND_TOP FATESP 6 #5
IF ~!Dead("Kindrek")
    !InMyArea("Kindrek")
    Global("KindrekSummoned","GLOBAL",0)~
THEN
  REPLY ~Bring me Kindrek, the Wizard-Hating Berserker.~
    DO ~CreateVisualEffect("SPPORTAL",[1999.1218])
     Wait(2)
     CreateCreature("KINDRE25",[1999.1218],0)
     SetGlobal("KindrekSummoned","GLOBAL",1)~
     GOTO 8
END
