BEGIN KKCIAN

CHAIN
IF ~See("Kindrek")
!StateCheck("Kindrek",STATE_SLEEPING)
Global("CianSurpriseKindrek","LOCALS",0)~
THEN KKCIAN CianSurpriseKindrek
~Look ladies: the fool has come!~
DO ~SetGlobal("CianSurpriseKindrek","LOCALS",1)~
== BKINDREK
~What is this? Where are the wizards?~
== KKCIAN
~Wizards? My, my. I have *no* idea what you're talking about.~
== BKINDREK
~Veigle told us about the gathering of wizards! Have you fiends slain them?~
== KKCIAN
~(Cian chuckles.) Oh, Veigle. Yes. He is sometimes given to flights of fancy, to distorting the facts.~
=
~Quite an equivocal being, that Veigle.~
== BKINDREK
~You're not making any sense, monster!~
== KKCIAN
~Then let me be perfectly clear: we mean to feast upon your flesh, wizard-slayer.~
== BKINDREK
~(Kindrek takes a cautious step back, and though he speaks to you, he keeps a wary eye on the vampire.) Uh, <CHARNAME>, let's get the hell out of here!~
END
 ++ ~Come on, Kindrek! A passel of vampires is nothing to worry about.~ GOTO CianSurpriseKindrek1
 ++ ~Yeah, I think you're right.~ GOTO CianSurpriseKindrek2
 ++ ~Why did you trick us into coming here, creature of the night?~ GOTO CianSurpriseKindrek3

CHAIN KKCIAN CianSurpriseKindrek1
~Fool! Then you will all die here.~
=
~Come, ladies. Let us to the banquet!~
DO ~SetGlobal("KindrekCianFight","GLOBAL",1)ReallyForceSpell(Myself,WIZARD_STONE_SKIN)~
EXIT

CHAIN KKCIAN CianSurpriseKindrek2
~Fools! You cannot escape our hunger.~
=
~Come, ladies. Let us to the banquet!~
DO ~SetGlobal("KindrekCianFight","GLOBAL",1)ReallyForceSpell(Myself,WIZARD_STONE_SKIN)~
EXIT

CHAIN KKCIAN CianSurpriseKindrek3
~The master provides us our prey, and the paladins, priests, and agents of the Sun know naught of our existence.~
=
~The master despises the wizard-slayer, and so we set a trap for him. And, being the brainless brute that he is, he took the bait!~
=
~And so we shall feast upon him and make him one of us! But <CHARNAME>, leave now, and your life will be spared.~
== BKINDREK
~You cannot leave me with these monsters!~
END
 ++ ~Kindrek, you've been lording it over the wizards for too long. It's time for your comeuppance!~ GOTO CianSurpriseKindrek4
 ++ ~Kindrek, lets make a run for it!~ GOTO CianSurpriseKindrek2
 ++ ~Kindrek, I would like to help, but I don't think we can win this fight. Farewell!~ GOTO CianSurpriseKindrek4
 ++ ~Kindrek, I will help you defeat these vampires and foil their master's plans!~ GOTO CianSurpriseKindrek1

CHAIN KKCIAN CianSurpriseKindrek4
~(Cian's laugh is cold.) <CHARNAME>, your black heart rivals my own!~
== BKINDREK
~Vile Bhaalspawn! I shall avenge myself upon you!~
DO ~SetGlobal("BetrayedKindrekToCian","GLOBAL",1)ClearAllActions()StartCutSceneMode()StartCutScene("KKBETRAY")~
EXIT
