BEGIN ~X#XZAR~

APPEND ~BXZAR~

IF WEIGHT #-2 ~
Global("XzFriendTalk","GLOBAL",1)
Global("XZPC1","LOCALS",0)~ THEN BEGIN XZPC1
SAY ~<CHARNAME>, one cannot remain long in your company without observing that you have been having …troublesome…dreams of late.~ [XZAR99]
IF ~~ THEN REPLY ~Of what concern are my dreams to a necromancer?~ DO ~SetGlobal("XZPC1","LOCALS",1)~ GOTO XZPC1.1
IF ~~ THEN REPLY ~Once or twice. Why, do they interfere with your beauty rest?~ DO ~SetGlobal("XZPC1","LOCALS",1)~ GOTO XZPC1.2
IF ~~ THEN REPLY ~If I knew you cared, I’d have brought you along...~ DO ~SetGlobal("XZPC1","LOCALS",1)~ GOTO XZPC1.3
IF ~~ THEN REPLY ~My dreams are my own affair. Leave them be.~ DO ~SetGlobal("XZPC1","LOCALS",1)~ GOTO XZPC1.4
END

IF ~~ THEN BEGIN XZPC1.1
SAY ~All things relating to so stalwart a companion as yourself are of interest to me, <CHARNAME>.~
IF ~~ THEN REPLY ~Are you suggesting that *I* am of interest to *you*… personally?~ GOTO XZPC1.5
IF ~~ THEN REPLY ~Would that I could say as much of you.~ GOTO XZPC1.6
IF ~~ THEN REPLY ~Dare to mention my dreams again and I’ll rip your lungs out.~ GOTO XZPC1.7
END

IF ~~ THEN BEGIN XZPC1.2
SAY ~Abominably, now that you mention it, but that was not my point.~
IF ~~ THEN REPLY ~You have a point?  Let’s hear it!~ GOTO XZPC1.8
IF ~~ THEN REPLY ~Well, don’t point it at me.  My dreams are my own.~ GOTO XZPC1.4
IF ~~ THEN REPLY ~*My* point will rejoice in your heart if you do not silence your mouth this instant!~ GOTO XZPC1.7
END

IF ~~ THEN BEGIN XZPC1.3
SAY ~If *I* dreamt that you were competent to return me also, I would go.  However, at present, I am concerned with what these dreams presage for your waking self.~
IF ~~ THEN REPLY ~Relax.  They’re just bad dreams, nothing more!~ GOTO XZPC1.4
IF ~~ THEN REPLY ~Look, I’ve had some bad times lately.  The wonder is that my dreams aren’t worse.~ GOTO XZPC1.4
IF ~~ THEN REPLY ~They presage YOUR death if you do not cease yammering!~ GOTO XZPC1.7
END


IF ~~ THEN BEGIN XZPC1.4
SAY ~I hope you are as uncertain of that as you sound, <CHARNAME>.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN XZPC1.5
SAY ~Don’t be absurd!  I merely wish to assure myself that your nightmares do not presage… insanity, or… possession.~
IF ~~ THEN REPLY ~Relax.  They’re just bad dreams, nothing more!~ GOTO XZPC1.4
IF ~~ THEN REPLY ~Look, I’ve had some bad times lately.  The wonder is that my dreams aren’t worse.~ GOTO XZPC1.4
IF ~~ THEN REPLY ~They presage YOUR death if you do not cease yammering!~ GOTO XZPC1.7
END

IF ~~ THEN BEGIN XZPC1.6
SAY ~You could, if you could cease for a moment wallowing in doltish self-absorption.  Alas, some miracles are beyond even my power.  No, I shall sully my intellect no further by such contact.~
IF ~~ THEN EXIT
END


IF ~~ THEN BEGIN XZPC1.7
SAY ~A most… revealing… reply.  Thank you, <CHARNAME>.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN XZPC1.8
SAY ~I have… no, ‘tis bootless to light the way for one whose eyes are shut tight.  <CHARNAME>, our joint effort possibly requires that you be whole of mind.  Yet your dreams presage an… other-ness within you that may… might… gain sway over your semi-conscious self.~
IF ~~ THEN REPLY ~Relax.  They’re just bad dreams, nothing more!~ GOTO XZPC1.4
IF ~~ THEN REPLY ~Look, I’ve had some bad times lately.  The wonder is that my dreams aren’t worse.~ GOTO XZPC1.4
IF ~~ THEN REPLY ~They presage YOUR death if you do not cease yammering!~ GOTO XZPC1.7
END

END

////////////////NEEDS CHECKING!////////////////
CHAIN
IF WEIGHT #-2 ~
Global("XZYE1","LOCALS",1)~ THEN ~XZARJ~ XZYE1
~Flo-oating away-ay.  Flo-oating away-HAY!~ [XZAR99]
END ~BXZAR~  XZYE1PC

APPEND ~BXZAR~

IF ~~ THEN BEGIN XZYE1PC
SAY ~Floating aw-~
IF ~~ THEN REPLY ~Xzar!~ DO ~SetGlobal("XZYE1","LOCALS",2)~ GOTO XZYE1.1
END

IF ~~ THEN BEGIN XZYE1.1
SAY ~Oh?  Did I say that aloud?~
IF ~~ THEN REPLY ~You *sang* it aloud. Think of Yeslick’s feelings!~ GOTO XZYE1.1YE
END

END

