///REPLACEMENTS///

REPLACE ~CORANJ~
IF ~~ THEN BEGIN 4 // from:
SAY ~I'm sorry Briel, but we…we have been over this already…and you have said, that…~
IF ~~ THEN EXTERN ~BRIELB~ 14
END
END

REPLACE ~BRIELB~
IF ~~ THEN BEGIN 14 // from:
SAY ~That you are an idiot. Go,if you want, but maybe someday you'll figure out what is it you really want, elf.~
IF ~~ THEN DO ~SetGlobal("BRIEL_STAY","GLOBAL",1)~
EXIT
END
END

REPLACE ~BRIELB~
IF ~Global("HelpBrielbara","GLOBAL",1)~ THEN BEGIN 16 // from:
SAY ~I must thank you again for the service you have done.~
IF ~Global("CORAN_BABY","GLOBAL",2) Global("BRIEL_STAY","GLOBAL",1)InParty("CORAN")~ THEN GOTO returnBriel
IF ~GlobalLT("CORAN_BABY","GLOBAL",2) Global("BRIEL_STAY","GLOBAL",1)InParty("CORAN")~ THEN GOTO NamaraCor
IF ~Global("BRIEL_STAY","GLOBAL",2)InParty("CORAN")~ THEN GOTO BrielCurse
IF ~Global("BRIEL_STAY","GLOBAL",3)~ THEN GOTO CoranStay
IF ~Global("BRIEL_STAY","GLOBAL",1) !InParty("CORAN")~ THEN EXIT
IF ~!Global("BRIEL_STAY","GLOBAL",1) !InParty("CORAN")~ THEN EXIT
IF ~GlobalGT("BRIEL_STAY","GLOBAL",1)~ THEN EXIT
END
END

////NEW CONTENT////

//GLOBAL BRIEL_STAY 1 - Briel is waiting to be talked to//
//GLOBAL BRIEL_STAY 2 - Coran turned CN need script to make Briel leave//
//GLOBAL BRIEL_STAY 3 - Coran left party need script to make Briel leave//
//GLOBAL BRIEL_STAY 4 - talked to Briel again and took Baby//
//GLOBAL CoranHasBaby 1 - for banters//
//Timer ReturnNamara for >3 weeks is for the romance//
//GLOBAN CoranRomancePath 3 sets the romance to CN path//
//ITEMS: X#CBOOK -guide to parenthood, X#CBABY - Namara, X#CMILK -everlasting milk bottles, X#COBAG -potion case//

APPEND ~CORANJ~

IF WEIGHT #-1 ~
Global("CNRBabeBack","GLOBAL",1)
~ THEN BEGIN CNRBabeBack
SAY ~<CHARNAME>, it's becoming too dangerous to keep Namara around. Not to mention all the bad habits she picks up from our rag-tag band... I'll go talk to Briel.~ [CORAN99]
= ~I hope that I still have some influence over her... *grins* so it should not take me long to presuade her to take money and visits over me babysitting Namara on battlefields. Meet me back in the "Sturgeon", <CHARNAME>.~
IF ~~ THEN DO ~LeaveParty() SetGlobal("KickedOut","LOCALS",1) SetGlobal("CoranMoves","GLOBAL", 4) SetGlobalTimer("Alimony","GLOBAL",604800)~
EXIT
END

IF WEIGHT #-100 ~Global("CoranMoves","GLOBAL",5)
~ THEN BEGIN CNRBack
SAY~ Ah, here you are. Back to adventures! ~
IF ~~ THEN DO ~JoinParty() SetGlobal("CoranMoves","GLOBAL", 6)~
EXIT
END

IF WEIGHT #-1 ~
OR(2)
Global("CORAN_BABY","GLOBAL",1)
Global("CoranPrompted","GLOBAL",2)
Global("BRIEL_STAY","GLOBAL",1)
~ THEN BEGIN CORANBABY
SAY ~May I have a word with you, <CHARNAME>?~ [CORAN99]
IF ~~ THEN REPLY ~Of course, Coran, what is it?~ DO ~SetGlobal("CORAN_BABY","GLOBAL",2)~ GOTO CB_1.1
IF ~~ THEN REPLY ~Yes, but not now.~ DO ~SetGlobal("CORAN_BABY","GLOBAL",2) SetGlobal("CoranRepeat","GLOBAL",1)~ GOTO CB_1.2
IF ~~ THEN REPLY ~Coran…frankly I have no desire to talk to you after what you have done…~ DO ~SetGlobal("CORAN_BABY","GLOBAL",2)~ GOTO CB_1.3
END

