I_C_T2 ~SILKE~ 1 X#SafanaSilke
== ~SAFANJ~  IF ~InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~Little Garrick? How very cute. But I say if you get yourself a guard dog, get the one which can bite; a big, strong one. They can fetch and dance on their hind legs as good as the lap variety and even better at times.~
END

//EXTEND_BOTTOM ~SIL~ 0
//IF ~InParty("safana")~ EXTERN ~SAFANJ~ X#SafanaQuest
//END

I_C_T2 ~ARDROU~ 2 X#SafanaArdrouine2
== ~SAFANJ~  IF ~InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~I cannot understand how any woman would want to have a husband and children. I have no time for taking care of anyone but myself… But then again, every matron I met was nowhere nearly as attractive and sophisticated as I am - so maybe they feel that it's pointless?~
END

I_C_T2 ~ARDROU~ 0 X#SafanaArdrouine1
== ~SAFANJ~  IF ~InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~Daarling, you are not going to drag me through the thicket to rescue this brat, are you? I shudder to think what it can do to my skin...~
END

I_C_T ~PALLON~ 3 X#SafanaPallon2
== ~SAFANJ~  IF ~InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~Why, of course the Sword Coast is the centre of the universe. At least for now - because that's where I am. You see, darling, I met this absolutely dashing philosopher once, who tried to seduce me with learning. Much of it were silly things, like giving up material wealth for… something; but one was useful. He taught that the only part of the world that exists is the one that rotates around us. I knew it all along, but it was pleasant to see that the sages are finally catching up with me… ~
END

I_C_T ~PALLON~ 0 X#SafanaPallon1
== ~SAFANJ~  IF ~Gender(Player1, MALE) InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~Daarling, that's quite an old strategy to get yourself invited into a company of dashing men - fiercely denying your desire to join. But you picked the wrong man - <CHARNAME> is too… straightforward to understand your little game. ~
END

INTERJECT_COPY_TRANS ~POE~ 15 PoeTLK
  == ~SAFANJ~  IF ~InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~That was not a particularly good poem. It surprises me that my beauty didn’t inspire him to greater heights.~
END

// Safana comment to Areana:- Noblewoman and Cyrdemac (Baldur’s Gate N)
INTERJECT_COPY_TRANS NOBW8 3 SCTA
  == ~SAFANJ~  IF ~InParty("safana") !Dead("safana") !StateCheck("safana",STATE_SLEEPING)~ THEN ~Darling, you forgot the cardinal rule: always make sure you have more on him than he has on you.~
END

//Safana's Mother Quest

CHAIN 
IF ~~ THEN ~SAFANJ~ X#SafanaQuest
~Wait! Not all of us are 'dirty land folk'. I… my father used to say that I'm of your blood, of sirine's. My mother… she escaped him. I always wanted to find her - I've run away from home with pirates even. But pirates see sirines as prey to catch and sell. So… I've learned nothing of her from them. And when I tried to influence a captian to stop 'Exzesus' from hunting sirines... well, does not matter now. What matters is that you can help me find my mother. Can you?~
== ~SIL~ ~I know you not, but if your story is true... I can help you. The sea is not like your dirt-land, where air suffocates a living voice. Call for your mother at the sea shore and she will hear.~
= ~I can give you a pebble that you can throw into the sea to attract attention of those who know me. They will make sure that the message is delivered even swifter.~
= ~In return you will leave my tribe's land. Now.~
== ~SAFANJ~ ~Please, <CHARNAME>… It is important!~
END
++ ~Well, give me this… pebble. We… we will try to summon your mother, Safana.~ DO ~SetGlobal("X#SafanaMother","GLOBAL",1)~ + X#SAQUEST1.1
+~Gender(Player1, MALE) CheckStatGT(Player1,14,CHR)~ + ~Safana! This woman is lying to you! And it looks like to get to Alaric's cave we need to pass through their land. Chose what is more important to you: Alaric's treasure or a feeble hope to find your mythical mother?~ DO ~SetGlobal("X#SafanaMother","GLOBAL",1)~ + X#SAQUEST1.2
+~OR(2) !Gender(Player1, MALE) !CheckStatGT(Player1,14,CHR)~ + ~Safana! This woman is lying to you! And it looks like to get to Alaric's cave we need to pass through their land. Chose what is more important to you: Alaric's treasure or a feeble hope to find your mythical mother?~ DO ~SetGlobal("X#SafanaMother","GLOBAL",1)~ + X#SAQUEST1.3
++ ~I have no time for this! Attack!~ DO ~SetGlobal("X#SafanaMother","GLOBAL",1)~ + X#SAQUEST1.4

