//set romance match

IF
Global("CoranMatch","GLOBAL",0)
Global("CheckCoranMatch","GLOBAL",0)
Gender(Player1,FEMALE)
!Global("KivanLover","GLOBAL",1)
!Global("KivanRomanceActive","GLOBAL",2)
!Global("XanRomanceActive","GLOBAL",2)
!Global("EldothRomanceActive","GLOBAL",2)
!Global("CoranRomanceInactive","GLOBAL",1)
!InParty("Safana")
!Alignment(Player1,LAWFUL_EVIL)
OR(3)
Race(Player1,HUMAN)
Race(Player1,ELF)
Race(Player1,HALF_ELF)
ReputationGT(Player1,10)
CheckStatGT(Player1,12,CHR)
THEN
RESPONSE #100
SetGlobal("CoranMatch","GLOBAL",1)
SetGlobal("CheckCoranMatch","GLOBAL",1)
END

//NPC Reactions

IF 
InParty(Myself)
Global("CoranMatch","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",0)
Global("CoranFriend","GLOBAL",1)
Global("CoRomReaction","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("CRoReactionTime","GLOBAL",500)
SetGlobal("CoRomReaction","GLOBAL",1)
END

//chaotic_good

IF 
InParty(Myself)
Global("CoranMatch","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",0)
Global("CoranFriend","GLOBAL",1)
Global("CGLoveTalk","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("CGLoveTalkTime","GLOBAL",10)
SetGlobal("CGLoveTalk","GLOBAL",1)
SetGlobal("CoranRomancePath","GLOBAL",1)
END

IF
InParty(Myself) 
RealGlobalTimerExpired("CGLoveTalkTime","GLOBAL")
ReputationGT(Player1,10)
OR(2)
Global("CoranRomancePath","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",6)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
OR(9)
Global("CGLoveTalk","GLOBAL",1)
Global("CGLoveTalk","GLOBAL",3)
Global("CGLoveTalk","GLOBAL",7)
Global("CGLoveTalk","GLOBAL",11)
Global("CGLoveTalk","GLOBAL",17)
Global("CGLoveTalk","GLOBAL",19)
Global("CGLoveTalk","GLOBAL",21)
Global("CGLoveTalk","GLOBAL",23)
Global("CGLoveTalk","GLOBAL",31)
!InParty("Safana")
THEN
RESPONSE #100
RealSetGlobalTimer("CGLovelyTalkTime","GLOBAL",1)
IncrementGlobal("CGLoveTalk","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CGLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
OR(9)
Global("CGLoveTalk","GLOBAL",2)
Global("CGLoveTalk","GLOBAL",4)
Global("CGLoveTalk","GLOBAL",8)
Global("CGLoveTalk","GLOBAL",12)
Global("CGLoveTalk","GLOBAL",18)
Global("CGLoveTalk","GLOBAL",20)
Global("CGLoveTalk","GLOBAL",22)
Global("CGLoveTalk","GLOBAL",24)
Global("CGLoveTalk","GLOBAL",32)
THEN
RESPONSE #100
RealSetGlobalTimer("CGLoveTalkTime","GLOBAL",1800)
IncrementGlobal("CGLoveTalk","GLOBAL",1)
END

IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("CGLoveTalkTime","GLOBAL")
OR(2)
Global("CoranRomancePath","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",6)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CGLoveTalk","GLOBAL",5)
ReputationGT(Player1,10)
!InParty("Safana")
PartyRested()
THEN
RESPONSE #100
IncrementGlobal("CGLoveTalk","GLOBAL",1)
RealSetGlobalTimer("CGLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CGLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CGLoveTalk","GLOBAL",6)
THEN
RESPONSE #100
IncrementGlobal("CGLoveTalk","GLOBAL",1)
RealSetGlobalTimer("CGLoveTalkTime","GLOBAL",1800)
END

IF 
InParty(Myself)
OR(2)
Global("CoranRomancePath","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",6)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoOcean","GLOBAL",1)
Global("CGLoveTalk","GLOBAL",29)
ReputationGT(Player1,10)
!InParty("Safana")
PartyRested()
THEN
RESPONSE #100
IncrementGlobal("CGLoveTalk","GLOBAL",1)
RealSetGlobalTimer("CGLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CGLovelyTalkTime","GLOBAL")
Global("CoOcean","GLOBAL",1)
Global("CGLoveTalk","GLOBAL",30)
THEN
RESPONSE #100
IncrementGlobal("CGLoveTalk","GLOBAL",1)
IncrementGlobal("CoOcean","GLOBAL",1)
RealSetGlobalTimer("CGLoveTalkTime","GLOBAL",1800)
END

//bored

IF 
InParty(Myself)
Global("CoranMatch","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",2)
Global("CoranFriend","GLOBAL",1)
Global("CBoredTalk","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("CBoredTalkTime","GLOBAL",10)
SetGlobal("CBoredTalk","GLOBAL",1)
END

IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("CBoredTalkTime","GLOBAL")
Global("CoranRomancePath","GLOBAL",2)
!Global("CoranRomanceInactive","GLOBAL",1)
!InParty("Safana")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CBoredTalk","GLOBAL",1)
ReputationGT(Player1,10)
OR(19)
AreaCheck("AR3701")
AreaCheck("AR6751")
AreaCheck("AR6704")
AreaCheck("AR6757")
AreaCheck("AR6707")
AreaCheck("AR6801")
AreaCheck("AR7203")
AreaCheck("AR7205")
AreaCheck("AR7214")
AreaCheck("AR7216")
AreaCheck("AR7219")
AreaCheck("AR7254")
AreaCheck("AR7265")
AreaCheck("AR7705")
AreaCheck("AR7807")
AreaCheck("AR8009")
AreaCheck("AR8013")
AreaCheck("AR8115")
AreaCheck("AR8206")
THEN
RESPONSE #100
IncrementGlobal("CBoredTalk","GLOBAL",1)
RealSetGlobalTimer("CBLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CBLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CBoredTalk","GLOBAL",2)
THEN
RESPONSE #100
IncrementGlobal("CBoredTalk","GLOBAL",1)
RealSetGlobalTimer("CBoredTalkTime","GLOBAL",1800)
END

IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("CBoredTalkTime","GLOBAL")
Global("CoranRomancePath","GLOBAL",2)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CBoredTalk","GLOBAL",5)
ReputationGT(Player1,10)
TimeOfDay(MORNING)
THEN
RESPONSE #100
IncrementGlobal("CBoredTalk","GLOBAL",1)
RealSetGlobalTimer("CBLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CBLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CBoredTalk","GLOBAL",6)
THEN
RESPONSE #100
IncrementGlobal("CBoredTalk","GLOBAL",1)
RealSetGlobalTimer("CBoredTalkTime","GLOBAL",1800)
END

//Neutral_1

IF 
InParty(Myself)
Global("CoranMatch","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",3)
Global("CoranFriend","GLOBAL",1)
Global("CNeutralTalk","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("CNeutralTalkTime","GLOBAL",10)
SetGlobal("CNeutralTalk","GLOBAL",1)
END

IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("CNeutralTalkTime","GLOBAL")
Global("CoranRomancePath","GLOBAL",3)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
OR(2)
Global("CNeutralTalk","GLOBAL",1)
Global("CNeutralTalk","GLOBAL",9)
THEN
RESPONSE #100
IncrementGlobal("CNeutralTalk","GLOBAL",1)
RealSetGlobalTimer("CNLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CNLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
OR(2)
Global("CNeutralTalk","GLOBAL",2)
Global("CNeutralTalk","GLOBAL",10)
THEN
RESPONSE #100
IncrementGlobal("CNeutralTalk","GLOBAL",1)
RealSetGlobalTimer("CNeutralTalkTime","GLOBAL",1800)
END

IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("CNeutralTalkTime","GLOBAL")
Global("CoranRomancePath","GLOBAL",3)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
GlobalLT("CBoredTalk","GLOBAL",2)
Global("CNeutralTalk","GLOBAL",5)
OR(19)
AreaCheck("AR3701")
AreaCheck("AR6751")
AreaCheck("AR6704")
AreaCheck("AR6757")
AreaCheck("AR6707")
AreaCheck("AR6801")
AreaCheck("AR7203")
AreaCheck("AR7205")
AreaCheck("AR7214")
AreaCheck("AR7216")
AreaCheck("AR7219")
AreaCheck("AR7254")
AreaCheck("AR7265")
AreaCheck("AR7705")
AreaCheck("AR7807")
AreaCheck("AR8009")
AreaCheck("AR8013")
AreaCheck("AR8115")
AreaCheck("AR8206")
THEN
RESPONSE #100
IncrementGlobal("CNeutralTalk","GLOBAL",1)
RealSetGlobalTimer("CNLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CNLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CNeutralTalk","GLOBAL",6)
THEN
RESPONSE #100
IncrementGlobal("CNeutralTalk","GLOBAL",1)
RealSetGlobalTimer("CNeutralTalkTime","GLOBAL",1800)
END

IF 
InParty(Myself) CombatCounter(0) !See([ENEMY])
RealGlobalTimerExpired("CNeutralTalkTime","GLOBAL")
Global("CoranRomancePath","GLOBAL",3)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
GlobalGT("CBoredTalk","GLOBAL",1)
Global("CNeutralTalk","GLOBAL",5)
THEN
RESPONSE #100
IncrementGlobal("CNeutralTalk","GLOBAL",2)
RealSetGlobalTimer("CNeutralTalkTime","GLOBAL",10)
END

IF 
InParty(Myself)
Global("CoranRomancePath","GLOBAL",3)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("Co3Healer","GLOBAL", 1)
PartyRested()
THEN
RESPONSE #100
IncrementGlobal("Co3Healer","GLOBAL", 1)
Interact(Player1)
END

IF 
InParty(Myself)
Global("CoranRomancePath","GLOBAL",3)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("Co3Marriage","GLOBAL", 1)
PartyRested()
THEN
RESPONSE #100
IncrementGlobal("Co3Marriage","GLOBAL", 1)
Interact(Player1)
END


//boredneutral
IF 
InParty(Myself)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",4)
GlobalLT("CBoredTalk","GLOBAL",5)
Global("CNBoredTalk","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("CNBoredTalkTime","GLOBAL",10)
SetGlobal("CNBoredTalk","GLOBAL",1)
END

IF
InParty(Myself) CombatCounter(0) !See([ENEMY])
Global("CoranRomancePath","GLOBAL",4)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CNBoredTalk","GLOBAL",1)
RealGlobalTimerExpired("CNBoredTalkTime","GLOBAL")
TimeOfDay(MORNING)
THEN
RESPONSE #100
IncrementGlobal("CNBoredTalk","GLOBAL",1)
RealSetGlobalTimer("CNBLovelyTalkTime","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CNBLovelyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CNBoredTalk","GLOBAL",2)
THEN
RESPONSE #100
IncrementGlobal("CNBoredTalk","GLOBAL",1)
RealSetGlobalTimer("CNBoredTalkTime","GLOBAL",1800)
END

//neutralsexy
IF 
InParty(Myself)
!Global("CoranRomanceInactive", "GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
Global("CoranRomancePath","GLOBAL",5)
Global("CNSexTalk","GLOBAL",0)
Global("CoranFriend","GLOBAL",1)
THEN
RESPONSE #100
RealSetGlobalTimer("CNSexTalkTime","GLOBAL",10)
SetGlobal("CNSexTalk","GLOBAL",1)
END

//babytalks

IF 
InParty(Myself)
Global("CoranMatch","GLOBAL",1)
!Global("CoranRomanceInactive", "GLOBAL", 1)
Global("CoranFriend","GLOBAL",1)
Global("CGBabyTalk","GLOBAL",0)
Global("BRIEL_STAY","GLOBAL",4)
THEN
RESPONSE #100
RealSetGlobalTimer("CGBabyTalkTime","GLOBAL",10)
SetGlobal("CGBabyTalk","GLOBAL",1)
SetGlobal("CoranRomancePath","GLOBAL",6)
END

IF
InParty(Myself) 
RealGlobalTimerExpired("CGBabyTalkTime","GLOBAL")
ReputationGT(Player1,10)
Global("CoranRomancePath","GLOBAL",6)
!Global("CoranRomanceInactive","GLOBAL",1)
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
GlobalGT("CGLoveTalk","GLOBAL",32)
OR(3)
Global("CGBabyTalk","GLOBAL",1)
Global("CGBabyTalk","GLOBAL",3)
Global("CGBabyTalk","GLOBAL",5)
!InParty("Safana")
THEN
RESPONSE #100
RealSetGlobalTimer("CGBabylyTalkTime","GLOBAL",1)
IncrementGlobal("CGBabyTalk","GLOBAL",1)
Interact(Player1)
END

IF 
InParty(Myself)
RealGlobalTimerExpired("CGBabylyTalkTime","GLOBAL")
Global("CoranFriend","GLOBAL",1)
Global("CoranMatch","GLOBAL",1)
OR(3)
Global("CGBabyTalk","GLOBAL",2)
Global("CGBabyTalk","GLOBAL",4)
Global("CGBabyTalk","GLOBAL",6)
THEN
RESPONSE #100
RealSetGlobalTimer("CGBabyTalkTime","GLOBAL",1800)
IncrementGlobal("CGBabyTalk","GLOBAL",1)
END

//coran-moves

IF
!Global("CoranRomancePath","GLOBAL",7)
Global("CoranMoves","GLOBAL",1)
THEN
RESPONSE #100
SetGlobal("CoranRomancePath","GLOBAL",7)
SetGlobal("CoranHasBaby","GLOBAL",2)
RealSetGlobalTimer("CoranReturn","GLOBAL",1)
TakePartyItem("X#CBABY")
TakePartyItem("X#CBOOK")
TakePartyItem("X#CMILK")
DestroyItem("X#CBABY")
DestroyItem("X#CBOOK")
DestroyItem("X#CMILK")
EscapeAreaMove("AR7203",368,402,2)
END

//back-uptimer
IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
OR(4)
Global("CGLoveTalk","GLOBAL",10)
Global("CGLoveTalk","GLOBAL",14)
Global("CGLoveTalk","GLOBAL",26)
Global("CGLoveTalk","GLOBAL",28)
THEN
RESPONSE #100
IncrementGlobal("CGLoveTalk","GLOBAL",-1)
END

IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
OR(2)
Global("CBoredTalk","GLOBAL",4)
Global("CBoredTalk","GLOBAL",8)
THEN
RESPONSE #100
IncrementGlobal("CBoredTalk","GLOBAL",-1)
END

IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
OR(2)
Global("CNeutralTalk","GLOBAL",4)
Global("CNeutralTalk","GLOBAL",8)
THEN
RESPONSE #100
IncrementGlobal("CNeutralTalk","GLOBAL",-1)
END

IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
Global("CNBoredTalk","GLOBAL",4)
THEN
RESPONSE #100
IncrementGlobal("CNBoredTalk","GLOBAL",-1)
END

IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
Global("CNSexTalk","GLOBAL",2)
THEN
RESPONSE #100
IncrementGlobal("CNSexTalk","GLOBAL",-1)
END

IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
Global("ComitmentTalk","GLOBAL",1)
THEN
RESPONSE #100
IncrementGlobal("ComitmentTalk","GLOBAL",-1)
END

IF
InParty(Myself)
RealGlobalTimerExpired("BackUpTimer","GLOBAL")
Global("KiCoConflictTalk","GLOBAL",1)
THEN
RESPONSE #100
IncrementGlobal("KiCoConflict","GLOBAL",-1)
END

//Move a global up on Bhaal
IF 
InParty(Myself)
RealGlobalTimerExpired("CFlirtyTalkTime","GLOBAL")
Global("CorBhaal","GLOBAL",1)
THEN
RESPONSE #100
IncrementGlobal("CorBhaal","GLOBAL",1)
RealSetGlobalTimer("CFlirtTalkTime","GLOBAL",1800)
END

