BEGIN X#NATAN
APPEND X#NATAN

IF ~OR(2) Global("X#CoranSuccubus","GLOBAL",13) Global("X#CoranSuccubus","GLOBAL",17) PartyHasItem("X#SUCRIN")~ NatanFinal2
SAY ~A-ha!  I can see from your faces, a bit burned and beaten but rather self-content, that you killed the demon... and here is her ring.  Great!  I am free now!~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",18) TakePartyItem("X#SUCRIN")~ GOTO NAFI2.2
END

IF ~~ NAFI2.2
SAY ~I suppose you have cleaned this dungeon of treasure? *Sighs* I'll go look for some other ruins.  Thanks for rescuing me!~
++ ~"Thank you" does not buy meat and wine.  Would not you express your gratitude in a more... materialistic way?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.1
++ ~Wait, how were the roses involved?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.2
++ ~Fare thee well, Natan... and stay out of trouble, will you?  I may not happen along next time... ~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.3
END

IF ~Global("X#CoranSuccubus","GLOBAL",16)~ NatanIsUnhappy
SAY ~What have you done?!  The woman is a succubus, a demon!  Long ago a mage who survived the fall of Ulcaster's School invented a way to travel between the planes - those very powders.  The succubus, whom he summoned to entertain him in his labors, has stolen the manual, but before she could get her claws on the powders, the mage warded the dungeon against her.  Now she is free to travel between the planes... Oh, well... things happen, I guess.  At least I am free from her spell now.  Bloody roses! ~
= ~I suppose you have cleaned this dungeon of treasure? *Sighs* I'll go look for some other ruins.  Thanks for rescuing me!~
++ ~"Thank you" does not buy meat and wine.  Would not you express your gratitude in a more... materialistic way?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.1
++ ~Wait, how were the roses involved?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.2
++ ~Fare thee well, Natan... and stay out of trouble, will you?  I may not happen along next time... ~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.3
END

IF ~~ NAFI1.1
SAY ~I do not have any money - almost all that I have found the succubus has taken.  I have a few potions, but I hoped to sell them to sustain my living... for awhile... ~
++ ~Potions will do. ~ + NAFI1.4
++ ~You need money more than I.  Fare thee well, Natan... and stay out of troubles, will you?  I may not happen along next time...~ + NAFI1.3
END

IF ~~ NAFI1.2
SAY ~Sorcery, that's how!  I am but a thief... a good thief, <PRO_SIRMAAM>, but unaccustomed to dealing with things... unnatural.  I came to Firewine for the same reason everybody does - treasure... and I saw a beautiful maiden outside the dungeon, collecting white wild roses in a small basket.  She was so beautiful--it took my breath away.  She could not get a flower from the very top of the bush, hanging just beyond her reach, so, naturally, I offered my help...~
= ~When I grabbed for the flower, thorns sprung from the stem, and the rose turned scarlet with my blood.  The terrible woman laughed and took it from me... I was enslaved.  The enchantment was not perfect, and sometimes I could do things out of my free will - and that's how I came upon the notes of that mage who summoned the succubus here in the first place, and found his magic powders. Among his other supplies I found a potion he called Dead Water, and I sprayed it over the damned roses. ~
= ~The roses died, and my will was freed, but the demon was unrelenting.  She said that she has time to wait... that I will either bring her the powders, or I will die in this dungeon.  The rest you know... well, more or less. ~
++ ~"Thank you" does not buy meat and wine.  Would not you express your gratitude in a more... materialistic way?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.1
++ ~Fare thee well, Natan... and stay out of trouble, will you?  I may not happen along next time... ~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",19)~ + NAFI1.3
END

IF ~~ NAFI1.3
SAY ~Oh, I will be very cautious... Now, where did I meet that beggar who was selling a treasure map for Maztica? ~
IF ~~ THEN DO ~ EscapeArea() AddexperienceParty(1000)~ EXIT
END

IF ~~ NAFI1.4
SAY ~Easy come, easy go.  They are yours.  I must go now... life is too short to spend it on anything but adventure!~
IF ~~ THEN DO ~GiveItem("POTN36",Player1) GiveItem("POTN37",Player1) GiveItem("POTN42",Player1) GiveItem("POTN07",Player1) EscapeArea() AddexperienceParty(100)~ EXIT
END

IF ~Global("X#CoranSuccubus","GLOBAL",11)~  NatanAdoreAmelia
SAY ~I adore Amelia...~
IF ~~ THEN EXIT
END

IF ~Global("X#CoranSuccubus","GLOBAL",7)~ HelpedAmelia
SAY ~The roses!  Oh, by the gods, the roses!  I... my will weakens by the second.  Here, take this!  That's what she wants! ~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",11) DestroyItem("X#COFRRO") GiveItem("X#CODYE1",Player1)~ GOTO X#NAAmelia1
END

IF ~~ X#NAAmelia1
SAY ~This woman... the demon... she tricked you!  She will not leave until she has the powders I gave you... I cannot say more now, but I swear that she is a being of pure evil.  Please, please kill her and release me! ~
= ~I must run to the Mistress' call.~
IF ~!InParty("coran")~ THEN DO ~EscapeAreaMove("FW4500",4040,2091,3)~ EXIT
IF ~InParty("coran") Global("CoranMatch","GLOBAL",1) !Global("X#CoranBlessed","GLOBAL",2)~THEN DO ~ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXTERN CORANJ CoranResistShort
IF ~InParty("coran") Global("CoranMatch","GLOBAL",1) Global("X#CoranBlessed","GLOBAL",2)~ THEN DO ~ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXTERN CORANJ CoranResistLong
IF ~InParty("coran") !Global("CoranMatch","GLOBAL",1) GlobalLT("X#CoranBlessed","GLOBAL",2)~ THEN DO ~ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXTERN CORANJ CoranNotResist
IF ~InParty("coran") !Global("CoranMatch","GLOBAL",1) Global("X#CoranBlessed","GLOBAL",2)~ THEN DO ~ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXTERN CORANJ CoranResistShort
END


IF ~GlobalGT("X#CoranSuccubus","GLOBAL",2) GlobalLT("X#CoranSuccubus","GLOBAL",7)~ NatanDidNotHelpAmelia
SAY ~Hello there. Say, have you noticed a woman... the most beautiful woman you have ever seen, nearby?~
+ ~PartyHasItem("X#COWIRO")~ + ~Yes, and I have bad news for you - she is not going to marry you, pal.~ + X#NA1.1
++ ~Not that I can recall.~ + X#NA1.2
+ ~PartyHasItem("X#COWIRO")~ + ~So you are the man she was promised to?  Be reasonable, get out of this ghastly place and free the woman of her vow!~ + X#NA1.3
+ ~PartyHasItem("X#COWIRO")~ + ~Yes, I have seen her, and I would like to hear your side of the story.~ + X#NA1.4
END

IF ~~ X#NA1.1
SAY ~M-Marry?  I would not marry that harpy for all the gold of Faerun...what did she say to you?  Does she still have those bloody roses?~
++ ~Erm... she said that she is your betrothed, and that she was supposed to give you an answer on her sixteenth birthday by presenting you with either red or white roses.  Her roses are but dust now, though.  Can't you act like a grown-up and go sort your relationship out? It would make my life so much easier...~ + X#NA1.6
++ ~I want to hear your side of the story first.~ + X#NA1.4
++ ~Amelia said that you'd try to sally her name!  You will die for that!~ + X#NA1.5
END

