//do not kill bears!
IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
OR(4)
NumDead("bearbl",5)
NumDead("bearbr",5)
NumDead("bearca",5)
NumDead("bearpo",5)
AreaType(FOREST)
Global("X#FalBear","GLOBAL",0)
THEN
RESPONSE #100
IncrementGlobal("X#FalBear","GLOBAL",1)
Dialogue(Player1)
END

IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
OR(4)
NumDead("bearbl",6)
NumDead("bearbr",6)
NumDead("bearca",6)
NumDead("bearpo",6)
AreaType(FOREST)
Global("X#FalBear","GLOBAL",3)
THEN
RESPONSE #100
IncrementGlobal("X#FalBear","GLOBAL",1)
Dialogue(Player1)
END


//FaldornQuit
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
AreaCheck("FW5200")
Global("FaDryadQuit","GLOBAL",1)
THEN
RESPONSE #100
MoveToObject("caldo")
SetGlobal("FaDryadQuit","GLOBAL",2)
Kill("caldo")
END

IF
AreaCheck("AR4200")
Global("FaDryadQuit","GLOBAL",2)
Dead("caldo")
THEN
RESPONSE #100
MoveToObject("krumm")
SetGlobal("FaDryadQuit","GLOBAL",3)
Kill("krumm")
SetGlobal("KickedOut","LOCALS",2)
LeaveParty()
END

IF
AreaCheck("AR4200")
Global("FaDryadQuit","GLOBAL",3)
Dead("krumm")
THEN
RESPONSE #100
SetGlobal("FaDryadQuit","GLOBAL",4)
SetGlobal("KickedOut","LOCALS",1)
END

// Faldorn, At Seeing The Firewine Ruins
IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
AreaCheck("AR3400")
Global("FASTFWR","GLOBAL",0)
See("X#poe")
THEN
RESPONSE #100
SetGlobal("FASTFWR","GLOBAL",1)
Dialogue(Myself)
END

//Faldorn at entering Map 0400
IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
AreaCheck("AR7600")
Global("FaldornM400","GLOBAL",0)
THEN
RESPONSE #100
SetGlobal("FaldornM400","GLOBAL",1)
Dialogue(Myself)
END

//Fergus
IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
AreaCheck("AR7707")
Global("FERGUS1","GLOBAL",1)
Global("X#FaldornFergus","GLOBAL",0)
THEN
RESPONSE #100
SetGlobal("X#FaldornFergus","GLOBAL",1)
Dialogue(Player1)
END