///////////DREAM SCRIPT////
CHAIN
IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("XZIM1","GLOBAL",1)~ THEN ~BXZAR~ XZIM1
~Ah, child, find anything of interest in our collective pocket as yet?~ [XZAR99]
DO ~SetGlobal("XZIM1","GLOBAL",2)~ 
== ~BIMOEN2~ ~Eh…no, just lint and crumbs.  Why?  You holding something back?~
== ~BXZAR~ ~I am not.  Just the poor tools of my trade as you have those of yours.~
== ~BIMOEN2~ ~Mm-hmm.  A surgical knife and gloves, parchment, quills, ink, a ball of gut-string, four empty ceramic vials and two steel vials that feel empty.~
= ~What are those stoppered with anyway?  It isn’t cork.  Seems more like some kind of tar.~
== ~BXZAR~ ~You *have* been curious.  They are non-reactive plugs made by specialists back at…of my acquaintance. One never knows when one might wish to preserve a… specimen.~
== ~BIMOEN2~ ~Specimen?  Of what?~ 
== ~BXZAR~ ~One never knows.  Why just the other day, I espied what I took for a specimen of true happiness.  Alas!  It fled before I could make certain of it.~
== ~BIMOEN2~ ~Bet that happens to you a lot.~ 
== ~BXZAR~ ~All things come to those who aspire… and wait.  Wait for someone to finish the drudge-work, damn their idle bones!  Why *can’t* they do their work and let me get on with mine?~
== ~BIMOEN2~ ~Maybe you haven’t waited long enough yet.~ 
== ~BXZAR~ ~*sigh* Probably not.  Would you like a jelly drop, Imoen?~
== ~BIMOEN2~ ~Uh… do you have any?~ 
== ~BXZAR~ ~I had some once-upon-a-time, and I should like another.  Please keep that in mind, should you run across any, hmmm?~
DO ~RestParty()~
EXIT

/////DREAM SCRIPT/////
CHAIN
IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
AreaType(FOREST)
Global("XZIM1","GLOBAL",3)~ THEN ~BXZAR~ XZIM2
~My child, you’ve been ignoring me.  That is very unkind of you.~ [XZAR99]
DO ~SetGlobal("XZIM1","GLOBAL",4)~
== ~BIMOEN2~ ~N-no, just ain’t had much to say, is all.~
== ~BXZAR~ ~Then heed me now, child.  How many deaths do you bear within you?~
== ~BIMOEN2~ ~Whew!  Just one quick, painless one, I hope.~
== ~BXZAR~ ~Truly?  And what of the children you will someday have, and their children and theirs again?  Consider this multitude, lining up before the pit of death, like gladiators in the arena.~
== ~BIMOEN2~ ~Are you *trying* to creep me out, Xzar?  Cause you’re doing a great job of it.~ 
== ~BXZAR~ ~Oh.  Then pass me my blue blankie, would you?  It’s just beside your knee there on the sward.~
DO ~RestParty()~
EXIT

/////SCRIPTS KILLED DAVAERON/////
CHAIN
IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("XZIM3","GLOBAL",1)~ THEN ~XZARJ~ XZIM3
~*Sings loudly* Ding, dong, the lich is dead, which oh lich, the wicked lich…~ [XZAR99]
DO ~SetGlobal("XZIM3","GLOBAL",2)~
== ~BIMOEN2~ ~Hey!  Pipe down, Xzar.  There’s still a lot of guards around.  You want ‘em all here in the room with us?~
== ~BXZAR~ ~Pfah!  They are nothing.  Yon agent of wickedness as met his term.  Is that not due cause for joy?  A song?  A birthday party?~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~Never thought o’ puttin’ candles on a fruitcake before.~
== ~BIMOEN2~ ~Okay!  We’ll throw a real wing ding when we get topside.  But let’s get there first; this place creeps me out.~
== ~BXZAR~ ~Your fussy practicality has slain joy in this place as dead as that wizard. Let us, then, take your implicit advice, instead. Loot and begone!~
EXIT

CHAIN
IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
Global("XZJA2","GLOBAL",1)~ THEN ~XZARJ~ XZJA2
~*Sings loudly* Ding, dong, the lich is dead, which oh lich, the wicked lich…~ [XZAR99]
DO ~SetGlobal("XZJA2","GLOBAL",2)~
== ~BJAHEI~ ~Restrain your hilarity lest you call every surviving guard to this room.~
== ~BXZAR~ ~Pfah!  They are nothing.  Yon agent of wickedness as met his term.  Is that not due cause for joy?  A song?  A birthday party?~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~Never thought o’ puttin’ candles on a fruitcake before.~
== ~BJAHEI~ ~It will be time enough for celebration when we are outside this wretched pit, Zhent.~ 
== ~BXZAR~ ~Zhent, is it?!  It is a poor servant of the Balance that grudges calling upon an alleged evil to redress this undoubted one.~
== ~BKHALI~ IF ~InParty("KHALID")~ THEN ~Though I might s-say that whoever wins between the Zhents and th-these slavers, the balance will be perverted to Evil.~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~Ye might – if’n ye could say anythin’ straight.~
== ~BXZAR~ IF ~InParty("MONTARON")~ THEN ~Hush, Monty. Let our esteemed colleagues have their say – tee-hee, as best they might.~
== ~BJAHEI~ ~Cruelty in small things as well as great.  Can you wonder why we oppose you?~
== ~BXZAR~ ~Yes, I could.  But your sourness has ended wonderment here as well as joy.  So we will take your implied advice instead.  Loot and begone!~
EXIT