IF ~~ X#NA1.2
SAY ~Oh, good for you!  If you see her - run for your life!~
++ ~What do you know of her?~ + X#NA1.4
+ ~GlobalGT("X#CoranSuccubus","GLOBAL",3)~+~Well, to tell the truth, we did meet her.  She said that she is your betrothed, and that she was supposed to give you an answer on her sixteenth birthday by presenting you with either red or white roses.  Her roses are but dust now, though.  Can't you act like a grown-up and go sort your relationship out?~ + X#NA1.6
++ ~Amelia said that you'd try to sally her name!  You will die for that!~ + X#NA1.5
END

IF ~~ X#NA1.3
SAY ~What... what vow?  What tale did that bitch cook up?  Does she still have those bloody roses? ~
++ ~Erm... she said that she is your betrothed, and that she was supposed to give you an answer on her sixteenth birthday by presenting you with either red or white roses.  Her roses are but dust now, though.  Can't you act like a grown-up and go sort your relationship out? ~ + X#NA1.6
++ ~I want to hear your side of the story first. ~ + X#NA1.4
++ ~Amelia said that you'd try to sally her name!  You will die for that! ~ + X#NA1.5
END

IF ~~ X#NA1.4
SAY ~I am but a thief... a good thief, <PRO_SIRMAAM>, but unaccustomed to deal with things... unnatural.  I came to Firewine for the same reason everybody does - treasure...  I saw her outside the dungeon, collecting white wild roses in a small basket.  She was so beautiful; it took my breath away. She could not get a flower from the very top of the bush, hanging just beyond her reach, so naturally I offered my help...~
IF ~~ THEN GOTO X#NA1.4A
END

IF ~~ X#NA1.6
SAY ~My dear <PRO_MANWOMAN>, those are all lies!~
= ~I am but a thief... a good thief, <PRO_SIRMAAM>, but unaccustomed to deal with things... unnatural.  I came to Firewine for the same reason everybody does - treasure...  I saw her outside the dungeon, collecting white wild roses in a small basket.  She was so beautiful; it took my breath away. She could not get a flower from the very top of the bush, hanging just beyond her reach, so naturally I offered my help...~
IF ~~ THEN GOTO X#NA1.4A
END

IF ~~ X#NA1.4A
SAY ~When I grabbed for the flower, thorns sprung from the stem and the rose turned scarlet with my blood.  The terrible woman laughed and took it from me... I was enslaved.  She ordered me to go into the dungeon and search for treasure for her.  At first I did not know what she wanted, but sometimes I managed to fight the compulsion to adore and to obey her and search on my own for the answers.~
++ ~Go on...~ +  X#NA1.4B
++ ~So, she is some sort of an evil witch?   I'll kill her for you, if you have a coin.  Oh, and spare me the rest of this awful story.~ +  X#NA1.4C
++ ~Amelia said that you'd try to sally her name!  You will die for that! ~ + X#NA1.5
END

IF ~~ X#NA1.4B
SAY ~One day I found a journal of a long-dead wizard.~
= ~This man escaped from the disaster in the Ulcaster School and settled here, studying in solitude... except for a succubus that he summoned from the Abyss.  She... entertained him, but also found out that he had created a set of magical powders, which, once combined, allowed the opening of gates between the planes.  No summons, no ships... just powders combined in the right way... and voilà!  The portal is opened.  She tried to steal the mage's powders and the manual...~
= ~The wizard, however, caught his demonic maiden red-handed, and she fled, carrying away the manual... but not the powders.  He warded the ruins against her entry and continued living as a hermit, never bothering to recreate his notes.  Among his other supplies I found a potion he called Dead Water, and I sprayed it over the damned roses.~                                                                                                                                                                                                                                                                                                                                                   
= ~Alas, the roses died, and my will was freed, but the demon was unrelenting.  She said that she has time to wait... that I will either bring her the powders, or I will die in this dungeon.  I choose to die in the dungeon... better than get my life sucked out of me drop by drop by a succubus - and I have no doubt she'd do that once I give her the powders.~
++ ~Are you finished?  Good. I am off to kill her then.~ DO ~ActionOverride("natan",DestroyItem("X#CODYE1")) GiveItemCreate("X#CODYE2","natan",1,0,0) ~ +  X#NA1.4D
++ ~Maybe I can convince her to give you a break if we bring her the powder?  Let me talk to her.~ DO ~ActionOverride("natan",DestroyItem("X#CODYE1")) GiveItemCreate("X#CODYE2","natan",1,0,0) ~ +  X#NA1.4E
++ ~She said that you'd try to sally her name!  You will die for that!~ DO ~ActionOverride("natan",DestroyItem("X#CODYE1")) GiveItemCreate("X#CODYE2","natan",1,0,0) ~ + X#NA1.5
++ ~I think I'll just kill both of you and use the powders and manual myself.~ DO ~ActionOverride("natan",DestroyItem("X#CODYE1")) GiveItemCreate("X#CODYE2","natan",1,0,0) ~+  X#NA1.4F
+ ~Global("X#CoranCharmed","GLOBAL",1) !InParty("coran")~ + ~Amelia charmed one of my companions as well.  I guess there is little to it but to go kill her and release both you and Coran.~ DO ~ActionOverride("natan",DestroyItem("X#CODYE1")) GiveItemCreate("X#CODYE2","natan",1,0,0) ~ +  X#NA1.4D
++ ~I would not want to be you, pal.  Fear not, however, I can kill the demon and set you free... for a good coin, that is.~ DO ~ActionOverride("natan",DestroyItem("X#CODYE1")) GiveItemCreate("X#CODYE2","natan",1,0,0) ~ +  X#NA1.4D
END

IF ~~ X#NA1.5
SAY ~So, you have fallen under her spell?  Very well, let us fight. But you fight for succubus' honor! I'd rather die in battle than rot here or surrender to the demon!~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",8) Enemy()~ EXIT
END

//Did not hear the whole story
IF ~~ X#NA1.4C
SAY ~Ah, a <PRO_MANWOMAN> of actions?  I see.  I cannot offer you money, but in the old wizard's cache I found rare potions - I will give them to you if you bring me proof that the demon is dead.  A ring from her toe will suffice - I know that it cannot be removed from her while she is alive.  Hey, do not stare at me like that!  I know because I know.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",9)~ 
UNSOLVED_JOURNAL ~Amelia is apparently a being of evil who has enslaved Natan.  We agreed to kill Amelia and free Natan.~
EXIT
END

IF ~~ X#NA1.4D
SAY ~Ah, a <PRO_MANWOMAN> of actions?  I see.  I cannot offer you money, but in the old wizard's cache I found rare potions - I will give them to you if you bring me proof that the demon is dead.  A ring from her toe will suffice - I know that it cannot be removed from her while she is alive.  Hey, do not stare at me like that!  I know because I know.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",10)~
UNSOLVED_JOURNAL ~Amelia is apparently a succubus who is after some centuries old snuff-powders! She had enslaved Natan to find them for her.  We agreed to kill Amelia and free Natan.~
EXIT
END

