BEGIN KIDOJ25

IF ~Global("kidohistory25","GLOBAL",1)~ THEN BEGIN needexplanation
  SAY @0 
  IF ~~ THEN REPLY @1 DO ~SetGlobal("kidohistory25","GLOBAL",2)~ GOTO trytoshort
  IF ~~ THEN REPLY @2 DO ~SetGlobal("kidohistory25","GLOBAL",2)~ GOTO trytoshort
  IF ~~ THEN REPLY @3 DO ~SetGlobal("kidohistory25","GLOBAL",2)~ GOTO tale
  IF ~~ THEN REPLY @4 DO ~SetGlobal("kidohistory25","GLOBAL",2)~ GOTO quickend
END

IF ~~ THEN BEGIN trytoshort
  SAY @5
  IF ~~ THEN REPLY @6 GOTO tale
  IF ~CheckStatGT(PLAYER1,12,CHR)~ THEN REPLY @7 GOTO extraversion
END

IF ~~ THEN BEGIN tale
  SAY @8
  =
  @9
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN extraversion
  SAY @10
  IF ~~ THEN REPLY @11 GOTO conextraversion
END

IF ~~ THEN BEGIN conextraversion
  SAY @12
  IF ~~ THEN REPLY @13 GOTO tale
END

IF ~~ THEN BEGIN quickend
  SAY @14
  IF ~~ THEN EXIT
END

IF ~Global("weareone25","GLOBAL",1)~ THEN BEGIN childofcyrica
  SAY @15 
  IF ~~ THEN REPLY @16 DO ~SetGlobal("weareone25","GLOBAL",2)~ GOTO difopinion
  IF ~~ THEN REPLY @17 DO ~SetGlobal("weareone25","GLOBAL",2)~ GOTO greypath
  IF ~~ THEN REPLY @18 DO ~SetGlobal("weareone25","GLOBAL",2)~ GOTO cheerus
  IF ~~ THEN REPLY @19 DO ~SetGlobal("weareone2","LOCALS",1)~ GOTO knowalot
  IF ~~ THEN REPLY @20 DO ~SetGlobal("weareone25","GLOBAL",2)~ GOTO childofcyric
END

IF ~~ THEN BEGIN knowalot
  SAY @21
  IF ~~ THEN REPLY @22 GOTO difopinion
  IF ~~ THEN REPLY @23 GOTO greypath
  IF ~~ THEN REPLY @24 GOTO cheerus
  IF ~~ THEN REPLY @25 GOTO childofcyric
END

IF ~~ THEN BEGIN difopinion
  SAY @26
  IF ~~ THEN REPLY @27 GOTO angryend
  IF ~~ THEN REPLY @28 GOTO greypath 
END

IF ~~ THEN BEGIN greypath
  SAY @29
  IF ~~ THEN REPLY @30 GOTO angryend
  IF ~~ THEN REPLY @31 GOTO comeback 
  IF ~~ THEN REPLY @32 GOTO cheerus
END

IF ~~ THEN BEGIN cheerus
  SAY @33
  IF ~~ THEN REPLY @34 GOTO happyend
  IF ~~ THEN REPLY @35 GOTO childofcyrice
END

IF ~~ THEN BEGIN childofcyric
  SAY @36
  IF ~~ THEN REPLY @37 GOTO difopinion
  IF ~~ THEN REPLY @38 GOTO greypath
  IF ~~ THEN REPLY @39 GOTO myfate
  IF ~~ THEN REPLY @40 GOTO happyend
  IF ~~ THEN REPLY @41 GOTO okayend
END

IF ~~ THEN BEGIN childofcyrice
  SAY @42
  IF ~~ THEN REPLY @43 GOTO okayend
  IF ~~ THEN REPLY @44 GOTO happyend
END

IF ~~ THEN BEGIN myfate
  SAY @45
  IF ~~ THEN REPLY @46 GOTO difopinion 
  IF ~~ THEN REPLY @47 GOTO greypath 
  IF ~~ THEN REPLY @48 GOTO okayend
  IF ~~ THEN REPLY @49 GOTO okayend
  IF ~~ THEN REPLY @50 GOTO happyend
  IF ~CheckStatGT(PLAYER1,12,INT)~ THEN REPLY @51 GOTO detail