IF ~~ THEN BEGIN CB_1.1
SAY ~I…I would like very much to go back and talk to Briel again. The girl might need help, and I feel that I have wronged her… Can we go meet with her?~
IF ~~ THEN REPLY ~Coran, I am glad that you have decided to sort it out. All this made me feel awkward. We should go visit Briel as soon as we are able.~ GOTO CB_1.4
IF ~~ THEN REPLY ~Coran, are you kidding? The girl is blackmailing you! I mean, you never wanted no child, did you? Why do you need to waste your time? She wanted it, so she can take care of the whelp herself!~ GOTO CB_1.5
IF ~~ THEN REPLY ~Well, I am afraid that in this case we should part our company. ~ GOTO CB_1.6
END

IF ~~ THEN BEGIN CB_1.3
SAY ~I understand that, <CHARNAME>. I am unhappy with what I have said to Briel myself. The girl might need help, and I feel that I have wronged her… I…I would like very much to go back and talk to Briel again. Can we go meet with her?~
IF ~~ THEN REPLY ~Coran, I am glad that you have decided to sort it out. All this made me feel awkward. We should go visit Briel as soon as we are able.~ GOTO CB_1.4
IF ~~ THEN REPLY ~Coran, are you kidding? The girl is blackmailing you! I mean, you never wanted no child, did you? Why do you need to waste your time? She wanted it, so she can take care of the whelp herself!~ GOTO CB_1.5
IF ~~ THEN REPLY ~Well, I am afraid that in this case we should part our company.~ GOTO CB_1.6
END

IF ~~ THEN BEGIN CB_1.2
SAY ~We will talk later then.~
IF ~~ THEN DO ~SetGlobal("CoranRepeat","GLOBAL",1)~  EXIT
END

IF ~~ THEN BEGIN CB_1.4
SAY ~Thank you, <CHARNAME>. I feel much better now.~
IF ~~ THEN DO ~SetGlobal("COWillComplain","GLOBAL",1)~  EXIT
END

IF ~~ THEN BEGIN CB_1.5
SAY ~Indeed…the child I have never wanted and a half-breed at that. Half-bloods are always raised by their mothers. Besides, I just don't have the time or inclination to care for my..... I mean Briel’s child.~
IF ~~ THEN DO ~ReputationInc(-1) ChangeAlignment("CORAN",CHAOTIC_NEUTRAL) SetGlobal("BRIEL_STAY","GLOBAL",2) SetGlobal("BRIEL_STAY","GLOBAL",2) SetGlobal("CoranRomancePath","GLOBAL",3)~  EXIT
END

IF ~~ THEN BEGIN CB_1.6
SAY ~*Sighs* You are right. See you in 20 years or so…~
IF ~~ THEN DO ~ReputationInc(-1) LeaveParty()
EscapeArea() SetGlobal("BRIEL_STAY","GLOBAL",3)~  EXIT
END

IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])See(Player1)
Global("CBABY_AGAIN","GLOBAL",1)~ THEN BEGIN CBABY_SECOND
SAY ~I'd like to talk about Briel, <CHARNAME>.~ [CORAN99]
IF ~~ THEN REPLY ~Of course, Coran, what is it?~ DO ~SetGlobal("CBABY_AGAIN","GLOBAL",2)~ GOTO DCB_1.1
IF ~~ THEN REPLY ~Coran…frankly I have no desire to talk to you after what you have done…~ DO ~SetGlobal("CBABY_AGAIN","GLOBAL",2)~ GOTO DCB_1.3
END