IF ~~ X#NA1.4E
SAY ~I doubt she'd hold on to her end of the bargain.  Besides, you will not really kill her - just cast her back into the Abyss, where she belongs.  The Planes would be much better off without a succubus who can travel unobtrusively between them.  Kill her, my good <PRO_LADYLORD>, I beg you.  I cannot offer you money, but in the old wizard's cache I found rare potions - I will give them to you if you bring me proof that the demon is dead.  A ring from her toe will suffice - I know that it cannot be removed from her while she is alive.  Hey, do not stare at me like that! I know because I know.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",10)~
UNSOLVED_JOURNAL ~Amelia is apparently a succubus who is after some centuries old snuff-powders! She had enslaved Natan to find them for her.  We agreed to kill Amelia and free Natan.~
EXIT
END

IF ~~ X#NA1.4F
SAY ~How do you know if I carry the potions on me or if I have hidden them somewhere? How do you know that Amelia still has the manual?~
++ ~I suppose I'll just have to trust my luck!  Die, scum!~ + X#NA1.5
++ ~You are right.  But I would not venture to kill a demon without some substantial reward to inspire my bravery...~ + X#NA1.4D
++ ~Rats.  All right, all right, I'll go kill her.~ + X#NA1.4D
END

END

BEGIN X#RASHEL

APPEND X#RASHEL

IF ~True()~ RashelGreeting
SAY ~Greetings to you from a humble servant of Lathander, Rashel the Sunray.~
IF ~!Global("X#CoranSuccubus","GLOBAL",5) !Global("X#CoranSuccubus","GLOBAL",6)~ THEN GOTO RashelGreeting1
IF ~InParty("coran") Global("X#CoranSuccubus","GLOBAL",5) Global("X#CoranBlessed","GLOBAL",0)~ THEN GOTO RashelRoses1
IF ~InParty("coran") Global("X#CoranSuccubus","GLOBAL",6)~ THEN GOTO RashelRoses2
IF ~InParty("coran") Global("X#CoranSuccubus","GLOBAL",5) Global("X#CoranBlessed","GLOBAL",1)~ THEN GOTO RashelRoses2
IF ~InParty("coran") Global("X#CoranSuccubus","GLOBAL",5) Global("X#CoranBlessed","GLOBAL",2)~ THEN GOTO RashelGreeting1
END

IF ~~ RashelGreeting1
SAY ~What kind of aid can I give you?~ 
++ ~Do you sell magical healing or scrolls?~ + RashelKeldath
++ ~Can you tell us about the lands nearby?~ + RashelLands
+ ~Gender(Player1,MALE)~ + ~When are you getting off?  I have seen a cozy inn nearby and was wondering if you'd join me for dinner?~ + RashelDinner
++ ~Please, tell me about this temple.~ + RashelTemple
END

IF ~~ RashelKeldath
SAY ~The Most Radiant of Lathander Kelddath Ormlyr should be able to help you with this, my good <PRO_MANWOMAN>. He can be found in the Song of the Morning Temple.  ~
= ~Is there anything else you wish to know?~
++ ~Can you tell us about the lands nearby?~ + RashelLands
+ ~Gender(Player1,MALE)~ + ~When are you getting off?  I have seen a cozy inn nearby and was wondering if you'd join me for dinner?~ + RashelDinner
++ ~Please, tell me about this temple.~ + RashelTemple
++ ~No, thank you, Rashel. Have a good <DAYNIGHT>.~ + RashelBuy
END

IF ~~ RashelLands
SAY ~You are now in Beregost, my good <PRO_MANWOMAN>. It was a village once, under the protection of the School of Wizardry. The Ulcaster School it was called, for it was founded by Ulcaster, a conjurer of some renown, but it was ruined by Calishate mages out of fear.~
= ~But the Most Radiant of Lathander, Kelddath Ormlyr, frowns upon us talking of this haunted place, let alone approaching it.~
= ~Craumerdaun family of Amn has estates nearby and they breed fine horses, highly prized in Amn and Tethyr.~
= ~To northwest stands High Hedge, the estate of Thalantyr the Conjurer. He is a loner, I think, and doesn't welcome visitors. However, he's said to be interested in far-off places and things, so if you have anything peculiar for sale, you might try your luck.~
= ~Is there anything else you wish to know?~
++ ~Do you sell magical healing or scrolls?~ + RashelKeldath
+ ~Gender(Player1,MALE)~ + ~When are you getting off?  I have seen a cozy inn nearby and was wondering if you'd join me for dinner?~ + RashelDinner
++ ~Please, tell me about this temple.~ + RashelTemple
++ ~No, thank you, Rashel. Have a good <DAYNIGHT>.~ + RashelBuy
END

IF ~~ RashelTemple
SAY ~*Rashel's face lits up with pride* The Song of the Morning is the name of our Temple consecrated in the name of the Morning Lord, Lathander. We protect the good people of Beregost. The servants of the Morning Lord also tend temple fields of potatoes and herb flowers east of the road, and keep sheep on the slopes of the hill topped by the ruined school of Ulcaster.~
= ~The sheep are more easily watched there, preventing theft and raiding beasts from ravaging them. It give us some keep some control over expeditions into the ruins and to prevents expansion of Beregost.~
= ~Over the years, various Amnian merchants have shown a distressing tendency to lay claim to all land within easy reach of the Coast Way that's not strongly defended.~
= ~Is there anything else you wish to know?~
++ ~Do you sell magical healing or scrolls?~ + RashelKeldath
+ ~Gender(Player1,MALE)~ + ~When are you getting off?  I have seen a cozy inn nearby and was wondering if you'd join me for dinner?~ + RashelDinner
++ ~No, thank you, Rashel. Have a good <DAYNIGHT>.~ + RashelBuy
END

IF ~~ RashelBuy
SAY ~Walk in the blessed light of the Sun, my good <PRO_MANWOMAN>.~
IF ~~ THEN EXIT
END

IF ~~ RARO1.1
SAY ~I am not sure I know what you are up to, but I guess there is no harm in restoring a few flowers to life.  I will ask 200 gold for the spell.~
++ ~200 gold?  We can buy a cart full of roses for that price!  Blue roses, too!  Huh, let us see if we can just kill Natan or do something else... cheaper.~ + RARO1.3
+ ~PartyGoldGT(200)~ + ~Please do it, my good woman.  Here is the money.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",7)~ + RARO1.4
++ ~Have you ever heard of charity my good woman?  This is as goodly a deed as they come!  We met a lady by the Firewine Bridge ruins, Amelia by name, and she is the most beautiful woman I have ever seen.  Amelia's betrothed asked her to give him the final answer on her sixteenth birthday.  If she agreed to their wedding she was to give him the white roses, and if she disagreed - the reds.  Now, Amelia did not like the guy all that much, so she chose the red roses.  Her louse of a fiancé, however, found a way to avenge his pride - he hid himself in the ruins, and Amelia, bound by her vow, cannot leave without giving him the flowers.  She cannot enter the ruins either - sounds like that wretch warded the entrance against her.  So we decided to help Amelia, restore the red roses to life, and deliver them to Natan.~ + RARO1.2
END

IF ~~ RARO1.3
SAY ~As you wish. Walk in the blessed light of the Sun, my good <PRO_MANWOMAN>.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",6)~ EXIT
END

IF ~~ RARO1.2
SAY ~You need to restore the flowers to life to commit a goodly deed then?  I... I think I can help you.  The spell will be unusual, but I will not ask for money - I am glad to help in a charitable cause.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",7) TakePartyItem("X#COWIRO") DestroyItem("X#COWIRO")~ EXTERN CORANJ RosesRestored
END

