// Branwen's Interjections
// Coder: Rastor <rastor@rpgdungeonmods.tk>

ADD_STATE_TRIGGER ~BRANWP~ 0 ~!Global("X#BranwenAlone","GLOBAL",1)~
ADD_STATE_TRIGGER ~BRANWP~ 1 ~!Global("X#BranwenAlone","GLOBAL",1)~
ADD_STATE_TRIGGER ~BRANWP~ 2 ~!Global("X#BranwenAlone","GLOBAL",1)~
ADD_STATE_TRIGGER ~BRANWP~ 3 ~!Global("X#BranwenAlone","GLOBAL",1)~
ADD_STATE_TRIGGER ~BRANWP~ 4 ~!Global("X#BranwenAlone","GLOBAL",1)~
ADD_STATE_TRIGGER ~BRANWP~ 5 ~!Global("X#BranwenAlone","GLOBAL",1)~


ADD_STATE_TRIGGER ~TRANZI~ 1 ~HPGT(Myself,20) !See("branwen")~
ADD_STATE_TRIGGER ~TRANZI~ 2 ~HPGT(Myself,20) !See("branwen")~
ADD_STATE_TRIGGER ~TRANZI~ 3 ~HPGT(Myself,20) !See("branwen")~
ADD_STATE_TRIGGER ~TRANZI~ 4 ~HPGT(Myself,20) !See("branwen")~
ADD_STATE_TRIGGER ~TRANZI~ 5 ~HPGT(Myself,20) !See("branwen")~
ADD_STATE_TRIGGER ~TRANZI~ 6 ~HPGT(Myself,20) !See("branwen")~

APPEND ~TRANZI~ 