END

IF ~~ THEN BEGIN detail
  SAY @52
  IF ~~ THEN REPLY @53 GOTO difopinion
  IF ~~ THEN REPLY @54 GOTO comeback
  IF ~~ THEN REPLY @55 GOTO okayend 
END

IF ~~ THEN BEGIN angryend
  SAY @56
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN comeback
  SAY @57
  IF ~~ THEN REPLY @58 DO ~SetGlobal("Undecided25","LOCALS",1)~ EXIT
END

IF ~~ THEN BEGIN okayend
  SAY @59
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN happyend
  SAY @60
  IF ~~ THEN EXIT
END

IF ~Global("secweareone25","GLOBAL",1)~ THEN BEGIN retryconvincepl
  SAY @61 
  IF ~~ THEN REPLY @62 DO ~SetGlobal("secweareone25","GLOBAL",2)~ GOTO difopinionnew
  IF ~~ THEN REPLY @63 DO ~SetGlobal("secweareone25","GLOBAL",2)~ GOTO kidoquit
  IF ~~ THEN REPLY @64 DO ~SetGlobal("secweareone25","GLOBAL",2)~ GOTO cheerus
END

IF ~~ THEN BEGIN difopinionnew
  SAY @65
  IF ~~ THEN REPLY @66 GOTO angryend
  IF ~~ THEN REPLY @67 GOTO kidoquit
  IF ~~ THEN REPLY @68 GOTO cheerus
END

IF ~~ THEN BEGIN kidoquit
  SAY @69
  IF ~~ THEN EXIT
END

IF ~Global("plansunfold25","GLOBAL",1)~ THEN BEGIN spoketomuch
  SAY @70 
  IF ~~ THEN REPLY @71 DO ~SetGlobal("plansunfold25","GLOBAL",2)~ GOTO rapidend
  IF ~~ THEN REPLY @72 DO ~SetGlobal("plansunfold25","GLOBAL",2)~ GOTO rapidend
  IF ~~ THEN REPLY @73 DO ~SetGlobal("plansunfold25","GLOBAL",2)~ GOTO nearlythere
  IF ~CheckStatGT(PLAYER1,12,INT)~ THEN REPLY @74 DO ~SetGlobal("plansunfold25","GLOBAL",2)~ GOTO examination
  IF ~Class(Player1,CLERIC)~ THEN REPLY @75 DO ~SetGlobal("plansunfold25","GLOBAL",2)~ GOTO clericpath
END

IF ~~ THEN BEGIN nearlythere 
  SAY @76
  IF ~~ THEN REPLY @77 GOTO pleasure
  IF ~~ THEN REPLY @78 GOTO unpleasant 
  IF ~CheckStatGT(PLAYER1,12,CHR)~ THEN REPLY @79 GOTO morethere
END

IF ~~ THEN BEGIN morethere
  SAY @80
  IF ~~ THEN REPLY @81 GOTO unpleasant 
  IF ~~ THEN REPLY @82 GOTO pleasure 
  IF ~~ THEN REPLY @83 GOTO nonono 
END

IF ~~ THEN BEGIN examination
  SAY @84
  IF ~~ THEN REPLY @85 GOTO murder
  IF ~~ THEN REPLY @86 GOTO murder
END

IF ~~ THEN BEGIN clericpath
  SAY @87
  IF ~~ THEN REPLY @88 GOTO murder
  IF ~~ THEN REPLY @89 GOTO kidoagenda
END

IF ~~ THEN BEGIN murder
  SAY @90
  IF ~~ THEN REPLY @91 GOTO kidoagenda
  IF ~~ THEN REPLY @92 GOTO kidoagenda
  IF ~~ THEN REPLY @93 GOTO diechild
END