IF ~~ RARO1.4
SAY ~As you wish my good <PRO_LADYLORD>.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",7) GiveGoldForce(-200) TakePartyItem("X#COWIRO") DestroyItem("X#COWIRO")~
EXTERN CORANJ RosesRestored
END

IF ~~ RARO1.5
SAY ~May the light of the Morning Lord guide you.~
IF ~~ THEN EXIT
END

IF ~~ RARO1.6
SAY ~It is too faint and unusual, and I doubt that I can even sense it.  But I can bless your companion, just in case.  Unfortunately, I will have to do it for a price, as I am afraid my superiors would not agree that the spell is even necessary, let alone life-saving... I will need 100 gold pieces.~
++ ~Bless Coran, acolyte, and use the money well to instill the love of light and goodness in the common folk and lords alike.~ + RARO1.7
++ ~Now, that's a rip-off!  We are out of here.~   + RARO1.5
++ ~The bureaucracy and corruption of priests are well known.  Maybe *that's* the evil you are smelling?  But one cannot be too careful.  Cast the spell, acolyte Rashel.~ + RARO1.7
END

IF ~~ RARO1.7
SAY ~Doubt not, your money will be spent wisely.~
IF ~~ THEN DO ~GiveGoldForce(-100) ReallyForceSpellRES("SPPR101","coran") SetGlobal("X#CoranBlessed","GLOBAL",2)~ EXIT
END

IF ~~ RashelRoses2
SAY ~May the light of the Morning Lord always shine in your heart.  You have returned - do you seek help again? ~
+ ~Global("X#CoranSuccubus","GLOBAL",6)~ + ~Yes, we decided to restore the roses for the cursed girl.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",7)~ + RARO1.4
+ ~Global("X#CoranSuccubus","GLOBAL",7) Global("X#CoranBlessed","GLOBAL",0)~ + ~I changed my mind, Rashel.  One cannot be too careful these days.  Here are your coins; please, bless Coran.~ + RARO1.7
+ ~Gender(Player1,MALE)~ + ~When are you getting off?  I have seen a cozy inn nearby and was wondering if you'd join me for dinner?~ + RashelDinner
++ ~I was just passing by and decided to say hello.~ + RARO1.8
++ ~Who are you and how do you know me?~ + RARO1.9
END

IF ~~ RashelDinner
SAY ~I am flattered by your interest in my humble persona, but my heart belongs to the Morning Lord, to whom I serve and to whom all my time belongs.~
+ ~Global("X#CoranSuccubus","GLOBAL",6)~ + ~Yes, we decided to restore the roses for the cursed girl.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",7)~ + RARO1.4
+ ~Global("X#CoranSuccubus","GLOBAL",7) Global("X#CoranBlessed","GLOBAL",0)~ + ~I changed my mind, Rashel.  One cannot be too careful these days.  Here are your coins; please, bless Coran.~ + RARO1.7
+ ~Gender(Player1,MALE)~ + ~So be it, but you do not know what you are missing!~ + RARO1.5
++ ~I was just passing by and decided to say hello.~ + RARO1.8
++ ~I'll go, then.~ + RashelBuy
END

IF ~~ RARO1.8
SAY ~ Well, hello, then. And welcome to the Song of the Morning.~
IF ~~ THEN EXIT
END

IF ~~ RARO1.9
SAY ~I must be taking you for someone else.  Strange, I was sure that you were that <PRO_MANWOAMN> with roses... I need to study less.~
IF ~~ THEN EXIT
END

END

CHAIN X#RASHEL RashelRoses1
~Why do you carry withered flowers into the House of the Morning Lord?~
== CORANJ ~It is a long story, holy sister, but a maiden's heart will know no happiness until these roses are restored to life.~
END
++ ~Yes, my friend Coran is right.  Someone's peace and quiet depends on whether these petals can be made red and fresh again.~ + RARO1.1
++ ~It's a very interesting tale actually...  We met a lady by the Firewine Bridge ruins, Amelia by name, and she is the most beautiful woman I have ever seen.  Amelia's betrothed asked her to give him the final answer on her sixteenth birthday.  If she agreed to their wedding she was to give him the white roses, and if she disagreed - the reds.  Now, Amelia did not like the guy all that much, so she chose the red roses.  Her louse of a fiancé, however, found a way to avenge his pride - he hid himself in the ruins, and Amelia, bound by her vow, cannot leave without giving him the flowers.  She cannot enter the ruins either - sounds like that wretch warded the entrance against her.  So we decided to help Amelia, restore the red roses to life, and deliver them to Natan.~ + RARO1.2

CHAIN CORANJ RosesRestored
~Ow!  My hand...it bleeds again...~
== X#RASHEL ~I feel a faint sense of evil on these roses… and on your companion. You, however, sound sincere and kind.  Maybe I am mistaken.~
DO ~SetGlobal("X#CoranBlessed","GLOBAL",1) GiveItemCreate("X#COFRRO","coran",1,0,0)~
END
++ ~You must be mistaken.  Thank you for your help.~ EXTERN X#RASHEL RARO1.5
++ ~Well, we'll get soon enough to the bottom of this story.  However, just in case... can you do anything to take away that evil presence from Coran and the roses? ~ EXTERN X#RASHEL RARO1.6


BEGIN X#AMELIA

APPEND X#AMELIA

IF ~Global("X#CoranSuccubus","GLOBAL",11)~ AMRE2
SAY ~My pet here told me that you have the item I require - the powders.  Hand it over, <CHARNAME>... ~
+~Global("KnowBhaal","GLOBAL",1)~ + ~I want to know the truth before I announce my decision.~ + AMRE2.1B
+~!Global("KnowBhaal","GLOBAL",1)~ + ~I want to know the truth before I announce my decision.~ + AMRE2.1NB
++ ~Of course, of course.~ + AMRE2.2A
++ ~Of course, of course. But you should release your captives and give us something....~ + AMRE2.2B
+ ~!InParty("coran") Global("X#CoranCharmed","GLOBAL",1)~ + ~You took my companion captive and you are telling me to be a good <PRO_BOYGIRL> and trade with you!  I say the time is ripe for swords. ~ + AMRE2.3
+ ~!InParty("coran") Global("X#CoranCharmed","GLOBAL",1) Gender(Player1,MALE)~ + ~I will give you the powders in exchange for my companion... and a bit of a reward.~ + AMRE2.4M
+ ~!InParty("coran") Global("X#CoranCharmed","GLOBAL",1) Gender(Player1,FEMALE)~ + ~I will give you the powders in exchange for my companion... and a bit of a reward.~ + AMRE2.4F
END

IF~~ AMRE2.1NB
SAY ~What is the truth, mortal?  Look in the mirror, <CHARNAME>, and you will see yet another young <RACE>... and that is the truth about you, of course.  Yet there is another truth, the one that cannot be seen in the mirror - and it is a frightful one.  Look at me as if you were a mirror - do not ask for the hidden truth.  I am but a girl in need and I earned the item you hold.~
IF ~~ THEN GOTO AMRE2.1A
END

IF ~~ AMRE2.1B
SAY ~What is the truth, mortal?  Not so long ago, you were but a young <RACE>... and now you've grown tail feathers befit to a child of Murder. Are you happier for that?  Are you any different?  Here is truth about me: I am a girl in need, who earned the item you hold.  Give it to me, and I shall release the pathetic Primer...~
IF ~~ THEN GOTO AMRE2.1A
END