APPEND SAFANJ

// Safana, Larriaz The Sirine - BG Harbor
IF WEIGHT #-1 ~Global("SLTSBGH","GLOBAL",1)~ THEN SLTSBGH1
SAY ~Poor thing. I wish we could have returned her to the sea in time.~
IF ~~ THEN DO ~SetGlobal("SLTSBGH","GLOBAL",2)~ EXIT
END

IF ~Global("X#SafanaMother","GLOBAL",1)~ THEN X#SAQUEST1.1
SAY ~I knew that you were a <PRO_MANWOMAN> of integrity, <CHARNAME>.~
= ~I walked about before I met you, and I saw a high cliff to the north of here. It stretches well into the sea, so a pebble would go into the deep waters, farther away… We should go there to call for my mother!~
IF ~~ THEN DO ~GiveItemCreate("X#SAPEB","Safana",1,0,0) SetGlobal("X#SafanaMother","GLOBAL",2) CreateCreature("x#fw3600",[557.386],3) ChangeEnemyAlly("x#fw3600",NEUTRAL)~ JOURNAL ~Apparently my companion Safana belives herself to be a sirine's daughter. Sil, the Sirine did not disprove this and gave Safana a special pebble to throw into the sea to alert Safana's mother of her daughter's desire to meet. In exchange Sil asked me to get off her lands. Safana would like to throw the pebble off the peninsula point north from here.~
EXIT
END

IF ~Global("X#SafanaMother","GLOBAL",1)~ THEN X#SAQUEST1.2
SAY ~Why, you are a real pirate, darling!~
IF ~~ THEN DO ~SetGlobal("X#SafanaMother","GLOBAL",3)~ EXTERN ~SIL~ 2
END

IF ~Global("X#SafanaMother","GLOBAL",1)~ THEN X#SAQUEST1.4
SAY ~No! That was my only chance, you fool! I will not fight sirines.~
IF ~~ THEN DO ~LeaveParty() EscapeArea() SetGlobal("X#SafanaMother","GLOBAL",5)~ EXTERN ~SIL~ 1
END

IF ~Global("X#SafanaMother","GLOBAL",6)~ THEN X#SAQUEST2.1
SAY ~Darling, it was a pleasure working with you, but you do not hold what I want. I am leaving you to recover my pebbel. Ta-ta.~
IF ~~ THEN DO ~LeaveParty() EscapeArea() SetGlobal("X#SafanaMother","GLOBAL",5)~ EXIT
END

IF ~Global("X#SafanaMother","GLOBAL",7)~ THEN X#SAQUEST3.1
SAY ~Here it is! The point I talked about.~
+~Gender(Player1, MALE) CheckStatGT(Player1,14,CHR)~ + ~Safana! Wait! This 'pebble' is a rare jewel. You know how much it costs? Do not just throw it into the sea!~ DO ~SetGlobal("X#SafanaMother","GLOBAL",8) ActionOverride("x#fw3600",DestroySelf())~ + X#SAQUEST3.2
+~OR(2) !Gender(Player1, MALE) !CheckStatGT(Player1,14,CHR)~ + ~Safana! Wait! This 'pebble' is a rare jewel. You know how much it costs? Do not just throw it into the sea!~ DO ~SetGlobal("X#SafanaMother","GLOBAL",8) ActionOverride("x#fw3600",DestroySelf())~ + X#SAQUEST3.3
++ ~*You hand the 'pebble' over and Safana throws it into the sea. A few ripples appear on the blue surface, and then even they are gone.*~ DO ~SetGlobal("X#SafanaMother","GLOBAL",8) ActionOverride("x#fw3600",DestroySelf())~ + X#SAQUEST3.4
END

IF ~Global("X#SafanaMother","GLOBAL",8)~ THEN X#SAQUEST3.2
SAY ~Indeed it is... And I with such a strong, dear man by my side the time flies. Let us hope my mother will get me message in time and save the gem.~
IF ~~ THEN EXIT
END

