IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("DreamTimerStarted","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("DreamTalk","GLOBAL",180)
SetGlobal("DreamTimerStarted","GLOBAL",1)
END

IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("GaPCTimerStarted","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("GaFriendTalkTime","GLOBAL",1800)
SetGlobal("GaPCTimerStarted","GLOBAL",1)
END

IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("GaFriendTalkTime","GLOBAL")
Global("GaFriendTalk","GLOBAL",0)
!StateCheck(Player1,STATE_SLEEPING)
THEN
RESPONSE #100
IncrementGlobal("GaFriendTalk","GLOBAL",1)
RealSetGlobalTimer("GaFriendlyTalkTime","GLOBAL",10)
Interact(Player1)
END

IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("GaFriendlyTalkTime","GLOBAL")
Global("GaFriendTalk","GLOBAL",1)
THEN
RESPONSE #100
IncrementGlobal("GaFriendTalk","GLOBAL",1)
RealSetGlobalTimer("GaFriendTalkTime","GLOBAL",18000)
END

IF
PartyHasItem("X#garbk")
GlobalTimerExpired("X#GarrickBookTalk","GLOBAL")
Global("X#GarrickReadBook","GLOBAL",0)
THEN
RESPONSE #100
StartDialogueNoSet(Player1)
SetGlobal("X#GarrickReadBook","GLOBAL",1)
END

IF
AreaCheck("AR3800")
Global("X#ArchiSpawn","LOCALS",0)
THEN
RESPONSE #100
CreateCreature("X#Garar",[2600.3300],1)
SetGlobal("X#ArchiSpawn","LOCALS",1)
END

IF
AreaCheck("AR9800")
Global("X#GarrickQuest","GLOBAL",1)
Global("X#GarrickReadBook","GLOBAL",1)
Global("X#WyliamSpawn","LOCALS",0)
THEN
RESPONSE #100
SetGlobal("X#GarrickQuest","GLOBAL",2)
SetGlobal("X#WyliamSpawn","LOCALS",1)
CreateCreature("X#GarWyl",[950.1675],1)
CreateCreature("X#Garz01",[925.1675],1)
CreateCreature("X#Garz02",[975.1675],1)
CreateCreature("X#Garz03",[950.1650],1)
CreateCreature("X#Garz04",[950.1625],1)
END

IF
AreaCheck("AR9800")
PartyHasItem("X#GARCH")
Global("X#PostMyrChat","LOCALS",0)
THEN
RESPONSE #100
StartDialogueNoSet(Player1)
SetGlobal("X#PostMyrChat","LOCALS",1)
END