IF ~~ AMRE2.1A
SAY ~Give it to me, and I shall release the pathetic thieves...~
++ ~*Sighs* I do not want to stand here all day and bandy words with you.  Here are the powders and suit your words - release the thief, or I will cut you down!~ + AMRE2.5
+~!Global("KnowBhaal","GLOBAL",1)~ + ~Frightful truth?  What do you know about me, Amelia?  Please, tell me and the powders shall be yours!~ + AMRE2.6
+ ~!InParty("coran") Global("X#CoranCharmed","GLOBAL",1) Gender(Player1,MALE)~ + ~Hmmm... you nearly convinced me... Release my companion, and a bit of a reward added in the bargain might just do the trick.~ + AMRE2.4M
+ ~!InParty("coran") Global("X#CoranCharmed","GLOBAL",1) Gender(Player1,MALE)~ + ~Hmmm... you nearly convinced me... Release my companion, and a bit of a reward added in the bargain might just do the trick.~ + AMRE2.4F
++ ~Your elusive wordiness proves that you are a villain, and I shall give you the same answer I give to every villain I meet.  DIE!~ + AMRE2.3
END

IF ~~ AMRE2.2A
SAY ~I have it! I have it! Fare thee well, you, stupid primer!~
IF ~~ THEN DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",15) ActionOverride("coran",LeaveParty()) GiveItemCreate("X#COAMUL",Player1,1,0,0) EscapeArea() ActionOverride("coran",EscapeArea()) ActionOverride("natan",EscapeArea()) AddexperienceParty(8000)~
EXIT
END

IF ~~ AMRE2.2B
SAY ~I have it! I have it! Here, take this necklace. What is a trinket compared to freedom?~
IF ~~ THEN DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",16) GiveItemCreate("X#COAMUL",Player1,1,0,0) EscapeArea()  AddexperienceParty(8000)~
EXIT
END

IF ~~ AMRE2.3
SAY ~Then today is the day you die, silly mortal!~
IF ~~ THEN DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",17) Polymorph(ANTISOLAR) Enemy() ActionOverride("coran",Enemy()) ActionOverride("natan",Enemy()) AddexperienceParty(5000)~ EXIT
END

IF ~~ AMRE2.4F
SAY ~'Twas pleasure doing business with you, girl.~
IF ~~ THEN GOTO AMRE2.2B
END

IF ~~ AMRE2.4M
SAY ~'Twas a pleasure doing business with you... But I am afraid that you are not getting enough out of this deal, my hero.  Allow me to add the sweetest kiss, a kiss you shall never forget, to the payment....~
++ ~ Now, that's a lovely way to seal the bargain!~ + AMRE2.7
++ ~My father, Gorion, taught me never to kiss strange women!  Here are the powders, and suit your words - release the thieves, quickly!~ + AMRE2.8
END

IF ~~ AMRE2.5
SAY ~I doubt that you could, but I wish to be away from this plane.~
IF ~~ THEN GOTO AMRE2.2B
END

IF ~~ AMRE2.6
SAY ~*She smiles viciously* It's a deal.~
= ~The frightful truth is that you are only a demi-<RACE>... the second blood that flows trough your veins is powerful and dark... Now, I must go.  Follow me, my pets.~
IF ~~ THEN DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",15) ActionOverride("coran",LeaveParty()) EscapeArea() ActionOverride("coran",EscapeArea()) ActionOverride("natan",EscapeArea()) AddexperienceParty(8000)~
EXIT
END

IF ~~ AMRE2.7
SAY ~Come closer, sweetheart.~
IF ~~ THEN DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",15) Kill(Player1)~ EXIT
END

IF ~~ AMRE2.8
SAY ~Phew, boring mortal, no spine, no flames... but I have no time for games.  Give me the powders!  Ha!  I will be seeing you in the Nine Hells, <CHARNAME>! ~
IF ~~ THEN DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",16) GiveItemCreate("X#COAMUL",Player1,1,0,0) EscapeArea()  AddexperienceParty(8000)~
EXIT
END



//Talked to Natan w/o restoring roses

IF ~GlobalGT("X#CoranSuccubus","GLOBAL",7) GlobalLT("X#CoranSuccubus","GLOBAL",11)~ AmeliaReturn1
SAY ~You have returned.  Have your hearts softened to the plea of poor Amelia?  Will you help me?~
+ ~Global("X#CoranSuccubus","GLOBAL",8) Gender(Player1,FEMALE) OR(2) PartyHasItem("X#CODYE1") PartyHasItem("X#CODYE2")~+~Oh, stop this comedy already, succubus.  I have what you want. Will you buy it from me?~ + AMRE1.1F
+ ~Global("X#CoranSuccubus","GLOBAL",8) Gender(Player1,MALE) OR(2) PartyHasItem("X#CODYE1") PartyHasItem("X#CODYE2")~+~Oh, stop this comedy already, succubus.  I have what you want. Will you buy it from me?~ + AMRE1.1M
+ ~Global("X#CoranSuccubus","GLOBAL",8)~ + ~I… accidentally killed him. ~ + AMRE1.2
+ ~Global("X#CoranSuccubus","GLOBAL",10)~ + ~I heard Natan's side of the story, and I am inclined to believe him.  I have come to banish you from the Material Plane and free the thief.  Defend yourself, demon!~ + AMRE1.3
+ ~Global("X#CoranSuccubus","GLOBAL",9)~ + ~Natan told me that you are evil, and I'm inclined to believe him.  I let my sword do the talking when I meet with evil critters.  Die, witch!~ + AMRE1.3
+ ~Global("X#CoranSuccubus","GLOBAL",10) InParty("coran")~ + ~ You were right.  Natan had conjured some incomprehensible story accusing you of being a demon, of thievery, soul stealing... I wonder why he did not include a murder in the list?  Rather unfair...  At any rate, he is no man for you to be bonded to, so give me those roses and I shall try to free you.~ + AMRE1.4
+ ~Global("X#CoranSuccubus","GLOBAL",9) InParty("coran")~ + ~I decided to help you after all.  Natan was trying to tell me some complicated lie, and he is clearly not a man for a fair maiden like you to be bonded to.~ + AMRE1.4
+ ~Global("X#CoranSuccubus","GLOBAL",10)~ + ~ Listen, your game is over. I will spare you, however, if you surrender the stolen manual and swear not to hurt Natan.~ + AMRE1.5
END

IF ~~ AMRE1.1F
SAY ~You have it?  Wonderful.  Here is the magical item for your troubles... Give me the powders.~
+ ~OR(2) PartyHasItem("X#CODYE1") PartyHasItem("X#CODYE2") ~ + ~Everyone profits from the good honest trade.  Except for poor Natan, of course, but his death is inconsequential.  Farewell, Amelia, have fun with the powders.~ DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",12)~ + AMRE1.6
++ ~So Natan's story was true.  I cannot return him to life, but I can cleanse my group of blood wrongly spilled and avenge him.  Die, demon!~ + AMRE1.7
END

IF ~~ AMRE1.1M
SAY ~My hero!  The magical item I promised you is not enough to reward such a courageous act... Let me give you a kiss you will not forget, a kiss that no mortal woman will rival...~
++ ~The item is a sufficient reward, Amelia.  Everyone profits from good, honest trade, and I am not the one to mix business with pleasure.  Farewell, Amelia and have fun with the powders. ~ DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",12)~ + AMRE1.12
++ ~ Not so fast!  One measly item and a kiss?  How about you give us the manual and we split the powders in half?  A fair deal... ~ + AMRE1.7
++ ~So Natan's story was true.  I cannot return him to life, but I can cleanse my group of blood wrongly spilled and avenge him.  Die, demon!~ + AMRE1.7
+~!InParty("coran")~+ ~Kiss me then, beautiful, and kiss me hard. ~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",12) Kill(Player1)~ EXIT
+ ~InParty("coran")~ + ~Kiss me then, beautiful, and kiss me hard. ~ EXTERN CORANJ AMRE1.8A
END