IF ~~ THEN BEGIN DCB_1.1
SAY ~I…I would like very much to go back and talk to Briel again. The girl might need help, and I feel that I have wronged her… Can we go meet with her?~
IF ~~ THEN REPLY ~Coran, I am glad that you have decided to sort it out. All this made me feel awkward. We should go visit Briel as soon as we are able.~ GOTO DCB_1.4
IF ~~ THEN REPLY ~Coran, are you kidding? The girl is blackmailing you! I mean, you never wanted no child, did you? Why do you need to waste your time? She wanted it, so she can take care of the whelp herself!~ GOTO DCB_1.5
IF ~~ THEN REPLY ~Well, I am afraid that in this case we should part our company. See you in 20 years or so…~ GOTO DCB_1.6
END

IF ~~ THEN BEGIN DCB_1.3
SAY ~I understand that, <CHARNAME>. I am unhappy with what I have said to Briel myself. The girl might need help, and I feel that I have wronged her… I…I would like very much to go back and talk to Briel again. Can we go meet with her?~
IF ~~ THEN REPLY ~Coran, I am glad that you have decided to sort it out. All this made me feel awkward. We should go visit Briel as soon as we are able.~ GOTO DCB_1.4
IF ~~ THEN REPLY ~Coran, are you kidding? The girl is blackmailing you! I mean, you never wanted no child, did you? Why do you need to waste your time? She wanted it, so she can take care of the whelp herself!~ GOTO DCB_1.5
IF ~~ THEN REPLY ~Well, I am afraid that in this case we should part our company.~ GOTO DCB_1.6
END

IF ~~ THEN BEGIN DCB_1.4
SAY ~Thank you, <CHARNAME>. I feel much better now.~
IF ~~ THEN DO ~SetGlobal("COWillComplain","GLOBAL",1)~  EXIT
END

IF ~~ THEN BEGIN DCB_1.5
SAY ~Indeed…the child I have never wanted and a half-breed at that. Half-bloods are always raised by their mothers. Besides, I just don't have the time or inclination to care for my..... I mean Briel’s child.~
IF ~~ THEN DO ~ReputationInc(-1) ChangeAlignment("CORAN",CHAOTIC_NEUTRAL) SetGlobal("BRIEL_STAY","GLOBAL",2) SetGlobal("CoranRomancePath","GLOBAL",3)~  EXIT
END

IF ~~ THEN BEGIN DCB_1.6
SAY ~*Sighs* You are right. See you in 20 years or so…~
IF ~~ THEN DO ~ReputationInc(-1) LeaveParty()
EscapeArea() SetGlobal("BRIEL_STAY","GLOBAL",3)~  EXIT
END

IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])See(Player1)
Global("BRIEL_STAY","GLOBAL",1)
Global("CB_COMPLAINS","GLOBAL",1)~ THEN BEGIN CB_COMPLAINT
SAY ~Ahem, <CHARNAME>, I know we are rather busy, but I really need to talk to Briel…Can we go see her now?~ [CORAN99]
IF ~~ THEN REPLY ~We should go visit Briel as soon as we are able.~ DO ~SetGlobal("CB_COMPLAINS","GLOBAL",2)~ GOTO CB_2.1
IF ~~ THEN REPLY ~Coran, I like this idea less and less. The girl is just blackmailing you! I mean you never wanted no child, did you? Why do you need to waste your time? She wanted it, so she can take care of the whelp herself.~ DO ~SetGlobal("CB_COMPLAINS","GLOBAL",2)~ GOTO CB_2.2
IF ~~ THEN REPLY ~Well, I am afraid that in this case we should part our company. See you in 20 years or so…~ DO ~SetGlobal("CB_COMPLAINS","GLOBAL",2)~ GOTO CB_2.3
END

IF ~~ THEN BEGIN CB_2.1
SAY ~Thank you, <CHARNAME>. I feel much better now.~
IF ~~ THEN DO ~SetGlobal("COWillQuit","GLOBAL",1)~  EXIT
END

IF ~~ THEN BEGIN CB_2.2
SAY ~Indeed…the child I have never wanted and a half-breed at that. Half-bloods are always raised by their mothers. Besides, I just don't have the time or inclination to care for my..... I mean Briel’s child.~
IF ~~ THEN DO ~ReputationInc(-1) ChangeAlignment("CORAN",CHAOTIC_NEUTRAL) SetGlobal("BRIEL_STAY","GLOBAL",2) SetGlobal("BRIEL_STAY","GLOBAL",2) SetGlobal("CoranRomancePath","GLOBAL",3)~  EXIT
END