IF ~~ THEN BEGIN kidoagenda
  SAY @94
  IF ~~ THEN REPLY @95 GOTO diechild
  IF ~~ THEN REPLY @96 GOTO diebhaal
  IF ~~ THEN REPLY @97 GOTO diebhaal
END

IF ~~ THEN BEGIN diebhaal
  SAY @98
  IF ~~ THEN REPLY @99 GOTO kidosad 
  IF ~~ THEN REPLY @100 GOTO kidohappy 
END

IF ~~ THEN BEGIN rapidend
  SAY @101
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN pleasure
  SAY @102
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN unpleasant
  SAY @103
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN nonono
  SAY @104
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN diechild
  SAY @105 // Moved DO to IF ~~ THEN
  IF ~~ THEN DO ~Attack(Player1)~ EXIT
END

IF ~~ THEN BEGIN kidosad
  SAY @106
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN kidohappy
  SAY @107
  IF ~~ THEN EXIT
END

IF ~Global("notsopitoresque","GLOBAL",1)~ THEN BEGIN kidotellsara
  SAY @108 
=
@109
  IF ~~ THEN DO ~SetGlobal("notsopitoresque","GLOBAL",2)~ EXIT
END

IF ~Global("finalconKaAn25","GLOBAL",1)~ THEN BEGIN lastquabAnjo25
 SAY @110 
  IF ~~ THEN REPLY @111 DO ~SetGlobal("finalconKaAn25","GLOBAL",2)~ GOTO ihearyaplay
  IF ~~ THEN REPLY @112 DO ~SetGlobal("finalconKaAn25","GLOBAL",2)~ GOTO ihearyaplay
  IF ~~ THEN REPLY @113 DO ~SetGlobal("finalconKaAn25","GLOBAL",2)~ GOTO ihearyaplay
  IF ~~ THEN REPLY @114 DO ~SetGlobal("finalconKaAn25","GLOBAL",2)~ EXTERN KIDOP25 0
  IF ~!Gender(Player1,MALE)~ THEN REPLY @115 DO ~SetGlobal("finalconKaAn25","GLOBAL",2)~ GOTO dieplayer
END

IF ~~ THEN BEGIN dieplayer
  SAY @116
  IF ~~ THEN DO ~Attack(Player1)~ EXIT
END

IF ~~ THEN BEGIN ihearyaplay
  SAY @117
  IF ~~ THEN EXIT
END

IF ~InParty("Player1")
  See("Player1")
  !StateCheck("Player1",STATE_SLEEPING)~ THEN BEGIN notthatlore25
  SAY @118
  IF ~~ THEN REPLY @119 EXTERN GORMAD 16
  IF ~~ THEN REPLY @120 EXTERN GORMAD 16
  IF ~~ THEN REPLY @121 EXTERN GORMAD 17
END

IF ~InParty("Player1")
  See("Player1")
  !StateCheck("Player1",STATE_SLEEPING)~ THEN BEGIN kidonotrustme
  SAY @122
  IF ~~ THEN EXTERN SARMEL01 17
END

IF ~InParty("Player1")
  See("Player1")
  !StateCheck("Player1",STATE_SLEEPING)~ THEN BEGIN kidonotrustme2
  SAY @123
  IF ~~ THEN EXTERN SARMEL01 17
END

EXTEND_TOP GORCAR 18 #3
IF ~InParty("DKido") See("DKido")~ 
THEN REPLY @124
EXTERN KIDOJ25 notthatlore25
END

EXTEND_BOTTOM SARMEL01 16
IF ~InParty("DKido") See("DKido")~ THEN EXTERN KIDOJ25 whatisnew
END

CHAIN
IF ~InParty("DKido") See("DKido")~ THEN KIDOJ25 whatisnew
 @125
END
 IF ~~ THEN REPLY @126 EXTERN SARMEL01 17
 IF ~~ THEN REPLY @127 EXTERN SARMEL01 17
 IF ~Gender(Player1,MALE)~ THEN REPLY @128 GOTO kidonotrustme
 IF ~!Gender(Player1,MALE)~ THEN REPLY @128 GOTO kidonotrustme2
 IF ~~ THEN REPLY @129 EXTERN SARMEL01 17