IF ~~ AMRE1.2
SAY ~You killed him?  Did he… did he have a pouch with powders on him?  They are mine and I would like to have them back.  I will give you a magical item in exchange… ~
+ ~OR(2) PartyHasItem("X#CODYE1") PartyHasItem("X#CODYE2") ~ + ~Everyone profits from the good honest trade.  Except for poor Natan, of course, but his death is inconsequential.  Farewell, Amelia, have fun with the powders.~ DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",12)~ + AMRE1.6
+ ~!PartyHasItem("X#CODYE1") !PartyHasItem("X#CODYE2") ~ + ~I did not find any powders, Amelia, but I can return and search for them.~ + AMRE1.11
++ ~Hold on… there is more to this story then?  Maybe you are evil then… and you tricked me into killing an innocent man!  I cannot return him to life, but I can cleanse my group of blood wrongly spilled and avenge him.  Die, witch!~ + AMRE1.3
END

IF ~~ AMRE1.3
SAY ~Today is the day you die, silly mortal!~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",13) Polymorph(ANTISOLAR) Enemy() AddexperienceParty(5000)~ EXIT
END

IF ~~ AMRE1.4
SAY ~How very kind of you, my <PRO_LADYLORD>... ~
IF ~~ THEN GOTO COSU2.6
END

IF ~~ AMRE1.5
SAY ~So the petty thief figured it out?  I underestimated him... and your companion. Alas for you that you are not biddable fools after all.  I will not allow you to roam free, knowing who I am!  Today is the day you die, silly mortals!~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",13) Polymorph(ANTISOLAR) Enemy() AddexperienceParty(5000)~ EXIT
END

IF ~~ AMRE1.6
SAY ~Here, take this necklace. What is a trinket compared to freedom?~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",12) GiveItemCreate("X#COAMUL",Player1,1,0,0) EscapeArea() ActionOverride("natan",DestroySelf()) AddexperienceParty(8000)~
EXIT
END

IF ~~ AMRE1.7
SAY ~Mortal, you are not a biddable fool, but still you are a fool.  Do you think I shall allow you roam freely knowing who I am?  Today is the day you die!~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",13) Polymorph(ANTISOLAR) Enemy() AddexperienceParty(5000)~ EXIT
END

IF ~~ AMRE1.8
SAY ~Don't pay him any mind, <CHARNAME>, he is jealous...  ~
++ ~No!  He is right!  There was something dire about a succubus' kiss!  Stay away from me, demon, and let's exchange goods.~ + AMRE1.9
++ ~Your kisses… They kill, do they not?  You wanted to murder me!  Die, traitorous beast!~ + AMRE1.7
++ ~Pay him no mind, sweetheart... ~ + AMRE1.10
END

IF ~~ AMRE1.9
SAY ~Phew, boring mortal, no spine, no flames... Here, take this necklace.  I never liked it anyway.~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",12) GiveItemCreate("X#COAMUL",Player1,1,0,0) EscapeArea() ActionOverride("natan",DestroySelf()) AddexperienceParty(8000)~
EXIT
END

IF ~~ AMRE1.10
SAY ~He is nothing, darling, absolutely nothing. ~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",12) Kill(Player1)~ EXIT
END

IF ~~ AMRE1.11
SAY ~Please do, my friend, please do… I will reward you for bringing me those powders, for my freedom is in them--I feel it!~
IF ~~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",14)~ EXIT
END

IF ~~ AMRE1.12
SAY ~I am free at last!  My hero, you deserve more than the silly trinket.  Allow me to give you the sweetest kiss you shall never forget.~
++ ~That's really too much, Amelia.~ + AMRE1.6
+~!InParty("coran")~+ ~Kiss me then, beautiful, and kiss me hard. ~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",13) Kill(Player1)~ EXIT
+ ~InParty("coran")~ + ~Kiss me then, beautiful, and kiss me hard. ~ EXTERN CORANJ AMRE1.8A
++ ~You are free?  Without restoring the roses?  You know, all of this sounds odd.  I'd better kill you… in case you are evil.~ + AMRE1.3
END

IF ~Global("X#CoranSuccubus","GLOBAL",14) OR(2) PartyHasItem("X#CODYE1") PartyHasItem("X#CODYE2")~ LastChance
SAY ~You have the powders?  Wonderful.  Give them to me… quickly!  I am losing my patience!  Here is the magical item I promised you.~
++ ~Everyone profits from the good honest trade.  Except for poor Natan, of course, but his death is inconsequential.  Farewell, Amelia, have fun with the powders.~ DO ~TakePartyItem("X#CODYE1") TakePartyItem("X#CODYE2") SetGlobal("X#CoranSuccubus","GLOBAL",12)~ + AMRE1.6
++ ~Hold on… how do the powders free you?  I thought those were roses you needed?  Odd.  Maybe you are evil then… and you tricked me into killing an innocent man!  I cannot return him to life, but I can cleanse my group of blood wrongly spilled and avenge him.  Die, witch!~ + AMRE1.3
END


IF ~ Global("X#CoranSuccubus","GLOBAL",7)~ THEN YayRoses
SAY ~You have the roses? My heart sings with joy at this sight! Soon I shall be free. Hurry, hurry! Into the dungeon!~
= ~ *Cough* Forgive me my hastiness my good <PRO_LADYLORD>.~
IF ~~ THEN EXIT
END

IF ~Global("X#CoranSuccubus","GLOBAL",4)~ THEN Sob
SAY ~*She sobs*~
+~InParty("Coran")~+ ~OK, OK, give me your stupid roses!~ + COSU2.6
++ ~You have yourself a very good day, Amelia.~ EXIT
END

IF ~~ COSU2.1
SAY ~Thank you, kind strangers, and thank you, Coran, for being so understanding.  Take these roses to the temple in Beregost; ask the priest to restore them to life and once you are in the dungeon give them to Natan.  He is... he was a rogue. I am afraid, however, that he is angry with me for my rejecting his love, and he may try to tell you some nonsense about me... please, do not believe him!~
+ ~CheckStatGT(Player1,15,INT)~ + ~Your story - it sounds very suspicious to me.  Rogues are not the type to ask for oaths...~ + COSU2.4
++ ~What kind of tales exactly?~ + COSU2.5A
+ ~Gender(Player1,MALE)~ + ~If this cowardly dog tries in any way to dishonor you, my Lady, he will be stopped.  You have suffered enough.  Here, give me those roses and I vow to you that I shall do my best to free you.~ + COSU2.6
+ ~Gender(Player1,FEMALE)~ + ~Men... You tell me!  Ready to invent anything when they think that their tail was stepped on. Do not worry, sis, I'll see that he gets your roses!~ + COSU2.6
++ ~Is there any other way to give the message to Natan?  Perhaps a simple "I do not love you, and I will not marry you" on a scroll sealed with your signet ring?  I do not really want to go to the temple.~ + COSU2.7
END