IF ~Global("X#SafanaMother","GLOBAL",8)~ THEN X#SAQUEST3.3
SAY ~O, too late now, da-a-arling.~
= ~*Safana throws the 'pebble' into the sea. A few ripples appear on the blue surface, and then even they are gone.*~
= ~Well, that's done. All that is left now is waiting. Perhaps we can go now and return later. I am sure, my mother will be here, waiting for me in just a few weeks. It's a long way from Calimshan... ~
IF ~~ THEN DO ~DestroyItem("X#SAPEB") SetGlobal("X#SafanaMother","GLOBAL",9) SetGlobalTimer("X#SAMOM","GLOBAL",THIRTY_DAYS)~ JOURNAL ~After throwing a precious gem into the sea, Safana is sure that her message will reach her mother-sirine. Perhaps, we can return here in a month or so to show poor rogue that her fantasies are just that....~
EXIT
END

IF ~Global("X#SafanaMother","GLOBAL",8)~ THEN X#SAQUEST3.4
SAY ~Well, that's done. All that is left now is waiting. Perhaps we can go now and return later. I am sure, my mother will be here, waiting for me in just a few weeks. It's a long way from Calimshan... ~
IF ~~ THEN DO ~DestroyItem("X#SAPEB") SetGlobal("X#SafanaMother","GLOBAL",9) SetGlobalTimer("X#SAMOM","GLOBAL",THIRTY_DAYS)~ JOURNAL ~After throwing a precious gem into the sea, Safana is sure that her message will reach her mother-sirine. Perhaps, we can return here in a month or so to show poor rogue that her fantasies are just that....~
EXIT
END

IF ~Global("X#SafanaMother","GLOBAL",12)~ THEN X#SAQUEST4.2
SAY ~She is gone… but she promised to come and see me again. And she gave me these - would not they look good on me?~
IF ~Gender(Player1, MALE) CheckStatGT(Player1,14,CHR)~ THEN DO ~SetGlobal("X#SafanaMother","GLOBAL",13) AddexperienceParty(5000) GiveItemCreate("AMUL11","Safana",1,0,0) GiveItemCreate("MISC44","Safana",1,0,0) GiveItemCreate("RING06","Safana",1,0,0)~ + X#SAQUEST4.3
IF ~OR(2) !Gender(Player1, MALE) !CheckStatGT(Player1,14,CHR)~ THEN DO ~SetGlobal("X#SafanaMother","GLOBAL",13) AddexperienceParty(5000) GiveItemCreate("AMUL11","Safana",1,0,0) GiveItemCreate("MISC44","Safana",1,0,0) GiveItemCreate("RING06","Safana",1,0,0)~ EXIT
END

IF ~~ THEN X#SAQUEST4.3
SAY ~You are a marvelous man, <CHARNAME>, so storng and wise. No wonder that I feel so... sensual around you all the time.~
IF ~~ THEN DO ~SetGlobal("X#SafanaMatch","GLOBAL",1) SetGlobal("X#SafanaRomanceActive","GLOBAL",1)~ EXIT
END

IF ~~ X#SAQUESTComplain
SAY ~I hope that I will find my mother.~
IF ~~ THEN DO ~SetGlobal("PirateTreasure","GLOBAL",1)~ EXIT
END
END

BEGIN X#ARISHA

CHAIN
IF ~Global("X#SafanaMother","GLOBAL",1)~ THEN ~SAFANJ~ X#SAQUEST1.3
~I do not want to hurt my mother's people. But the treasure in the cave is immense.~
== ~SIL~ ~You are not one of us if you care for the trinkets in that deep dirty hole.~
DO ~SetGlobal("X#SafanaMother","GLOBAL",4)~
END ~SIL~ 2

CHAIN 
IF ~Global("X#SafanaMother","GLOBAL",10)~ THEN ~X#ARISHA~ X#SAQUEST4.1
~My land-daughter, I am glad that you have called on me.~
== ~SAFANJ~ ~Mother!~
= ~<CHARNAME>, give us some time… ~
DO ~SetGlobal("X#SafanaMother","GLOBAL",11) RestParty()~
EXIT

EXTEND_BOTTOM ~SAFANJ~ 2
IF ~InParty("safana") GlobalGT("X#SafanaMother","GLOBAL",1) GlobalLT("X#SafanaMother","GLOBAL",12)~ EXTERN ~SAFANJ~ X#SAQUESTComplain
END