INTERJECT SARTRO03 0 gromniris
 == KIDOJ25 IF ~InParty("DKido") See("DKido") !Race(Player1,HALFORC) !InParty("Ariena")~ THEN
 @130
COPY_TRANS SARTRO03 1

I_C_T 25SPELL 21 notellhectan
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @131 DO ~SetGlobal("lazarusscroll","GLOBAL",1)~
END

I_C_T GORMAD1 8 scaryakkman25
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @132
 == GORMAD1
 @133 DO ~RunAwayFrom(LastTalkedToBy,30)~
 == KIDOJ25
 @134
END

I_C_T GORCAR 4 Lumthemad25
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @135
END

EXTEND_BOTTOM SARVOLO 9 #7
IF ~InParty("DKido")~ THEN REPLY @136 GOTO volokido
END

CHAIN SARVOLO volokido
@137
== KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN @138
EXTERN SARVOLO 9
 
EXTEND_BOTTOM AMTGEN01 0
IF ~InParty("DKido") See("DKido")~ THEN EXTERN KIDOJ25 hidege
END

CHAIN
IF ~InParty("DKido") See("DKido")~ THEN KIDOJ25 hidege
 @139
 == AMTGEN01
@140
 == KIDOJ25
 @141
 == AMTGEN01
 @142 
END
 IF ~ReputationGT(Player1,14)~ THEN REPLY @143 EXTERN AMTGEN01 1
 IF ~~ THEN REPLY @144 EXTERN AMTGEN01 1
 IF ~~ THEN REPLY @145 EXTERN AMTGEN01 2
 IF ~~ THEN REPLY @146 EXTERN AMTGEN01 1
 IF ~ReputationLT(Player1,5)~ THEN REPLY @147 EXTERN AMTGEN01 1

I_C_T AMTGEN01 1 bydege
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @148
END

INTERJECT HGNYA01 25 betrayelfrse
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @149
 == HGNYA01
 @150
 =
 @151
COPY_TRANS HGNYA01 25

I_C_T BALTH 1 WhdoIknBalfr
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @152
END

I_C_T AMCST04 4 Iknowoncaga
 == KIDOJ25 IF ~Global("Iknowoncaga2","LOCALS",0) InParty("DKido") See("DKido")~ THEN
 @153
END

I_C_T AMMAN01 1 Iknowoncag2
 == KIDOJ25 IF ~Global("Iknowoncaga","LOCALS",0) InParty("DKido") See("DKido")~ THEN
 @154
 == AMMAN01
 @155
 == KIDOJ25
 @156
END

I_C_T AMMAN01 1 Iknowoncag3
 == KIDOJ25 IF ~!Global("Iknowoncaga","LOCALS",0) InParty("DKido") See("DKido")~ THEN
 @157
 == AMMAN01
 @155
 == KIDOJ25
 @158
END

I_C_T AMBOY01 0 corruptamboy
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @159
 == AMBOY01
 @160
 == KIDOJ25
 @161
 == AMBOY01
 @162
END

INTERJECT AMSAEMON 3 ahhacifohi
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @163
COPY_TRANS AMMERC01 2

INTERJECT AMSAEMON 6 useusagainhedid
 == KIDOJ25 IF ~InParty("DKido") See("DKido")~ THEN
 @164
COPY_TRANS AMMERC01 5

I_C_T2 CHALCY01 0 kidocyricid
 == CHALCY01 IF ~InParty("DKido") See("DKido")~ THEN
 @165
 == KIDOJ25
 @166 DO ~SetGlobal("BeginChallenge4","GLOBAL",3)~
END

EXTEND_BOTTOM CHALCY01 2 #5
IF ~!Class(Player1,CLERIC_ALL) CheckStatGT(Player1,8,WIS) CheckStatGT(Player1,12,INT) InParty("DKido")~ 
THEN REPLY @167 EXTERN CHALCY01 4
END