IF ~~ COSU2.2
SAY ~Woe to me! How long will I be wandering unaided, desperate, desolate... *she sobs*  ~
IF ~Global("CoranMatch","GLOBAL",1)~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",4)~ UNSOLVED_JOURNAL ~Met an odd but most beautiful woman, Amelia.  She asked us to restore to life some withered roses and give them to Natan - a rogue who apparently hides somewhere in the Firewine ruins.  Her story sounded strange and, anyway, I have no time for delivering flowers, so I declined to help her.~
EXIT
IF ~!Global("CoranMatch","GLOBAL",1)~ THEN EXTERN CORANJ CoranQuitsSuccubus
END 


IF ~~ COSU2.3
SAY ~Would that I knew, my good <LADYLORD>.  Some ward guards it against me.  Whenever I want to enter, I am transferred to some far-away corner of Faerun.  The last time I ended in Turmish... so I do not dare to try again.~
++ ~This is all quite wondrous and strange.  We will help you, my dear woman, to the best of our abilities.~ + COSU2.6
++ ~I have no time for silly tales and roses.  Let's get moving, comrades.~ + COSU2.2
+ ~CheckStatGT(Player1,15,INT)~ + ~Your story - it sounds very suspicious to me.  Rogues are not the type to ask for oaths...~ + COSU2.4
END

IF ~~ COSU2.4
SAY ~It is a common misconception, my good <PRO_LADYLORD>.  In my fiancé's Guild all sorts of oaths were given and taken.  Some even involved family members... to tie them into their schemes entirely.  I was young and foolish and found it most enticing.  Alas, his charms faded with distance and time and now I would like to have my life back... if I still can, or to die in peace.  Will you help me?~
++ ~ I see.  Well, give me those roses and I will try to release you from your oath.~ + COSU2.6
++ ~That sounds more and more intriguing.  Where are you from?  I have heard of a number of Thieve Guilds, and, in fact, I would like to record such an interesting custom as making a member's fiancée give a solemn vow.~ + COSU2.8
++ ~Is there any other way to give the message to Natan?  Perhaps a simple "I do not love you, and I will not marry you" on a scroll sealed with your signet ring?  I do not really want to go to the temple.~ + COSU2.7
END

IF ~~ COSU2.5
SAY ~I see that you trust me not.  Alas, I will be wandering unaided then...  ~
IF ~Global("CoranMatch","GLOBAL",1)~ THEN DO ~SetGlobal("X#CoranSuccubus","GLOBAL",4)~ UNSOLVED_JOURNAL ~Met an odd but most beautiful woman, Amelia.  She asked us to restore to life some withered roses and give them to Natan - a rogue who apparently hides somewhere in the Firewine ruins.  Her story sounded strange and, anyway, I have no time for delivering flowers, so I declined to help her.~
EXIT
IF ~!Global("CoranMatch","GLOBAL",1)~ THEN EXTERN CORANJ CoranQuitsSuccubus
END 

IF ~~ COSU2.5A
SAY ~O, I do not know.  It just occurred to me that Natan might be angry, and he was never a sweet-spoken man.  He will lash me with his tongue, I am sure.  He will call me a witch and tell other lies... only to get back at me, of course.~
+ ~CheckStatGT(Player1,15,INT)~ + ~That sounds a bit excessive for a man rejected by his fiancée... even if he is a rogue of the worst kind.  Tell me, my dear, is there a grain of truth in those tales?~ + COSU2.5
+ ~Gender(Player1,MALE)~ + ~If this cowardly dog tries in any way to dishonor you, my Lady, he will be stopped.  You have suffered enough.  Here, give me those roses and I vow to you that I shall do my best to free you.~ + COSU2.6
+ ~Gender(Player1,FEMALE)~ + ~Men... You tell me!  Ready to invent anything when they think that their tail was stepped on. Do not worry, sis, I'll see that he gets your roses!~ + COSU2.6
++ ~Is there any other way to give the message to Natan?  Perhaps a simple "I do not love you, and I will not marry you" on a scroll sealed with your signet ring?  I do not really want to go to the temple.~ + COSU2.7
END

END

APPEND ~CORANP~

IF WEIGHT #-2 ~Global("X#CoranCharmed","GLOBAL",1)~ X#CoranCharmed
SAY ~Amelia... I adore Amelia...~
IF ~~ THEN DO ~EscapeAreaMove("AR3700",4040,2091,3)~ EXIT
END
END

CHAIN CORANJ CoranQuitsSuccubus
~No, my Lady, you will not!  I am at your disposal.~
== X#AMELIA ~Oh, it's quite noble of you my good elf.  Forgive me kindly for breaking up your small fellowship.~
DO ~SetGlobal("X#CoranCharmed","GLOBAL",1) ActionOverride("coran",LeaveParty()) ActionOverride("coran",SetDialogue("CoranP")) ActionOverride("coran",EscapeAreaMove("AR3700",4040,2091,3)) SetGlobal("X#CoranSuccubus","GLOBAL",4)~
END
IF ~~ UNSOLVED_JOURNAL ~Met an odd but most beautiful woman, Amelia.  She asked us to restore to life some withered roses and give them to Natan - a rogue who apparently hides somewhere in the Firewine ruins.  Her story sounded strange and, anyway, I have no time for delivering flowers, so I declined to help her. Coran, however ran away to help the girl. Typical.~ EXIT

CHAIN X#AMELIA COSU2.6
~Oh, you are the most noble company I have ever met!  Coran, my brave elf, will you take these awful dead roses from me?~
== CORANJ ~'Twill be my pleas- Ow! Auw!  They certainly kept their thorns!~
== X#AMELIA ~Are you hurt, my poor hero?  Ah, I'm so clumsy!  I've scratched the most wonderful man I have ever met... you must think me so terrible.  Now, allow me to bandage your wound with my handkerchief...~
END
++ ~Gods have pity on me!  Amelia, Coran gets hacked to pieces every other day.  The scratch is nothing!~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT
+ ~Global("CoranMatch","GLOBAL",1)~+ ~He has a woman to take care of his wounds, Amelia.  Fare thee well.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT
+ ~Global("CoranMatch","GLOBAL",1)~ + ~There is no need.  Coran, remind me to box your ears later... after I've skinned you alive.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT
++ ~Hmm… good thing that we are going to a temple!  They will have a priest at the ready in case Coran perishes from his grievous hurts.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT
++ ~We will take most gentle care of our ailing comrade, Amelia.  I am sure he will forget this terrifying flesh wound for the pain he has now in his heart.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT
++ ~Excuse me whilst I gag.  Just don't start reciting poetry, both of you, or I'll have your hides!~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT
++ ~*Smile* I am sorry to take my smitten comrade from you, my lady but we better get moving if we are to free you from the curse.~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",5) GiveItemCreate("X#COWIRO","Coran",1,0,0)~ UNSOLVED_JOURNAL ~We have encountered a maiden, apparently betrothed to a thief who is hiding from her in the Firewine Bridge ruins. Apparently Amelia cannot enter the ruins, but she cannot depart the area either until giving her fiancé a "yes" or "no" response - in the form of white and red roses, respectively.  We agreed to restore to life a bunch of withered roses for her and give it to this wretch Natan. According to Amelia it will set her free her from her vow.~ EXIT