IF ~~ THEN BEGIN CB_2.3
SAY ~Well, I am afraid that in this case we should part our company. See you in 20 years or so…~
IF ~~ THEN DO ~ReputationInc(-1) LeaveParty()
EscapeArea() SetGlobal("BRIEL_STAY","GLOBAL",3)~  EXIT
END

IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])See(Player1)
Global("CB_QUITS","GLOBAL",1)~ THEN BEGIN CB_QUITS
SAY ~Briel is not going to wait forever! It is apparent that you have things more important to attend to than the fate of my daughter. I do not. See you in 20 years or so…~ [CORAN99]
IF ~~ THEN DO ~SetGlobal("CB_QUITS","GLOBAL",2)SetGlobal("BRIEL_STAY","GLOBAL",3) LeaveParty()
EscapeArea()~  EXIT
END

IF ~~ THEN BEGIN CoranRun
SAY ~Thank you, <CHARNAME>. I am no coward, but when the baby's life is at stake...I will run for it.~
IF ~~ THEN DO ~SetGlobal("CoranHasBaby","GLOBAL",1) SetGlobalTimer("ReturnNamara","GLOBAL",151500)~ EXIT
END

IF ~~ THEN BEGIN Grumbles
SAY ~Erm...<CHARNAME>. It cannot be that bad, can it?~
IF ~~ THEN DO ~SetGlobal("CoranHasBaby","GLOBAL",1) SetGlobalTimer("ReturnNamara","GLOBAL",151500)~ EXIT
END

IF ~~ THEN BEGIN Lover
SAY ~I...I am glad that you see it that way. It is a bastard child after all.~
IF ~~ THEN DO ~SetGlobal("CoranHasBaby","GLOBAL",1) SetGlobalTimer("ReturnNamara","GLOBAL",151500)~ EXIT
END

IF ~~ THEN BEGIN CoranMumbles
SAY ~I...I...Briel...I do not know.~
IF ~~ THEN DO ~SetGlobal("CoranPrompted","GLOBAL",1)~
EXTERN BRIELB BrielCurse
END

IF ~~ THEN BEGIN CoranSigh
SAY ~*Sighs* I am sorry, beautiful, but there is really nothing I can do for you or your child.~
IF ~~ THEN EXIT
END

END


APPEND ~BRIELB~
IF ~Global("BRIEL_STAY","GLOBAL",1)InParty("CORAN")~ THEN BEGIN returnBriel
SAY ~Coran?~
IF ~~ THEN EXTERN ~CORANJ~ CBaby_Chain
END

IF ~~ THEN BEGIN BRIEL_PC
SAY ~Thank you, again, <CHARNAME>.~
IF ~~ THEN REPLY ~Brielbara, I promise you, that if it gets hot, Coran will run and save the child.~ DO ~SetGlobal("BRIEL_STAY","GLOBAL",4) GiveItemCreate("X#CBABY","Coran",1,0,0) GiveItemCreate("X#CBOOK","Coran",1,0,0) GiveItemCreate("X#COBAG","Coran",1,0,0) GiveItemCreate("X#CMILK","Coran",1,0,0)~ EXTERN ~CORANJ~ CoranRun
IF ~~ THEN REPLY ~You are a mad woman, Brielbara, but we'll try to keep Namara safe and well.~ DO ~SetGlobal("BRIEL_STAY","GLOBAL",4) GiveItemCreate("X#CBABY","Coran",1,0,0) GiveItemCreate("X#CBOOK","Coran",1,0,0) GiveItemCreate("X#COBAG","Coran",1,0,0) GiveItemCreate("X#CMILK","Coran",1,0,0)~ EXTERN ~CORANJ~ CoranRun
IF ~~ THEN REPLY ~Great, just great. That's *just* what we need.~ DO ~SetGlobal("BRIEL_STAY","GLOBAL",4) GiveItemCreate("X#CBABY","Coran",1,0,0) GiveItemCreate("X#CBOOK","Coran",1,0,0) GiveItemCreate("X#COBAG","Coran",1,0,0) GiveItemCreate("X#CMILK","Coran",1,0,0)~ EXTERN ~CORANJ~ Grumbles
IF ~Global("CoranRomancePath","GLOBAL",1)~ THEN REPLY ~You have done well, my love.~ DO ~SetGlobal("BRIEL_STAY","GLOBAL",4) GiveItemCreate("X#CBABY","Coran",1,0,0) GiveItemCreate("X#CBOOK","Coran",1,0,0) GiveItemCreate("X#COBAG","Coran",1,0,0) GiveItemCreate("X#CMILK","Coran",1,0,0)~ EXTERN ~CORANJ~ Lover
END

