BEGIN BKKVEIGL



CHAIN
IF ~See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("KindrekVeigleTalk","LOCALS",1)~
THEN BKKVEIGL KindrekVeigleTalk
~Ah, the mighty Kindrek! Wizard-slayer extraordinaire! You have slain the all-powerful demi-lich, Kangaxx, and the thrill of that victory still courses through your veins!~
DO ~SetGlobal("KindrekVeigleTalk","LOCALS",2)~
== BKINDREK
~It does! Who are you? Have you, too, come to taste my wrath?~
== BKKVEIGL
~(The stranger takes a defensive step back.) No, not at all! I am called Veigle, and I can give you information on a gathering of wizards.~
== BKINDREK
~That I long to hear! Speak man!~
== BKKVEIGL
~Very well. Know that a certain convocation of wizards has come together for their annual banquet. They meet each year to exchange magical research.~
== BKINDREK
~And I was not invited? How rude! I shall teach these wizards some manners!~
== BKKVEIGL
~That's the spirit! The location of their meeting is always kept secret, but I was able to bribe an informant to give me the precise location of this year's banquet.~
== BKINDREK
~(Kindrek grasps Disruptor impatiently.) Well, out with it, man!~
== BKKVEIGL
~They are meeting in a cave in the Umar Hills. I think--~
== BKINDREK
~--Enough! Let us find these wizards and spill their hot blood! <CHARNAME>?~
END
 ++ ~Right, Kindrek. After Kangaxx, how hard can these wizards be?~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1
 ++ ~No, Kindrek. It smells like a trap to me.~ GOTO KindrekVeigleTalk2
 ++ ~Wait! Who are you, Veigle, to know about a secret wizard meeting?~ GOTO KindrekVeigleTalk3
 ++ ~Wait! We can't go around murdering people, just because they are wizards!~ GOTO KindrekVeigleTalk4

CHAIN BKKVEIGL KindrekVeigleTalk1
~Then good luck, mighty <CHARNAME> and Kindrek!~ DO ~EscapeArea()~
EXIT

CHAIN BKKVEIGL KindrekVeigleTalk2
~A trap?~
== BKINDREK
~A trap?~
== BKKVEIGL
~I assure you it is not! I loathe wizards and will see them all dead! My family was murdered by wizards!~
== BKINDREK
~<CHARNAME>, surely we must act!~
END
 ++ ~Family murdered by wizards, eh? That's so cliche, now I *know* he's lying.~ GOTO KindrekVeigleTalk5
 ++ ~(Sigh.) Very well, Kindrek. Let's go sate your bloodthirst.~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1
 ++ ~Wait! Who are you, Veigle, to know about a secret wizard meeting?~ GOTO KindrekVeigleTalk3

CHAIN BKKVEIGL KindrekVeigleTalk3
~I have made my life a study of tracking wizards. Though I lack the power to confront them, I know many, like Kindrek, to whom I can pass off the information I come by.~
== BKINDREK
~Sounds great to me! Let us go!~
END
 ++ ~Very well.  Let's just get this over with.~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1
 ++ ~Not a chance. This is a trap.~ GOTO KindrekVeigleTalk6
 ++ ~Not a chance. I will not indiscriminately murder people.~ GOTO KindrekVeigleTalk7

CHAIN BKKVEIGL KindrekVeigleTalk4
~(Veigle eyes you suspiciously.)~
== BKINDREK
~Of course we can! I will go without you, then!~
END
 ++ ~Then go.~ GOTO KindrekVeigleTalk8
 ++ ~All right, all right! We'll *all* go!~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1

CHAIN BKKVEIGL KindrekVeigleTalk5
~I am *not* lying! Kindrek, you cannot allow such a gathering to continue!~
== BKINDREK
~No, I can't! <CHARNAME>, I will go alone, if I must!~
END
 ++ ~Then go.~ GOTO KindrekVeigleTalk8
 ++ ~All right, all right! We'll *all* go!~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1

CHAIN BKKVEIGL KindrekVeigleTalk6
~It is *not* a trap, suspicious one! Kindrek, you cannot allow such a gathering to continue!~
== BKINDREK
~No, I can't! <CHARNAME>, I will go alone, if I must!~
END
 ++ ~Then go.~ GOTO KindrekVeigleTalk8
 ++ ~All right, all right! We'll *all* go!~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1

CHAIN BKKVEIGL KindrekVeigleTalk7
~(Veigle eyes you suspiciously.)~
== BKINDREK
~Indiscriminate? I am decidedly *discriminate* about whom I slay! And I will go, alone if necessary!~
END
 ++ ~Then go.~ GOTO KindrekVeigleTalk8
 ++ ~All right, all right! We'll *all* go!~ DO ~SetGlobal("AcceptedVeigleQuest","GLOBAL",1)~ GOTO KindrekVeigleTalk1

CHAIN BKKVEIGL KindrekVeigleTalk8
~(Veigle smiles deviously.)~ DO ~EscapeArea()~
== BKINDREK
~I'm gone!~ DO ~SetGlobal("KindrekJoined","LOCALS",0)LeaveParty()EscapeArea()~
EXIT