CHAIN X#AMELIA COSU2.7
~ No, there is no other way... it has to be the red roses...~
== CORANJ ~I'd cut you fresh roses in the closest garden, my darling, as many as you want!~
== X#AMELIA ~No, it will not do, my dear friend.  I need *these ones* restored and brought to Natan. *She sobs*~
END
+ ~CheckStatGT(Player1,15,INT)~ + ~Oh?  And why is that?  How is one red rose different from another?~ + COSU2.8
++ ~Please, do not cry.  We are on our way to help you.~ + COSU2.6
++ ~Well, you must know better - it's *your* curse after all.  We will go to the temple, restore the roses to life, and then we shall deliver them to Natan.~ + COSU2.6

CHAIN X#AMELIA COSU2.8
~My kind <PRO_LADYLORD>, I will gladly trade tales with you after you deliver me from this terrible curse. *sobs* Please... help me.~
== CORANJ ~ <CHARNAME>! Do not be so heartless.... Look, she is nearly fainting!~
END
++ ~I am sorry, Amelia, but I do not believe you.  Either you tell me the truth, or I am not going to help you.~ + COSU2.5
++ ~Please, do not cry.  We are on our way to help you.~ + COSU2.6

APPEND CORANJ

IF ~~ AMRE1.8A
SAY ~Wait... wait <CHARNAME>, she is a... ~
IF ~~ THEN EXTERN X#AMELIA AMRE1.8
END

IF ~~ CoranResistShort
SAY ~I feel... I feel Amelia calling me to come and serve her.  I am afraid that the priestess and Natan are right - there is evil in those roses and this... woman.  I… I can resist for now, but not for long.  We need to find Amelia, <CHARNAME>.~ 
IF ~~ THEN DO ~ SetGlobalTimer("X#CoranResistTimer","GLOBAL", 10800) ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXIT
END

IF ~~ CoranResistLong
SAY ~I feel... I feel Amelia calling me to come and serve her.  I am afraid that the priestess and Natan are right - there is evil in those roses and this... woman.  I… I can resist for now, but not for long.  We need to find Amelia, <CHARNAME>.~ 
IF ~~ THEN DO ~SetGlobalTimer("X#CoranResistTimer","GLOBAL", 21600) ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXIT
END

IF ~~ CoranNotResist
SAY ~The Mistress calls!  I must run!~
IF ~~ THEN DO ~SetGlobal("X#CoranCharmed","GLOBAL",1) LeaveParty() SetDialogue("CoranP") EscapeAreaMove("AR3700",4040,2091,3) ActionOverride("natan",EscapeAreaMove("AR3700",4040,2091,3))~ EXIT
END

IF WEIGHT #-2 ~Global("X#CoranCharmedRun","GLOBAL",1) ~ CoranNotResistAfterTimer
SAY ~The Mistress calls!  I must run!~
IF ~~ THEN DO ~SetGlobal("X#CoranCharmedRun","GLOBAL",2) SetGlobal("X#CoranCharmed","GLOBAL",1) LeaveParty() SetDialogue("CoranP") EscapeAreaMove("AR3700",4040,2091,3)~ EXIT
END


IF WEIGHT #-2 ~Global("X#CoranSuccubus","GLOBAL",2)~ THEN BEGIN CoranSuccubus
SAY ~Hail, lovely Lady!  What are you doing in this desolate place?~
++ ~*Sigh* Now, Coran, please limit yourself to chasing real women.  Gods be good!  Did I really say that?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",3)~ + COSUC1.1
++ ~Blasted ruins!  They're going to drive us all mad!  Coran, come along, no living Lady will ever wander this place... But there are plenty of ghosts in the ruins of Firewine...~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",3)~ + COSUC1.1
++ ~I… I do not see anyone.  Do you, Coran?~ DO ~SetGlobal("X#CoranSuccubus","GLOBAL",3)~ + COSUC1.2
END

IF ~~ COSUC1.1
SAY ~She is real... or surreal... I could see her vanishing in the mists and hear her singing.  She sounded sad.  Perhaps she needs help.  Let us go search for her - she went eastwards.~
++ ~Coran, when we need to go east, I will issue such an order.  Now fall back in line.~ + COSUC1.3
+ ~!Race(Player1,ELF)~ + ~Wow, that's elven-keen eyes and ears for you!  East, you said?  Off we go!~ + COSUC1.4
++ ~I see... A ghostly damsel in distress.  Let me know if you spot her again.~ + COSUC1.4
++ ~*You sigh* Another good deed?  Alright, alright.  Let us search for that weeping woman.~ + COSUC1.4
++ ~We came here to do other things!  I will not be diverted by your foolish fantasies.~ + COSUC1.3
END

IF ~~ COSUC1.2
SAY ~Yes, I see... er... I saw her.  To be more exact, I have seen her vanishing into the mists and heard her singing.  She sounded sad.  Perhaps she needs help.  Let us go search for her - she went in that direction, eastwards.~
++ ~Coran, when we need to go east, I will issue such an order.  Now fall back in line.~ + COSUC1.3
+ ~!Race(Player1,ELF)~ + ~Wow, that's elven-keen eyes and ears for you!  East, you said?  Off we go!~ + COSUC1.4
++ ~I see... A ghostly damsel in distress.  Let me know if you spot her again.~ + COSUC1.4
++ ~*You sigh* Another good deed?  Alright, alright.  Let us search for that weeping woman.~ + COSUC1.4
++ ~We came here to do other things!  I will not be diverted by your foolish fantasies.~ + COSUC1.3
END

IF ~~ COSUC1.3
SAY ~As you wish.  But mark my words, there is a maiden out there, crying her heart out and... Ah, you are the type who does not care of anything but your own schemes.~
IF ~Global("CoranMatch","GLOBAL",1)~ THEN EXIT
IF ~!Global("CoranMatch","GLOBAL",1)~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

IF ~~ COSUC1.4
SAY ~Wonderful!  I wonder, what was her name?~
IF ~~ THEN EXIT
END
END

CHAIN IF ~Global("X#CoranSuccubus","GLOBAL",3)~ THEN X#AMELIA AmeliaRoses
~Roses opened too early that year.
When winds came and ice storms
The roses blooming, red and fair
Turned into monsters with thorns.~
== CORANJ ~I hear you, beautiful... who are you?  What are you?  A spirit? ~
== X#AMELIA ~Coran... Coran, I do not know what I am.  Probably a ghost.~
= ~All I know is that I was to give an answer to the man I was promised to. He went into those dungeons in search of his fortune... and never came back.  I swore to give him a red rose on my sixteenth birthday if I rejected his love and a white one if I accepted it... and the oath brought me here.  I cannot enter the place; I cannot find him... cannot give him the flowers.~
= ~I wander around with a basket of withered roses - O, cruel fate!~
== CORANJ ~Red or white roses?~
== X#AMELIA ~Red...~
== CORANJ ~I am sure we can help you... um, what did you say was your name?~
== X#AMELIA ~Amelia... my name is Amelia.~
== CORANJ ~Lady Amelia, there will be no trouble at all for us to cut you some fresh roses, exorcise the dungeon, lay that cavalier of yours to his grave, and free you from your oath.  A smile, my Lady?~
== X#AMELIA ~Kind sir, I am delighted to meet a man of such exceptional gallantry and one so handsome... but your friend - <PRO_HESHE> is frowning... I would not want you to...~
END
++ ~We will help you, my dear woman, to the best of our abilities.~ + COSU2.1
++ ~Good eye, wench.  Indeed, we have no time for charity and roses.~ + COSU2.2
++ ~Why can't you enter the dungeon by yourself, Amelia? ~ + COSU2.3