CHAIN
IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])InParty("JAHEIRA")
Global("XZJA3","GLOBAL",1)~ THEN ~XZARJ~ XZJA3
~*Sings loudly* Ding, dong, the lich is dead, which oh lich, the wicked lich…~ [XZAR99]
DO ~SetGlobal("XZJA3","GLOBAL",2)~
== ~BJAHEI~ ~Restrain your hilarity lest you call every surviving guard to this room.~
== ~BXZAR~ ~Pfah!  They are nothing.  Yon agent of wickedness as met his term.  Is that not due cause for joy?  A song?  A birthday party?~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~Never thought o’ puttin’ candles on a fruitcake before.~
== ~BJAHEI~ ~It will be time enough for celebration when we are outside this wretched pit, Zhent.~ 
== ~BXZAR~ ~Zhent, is it?!  It is a poor servant of the Balance that grudges calling upon an alleged evil to redress this undoubted one.~
== ~BJAHEI~ ~Wretch! My hus…Khalid has fallen on this quest. Must I suffer your inanities as well?~
== ~BXZAR~ ~Ah, but he looks so at peace. Like a lawn ornament of the tackier sort.~
== ~BJAHEI~ ~Cruelty in small things as well as great.  Can you wonder why we oppose you?~
== ~BXZAR~ ~Yes, I could.  But your sourness has ended wonderment here as well as joy.  So we will take your implied advice instead.  Loot and begone!~
EXIT


