//Coran Interjections

//Coran Durlyle
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
IsValidForPartyDialogue("Coran")
Global("X#CoranDur","GLOBAL",2)
!See("durlyle")
THEN
RESPONSE #100
SetGlobal("X#CoranDur","GLOBAL",3)
Dialog(Player1)
END


//Unicorn Run
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("X#CoranUnicorn","GLOBAL",1)
PartyHasItem("BOOK55")
THEN
RESPONSE #100
SetGlobal("X#CoranUnicorn","GLOBAL",2)
Dialog(Player1)
END

//Taxek
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("X#CoranTaxek","GLOBAL",1)
!See("michael")
THEN
RESPONSE #100
SetGlobal("X#CoranTaxek","GLOBAL",2)
Dialog(Player1)
END

//Natasha Dead
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("X#CoranNatasha","GLOBAL",0)
Dead("natasha")
AreaCheck("AR8602")
THEN
RESPONSE #100
SetGlobal("X#CoranNatasha","GLOBAL",1)
StartDialogueNoSet(Player1)
END

//FW4003 halfling brewery
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("X#CoranHB","GLOBAL",0)
AreaCheck("AR9903")
THEN
RESPONSE #100
SetGlobal("X#CoranHB","GLOBAL",1)
Dialog(Player1)
END

// Coran, Sighting The Dragon Skeleton  TOTSC
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
AreaCheck("ARD013")
Global("CSTDS","GLOBAL",0)
!See("ENEMY")
THEN
RESPONSE #100
SetGlobal("CSTDS","GLOBAL",1)
Dialog(Myself)
END

// Coran, Shoal Kiss - Female
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("ShoalHit","GLOBAL",0)
Global("ShoalKiss","GLOBAL",1)
Global("CSKFemale","GLOBAL",0)
Allegiance("SHOAL",ENEMY)
  OR(9)
Dead("ALORA")
Dead("DYNAHEIR")
Dead("JAHEIRA")
Dead("SAFANA")
Dead("FALDORN")
Dead("BRANWEN")
Dead("SKIE")
Dead("SHARTEEL")
Dead("VICONIA")
THEN
RESPONSE #100
SetGlobal("CSKFemale","GLOBAL",1)
Wait(1)
Dialog(Myself)
END

// Coran, Shoal Kiss - Male
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("ShoalHit","GLOBAL",0)
Global("ShoalKiss","GLOBAL",1)
Global("CSKMale","GLOBAL",0)
Allegiance("SHOAL",ENEMY)
OR(14)
Dead("KIVAN")
Dead("MINSC")
Dead("YESLICK")
Dead("AJANTIS")
Dead("KHALID")
Dead("GARRICK")
Dead("QUAYLE")
Dead("XAN")
Dead("ELDOTH")
Dead("XZAR")
Dead("MONTARON")
Dead("TIAX")
Dead("KAGAIN")
Dead("EDWIN")
THEN
RESPONSE #100
SetGlobal("CSKMale","GLOBAL",1)
Wait(1)
Dialog(Myself)
END

IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("CSKCCIV","GLOBAL",1)
Allegiance("SHOAL",ENEMY)
Dead("Coran")
THEN
RESPONSE #100
SetGlobal("CSKCCIV1","GLOBAL",1)
END

// Coran, Shoal kiss, Coran's Comment
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("CSKCCIV1","GLOBAL",1)
Global("CSKCCIV","GLOBAL",1)
Global("ShoalHit","GLOBAL",1)
Global("LastBug","GLOBAL",1)
Global("ShoalKiss","GLOBAL",1)
Global("CSKCC","GLOBAL",0)
THEN
RESPONSE #100
SetGlobal("CSKCC","GLOBAL",1)
Dialog(Myself)
END

// Coran, Entry to Baldur’s Gate
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
AreaCheck("AR7800")
Global("CEBG","GLOBAL",0)
THEN
RESPONSE #100
SetGlobal("CEBG","GLOBAL",1)
Dialog(Myself)
END


// Coran, Entry to Durlag’s Tower
IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("CEDT","GLOBAL",0)
AreaCheck("ARD002")
THEN
RESPONSE #100
SetGlobal("CEDT","GLOBAL",1)
Dialog(Myself)
END