IF ~HPGT(Myself,20) See("branwen")~ THEN BEGIN X#TranzigStone2
SAY ~Now ya gonna be stone again!~
IF ~~ THEN DO ~ActionOverride("tranzig",ForceSpell("branwen",WIZARD_FLESH_TO_STONE)~ EXIT
END

END

I_C_T SONNER 4 X#BranwenSonner1
== ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Sea Wolf venerate Umberlee, <CHARNAME>. She rules the waves and sea winds from her flooded layer of the Abyss. She is worshipped out of fear, not adoration. Mariners throw gold and gems into the ocean when caught by the storms in hopes to appease the Bitch Queen. Her followers are as violent as their patron. It will be a good battle, <CHARNAME>, but if you ever plan to sail the seas... I know that you can fight men, but could you fight the tall waves?~
END

I_C_T2 GAZIB 1 X#BranwenOopah
== ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Hahaha! Again, again! *claps*~
END

I_C_T ~TRANZI~ 7 X#BranwenTranzigChicken
== ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are disgusting, wretch... Kill him, <CHARNAME>. One who beggs for his life has no honor. He will betray you to Tazok if you let him go.~
END

INTERJECT_COPY_TRANS ~BGWILLIA~ 10 X#ManyInt6
== ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Our prim and proper <CHARNAME> on a bearskin rug. A thought I will not forget anytime soon.~
== ~BGWILLIA~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Ah, <PRO_HESHE> is still a cutie!~
END

INTERJECT_COPY_TRANS ~ZEKE~ 4 X#BranwenAlive
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~It's good to see SOMEONE is making a profit off of my misfortune. I suppose.~
 == ~ZEKE~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Er... Gotta go!~
END

INTERJECT_COPY_TRANS ~NOOBER~ 11 X#BranwenNoober
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~If only that one were gifted to wield a blade half as well as he wields his tongue, he'd be truly a wondrous creature.~
== ~NOOBER~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~ Aye, I wish that too sometimes. Then I could be an adventurer.~
END

INTERJECT_COPY_TRANS ~MULAHE~ 6 X#BranwenTricked
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Filthy, vermin-ridden pig spawn! Tempus knows your treachery and will grant me the strength to strike you down!~
== ~MULAHE~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Kill them, but leave the big wench to me!~
END

INTERJECT_COPY_TRANS ~ARDROU~ 0 x#BranwenWorgs
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Honestly, cannot you people take care of yourselves? Has the brat not been taught to hold a sword, at least? This display of abject cowardice against mere worgs is pathetic.~
END

INTERJECT_COPY_TRANS ~ARDROU~ 3 X#BranwenWorgs2
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Honestly, cannot you people take care of yourselves? Has the brat not been taught to hold a sword, at least? This display of abject cowardice against mere worgs is pathetic.~
END

INTERJECT_COPY_TRANS ~TIBER~ 2 X#BranwenTiber
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~'Tis a valiant deed these two have attempted, though all for naught 'less we grant them aid. I respect their forthrightness; let us lend them our strength.~
 == ~TIBER~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Please.  What say you m'<PRO_LADYLORD>?~
END

INTERJECT_COPY_TRANS ~MEILUM~ 4 X#BranwenMelium
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This one has confidence in his bearing but his hands do not bear the calluses of a skilled swordsman, and his eyes are dim and lazy. Let us show him what a true warrior is like in battle.~
== ~MEILUM~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Ah, my pretty, I'd rather you show me what you like between the sheets, but if you doubt my skill...~
END

INTERJECT_COPY_TRANS ~NIKLOS~ 8 X#BranwenNiklos
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~I like not the looks of this, <CHARNAME>. This one has a furtive manner and I trust not the suspicious set of his face. He would not be so cautious 'less he had something to hide from Tempus' sight.~
== ~NIKLOS~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~ Dont'ya be standin' there all day! Comme on!~
END

INTERJECT_COPY_TRANS ~NADARI~ 1 X#BranwenBasilisk
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~A basilisk! Stonegazers, slayers with sight... I have known what it is like to be stone, and greatly desire to take vengeance of the memory out of the hide of this creature!~
 == ~NADARI~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~Bored, foolish and have a score t' settle. You qualify. Now, got in there and kill the critter already!~
END

INTERJECT_COPY_TRANS ~PERDUE~ 7 X#BranwenPerdue
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~A miserable, undignified little errand, but so long as it grants us the chance to battle once more....~
 == ~PERDUE~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~Listen ta tha lady.~
END

INTERJECT_COPY_TRANS ~PERDUE~ 8 X#BranwenPerdue2
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~A miserable, undignified little errand, but so long as it grants us the chance to battle once more....~
== ~PERDUE~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN  ~Listen ta tha lady.~
END

INTERJECT_COPY_TRANS ~BASSIL~ 5 X#BranwenBassil
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
  == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~BASSIL~ 6 X#BranwenBassil2
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
  == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~BASSIL~ 10 X#BranwenBassil3
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
  == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~BASSIL~ 11 X#BranwenBassil4
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
  == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~BASSIL~ 12 X#BranwenBassil5
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
  == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~BASSIL~ 13  X#BranwenBassil6
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
 == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~BASSIL~ 14 X#BranwenBassil7
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~This priest is out of his mind. Perhaps a hearty stroke with a hammer will put him back in it again.~
 == ~BASSIL~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~You are mad yourself, sister but you will be cured shortly...~
END

INTERJECT_COPY_TRANS ~ARGHAI~ 0 X#BranwenIron
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Give up all our iron?! I would sooner give up my maidenhead first!~
== ~ARGHAI~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Your iron and your life!~
END

INTERJECT_COPY_TRANS ~MINEC2~ 10 X#BranwenMines
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~I fail to see the need for such an act. Can we not simply slay all who dwell here and oppose us and leave the place a tomb? Pah, we should bring ruin to our enemies with the fair and forthright might of our swordarms! Not by trickery and sabotage. *spits*~
 == ~MINEC2~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Ruuun!~
END

INTERJECT_COPY_TRANS ~COKSMTH~ 3  X#BranwenWyverns
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Infant wyverns? PaTHETic. I'd rather find an enemy more worthy of gutting, but as Tempus wills it.~
== ~COKSMTH~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~*Laughs unkindly* Nobody laughs at my students!~
END

INTERJECT_COPY_TRANS ~COKSMTH~ 5  X#BranwenWyverns2
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Infant wyverns? PaTHETic. I'd rather find an enemy more worthy of gutting, but as Tempus wills it.~
== ~COKSMTH~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~*Laughs unkindly* Nobody laughs at my students!~
END

INTERJECT_COPY_TRANS ~COKSMTH~ 6  X#BranwenWyverns2
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~Infant wyverns? PaTHETic. I'd rather find an enemy more worthy of gutting, but as Tempus wills it.~
== ~COKSMTH~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~*Laughs unkindly* Nobody laughs at my students!~
END

INTERJECT_COPY_TRANS ~NALIN~ 1 X#BranwenBrage
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~A man so cursed with madness as to be berserk? I almost envy him his clarity of vision.~
END

INTERJECT_COPY_TRANS ~THALAN~ 0 X#BranwenThalantyr
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~In truth, that mageling is too rude for my liking. I'm tempted to teach him how to be more mannerly and hospitable. But Tempus forgive me, what is the point in challenging someone so obviously weak?~
END

INTERJECT_COPY_TRANS ~DRIZZT~ 1 X#BranwenDrizzt
 == ~BRANWJ~ IF ~InParty("branwen") !Dead("branwen") !StateCheck("branwen",STATE_SLEEPING)~ THEN ~FINALLY, a warrior with real potential! Though he COULD use a good dose of enthusiasm.~
END

INTERJECT_COPY_TRANS ~BREVLI~ 17  X#BranwenTheft
 == ~BRANWJ~ IF ~!InParty("Xan") !InParty("Montaron") !InParty("Viconia")~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us!~
 == ~BRANWJ~ IF ~InParty("Xan") !InParty("Montaron") !InParty("Viconia")~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Xan.~
 == ~BRANWJ~ IF ~InParty("Montaron") !InParty("Xan") !InParty("Viconia")~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Montaron.~
 == ~BRANWJ~ IF ~InParty("Viconia") !InParty("Xan") !InParty("Montaron")~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Viconia.~
 == ~BRANWJ~ IF ~InParty("Viconia") InParty("Xan") !InParty("Montaron") RandomNum(2,1)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Viconia.~
 == ~BRANWJ~ IF ~InParty("Viconia") InParty("Xan") !InParty("Montaron") RandomNum(2,2)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Xan.~
 == ~BRANWJ~ IF ~InParty("Viconia") !InParty("Xan") InParty("Montaron") RandomNum(2,1)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Viconia.~
 == ~BRANWJ~ IF ~InParty("Viconia") !InParty("Xan") InParty("Montaron") RandomNum(2,2)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Montaron.~
 == ~BRANWJ~ IF ~!InParty("Viconia") InParty("Xan") InParty("Montaron") RandomNum(2,1)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Xan.~
 == ~BRANWJ~ IF ~!InParty("Viconia") InParty("Xan") InParty("Montaron") RandomNum(2,2)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Montaron.~
 == ~BRANWJ~ IF ~InParty("Viconia") InParty("Xan") InParty("Montaron") RandomNum(3,1)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Viconia.~
 == ~BRANWJ~ IF ~InParty("Viconia") InParty("Xan") InParty("Montaron") RandomNum(3,2)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Xan.~
 == ~BRANWJ~ IF ~InParty("Viconia") InParty("Xan") InParty("Montaron") RandomNum(3,3)~ THEN ~Are we to be hired by this foul-smelling, weasely little man to attempt petty theft?! Come now, this is beneath all of us! Even Montaron.~
END

APPEND ~BRANWJ~

IF WEIGHT #-2  ~Global("BranTranzig","GLOBAL",3)~ THEN BEGIN BranQuest2
SAY ~Praise Tempus! The evil magling is dead! The victory is mine!~
IF ~~ THEN DO ~SetGlobal("BranTranzig","GLOBAL",4)~ EXIT
END

IF WEIGHT #-100 ~Global("BranTranzig","GLOBAL",1)~ THEN BEGIN BranQuest1
SAY~<CHARNAME> wait! Wait just a moment! ~
++ ~What? Why? What's wrong?~ DO ~SetGlobal("BranTranzig","GLOBAL",2)~ + BRQU1.1
END

IF ~~ BRQU1.1
SAY ~That robed man over there. The mage…~
= ~By Valkur's blade! It is him! I knew that I would lay eyes upon him again, but I dared not hope it would be so soon!~
++ ~Branwen, what the hell are you babbling on about? See who again so soon? Who is that man? ~ + BRQU1.2
++ ~I hate to see you so upset, Branwen. Tell me, who is that man? ~ + BRQU1.2
+ ~OR(2) CheckStatGT(Player1,10,WIS) CheckStatGT(Player1,10,INT)~ + ~Is that Tranzig, Branwen? The foul mage who turned you into stone?!~ + BRQU1.3
END

IF ~~ BRQU1.2
SAY ~Tranzig! That is who he is! The demon mage who cast his foul magics upon me and left me to rot as some stone curiosity for carnival goers to gawk at!~
= ~Stand aside <CHARNAME>. I want his head crushed beneath my boot before another moment has passed!~
++ ~To battle! Tranzig, defend yourself!~ + BRQU1.4
++ ~I am so going to hand him his own ass back on a silver platter!~ + BRQU1.4
++ ~Branwen! Stop! Do not you do anything foolish! *you take a hold of Branwen's arm*~ + BRQU1.5
END

IF ~~ BRQU1.3
SAY ~Yes! That's him, alright! The demon mage who cast his foul magics upon me and left me to rot as some stone curiosity for carnival goers to gawk at!~
= ~Stand aside <CHARNAME>. I want his head crushed beneath my boot before another moment has passed!~
++ ~To battle! Tranzig, defend yourself!~ + BRQU1.4
++ ~So that's Tranzig? I am so going to hand him his own ass back on a silver platter!~ + BRQU1.4
++ ~Branwen! Stop! Do not you do anything foolish! *you take a hold of Branwen's arm*~ + BRQU1.5
END

IF ~~ BRQU1.5
SAY ~Unhand me <CHARNAME>! You cannot stop me! This is my right! I will not allow this opportunity to pass me by when it has been placed so readily in my path.~
++ ~Branwen! Wait a minute! You can't just storm over there and kill the guy in cold blood!~ + BRQU1.7
++ ~Fine! Go ahead! It *is* your right. Just don't expect me to come bail you out of the Amnish prison!~ + BRQU1.8
++ ~I... I just wanted you to do the right thing. But if *this* is what you want... I won't stand on your way.~ + BRQU1.4
END

IF ~~ BRQU1.6
SAY ~<CHARNAME>! Stop! What are you doing?~
++ ~*Grind your teeth* Helping you to kill this twit, you stupid cow!~ + BRQU1.9
++ ~*Grin* Dancing with the dragons, what else?!~ + BRQU1.9
++ ~I am going to kill this illdoer for turning you to -~ + BRQU1.9
END

IF ~~ BRQU1.7
SAY ~But his spilled blood will not be cold <CHARNAME>! As a matter of fact, I expect that it will fell pleasantly hot as it splashes across my face and stains my armor!~
IF ~~ GOTO BRQU1.4
END

IF ~~ BRQU1.8
SAY ~Let the guards come! I have faced far worse than the bowels of some dreary jail cell!~
IF ~~ GOTO BRQU1.4
END

IF WEIGHT #-2 ~Global("BranInAR9400","LOCALS",1)~ THEN BEGIN BranwenEastTemple
 SAY ~*shivers* There is a foul smell about this place... something cold and rank, and somehow... it seems familiar. Tempus give us the fortitude to find the source.~
 IF ~~ THEN DO ~SetGlobal("BranInAR9400","LOCALS",2)~ EXIT
END

IF WEIGHT #-2 ~Global("BranwenScalp","LOCALS",1)~ THEN BEGIN BranwenScalp
 SAY ~Ah, there's nothing like the smell of fresh blood to bring a tingle to the nose and a smile to the face. Ugh, this one could have stood to have washed his hair once a tenday.~
 IF ~~ THEN DO ~SetGlobal("BranwenScalp","LOCALS",2)~ EXIT
END

IF WEIGHT #-2 ~Global("BranwenIdol","LOCALS",1)~ THEN BEGIN BranwenIdol
 SAY ~At least, a battle worthy of my mettle! COME TO THY DOOM, FIEND! TEMPUS WILL SEE THY BLOOD BOIL!~
 IF ~~ THEN DO ~SetGlobal("BranwenIdol","LOCALS",2)~ EXIT
END

IF ~~ THEN BEGIN GantolBranwen
 SAY ~ Arise, sluggard! If I must slink so low as to be a mere robber, I will not deprive my victims of a chance to retain their wealth fairly! DEFEND THYSELF!~
 IF ~~ THEN EXTERN ~GANTOL~ 2
END

IF WEIGHT #-2 ~Global("BranDurlag","GLOBAL",1)
 Global("x#BranwenSlayDwarfs","LOCALS",0)~ THEN BEGIN BranwenSlayDwarfs
 SAY ~Well, tis about TIME. This is more like it!~
 IF ~~ THEN DO ~SetGlobal("x#BranwenSlayDwarfs","LOCALS",1)~ EXIT
END

IF WEIGHT #-2 ~ Global("BranDurlag","GLOBAL",2)
 Global("x#BranwenDwarfInterject","GLOBAL",1)~ THEN BEGIN BranwenRiddlesDwarfs
 SAY ~Riddles. I HATE riddles. Can't we just slay them all instead?~
 IF ~~ THEN DO ~SetGlobal("x#BranwenDwarfInterject","GLOBAL",2) SetGlobal("BranDurlag","GLOBAL",3)~ EXIT
END

END // of APPEND

ADD_STATE_TRIGGER ~GANTOL~ 5 ~!InParty("Branwen")~

APPEND ~GANTOL~

IF ~NumTimesTalkedTo(1) InParty("Branwen")~ THEN BEGIN GantolBranwen
  SAY ~Zzzzz...wha...wait a minute.  I don't own a cat.  Who's there?~
  ++ ~Your death if you don't keep still and quiet!  I'll take my fill and you will live another day!~ + 2
  ++ ~The jig's up!  Out, we must get out!~ + 3
  ++ ~I'm a stray, go back to sleep.  Shhhhhhhhhh...~ EXTERN ~BRANWJ~ GantolBranwen
END

END

APPEND ~BRANWP~
IF WEIGHT #-2 ~Global("X#BranwenAlone","GLOBAL",1) Dead("tranzig")~ THEN BEGIN X#BranRejoinTranzig
SAY ~The dog is dead? Good.~
IF ~~ THEN DO ~SetGlobal("X#BranwenAlone","GLOBAL",2) JoinParty()~ EXIT
END

END

CHAIN
IF ~~ THEN ~BRANWJ~ BRQU1.9
~The mageling is mine to kill!~
== ~TRANZI~ ~Let <PRO_HIMHER> come! I would know the fool ya travel with before I destroy <PRO_HIMHER>!~
= ~You there! <PRO_BOYGIRL>! Come forward and let me see ya!~
END
++ ~One death is coming right up, Sir!~ DO ~ActionOverride("tranzig",Enemy())~ EXIT
++ ~You heard Branwen. This is between you and her.~ DO ~SetGlobal("X#BranwenAlone","GLOBAL",1) ActionOverride("branwen",LeaveParty()) ActionOverride("branwen",Attack("tranzig")) ActionOverride("tranzig",ForceSpell("branwen",WIZARD_FLESH_TO_STONE)) ActionOverride("tranzig",Enemy())~ EXIT


CHAIN
IF ~~ THEN ~BRANWJ~ BRQU1.4
~Tranzig! Turn around and face me you dog! I will have you look upon the face of the one you betrayed and left imprisoned in that cold stone shell!~
== ~KIVANJ~ IF ~InParty("Kivan")~ THEN ~<CHARNAME> has reversed the vile enchantment that had been placed on this woman, but that does not excuse your foul deed. Own up to your crime, bandit!~
== ~TRANZI~ ~*The mage turns at the sound of Branwen's voice and for a moment you are almost certain that she has made an error. Surely this cannot be the monster that the priestess has described!*~
= ~*Tranzig's is the face you would expect to find on someone's grandfather, or elderly uncle. The skin is covered with lines and wrinkles, brought on by a combination of age and time spent out in the sun and wind of the road.*~
= ~*In spite of his appearance, Tranzig does not move as a man who looks his age might. There is a spring to his step and when his eyes fall upon the woman facing him, the malice gleaming in those bright orbs sends a chill across your skin.*~
= ~My, my, my! And who should my eyes alight upon but the wayward Priestess of Tempus! Branwen! Now, ta see ya again! Tell me, how have ya been?~
== ~BRANWJ~ ~Cease your false pleasantries mage for I am not going to banty words with you! You may try to hide it, but I can tell that you are as surprised to see me as I am to see you!~
= ~Surely you did not expect me to remain trapped within the confines of your spell forever?~
== ~TRANZI~ ~*sigh* No. I figured some bleeding heart would eventually come along to release ya, though I had hoped ya would remain trapped long enough to sustain a few good cracks! Oh well! Ya can't have everything!~
= ~And I can see that you brought along your savior who released you to help you extract your revenge! It is good to know that you realize you cannot fight me on your own! Tell me, is <PRO_HESHE> as susceptible to Petrification spells as you are?~
== ~BRANWJ~ ~Leave <PRO_HIMHER> out of this! I need no help to dispose of you! You will find this fight much tougher than the last for I will not turn my back upon you this time!~
== ~TRANZI~ ~Front, back. It matters not!~
= ~The only thing that does matter is that this time I will finish the job instead of leaving it half done!~
END
++ ~Alright! I've had just about all I can take of this nonsense!~ + BRQU1.6
++ ~Let's kill the bastard!~ DO ~ActionOverride("tranzig",Enemy())~ EXIT
++ ~*Do nothing*~ DO ~SetGlobal("X#BranwenAlone","GLOBAL",1) ActionOverride("branwen",LeaveParty()) ActionOverride("branwen",Attack("tranzig")) ActionOverride("tranzig",ForceSpell("branwen",WIZARD_FLESH_TO_STONE))~ EXIT