IF ~InParty("CORAN")~ THEN BEGIN NamaraCor
SAY ~Coran? Do not you even want to see Namara? She has your eyes...elven eyes.~
IF ~~ THEN EXTERN ~CORANJ~ CoranMumbles
END

IF ~InParty("CORAN")~ THEN BEGIN BrielCurse
SAY ~I curse the day I layed my eyes on you, Coran.~
IF ~~ THEN EXTERN ~CORANJ~ CoranSigh
END

IF ~InParty("CORAN")~ THEN BEGIN CoranStay
SAY ~And...thank you for sending that no good thief my way. *Sighs dreamily* He is not *that* bad actually.~
IF ~~ THEN EXIT
END

END

CHAIN3 ~CORANJ~ CBaby_Chain
~Ahem, Briel...I did a lot of thinking and... I come to apologize, Briel...~
== ~BRIELB~ ~Apology? What do I need an apology for? Would it put food on Namara’s plate and clothes on her back? Or should I sing your apology as a lullaby for her, when she would not stop crying for her father?~
== ~CORANJ~ ~Eh, Briel, slow down! I came to offer my help as well. I know, that we disagree about my hmm...lifestyle, and that you are too noble to be a thief’s mate...~
== ~BRIELB~ ~Coran, why must you be so incredibly stubborn about it? You are going to end up in prison or hanged for a bandit, silly Elf. I know you have a better heart than that...why would not you...~
== ~CORANJ~ ~Briel, Briel... Please, let us spare the further details of our favorite argument to <CHARNAME>. The City of Baldur’s Gate needs something newer than that to listen to. I am not cut out for becoming a merchant or some other respectful member of a society.~
== ~BRIELB~ ~A pity...~
== ~CORANJ~ ~May be. Briel, I promise you that every time I’d come into money, Namara and you will have... ~
== ~BRIELB~ ~I see. Coran, I feel that you are sincere and that you do want to help. However, I am afraid that will not be enough, not with your peculiar notion on what responsibility is. I have an idea though, on how you can help.~
== ~CORANJ~ ~What would you have me do, Briel? I agree to anything, except for settling down, of course.~
== ~BRIELB~ ~It has been rough going for us lately with Namara sick and my husband plotting against us... He took all, Coran! House, money, everything. I can hardly get by, and I am so tired... Would you take Namara with you and take care of her for a while to give me some time to get back to my feet?~
== ~CORANJ~ ~Huh, Briel...are you sure? I lack knowledge on baby care. I doubt that I can...you know...feed the baby and...and do whatever else you have to do. Actually, I know nothing of babies at all.~
== ~BRIELB~ ~Then it is past time that you learnt. She is now at an age when she does not require breast feeding and I have here a book of helpful hints...~
== ~CORANJ~ ~Briel! Not that I refuse, but won’t it be dangerous for a child to travel with me? We are constantly fighting for our lives and...~
== ~BRIELB~ ~It is no more dangerous for her in your company than in that place in the bowels of this city I keep her now...I never know if she won’t be sold to some slavers or killed out of spite by some lowlife while I am away... Coran, desperate people cannot be choosy.~
== ~CORANJ~ ~Would you want to travel with me then? I am sure <CHARNAME>...~
== ~BRIELB~ ~No, Coran, I will not be a part of a mercenary group and I would not go about robbing people with you. My reputation is ruined as is. If you want to help - take care of Namara for a bit...~
== ~CORANJ~ ~Well, if that’s what you want me to do, I will do it.~
== ~BRIELB~ ~Good. Thank you, Coran. And do not look so sour, you might come to enjoy it after all. Here is the book and I will bring Namara in a moment.~
END  ~BRIELB~ BRIEL_PC