CHAIN3 ~BXZAR~ XZYE1.1YE
~~
== ~BYESLI~ ~Nay matter. There be wisdom in the wizard’s mocking tune fer me.~
== ~BXZAR~ ~HA!  All applaud the rapidity of the squatling’s perception!~
== ~BYESLI~ ~I’ve nae clanbrothers left ta hold this place against the Throne. An' I've seen the evil me home can be put ta if undefended.~
= ~‘Flo-oating away-ay.’Aye, ‘tis best so.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("AJANTIS")
See("AJANTIS")
!StateCheck("AJANTIS",STATE_SLEEPING)
AreaType(FOREST)
TimeofDay(DAY)
Global("XZAJ1","LOCALS",0)~ THEN ~BXZAR~ XZAJ1
~Sir Paladin, quickly! A dragon!~ [XZAR99]
DO ~SetGlobal("XZAJ1","LOCALS",1)~
== ~BAJANT~ ~Eh, what? I see nothing.~
== ~BXZAR~ ~There! In that gorse bush!~
== ~BAJANT~ ~Your mockery is repellent as is all else about you. You see clearly enough that I am a paladin but feign to believe that a sparrow is a dragon.~
== ~BXZAR~ ~Ah, your pardon, sirrah; curse these wandering senses of mine.  I perceive now that I was twice mistaken.~
== ~BAJANT~ ~Twice?!~
== ~BXZAR~ ~Indeed. For an instant, I had truly believed yon twitting avian to be a paladin.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("AJANTIS")
See("AJANTIS")
!StateCheck("AJANTIS",STATE_SLEEPING)
AreaCheck("FW3600")
Dead("SIRINE")
Global("XZAJ2","LOCALS",0)~ THEN ~BXZAR~ XZAJ2
~These lovely spirit's dead. ‘Tis a black day, indeed…~ [XZAR99]
DO ~SetGlobal("XZAJ2","LOCALS",1)~
== ~BAJANT~ ~I should not have thought you so susceptible to natural beauty, Xzar. Perhaps I have misjudged you…~
== ~BXZAR~ ~Alas, that I should contemplate such carnage without a single vial-~
== ~BAJANT~ ~Vile? Well, I admit they tried to ensnare and then slay us but such is their wont…~
== ~BXZAR~ ~No, you idiot, VIAL! Ceramic receptacles for their hearts’ blood. You don’t expect me to mop up their muckage with my cloak, do you? It would be no good afterwards, I assure you.~
== ~BAJANT~ ~You … would ….experiment upon these misguided creatures?~
== ~BXZAR~ ~Aha! Dawn after the darkest night. Of course I would experiment on them. What would *you* have me do…eat them?~
== ~BAJANT~ ~Truly, I *have* misjudged you. Far too favorably, I deem.~
== ~BXZAR~ ~Good Sir Knightly, ‘tis a harsh and penurious world. One simply cannot afford to miss opportunities such as this for want of the appropriate equipment.~
= ~Although now you mention it… sirine is delicate, like young sole, not at all heavy like old beef. Grilled loin, thinly sliced, with a few robins’ eggs and a bit of cress for garnish and it might be…~
== ~BXZAR~ IF ~InParty("MONTARON")~ THEN ~I’ll ask Monty what he thinks.~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~I thinks ye be thinkin’ too slow. They already smells somethin’ fierce.~
== ~BXZAR~ IF ~InParty("MONTARON")~ THEN ~*sigh* It seems to be my day for missing opportunities. I really should have cast my horoscope before stirring this morn.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("ALORA")
See("ALORA")
!StateCheck("ALORA",STATE_SLEEPING)
Global("XZAL1","LOCALS",0)~ THEN ~BXZAR~ XZAL1
~Oh little lady lightfinger, please tell me a story.~ [XZAR99]
DO ~SetGlobal("XZAL1","LOCALS",1)~
== ~BALORA~ ~Wh-what kind of story do you want to hear?~
== ~BXZAR~ ~A happy little fable about merry halflings gossiping, drinking ale, butchering their flocks, drawing each nerve forth separately from their victims to prolong the ecstatic agony until it becomes an art form.~
== ~BALORA~ ~That’s awful! I…I don’t think I like you!~
== ~BXZAR~ ~Me? What have I do with it? I was asking *you* about halflings.~
== ~BALORA~ ~We’re not like THAT! And I won’t say what we are like; *you* clearly wouldn’t understand.~
== ~BXZAR~ ~Hmph. Judging by dear Monty’s little hobbies…but you are quite right. The matter is of no consequence whatsoever to such as I. I was merely essaying a bit of polite conversation… obviously a wasted effort.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("BRANWEN")
See("BRANWEN")
!StateCheck("BRANWEN",STATE_SLEEPING)
Global("XZBR1","LOCALS",0)~ THEN ~BXZAR~ XZBR1
~Mooo. Moooo! MOOOO!…uh…I say.~ [XZAR99]
DO ~SetGlobal("XZBR1","LOCALS",1)~
== ~BBRANW~ ~Do not cease your lowing. It is far less odious than your usual discourse.~
== ~BXZAR~ ~B-but ‘tis beefsteak time and…no, damn it! ‘Tis a fruit-eating day for me.~
== ~BBRANW~ ~Tell me when ‘tis due and I’ll dispatch you to the knacker’s with good cheer.~
== ~BXZAR~ ~You misunderstand…of course you would. I was testing the basic theory of magic about like calling to like.~
== ~BBRANW~ ~Then you have committed the simple error of identifying yourself with a cow’s head as opposed to her nether quarters.~
== ~BXZAR~ ~As a cow’s head, I am answered by the nether end! Another theory vindicated by practice! Thank you, dear lady, for prompting me upon the essence of the matter.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
!StateCheck("CORAN",STATE_SLEEPING)
Global("XZCO1","LOCALS",0)~ THEN ~BXZAR~ XZCO1
~<CHARNAME> must be going mad.~ [XZAR99]
DO ~SetGlobal("XZCO1","LOCALS",1)~
== ~BCORAN~ ~I didn’t realize that such affliction was contagious. I’ll keep my distance.~
== ~BXZAR~ ~Buffoon! ‘Tis you whom I hold to be evidence for my case.~
== ~BCORAN~ ~Oh? You believe that acquiring an archer of my talent is a sign of madness?~
== ~BXZAR~ ~Clots the area where great spells should be cast. Where *I* am!~
== ~BCORAN~ ~Take heart, wizard. At need, you’ll find my bladecraft no less able than my marksmanship. A comforting companion for yourself, I would say, should our little band be assailed from the flank.~
== ~BXZAR~ ~Really?  You would sacrifice yourself to save me?  On such short acquaintance?  Truly, I had thought you incapable of such rapid discernment.~
== ~BCORAN~ ~I did not say “sacrifice” exactly. I’m no more suicidal than you are.~
== ~BXZAR~ ~What?!?  Unwilling to die in so worthy a cause?  Then I was right! <CHARNAME> *is* an idiot!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("DYNAHEIR")
See("DYNAHEIR")
!StateCheck("DYNAHEIR",STATE_SLEEPING)
Global("XZDY1","LOCALS",0)~ THEN ~BXZAR~ XZDY1
~Oh, witch, I would know…uh…~[XZAR99]
DO ~SetGlobal("XZDY1","LOCALS",1)~
== ~BDYNAH~ ~Yes?  Out with thy question and hast it done.~
== ~BXZAR~ ~If you’re a *real* witch, why don’t you cackle more often?  And, where, pray tell, do you conceal about your person your cat, your broom and your black, pointy hat?~
== ~BDYNAH~ ~I do not understand thy references, but they sound like refugees from tales for children.~
== ~BXZAR~ ~No!  No, no, no, no, noooo!  Mummy wouldn’t tell a lie! She wouldn’t!~
== ~BDYNAH~ ~Maybe she didst not, but rest assured that she was not relating of mine homeland, either. In Rashemen, the 'witches' art the sisterhood of mages who govern the land and art properly named Hathran.~
== ~BXZAR~ ~I don’t like your witches!  They’re mean!  I like Mummy’s witches better.  They fly through the air and cackle and… and … eat bad little boys for breakfast.  Why can’t you be a witch like that?~
== ~BDYNAH~ ~*sigh* Were I to consume *all* the ‘bad little boys’ whom I encounter, I should soon grow too great in girth to fly over an anthill.~
== ~BXZAR~ ~Oh.  That’s true… you really should exercise more, you know.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("XZED1","LOCALS",0)~ THEN ~BXZAR~ XZED1
~Ah, redlegs, contemplating the sources of the Infinite again, eh?~[XZAR99]
DO ~SetGlobal("XZED1","LOCALS",1)~
== ~BEDWIN~ ~Your overestimation of my current subject is understandable.  However, I fear my ineffable flow of thought has been diverted to a channel far more base for the nonce.~
== ~BXZAR~ ~Panda bears on roller skates!  Or balloons.  Bright-colored balloons rising to the sun and bursting with such futile little pops…~
== ~BEDWIN~ ~Your comprehension of the trivial is at a level with your grasp of the profound.  Nil, in both cases.~
== ~BEDWIN~ IF ~InParty("MONTARON")~ THEN ~And inform your halfling ‘friend’ that I have just traversed the region now directly behind me.  There is nothing there to merit his covert attention.~
== ~BXZAR~ IF ~InParty("MONTARON")~  THEN ~You would be surprised… one day, will be surprised, I trust… to learn what interests Montaron~
== ~BXZAR~ ~But… but… you’re mean! You don’t like pandas or balloons and you’re a big phony, too. You weren’t thinking anything at all.  You couldn’t!  Because *I* was thinking EVERYTHING!  There was nothing left for you!~
== ~BEDWIN~ ~You are mistaken. I was considering a number of agreeable methods whereby a deranged necromancer might be put out of his – and, far more importantly, out of *my* – misery.~
== ~BXZAR~ ~When ye settle on one, I’d like to hear it. Each stick’s got two ends, after all.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("XZEL1","LOCALS",0)~ THEN ~BXZAR~ XZEL1
~Eldoth, sing me a song, a happy song of a mother’s betrayal of her loving son.~ [XZAR99]
DO ~SetGlobal("XZEL1","LOCALS",1)~
== ~BELDOT~ ~You set me a strange theme, mage.  I know many of the obverse sort but none to suit your request.~
== ~BXZAR~ ~Then make one!  The gods themselves cry out for it!~
== ~BELDOT~ ~Perhaps if you gave me a bit more material than the bare words….~
== ~BXZAR~ ~No, no, no!  That won’t do at all.  I had thought to ask you to sing at my wedding.  Or my funeral.  Whichever.  But you have no comfort for me.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("XZEL2","LOCALS",0)~ THEN ~BXZAR~ XZEL2
~Eldoth, you have known women…~ [XZAR99]
DO ~SetGlobal("XZEL2","LOCALS",1)~
== ~BELDOT~ ~Aye, one or two.~
== ~BXZAR~ ~Then tell me, how do you treat the urge to delve deeper, ever inward, to the black core of squalid putrescence?~
== ~BELDOT~ ~By feeling nothing of the sort, if I understand you.  Groping their outsides is oft hard enough labor for me.  And their gold is not lighter nor more plentiful for having blood on it.~
== ~BXZAR~ ~Gold?  What has gold to do with it?~
== ~BELDOT~ ~Why, ‘tis the world’s finest erotic enchantment, sir.~
== ~BXZAR~ ~Truly, your words are like jellyfish, capable of any shape or none.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("FALDORN")
See("FALDORN")
!StateCheck("FALDORN",STATE_SLEEPING)
Global("XZFA1","LOCALS",0)~ THEN ~BXZAR~ XZFA1
~Oh priestess of stone, wood and mud, what difference can one person – even I – make in the great scheme of things?  Reassure me, I beg, for I am nigh disparaging.~ [XZAR99]
DO ~SetGlobal("XZFA1","LOCALS",1)~
== ~BFALDO~ ~You’ll get no comfort here, madman.  The seasons roll on without let or hindrance from any man or all.~
== ~BXZAR~ ~Phah!  The seasons, how I loathe them!  Spring is for young animals from the waist down.  Summer enervates the bones.  In autumn one eats beyond the point of biliousness.  And winter…ah, noble winter, so cold, so rigid, so unforgiving…~
== ~BFALDO~ ~Like death, in fact.~
== ~BXZAR~ ~Death?  Has someone died?~
== ~BFALDO~ ~Assuredly so.~
== ~BXZAR~ ~Why wasn’t I told?  Who died?  When?~
== ~BFALDO~ ~When?  This instant.  Who?  I could not say, Toril is very large... but someone has died.  A beast, a bird, a plant, a man… Know that, necromancer.~
== ~BXZAR~ ~Ah, I see.  Good to know our common bedfellow’s still on the job.  And I am as much for statistical normalcy as any man who ever raged but… I refuse to be its victim!~
== ~BFALDO~ ~You will have no more say in the matter than any other man or mayfly.~
== ~BXZAR~ ~So said the pessimists to great Vecna and yet decent Chianti cannot be had in these parts for under three pieces of gold.  Where’s the natural balance in that!?!~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("XZGA1","LOCALS",0)~ THEN ~BXZAR~ XZGA1
~Oh, songster, that tune you hum….~ [XZAR99]
DO ~SetGlobal("XZGA1","LOCALS",1)~
== ~BGARRI~ ~Yes?~
== ~BXZAR~ ~‘Tis a martial air, is it not?  It fills the heart with eager hope, with ardor for the struggles ahead?~
== ~BGARRI~ ~You have a ready ear.  That, indeed, is my song’s purport.~
== ~BXZAR~ ~Well, stop it, won’t you?  It is TOO depressing.~
== ~BGARRI~ ~You’d rather be a corpse than make them, I suppose.~
== ~BXZAR~ ~No, that would be silly.  But the exertion gives me migraine… *sighs*… why, oh, *why* will nothing die simply because I want it to?~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("XZKA1","LOCALS",0)~ THEN ~BXZAR~ XZKA1
~Ho, squatling….~ [XZAR99]
DO ~SetGlobal("XZKA1","LOCALS",1)~
== ~BKAGAI~ ~Watch your tongue or you’ll be squatting to pee.~ 
== ~BXZAR~ ~Why do I bother? Such pettiness from minds so close to the dirt… no! I have a discovery to share with you and will not be diverted.~
== ~BKAGAI~ ~Whassat, then?~ 
== ~BXZAR~ ~I have divined by my Art that I may pull a gold coin from your ear once each day.~
== ~BKAGAI~ ~And I can pull dung from yours, jarred loose by the ceaseless wagging of your tongue, I doubt not.~ 
== ~BXZAR~ ~Your barnyard reminiscences are beside the point. Now just hold still a moment…~
== ~BKAGAI~ ~Ho! You ain’t cutting my ear off, ya crazy bastard!~
== ~BXZAR~ ~If it is still attached to your head, you can *hardly* expect me to fashion it into the gold-yielding silk purse.~
== ~BKAGAI~ ~I don’t expect nothing but you to leave me alone – if you know what’s good for ya!~
== ~BXZAR~ ~Alas, for an explorer at the limits of knowledge to be entombed in a land of purblind fools!~
== ~BKAGAI~ ~Entombed you should be and I’m just the lad for it. Service is even free in your case.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
Global("XZKH1","LOCALS",0)~ THEN ~BXZAR~ XZKH1
~Why, hello, b-b-brave p-protector. We should chat a moment, you and I.~[XZAR99]
DO ~SetGlobal("XZKH1","LOCALS",1)~
== ~BKHALI~ ~Say what you must and be d-done the sooner.~
== ~BXZAR~ ~Oh, get stuffed.  I was merely looking under thumbs and there you were.  So I thought it civil to pass the time of day.~
== ~BKHALI~ ~My d-domestic arrangements are none of your affair and I’ve n-no desire to pass anything with *you*, n-necromancer.~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~Passin' somethin' sharp *through* 'im be a different story, though, eh?~
== ~BXZAR~ ~Well, there!  I take an intelligent interest in death, the sole and proper goal of all life, and what do I get from the yet-living minority?  Purblind bigotry, every time!~
== ~BKHALI~ ~The true goals of life appear in the living of it.~
== ~BXZAR~ ~ROT!  If we all lived forever, not ten of us would find justification for existence in that case.~
== ~BKHALI~ ~Then d-do you not risk the appearance of hypocrisy, d-declining to attain immediately to *your* proper goal?~
== ~BXZAR~ ~I?  Perish?  Who, then, would instruct you in the proprieties?~
== ~BKHALI~ ~If we are all to d-die in any case, our instruction cannot matter much.  C-certainly not to you.~
== ~BXZAR~ ~Ah, you speak too truly.  My altruism is sadly misplaced.~
= ~*Sighs* Beseems I must stay my lonely course for no reward beyond the meager returns of pure knowledge – for I utterly discount any value in the wealth, fame and power for which I am destined.~
== ~BKHALI~ ~Oh, n-naturally.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KIVAN")
See("KIVAN")
!StateCheck("KIVAN",STATE_SLEEPING)
AreaType(FOREST)
Global("XZKI1","GLOBAL",0)~ THEN ~BXZAR~ XZKI1
~Oh light-footed one, consider a natural phenomenon with me a moment, if you please.~
DO ~SetGlobal("XZKI1","GLOBAL",1)~
== ~BKIVAN~ ~You?  And nature?  That juxtaposition alone is profane. Be swift with your words… and few.~
== ~BXZAR~ ~Quite so.  Observe, then, the squirrel.  Squirrels dwell in trees, subsist on nuts and berries and chatter a great deal.  What then, my woodly friend, can be said to be the difference between squirrels and elves?~
== ~BKIVAN~ ~I beg to differ.  There are things that a squirrel would not contemplate.  Such as putting an arrow through a taunting human.  An elf, on another hand…~
== ~BXZAR~ ~Then you should teach them that trade.  Any human so rude would merit such chastisement.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MINSC")
See("MINSC")
!StateCheck("MINSC",STATE_SLEEPING)
Global("XZMI1","LOCALS",0)~ THEN ~BXZAR~ XZMI1
~Hmmm? A little louder, friend Boo.  I can hardly… woohooho, ha, ha, ha.  Yes, he does, doesn’t he?~ [XZAR99]
DO ~SetGlobal("XZMI1","LOCALS",1)~
== ~BMINSC~ ~What…what are you saying?~
== ~BXZAR~ ~HAHAHAHA!  Oh, stop it, Boo, you’re killing me… please, Minsc, do not interrupt.  It’s very rude.~
== ~BMINSC~ ~It is YOU who are rude.  Boo would never include Minsc out when he dispenses his wisdom.~
== ~BXZAR~ ~Oh, sure!  You think he’s going to tell *you* what he’s saying about you?~
== ~BMINSC~ ~I pity you, Xzar.  You are heeding voices in your head again rather than Boo.  Believe me in this for I know the difference.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MONTARON")
See("MONTARON")
!StateCheck("MONTARON",STATE_SLEEPING)
AreaType(CITY)
TimeofDay(DAY)
Global("XZMO1","LOCALS",0)~ THEN ~BXZAR~ XZMO1
~Ah, the bustle and throb of commerce, the lifeblood of civilization. *sigh * Why is must the envious malign us so?  What demerit is it in us if my methods… I and my colleagues… the efficiencies, the economies of scale do tend to monopolize… to return the slow and the backward to primary production where they belong…~ [XZAR99]
DO ~SetGlobal("XZMO1","LOCALS",1)~
== ~BMONTA~ ~Gilded fish.~
== ~BXZAR~ ~Huh?  Er… why….~
== ~BMONTA~ ~Heh. I remeber that time Xzar was gonna mernoperlize the market for gilded fish in Westgate. Painted 10,000 minnows yeller, stuck ‘em in tanks and stacked ‘em in a warehouse. Wanted 50 gold a pop ‘cause he had that there mernoperly on ‘em.~
== ~BXZAR~ ~Er… ~
== ~BMONTA~ ~Sold nary a one afore they all died. Had ever’ cat for twenny miles singin’ outside night ‘n’ day till some big mucky-muck closed him up as menacing publick health. Cost a pretty penny all told.~
== ~BXZAR~ ~Dear Monty! The aesthetic deficiencies of that philistine community will redound upon their heads in good time, I assure you. At the present moment, I would like a nice dish of strawberries and cream… with a monkey brain on top, just so.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MONTARON")
See("MONTARON")
!StateCheck("MONTARON",STATE_SLEEPING)
AreaType(DUNGEON)
!Global("KnowBhaal","GLOBAL",1)
Global("XZPC1","LOCALS",1)
Global("XZMO2","LOCALS",0)~ THEN ~BXZAR~ XZMO2
~……troublesome…dreams...~ [XZAR99]
DO ~SetGlobal("XZMO2","LOCALS",1)~
== ~BMONTA~ ~So, whatcha thinkin’, big think-maker?~
== ~BXZAR~ ~I was thinking… how boldly a scarlet waistcoat affronts light blue pantaloons.~
== ~BMONTA~ ~Supposin’ ye were, save it for yer haberdasher.  Think o’ somethin’ else.~
== ~BXZAR~ ~Oh, that… I suppose that the fact should be communicated… but not until our present incertitude has eased appreciably.~
== ~BMONTA~ ~Clear as mud.~
== ~BXZAR~ ~Precisely the dilemma.  And, naturally, our…um…colleagues could not be expected to cold store such a resource for my exclusive investigation…~
== ~BMONTA~ ~Nor would they.  Cold store *you* at the very idea, I’d say.~
== ~BXZAR~ ~Nonsense!  They return value for value… somewhat… but it would be so meager compared….~
= ~Damn them!  They have stifled me… uh, as yet, I am too inexp… far too busy, that is to say, upon our current and most important venture to contemplate assuming sole responsibility for so prolonged a digression.~
== ~BMONTA~ ~So we waits a bit yet, eh?~
== ~BXZAR~ ~In a clamshell, dear Monty.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("QUAYLE")
See("QUAYLE")
!StateCheck("QUAYLE",STATE_SLEEPING)
Global("XZQU1","LOCALS",0)~ THEN ~BXZAR~ XZQU1
~Oh, wise gnome, answer me a question if you can.~ [XZAR99]
DO ~SetGlobal("XZQU1","LOCALS",1)~
== ~BQUAYL~ ~Ask. My peerless intellect shall judge if ye merit a response.~
== ~BXZAR~ ~My question is this: what is the best brine recipe for pickling turnips for the winter?~
== ~BQUAYL~ ~You don’t pickle turnips, dunce. They’re roots. Keep them cool and dry in a box of sand and they last fresh.~
== ~BXZAR~ ~Quite – but I don’t *like* fresh turnips.  Or pickled ones either, very much, but…~
== ~BQUAYL~ ~Bah! Plant you, and you’d grow greens from your ankles. No gnome ever cared a tinker’s curse for turnips anyway.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SAFANA")
See("SAFANA")
!StateCheck("SAFANA",STATE_SLEEPING)
InParty("MONTARON")
See("MONTARON")
!StateCheck("MONTARON",STATE_SLEEPING)
Global("XZSA1","LOCALS",0)~ THEN ~BXZAR~ XZSA1
~Oh, black woe and blacker tidings, alas and alackaday.~ [XZAR99]
DO ~SetGlobal("XZSA1","LOCALS",1)~
== ~BSAFAN~ ~You seem to be your usual cheerful self.~
== ~BXZAR~ ~I am sad to observe you without that adornment which would best become you.~
== ~BSAFAN~ ~Is it something that will make me look like your dear departed Mummy?~
== ~BXZAR~ ~Less repulsively unlike; 'tis a vivisectionist’s laboratory - with *you* as the subject.~
== ~BSAFAN~ ~Thank you for thinking of me, darling, but I don't think that little halfling of yours could carry it for you.  Besides, I can think of lots of things that would be more…fun.~
== ~BXZAR~ ~FUN!?  You degraded mercenary, hawking putrescence from the cesspool of carnality, do you conceive that *I* would sully myself with anything you consider FUN?!  For food, perhaps, or study… but not for FUN!~
== ~BSAFAN~ ~Imagine… an insane necromancer claiming the moral high ground over little ol’ me.~
== ~BXZAR~ ~Consider well your own words, should you wish to measure the depth of your fall... fall, fall-alla-lah and Kalamazoo.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SHARTEEL")
See("SHARTEEL")
!StateCheck("SHARTEEL",STATE_SLEEPING)
Global("XZSH1","LOCALS",0)~ THEN ~BXZAR~ XZSH1
~Princess of the Dawn, why do you yet face the darkness rather than the light?~ [XZAR99]
DO ~SetGlobal("XZSH1","LOCALS",1)~
== ~BSHART~ ~Silence would better serve my temper and your tongue.~
== ~BXZAR~ ~Come now, you know you don’t mean that….~
== ~BSHART~ ~You are male, a cowardly mage and insane.  Were those defects all remedied, you would remain repulsive still.~
== ~BXZAR~ ~Which is precisely why you need my counsel.~
== ~BSHART~ ~I need nothing of you.  I desire your heart’s blood.  Do not tempt me, fool.~
== ~BXZAR~ ~Exactly.  You have, very wisely, rejected the male half of life but you cling to the female the more fervently, the howling travail, the dark pulse of flesh.~
= ~Why not turn about to the light, little sister, and behold the peace that shines beyond corruption?  Consider Mother Death, little sister, and rejoice!~
== ~BSHART~ ~I owe <CHARNAME> a service.  I once did hope to slay you in fulfillment of that debt, but you are too far beyond mind for satisfaction in this matter.  Drivel elsewhere, fool.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SKIE")
See("SKIE")
!StateCheck("SKIE",STATE_SLEEPING)
InParty("MONTARON")
See("MONTARON")
!StateCheck("MONTARON",STATE_SLEEPING)
Global("XZSK1","LOCALS",0)~ THEN ~BXZAR~ XZSK1
~My dear Lady Skie, what a lovely name.~ [XZAR99]
DO ~SetGlobal("XZSK1","LOCALS",1)~
== ~BSKIE~ ~Eh…thank you….~
== ~BXZAR~ ~But inverted.~
== ~BSKIE~ ~I knew it.  Now comes the comment about the air between my ears, right?~
== ~BXZAR~ ~No jest at all, I assure you.  Your skull encompasses so prettily the vacuous firmament.~
== ~BSKIE~ ~Mm-hmmm.  You’re still serious, right?~
== ~BXZAR~ ~Perfectly.  Whose head contains the Heavens will dream sweet dreams.~
== ~BSKIE~ ~I prefer to live my dreams during waking, thank you very much.~
== ~BXZAR~ ~Who does not prefer?  Who does not do so in fact?  Yet in waking the dreams impinge upon one another, so that my rest is troubled now by your dreams, then by <CHARNAME>’s, perhaps even by dear Monty’s quirky little snarks…~
== ~BSKIE~ ~Well, that’s one way of looking…~
== ~BXZAR~ ~I get no rest at all until I am asleep!  Is that any way to live?~
== ~BSKIE~ ~I am perfectly willing to remove myself from influence over your dream life.~
== ~BXZAR~ ~Selfish.  How do you know nothing worse would not fill that void, then?~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("TIAX")
See("TIAX")
!StateCheck("TIAX",STATE_SLEEPING)
Global("XZTI1","LOCALS",0)~ THEN ~BXZAR~ XZTI1
~Oh, mega, what is your position on free trade?  So I’ll be prepared when the great day arrives.~ [XZAR99]
DO ~SetGlobal("XZTI1","LOCALS",1)~
== ~BTIAX~ ~When Tiax rules, all will exist to serve Tiax.  Their maintenance is of no concern.~
== ~BXZAR~ ~Oooooh, *smart* thinking.  Let them consider *you*.  No sense in wasting the ol’ grey matter on the vice versa, hmmm?~
== ~BTIAX~ ~You mock now.  When the Day of Tiax comes, special torment shall be reserved to you.~
== ~BXZAR~ ~AARRRGGGH!  SERMONS!  From the Priests of HELM! Oh, great master, spare your servant and… and I’ll… I’ll help you!~
== ~BTIAX~ ~The destiny of Tiax is to rule all!  No help is needed or possible.~
== ~BXZAR~ ~But I *can* help.  I’ll cast my spell right now and you can start ruling at once!~
= ~Oh, Alley-garoo-garall
Tiax now rules all.
It makes no sense
To sit on the fence
From Springstein until Fall.~
= ~There!  You’re ruler of All, now.  How’s it feel?~
== ~BTIAX~ ~You are looser than lamb…~
== ~BXZAR~ ~Oops!  Too slow!  It’s all over and you’ve missed the boat!~
== ~BTIAX~ ~Tiax will not be…~
== ~BXZAR~ ~Now MY way is clear!  HAHAHAHA!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("VICONIA")
See("VICONIA")
!StateCheck("VICONIA",STATE_SLEEPING)
Global("XZVI1","LOCALS",0)~ THEN ~BXZAR~ XZVI1
~Tell me, Dark Lady, how would a personage such as myself be regarded by your people?~ [XZAR99]
DO ~SetGlobal("XZVI1","LOCALS",1)~
== ~BVICON~ ~The drow, indeed, have a special place for those who are as you.~
== ~BXZAR~ ~Really?  What’s it like?  What’s it called?~
== ~BVICON~ ~The name translates poorly into your impoverished tongue.  I believe you might term it the Losers’ Cemetery.~
== ~BXZAR~ ~What?!~
== ~BVICON~ ~Perhaps Cemetery of Wasted Lives is a more true version.  In any case, the ignominious place to dispose of the remains of those whom the Matron Mothers have judged misfit.~
== ~BXZAR~ ~I? Misfit!?~
== ~BVICON~ ~What else am I to conclude? I find a person of your talent and predilection yet whose mind has been broken by the irrationality of surface life, wandering without purpose upon dim and dusty byways, lacking honor or station.~
= ~What may I judge if not ‘misfit’?~
== ~BXZAR~ ~Ah, I perceive that you do not consider that the outside of the world is so very much larger than its innards.  Among us, excursions such as this, although they are certain to annoy, are not to be despised ipso facto.~
= ~Where else, for instance, might I have encountered an enchanted jewel such as yourself, Dark Lady?~
== ~BVICON~ ~Your flattery is inept but your advice may be wise. I shall regard you, male.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XAN")
See("XAN")
!StateCheck("XAN",STATE_SLEEPING)
Global("XZXA1","LOCALS",0)~ THEN ~BXZAR~ XZXA1
~Elf, stay your pondering upon the immutable for a time and sing me a song… of unicorns dancing ‘neath sun-dappled emerald boughs.~ [XZAR99]
DO ~SetGlobal("XZXA1","LOCALS",1)~
== ~BXANNN~ ~I have no such song to sing, human.~
== ~BXZAR~ ~Well, croak it then.  I don’t care about your voice.  But I must have something of the sort.  NOW!~
== ~BXANNN~ ~Has it ever occurred in your splintered mind that not all elves devote their lives to spewing random lyrics of fustian reflection?~
== ~BXZAR~ ~No, not for a moment.  Why would anyone be an elf if not to soothe others with bucolic airs?~
== ~BXANNN~ ~*sigh * From your perspective, I suppose that it is so you can murder us to obtain potions of longevity.  So like your dayfly races: you commit atrocities merely to prolong a weariness.~
== ~BXZAR~ ~Of course, how silly of me!  Please accept my apologies, dear compone... er, my dear fellow.~
EXIT



