BEGIN X#MARETH

BEGIN X#ANDART
APPEND X#ANDART

IF ~Global("X#AndSurrender","GLOBAL",1)~ THEN BEGIN AndSurrender
SAY ~Please! I… I implore you… have mercy and spare my life… I will leave these lands and never return. I stand defenseless.~
IF ~!Dead("beador")~ THEN DO ~SetGlobal("X#AndSurrender","GLOBAL",2)~ EXTERN JAHEIJ JahAndSur1
IF ~Dead("beador")~ THEN DO ~SetGlobal("X#AndSurrender","GLOBAL",2)~ EXTERN JAHEIJ JahAndSur2
END

IF ~Global("X#JaheiraSen","GLOBAL",25)~ THEN BEGIN ANDFA1
SAY ~Bah! If Amarande can ever agree to ally with one of Seniyad's whores, then he is as disloyal to our beliefs as you are, Faldorn! In Beastlord's name, let us teach these imbeciles a harsh lesson!~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",27) ActionOverride("andarthe",JumpToPoint([874.2175])) ActionOverride("andarthe",FaceObject(Player1)) ActionOverride("andarthe",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("takiyah",Enemy()) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0)~ EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",25)~ THEN BEGIN ANDFA2
SAY ~You stand no chance against a true defender of the Mother Nature, pretentious weakling! In the name of the Beastlord, kill these fools!~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",27) ActionOverride("andarthe",JumpToPoint([874.2175])) ActionOverride("andarthe",FaceObject(Player1)) ActionOverride("andarthe",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("takiyah",Enemy()) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0)~ EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",26)~ THEN BEGIN ANDFA3
SAY ~Bah! If Amarande can ever agree to ally with one of Seniyad's whores, then he is as disloyal to our beliefs as you are, Faldorn! In Beastlord's name, let us teach these imbeciles a harsh lesson!~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",28) ActionOverride("andarthe",JumpToPoint([874.2175])) ActionOverride("andarthe",FaceObject(Player1)) ActionOverride("andarthe",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("takiyah",Enemy()) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0)~ EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",26)~ THEN BEGIN ANDFA4
SAY ~You stand no chance against a true defender of the Mother Nature, pretentious weakling! In the name of the Beastlord, kill these fools!~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",28) ActionOverride("andarthe",JumpToPoint([874.2175])) ActionOverride("andarthe",FaceObject(Player1)) ActionOverride("andarthe",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("takiyah",Enemy()) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0)~ EXIT
END
 
END

CHAIN IF ~Global("X#AndSurrender","GLOBAL",2)~ THEN JAHEIJ JahAndSur1
~Run then, like a cowardly jackal with its tail between the legs! Know that Seniyad sent us and that your return to these woods will mean a swift execution. Filthy bastards like you do not deserve mercy as it is, and definitely not twice!~
END
++ ~Nah, I'm itching to finish him off, Jaheira. Put up your weapons, Andarthe!~ DO ~ChangeEnemyAlly("andarthe",ENEMY) SetGlobal("X#AndSurrender","GLOBAL",3)~ EXIT
++ ~That was the right thing to do, Jaheira. Killing an opponent that surrenders would be wrong.~ DO ~ActionOverride("andarthe",EscapeArea()) SetGlobal("X#AndSurrender","GLOBAL",4)~ EXTERN JAHEIJ JahAndSur4

CHAIN IF ~Global("X#AndSurrender","GLOBAL",2)~ THEN JAHEIJ JahAndSur2
~Mercy? You ask us for mercy? The same kind of mercy your lackeys showed Beador as they tortured and killed him? You are preaching to the wrong crowd, you despicable wretch! Now you die!~
DO ~ActionOverride("jaheira",Kill("andarthe"))~
END
++ ~You did the right thing, Jaheira. Someone taking pleasure in torturing others deserves nothing but death.~ DO~SetGlobal("X#AndSurrender","GLOBAL",5)~ EXTERN JAHEIJ JahAndSur5
++ ~Jaheira… how could you kill an unarmed man begging for mercy? 'Tis just not right!~ DO~SetGlobal("X#AndSurrender","GLOBAL",5)~ EXTERN JAHEIJ JahAndSur6

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",27) !Dead("beador")~ THEN X#MARETH MarethGreeting1
~I… I heard the sounds of battle, outside. And you are obviously not the Shadow Druids… dare I hope that you are my rescuers?~
== ~JAHEIJ~ ~Indeed, we were sent by Seniyad himself. You are free to go.~
== X#MARETH ~Thank you, sister. Have you not seen my friend, nearby… his name is Beador… they took him away and I fear for his life.~
== ~JAHEIJ~ ~We were able to save him, though despite my healing he is still injured. You will find him on the island, where the river forks, east from here.~
== X#MARETH ~Oh, I thank you! I am so relieved! Forgive me, but I must run and see him to be sure! Thank you, once again.~
DO ~EscapeArea() SetGlobal("X#JaheiraSen","GLOBAL",29) AddexperienceParty(2000) ReputationInc(1)~ EXIT

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",28) !Dead("beador")~ THEN X#MARETH MarethGreeting1
~I… I heard the sounds of battle, outside. And you are obviously not the Shadow Druids… dare I hope that you are my rescuers?~
== ~JAHEIJ~ ~Indeed, we were sent by Seniyad himself. You are free to go.~
== X#MARETH ~Thank you, sister. Have you not seen my friend, nearby… his name is Beador… they took him away and I fear for his life.~
== ~JAHEIJ~ ~We were able to save him, though despite my healing he is still injured. You will find him on the island, where the river forks, east from here.~
== X#MARETH ~Oh, I thank you! I am so relieved! Forgive me, but I must run and see him to be sure! Thank you, once again.~
DO ~EscapeArea() SetGlobal("X#JaheiraSen","GLOBAL",29) AddexperienceParty(2000) ReputationInc(1)~ EXIT

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",27) Dead("beador")~ THEN X#MARETH MarethGreeting2
~I… I heard the sounds of battle, outside. And you are obviously not the Shadow Druids… dare I hope that you are my rescuers?~
== ~JAHEIJ~ ~Indeed, we were sent by Seniyad himself. My name is Jaheira and these are... You are free to go.~
== X#MARETH ~Thank you, sister. Have you not seen my friend, nearby… his name is Beador… they took him away and I fear for his life.~
== ~JAHEIJ~ ~I am sorry to be the bearer of bad news, Maretha… we were unable to save him. His body lies on the island, where the river forks, east from here. ~
== X#MARETH ~What… NO! No… *sob*… Beador, no… but I guess it is unsurprising that you let him die, considering what I have heard of him and you... I… I must go and see him… ~
DO ~EscapeArea() SetGlobal("X#JaheiraSen","GLOBAL",29) AddexperienceParty(1000) ReputationInc(-1)~ EXIT

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",28) Dead("beador")~ THEN X#MARETH MarethGreeting2
~I… I heard the sounds of battle, outside. And you are obviously not the Shadow Druids… dare I hope that you are my rescuers?~
== ~JAHEIJ~ ~Indeed, we were sent by Seniyad himself. My name is Jaheira and these are... You are free to go.~
== X#MARETH ~Thank you, sister. Have you not seen my friend, nearby… his name is Beador… they took him away and I fear for his life.~
== ~JAHEIJ~ ~I am sorry to be the bearer of bad news, Maretha… we were unable to save him. His body lies on the island, where the river forks, east from here. ~
== X#MARETH ~What… NO! No… *sob*… Beador, no… but I guess it is unsurprising that you let him die, considering what I have heard of him and you... I… I must go and see him… ~
DO ~EscapeArea() SetGlobal("X#JaheiraSen","GLOBAL",29) AddexperienceParty(1000) ReputationInc(-1)~ EXIT


CHAIN IF ~Global("X#JaheiraSen","GLOBAL",23)~ THEN X#ANDART AndartGreeting
~Who dares to intrude on Shadow Druid territory during the sacred time of the Shadowclave? Whoever you are, fools, I sense that I must thank you. You have brought me another of those false druids to torture and punish accordingly to our sacred rites. She will scream as loudly and delightfully as that idiot Beador, until she recognizes the falseness of her ways! ~
== ~_KHALIJ~ IF ~InParty("Khalid")~ THEN ~D-don't you d-dare threaten her! Hand over your p-prisoners and we m-might be t-tolerant… ~
== ~_JAHEIJ~ ~This will only end in blood, I am afraid. But the blood that will flow will be yours Andarthe, not mine, of that I am certain!~
== ~_FALDOJ~ IF ~InParty("faldorn")~ THEN ~Wait, Andarthe! She and this group are on our side for now! I lead them to destroy the mines, as Amarande, himself, decreed. Once she has seen the wounds the Great Mother had suffered there, she will be more amendable to our cause.~
END
+ ~InParty("faldorn")~ + ~*cough* But as a payment for our participation we request Maretha to go free.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",25)~ + ANDFA1
+ ~InParty("faldorn")~ + ~Drop this nonsense, Faldorn. We are not siding with your bunch of brutes. I came here to free your prisoner and to destroy your cult!~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",25) ~ + ANDFA2
+ ~InParty("faldorn")~ + ~I am so bloody tired of all this. I am just going to kill whoever steps in my way and let Silvanus sort you out.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",25)~ + ANDFA2
IF ~!InParty("faldorn")~ THEN DO ~ActionOverride("andarthe",JumpToPoint([874.2175])) ActionOverride("andarthe",FaceObject(Player1)) ActionOverride("andarthe",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("takiyah",Enemy()) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0) SetGlobal("X#JaheiraSen","GLOBAL",25) ~ EXIT

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",24)~ THEN X#ANDART AndartGreeting
~Who dares to intrude on Shadow Druid territory during the sacred time of the Shadowclave? Whoever you are, fools, I sense that I must thank you. You have brought me another of those false druids to torture and punish accordingly to our sacred rites. She will scream as loudly and delightfully as that idiot Beador, until she recognizes the falseness of her ways! ~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~D-don't you d-dare threaten her! Hand over your p-prisoners and we m-might be t-tolerant… ~
== ~JAHEIJ~ ~This will only end in blood, I am afraid. But the blood that will flow will be yours Andarthe, not mine, of that I am certain!~
== ~FALDOJ~ IF ~InParty("faldorn") ~ THEN ~Wait, Andarthe! She and this group are on our side for now! I lead them to destroy the mines, as Amarande, himself, decreed. Once she has seen the wounds the Great Mother had suffered there, she will be more amendable to our cause.~
END
+ ~InParty("faldorn")~ + ~*cough* But as a payment for our participation we request Maretha to go free.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",26)~ + ANDFA3
+ ~InParty("faldorn")~ + ~Drop this nonsense, Faldorn. We are not siding with your bunch of brutes. I came here to free your prisoner and to destroy your cult!~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",26) ~ + ANDFA4
+ ~InParty("faldorn")~ + ~I am so bloody tired of all this. I am just going to kill whoever steps in my way and let Silvanus sort you out.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",26)~ + ANDFA4
IF ~!InParty("faldorn")~ THEN DO ~ActionOverride("andarthe",JumpToPoint([874.2175])) ActionOverride("andarthe",FaceObject(Player1)) ActionOverride("andarthe",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("takiyah",Enemy()) CreateCreature("WOLFDR",[-1.-1],0) CreateCreature("WOLFDR",[-1.-1],0) SetGlobal("X#JaheiraSen","GLOBAL",26) ~ EXIT

BEGIN X#SHDRG
APPEND X#SHDRG

IF ~Global("X#JaheiraSen","GLOBAL",15)~ FaShD1
SAY ~Then you all will die; Interlopers and our own false sister!~
IF ~~ THEN DO ~ActionOverride("jadruid6a",Enemy()) ActionOverride("jadruid6b",Enemy()) ActionOverride("jadruid6",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("jadruid8b",Enemy()) ActionOverride("jadruid8b",Attack("beador"))~
EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",15)~ FaShD2
SAY ~This naďve newcomer would agree to anything less than death for these false druids? We shall dispose of you and your newfound friends, weakling… and deal with the miners, afterwards!~
IF ~~ THEN DO ~ActionOverride("jadruid6a",Enemy()) ActionOverride("jadruid6b",Enemy()) ActionOverride("jadruid6",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("jadruid8b",Enemy()) ActionOverride("jadruid8b",Attack("beador"))~ EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",15)~ FaShD3
SAY ~Welcome back to the fold, Faldorn. Now let us kill the intruders!~
IF ~~ THEN DO ~ActionOverride("faldorn",LeaveParty()) ActionOverride("faldorn",Enemy()) ActionOverride("jadruid6a",Enemy()) ActionOverride("jadruid6b",Enemy()) ActionOverride("jadruid6",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("jadruid8b",Enemy()) ActionOverride("jadruid8b",Attack("beador"))~ EXIT
END

END

BEGIN X#BEADOR
APPEND X#BEADOR

IF ~Global("X#JaheiraSen","GLOBAL",11)~  THEN BEGIN BeadorStart
SAY ~Strangers… get away from here… to the Tree House. Maretha… rescue her… don't bother with me…~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",12)~ EXTERN JAHEIJ JaBeChain1
END

IF ~Global("X#JaheiraSen","GLOBAL",13)~  THEN BEGIN BeadorStart
SAY ~Strangers… get away from here… to the Tree House. Maretha… rescue her… don't bother with me…~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",14)~ EXTERN JAHEIJ JaBeChain2
END

IF ~ GlobalGT("X#JaheiraSen","GLOBAL",19) GlobalLT("X#JaheiraSen","GLOBAL",28)~  THEN BEGIN BeadorAsksMaretha
SAY ~Please, help Maretha! She is in danger...~
IF ~~ THEN EXIT
END

IF ~GlobalGT("X#JaheiraSen","GLOBAL",27)~ THEN BEGIN BeadorLeaves
SAY ~I am so glad Maretha is safe now. I have stayed here on the off chance that I can say you in person how grateful I am for your assistance.~
IF ~~ THEN DO ~AddexperienceParty(100) EscapeArea()~ EXIT
END

END

APPEND JAHEIJ

IF ~Global("X#AndSurrender","GLOBAL",6)~ THEN BEGIN JahAndSur3
SAY ~Well, perhaps you prevented me from making a mistake, <CHARNAME>. In either case, it is not worth pondering upon. Let us free Maretha while we have the chance.~
IF ~~ THEN DO ~SetGlobal("X#AndSurrender","GLOBAL",7) ReputationInc(-4)~ EXIT END

IF ~Global("X#AndSurrender","GLOBAL",4)~ THEN BEGIN JahAndSur4
SAY ~I suppose so, <CHARNAME>. But for now, it only means that we should be careful on our path as we proceed deeper into the Cloakwood. And let us free Maretha while we have the chance.~
IF ~~ THEN DO ~SetGlobal("X#AndSurrender","GLOBAL",7)~ EXIT 
END

IF ~Global("X#AndSurrender","GLOBAL",5)~ THEN BEGIN JahAndSur5
SAY ~I know that you are right, <CHARNAME>. Still, striking down a defenseless man is not something I  enjoy, despite how evil he might be. Now, let us free Maretha while we have the chance.~
IF ~~ THEN DO ~SetGlobal("X#AndSurrender","GLOBAL",7) ReputationInc(-2)~ EXIT END

IF ~Global("X#AndSurrender","GLOBAL",5)~ THEN BEGIN JahAndSur6
SAY ~I wonder what you will choose if that beast that killed your father was begging mercy from you! Ponder your answer carefully before you presume to judge my actions. Now, let us free Maretha while we have the chance.~
IF ~~ THEN DO ~SetGlobal("X#AndSurrender","GLOBAL",7) ReputationInc(-1)~ EXIT END

IF ~Global("X#JaheiraSen","GLOBAL",16)~ THEN BEGIN JahHealsBeador
SAY ~Beador, you… you fool! How could you be so reckless! Lie down and allow yourself to be healed!~
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",17)~ EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",22)~ THEN BEGIN JABD1.1
SAY ~It is not the memories of the past that weigh heavy on my heart. I am thinking of Maretha, having to lose him… no! No, enough of this foolishness.~
= ~Let us move onwards. We will return Beador's remains to the Great Mother later. Meanwhile, I thank you for your support once again. ~
IF ~~ THEN EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",22)~ THEN BEGIN JABD1.2
SAY ~What? Oh, of course… lead on, <CHARNAME>. You will have to indulge my somber mood for a while, so it appears. ~
IF ~~ THEN EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",30)~ THEN BEGIN JaheiraReward
SAY ~<CHARNAME>, I know you are anxious to proceed to the mines as soon as possible, and I feel the same. Still, perhaps you would consider making a little detour to bring the good news back to Seniyad? ~
++ ~Sure, let's head back. A day here or there should not matter.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",31)~ + JARE1.1
++ ~Nah, we'll drop by as we return from the mines, Jaheira. Let him wait a few days or until Maretha informs him.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",31)~ + JARE1.2
END

IF ~~ JARE1.1
SAY ~Thank you. You know, I usually would not make such requests, but this matter is important to me as a druid. I am glad you are willing to acknowledge that.~
IF ~~ THEN EXIT END

IF ~~ JARE1.2
SAY ~Very well, that is acceptable as well. Hmm, did I mention that Seniyad might have a reward for us?~
++ ~Do not bother, Jaheira. It won't work.~ + JARE1.3
++ ~Hmm, a reward you say? Alright, you've convinced me, let us head back.~ + JARE1.4
END

IF ~~ JARE1.3
SAY ~Ah, well, I thought I would try regardless. Let us move on, then.~
IF ~~ THEN EXIT END

END

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",31)~ THEN JAHEIJ JARE1.4
~I thought you would see reason, <CHARNAME>. *grin* Young and enthusiastic adventurers, nothing excites them as a reward for their task.~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~It brings back some fond memories, d-doesn't it, d-dear? ~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~ Of course, I was never as easy to distract as our young charge, here. I was always steadfast and dependable, as you well know, my dear Khalid.~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~Oh, of c-course. *snicker* You have always been a p-paragon of seriousness… except m-maybe last night…~
END
++ ~Oh, for heaven's sake! Get yourselves a room, will you?~ EXIT
++ ~Err… let's just get going, shall we?~ EXIT

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",21)~ THEN JAHEIJ JahBeadorDead
~No! By Silvanus… no! We have failed, damn it! Beador… Beador, you stupid fool…~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~I am truly sorry, my d-dear… we all d-did our best, but it was not enough. I feel very sorry for him. ~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~I know you did all that was in your powers, my love. It is just that… ~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~I know, d-dearest. Say n-no more… I understand. Your compassionate heart c-cannot remain unaffected. ~
== ~JAHEIJ~ ~Sad as this might be, we still must rescue Maretha. Beador… he spoke of a Tree House. We should try and locate it. ~
END
++ ~I am sorry for our inability to save him, Jaheira. I understand that you have lost more than just "an old friend" here… my condolences. ~ DO~SetGlobal("X#JaheiraSen","GLOBAL",22)~  + JABD1.1
++ ~He spoke of a Tree House. Should we not get moving, Jaheira? ~ DO~SetGlobal("X#JaheiraSen","GLOBAL",22)~ + JABD1.2

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",19)~ THEN X#BEADOR OldFlame1
~Jaheira? *cough* Jaheira, is that you? I thought I would never see your face again, after… after you left… *cough*~
== ~JAHEIJ~ ~I thought I told you to lie down, foolish man! And preserve your strength; do not speak… especially not of the past.~
== X#BEADOR ~You… you have not changed at all over these years, Jaheira. How you've been doing all this time?~
END
IF ~InParty("Khalid") !Dead("Khalid")~ THEN EXTERN KHALIJ KhalidBeadorChain
IF ~OR(2) !InParty("Khalid") Dead("Khalid")~ THEN EXTERN JAHEIJ JaheiraBeadorNoKhalidChain

CHAIN KHALIJ KhalidBeadorChain
~H-hello, Beador. It is g-good to see you again.~
== X#BEADOR IF ~InParty("Khalid")~ THEN ~Ah… and my greetings to you, Khalid, as well. *cough* It appears that my question has been answered, then.~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~Enough of this nonsense, Beador. We were sent by Seniyad to look for you and this woman, Maretha, and that is what we will attempt to do.~
== X#BEADOR IF ~InParty("Khalid")~ THEN ~By, Silvanus, praise you and Seniyad both! Please, Jaheira, you must free her… there is a bridge over the river nearby, cross it and go back south... find the Tree House. She was… *cough*… just taken there, to be tortured by Andarthe, one of the Shadow Archdruids. Please, hurry!~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~We will try our best, Beador. You stay here and try not to move around too much. Come <CHARNAME>, let us teach these heretics a few harsh lessons! ~
END
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",20) AddexperienceParty(500)~ EXIT

CHAIN  JAHEIJ JaheiraBeadorNoKhalidChain
~I have been doing… quite well, thank you for asking.~
== X#BEADOR ~Jaheira? What about this moistness in your eyes and the tremble in your voice? And why do I not see Khal- ~
== ~JAHEIJ~ ~Enough!! Enough… I will not speak of this! We were sent by Seniyad to look for you and this woman, Maretha, and that is our sole purpose for being here, Beador.~
== X#BEADOR ~As you wish, Jaheira. There is a bridge over the river nearby, cross it and go back south... find the Tree House. She was… *cough*… just taken there, to be tortured by Andarthe, one of the Shadow Archdruids. Please, hurry!~
== ~JAHEIJ~ ~We will try our best, Beador. You stay here and try not to move around too much. Come <CHARNAME>, let us teach these heretics a few harsh lessons!~
END
IF ~~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",20) AddexperienceParty(500)~ EXIT


CHAIN IF ~Global("X#JaheiraSen","GLOBAL",12)~ THEN JAHEIJ JaBeChain1
~Even when dying he is so foolishly noble! Onwards, <CHARNAME>, we cannot allow these Shadow Filth to kill him! ~
== X#SHDRG ~You dare intrude in our sacred rituals, outsider? And you have dragged one of those false druids with you? For that you shall die, interloper! ~
DO ~SetGlobal("X#JaheiraSen","GLOBAL",15) ActionOverride("jadruid6a",Enemy()) ActionOverride("jadruid6b",Enemy()) ActionOverride("jadruid6",Enemy()) ActionOverride("jadruid8a",Enemy()) ActionOverride("jadruid8b",Enemy()) ActionOverride("jadruid8b",Attack("beador"))~
EXIT

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",14)~ THEN JAHEIJ JaBeChain2
~Even when dying he is so foolishly noble! Onwards, <CHARNAME>, we cannot allow these Shadow Filth to kill him! ~
== X#SHDRG ~You dare intrude in our sacred rituals, outsider? And you have dragged one of those false druids with you?~
== ~FALDOJ~ ~Not all of us are traitorous weaklings! <CHARNAME>! You have promised to help me, not wipe away my brethren!~
END
++ ~Umm… that's a tough one. I would prefer to avoid bloodshed if I could. How about I promise to destroy the mines east of here in exchange for the return of Beador and Maretha? Do we have a deal?~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",15)~ EXTERN FALDOJ FaJaQuest1.1
+~CheckStatGT(Player1,15,CHR)~ + ~Faldorn! The true enemy is not these pathetic weaklings who dare to call themselves druids! Look, they waste their time hunting the weak and useless, instead of going for the true offenders - the MINERS! They have betrayed the Great Mother! Let's kill them for that!~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",15)~ EXTERN FALDOJ FaJaQuest1.2
+~!CheckStatGT(Player1,15,CHR)~ + ~Faldorn! The true enemy is not these pathetic weaklings who dare to call themselves druids! Look, they waste their time hunting the weak and useless, instead of going for the true offenders - the MINERS! They have betrayed the Great Mother! Let's kill them for that!~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",15)~ EXTERN FALDOJ FaJaQuest1.2A
++ ~Your 'brethren' are too evil for my taste. If you want to side with them, you are going to die by my sword as well! Chose now!~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",15)~ EXTERN FALDOJ FaJaQuest1.3
++ ~Faldorn, I am choosing the lives of two innocents over some stupid ideals you serve. Fight me for that, if you wish.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",15)~ EXTERN FALDOJ FaJaQuest1.3

CHAIN _FALDOJ FaJaQuest1.1
~Grrr! I hate deals! But the need to destroy the mines is more pressing than killing off some imbeciles. Listen, this <PRO_MANWOMAN>'s offer is worth considering.~
END  X#SHDRG FaShD2


CHAIN FALDOJ FaJaQuest1.2
~GRRR! You speak truth! Return to the Great Mother, you, traitors!~
END  X#SHDRG FaShD1

CHAIN FALDOJ FaJaQuest1.2A
~You are trying to trick me! You die for that!~
END  X#SHDRG FaShD3

CHAIN FALDOJ FaJaQuest1.3
~Then I shall fight you, you worthless weakling! For the Great Mother! ~
END  X#SHDRG FaShD3

ADD_TRANS_TRIGGER ~SENIYA~ 1 ~OR(2)!InParty("Jaheira") Dead("Jaheira")~
ADD_TRANS_TRIGGER ~SENIYA~ 2 ~OR(2)!InParty("Jaheira") Dead("Jaheira")~
ADD_TRANS_TRIGGER ~SENIYA~ 6 ~OR(2)!InParty("Jaheira") Dead("Jaheira")~

EXTEND_BOTTOM  ~SENIYA~ 1
IF ~InParty("Jaheira") !Dead("Jaheira)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",2) EndCutSceneMode()~ EXTERN JAHEIJ JaheiraMakePeace
END

EXTEND_BOTTOM  ~SENIYA~ 2
IF ~InParty("Jaheira") !Dead("Jaheira)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",1)~ EXTERN JAHEIJ JaheiraAldethDead
END

EXTEND_BOTTOM  ~SENIYA~ 6
IF ~InParty("Jaheira") !Dead("Jaheira)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",1)~ EXTERN JAHEIJ JaheiraAldethDead
END

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",1)~ THEN JAHEIJ JaheiraAldethDead
~Somehow, this did not feel like the right decision, <CHARNAME>. The man, while obviously a foppish fool, did not deserve such harsh punishment for his offences. ~
== ~SENIYA~ ~Bah! Do not let the cunning lies of civilization's worst products sway your mind, young dru-… Jaheira? Is that you, young one? I should have recognized you immediately!~
== ~JAHEIJ~ ~It is indeed I, Jaheira. It saddens me to see that you still cling to your aggressive approach when dealing with those that are less caring with nature's bounty. Despicable as these men may be, you do not seem to consider how much your attitude costs us by denting the respect the city dwellers might feel for our course.~
== ~SENIYA~ ~It appears that constant exposure to civilization has softened you even more than before your leave of the circle. Or, perhaps the recent troubles have affected me in the ways I can't see and I have grown more ruthless than  I realize? Perhaps… this is something to reflect upon.~
== ~JAHEIJ~ ~Recent troubles? What do you mean by that, Seniyad?~
DO ~SetGlobal("X#JaheiraSen","GLOBAL",3)~
END ~SENIYA~ SeniyadQuest

CHAIN IF ~Global("X#JaheiraSen","GLOBAL",2)~ THEN JAHEIJ JaheiraMakePeace
~Wait, Seniyad! Do you not recognize me? It is I, Jaheira! Surely you will not attack one of your own? ~
== ~SENIYA~ ~Jaheira? It is indeed you, young one! It has been long time since we last met… but your willingness to protect this filthy hunter saddens the occasion of our meeting.~
== ~JAHEIJ~ ~While I consider hunting for sport as something to be frowned upon, I would never consent to the views that look upon it as an offence punishable by death, Seniyad.~
== ~SENIYA~ ~Ah, yes. The source of our constant disagreement, wasn't it? I had hoped that your constant exposure to civilization would make you reconsider your views; alas it appears that has not happened. Still, I might be persuaded to leave yon hunter friend with his life… on one condition.~
== ~JAHEIJ~ ~Speak, Seniyad and I…  <CHARNAME> and I will listen.~
DO ~SetGlobal("X#JaheiraSen","GLOBAL",4)~
END ~SENIYA~ SeniyadQuest

CHAIN IF ~OR(2) Global("X#JaheiraSen","GLOBAL",3) Global("X#JaheiraSen","GLOBAL",4)~ THEN SENIYA SeniyadQuest
~A sect of Shadow Druids has taken over a part of our sacred forest as their territory and we have so far failed to reclaim it. No doubt the mere presence of them would worry any druid committed to our true beliefs.~
== ~JAHEIJ~ ~This does concern me greatly, Seniyad. I would be willing to aid you… if <CHARNAME> would agree to a distraction from our own quest.~
== ~SENIYA~ ~There is one thing that you could help us with, Jaheira, as we require the assistance of someone that is less known to the Shadow Druids than my loyal followers. A few months ago a Shadow Druid approached a young druidess from our circle by the name of Maretha giving her an invitation to join their circle. This was a part of my plan to infiltrate their accursed circle, and it seemed to work for a few months... until two tendays ago. Maretha has not shown up at her secret meeting place with one of our druids. We have not seen or heard from her since, Jaheira.~
== ~JAHEIJ~ ~And I assume that you want us to rescue her… if she is still alive.~
== ~SENIYA~ ~That is what I want you and your group to accomplish. Maretha possesses important information about the plans of the Shadow Druids and probably knows the names of the Shadow Druids who have infiltrated our own order. She must be rescued, and soon, for the time of Shadowclave draws near.~
== ~JAHEIJ~ ~I see. Then we do not have much time, I agree. <CHARNAME>, you will help us in this undertaking, of course?~
END
++ ~What is this Shadowclave you speak of, druid?~ EXTERN ~JAHEIJ~ JAQU1.1
++ ~I suppose so, if it saves me from hearing more of this tree hugger chatter.~ EXTERN ~JAHEIJ~ JAQU1.2
++ ~Forget it, Jaheira. Fall back in line; we have  more important things to attend to.~ EXTERN ~JAHEIJ~ JAQU1.3
+ ~Class(Player1, DRUID_ALL)~ + ~Then we must hurry to aid the girl as soon as possible. Those fanatics may be torturing her as we speak! A true servant of Nature and balance will always aid one of their own, 'tis a rule I've  sworn to follow as a druid!~ EXTERN ~JAHEIJ~ JAQU1.4
+ ~Class(Player1, DRUID_ALL)~ + ~I follow the Shadow Druid's doctrine myself. I will not oppose their plans.~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",9)~ EXTERN ~SENIYA~ PCShadowDruid

CHAIN _JAHEIJ JAQU1.1
~Shadowclave is the secret celebration of the Shadow Druid sect, during which many druidic ceremonies take place. Initiation of new members is also rumored to happen during this celebration. But what concerns Seniyad and I most, is the public torture and execution of traitors and enemies of the Shadow Druids. If we do not make it in time, unfortunate Maretha will die a horrible death. ~
== ~SENIYA~ ~That is not all, Jaheira. A few days ago, one of my druids chose to risk his life trying to sneak into the Shadow Druid territories and rescue the woman he was enamored with. We have not heard of him since. You would remember him, Jaheira… it was Beador.~
== ~JAHEIJ~ ~Beador… yes… yes, I remember him. And I see he is still the hotheaded fool he once was… ~
DO ~SetGlobal("X#SenBeador","GLOBAL",1)~
END
++ ~Who is this Beador, Jaheira?~ + JAQU2.1
++ ~Well, looks like another reason for us to hurry! Lead on, Jaheira!~ + JAQU2.2
++ ~A pity. Unfortunately, we will have to opt out of helping, as our own quest takes precedence.~ + JAQU1.3

CHAIN JAHEIJ JAQU1.2
~ Tree hugger chatter, is it? Hmpf! I would have thought that Gorion would have raised you with more reverence for the world you live in; alas, it appears that it will be up to me make you realize that. However, your sentiment to aid me, as reluctant as it seems, is still appreciated.~
== ~SENIYA~ ~That is not all, Jaheira. A few days ago, one of my druids chose to risk his life trying to sneak into the Shadow Druid territories and rescue the woman he was enamored with. We have not heard of him since. You would remember him, Jaheira… it was Beador.~
== ~JAHEIJ~ ~Beador… yes… yes, I remember him. And I see he is still the hotheaded fool he once was… ~
DO ~SetGlobal("X#SenBeador","GLOBAL",1)~
END
++ ~Who is this Beador, Jaheira?~ + JAQU2.1
++ ~Well, looks like another reason for us to hurry! Lead on, Jaheira!~ + JAQU2.2
++ ~A pity. Unfortunately, we will have to opt out of helping, as our own quest takes precedence.~ + JAQU1.3


CHAIN JAHEIJ JAQU1.4
~I am glad to see you so determined to help a fellow druid, <CHARNAME>. You have the makings of a fine servant of the Great Mother. By Silvanus I swear I will help you to realize your true potential!~
== ~SENIYA~ ~That is not all, Jaheira. A few days ago, one of my druids chose to risk his life trying to sneak into the Shadow Druid territories and rescue the woman he was enamored with. We have not heard of him since. You would remember him, Jaheira… it was Beador.~
== ~JAHEIJ~ ~Beador… yes… yes, I remember him. And I see he is still the hotheaded fool he once was… ~
DO ~SetGlobal("X#SenBeador","GLOBAL",1)~
END
++ ~Who is this Beador, Jaheira?~ + JAQU2.1
++ ~Well, looks like another reason for us to hurry! Lead on, Jaheira!~ + JAQU2.2
++ ~A pity. Unfortunately, we will have to opt out of helping, as our own quest takes precedence.~ + JAQU1.3

CHAIN _JAHEIJ JAQU2.1
~He was a… an old friend of mine. That is all you need to know, <CHARNAME>.~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~I'll advise you n-not to pry any f-further, <CHARNAME>… f-for your own sake. ~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~You are a wise man, Khalid, my love… and this wisdom has served you well. Now, <CHARNAME>, we should start moving into the depths of Cloakwood, if we are to save my friends.~
END
++ ~Very well, Jaheira, let us help your fellow druids.~ + JAQU2.2
++ ~Hold your horses, Jaheira. We have better things to do than this; the mines await us.~ + JAQU1.3

CHAIN JAHEIJ JAQU2.2
~Thank you, <CHARNAME>. I knew I could count on your assistance.~
== ~SENIYA~ ~You have made a wise decision. Good luck to you!~
== ~SENIYA~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~And you… get out of my sight, defiler of nature. Be glad that Jaheira's word is valued so highly, lest I would insist on your foul presence until the deed is carried out.~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~Y-yes, thank you for your assistance, strangers… If you ever travel to Baldur's Gate, come to the Merchants' League and I will aid you in any way I can. Take now this small token of my appreciation.~
END
IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",5) SetGlobal("AldethMove","GLOBAL",1) AddexperienceParty(1000) GiveItemCreate("POTN09",Player1,1,0,0) ActionOverride("aldeth",EscapeArea())~ EXIT
IF ~Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",8) AddexperienceParty(500)~ EXIT

CHAIN JAHEIJ JAQU1.3
~Have I misheard? <CHARNAME>, it is in the same direction we intend to travel, this would be only a slight distraction! Are you truly so self-absorbed that you would spit on the hand that heals and feeds you? ~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~Would you raise my hopes of rescue, only to hand me back over to these uncouth savages? You are despicable beyond description and I warn you, betray me and I will make sure that you won't survive this encounter! ~
END
++ ~Err… I don't know what came over me, there. Of course I misspoke, Jaheira. Let us… help your friends with all haste.~ EXTERN JAHEIJ JAQU4.1
++ ~Ah, shut up, you nagging forest wench. We do as I say, and for now my words are - return to your place in formation and keep quiet.~ EXTERN JAHEIJ JAQU4.2
++ ~Jaheira, I understand your concern, but we cannot afford any distractions now. We could return and help your friends later. ~ EXTERN JAHEIJ JAQU4.3

CHAIN ~JAHEIJ~ JAQU4.1
~Hmph. Very well, <CHARNAME>, let us march on, then. And make sure that you do not misspeak too often, or I would be forced to take the reigns in whatever conversations we might engage in.~
== ~SENIYA~ ~I am glad that you have reconsidered. Good luck to you!~
== ~SENIYA~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~And you… get out of my sight, defiler of nature. Be glad that Jaheira's word is valued so highly, lest I would insist on your foul presence until the deed is carried out.~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~That is exactly what I will do, you uncouth brute. Next year I am going to the Wood of Sharp Teeth instead of Cloakwood. I am sure it could not be worse than this trip!~
END
IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",5) SetGlobal("AldethMove","GLOBAL",1) AddexperienceParty(500) ActionOverride("aldeth",EscapeArea())~ EXIT
IF ~Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",8) AddexperienceParty(500)~ EXIT


CHAIN JAHEIJ JAQU4.2
~You bastard! I could have done without this slap in my face for all my efforts in aiding you! Very well, better to find out your true colors sooner than later! If that is how you wish, my aid will go my TRUE friends.~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~Come, Khalid! We have a mission to undertake, and spending more in time in presence of this ingrate simply sickens me. ~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~Yes, let us leave, my d-darling. Farewell, <CHARNAME>! I hope you will c-come to realize the folly of your actions, though it will be hard to earn Jaheira's trust, and m-mine, again.~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~I warned you, traitor! Now you will be punished! For Baldur's Gate!~
== ~SENIYA~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~So, not only you would ally with a filthy hunter, you would also betray those of my kin as well as those you called friend. You are a miserable abomination of humankind and your extermination takes precedence over punishing a mere hunter! For the balance!~
END
IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",6) ActionOverride("Jaheira",LeaveParty()) ActionOverride("Jaheira",EscapeArea()) ActionOverride("Khalid",LeaveParty()) ActionOverride("Khalid",EscapeArea()) ActionOverride("seniyad",Shout(1)) ActionOverride("seniyad",Enemy())~ EXIT
IF ~Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",7) ActionOverride("Jaheira",LeaveParty()) ActionOverride("Jaheira",EscapeArea()) ActionOverride("Khalid",LeaveParty()) ActionOverride("Khalid",EscapeArea())~ EXTERN ~SENIYA~ SenAllLeave

CHAIN JAHEIJ JAQU4.3
~<CHARNAME>, I MUST insist. You do not seem to understand the situation. The Shadow Druids would oppose our passing through their territories as we make our way to the mines… we would have to confront them regardless if you agree to help me or not, it coincides with our plans. I warn you: if you refuse, I will have to deal with the situation on my own and our ways will part here. ~
END
++ ~Then I suppose I have no choice but to agree. Very well, we shall help your druid friends. ~ + JAQU5.1
++ ~Then let us part! I am so sick of you bullying me!~ + JAQU4.2
++ ~I guess it means we say our farewells here then, as I have no willingness to help you or these druids. ~ + JAQU5.2

CHAIN JAHEIJ JAQU5.1
~Your reluctance is most displeasing, <CHARNAME>. Still, I admit to being thankful that you reconsidered. Let us depart then. ~
== ~SENIYA~ ~You have made a wise decision. Good luck to you!~
== ~SENIYA~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~And you… get out of my sight, defiler of nature. Be glad that Jaheira's word is valued so highly, lest I would insist on your foul presence until the deed is carried out.~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~That is exactly what I will do, you uncouth brute. Next year I am going to the Wood of Sharp Teeth instead of Cloakwood. I am sure it could not be worse than this trip!~
END
IF ~Global("X#SenBeador","GLOBAL",1) Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",5) SetGlobal("AldethMove","GLOBAL",1) AddexperienceParty(500) ActionOverride("aldeth",EscapeArea())~ EXIT
IF ~Global("X#SenBeador","GLOBAL",1) Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",8) AddexperienceParty(500)~ EXIT
IF ~!Global("X#SenBeador","GLOBAL",1)~ EXTERN ~SENIYA~ SenBeador1

CHAIN JAHEIJ JAQU5.2
~Then I will take my leave from you. Your lack of concern for nature, and this unwillingness to help your friends, make my decision all the easier. Goodbye, <CHARNAME>. ~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~Come, Khalid! We have other things to do and places to be. We are obviously not wanted here.~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~Yes, let us leave, my d-darling. Farewell, <CHARNAME>! *sigh* I r-really wished this would have t-turned out b-better.~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~I warned you, traitor! Now you will be punished! For Baldur's Gate!~
== ~SENIYA~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~So, not only you would ally with a filthy hunter, you would also betray those of my kin as well as those you called friend. You are a miserable abomination of humankind and your extermination takes precedence over punishing a mere hunter! For the balance!~
END
IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",6) ActionOverride("Jaheira",LeaveParty()) ActionOverride("Jaheira",EscapeArea()) ActionOverride("Khalid",LeaveParty()) ActionOverride("Khalid",EscapeArea()) ActionOverride("seniyad",Shout(1)) ActionOverride("seniyad",Enemy())~ EXIT
IF ~Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#JaheiraSen","GLOBAL",7) ActionOverride("Jaheira",LeaveParty()) ActionOverride("Jaheira",EscapeArea()) ActionOverride("Khalid",LeaveParty()) ActionOverride("Khalid",EscapeArea())~ EXTERN ~SENIYA~ SenAllLeave


CHAIN IF ~!Global("X#SenBeador","GLOBAL",1)~ THEN _SENIYA SenBeador1
~Wait! That is not all, Jaheira. A few days ago, one of my druids chose to risk his life, trying to sneak into the Shadow Druid territories and rescue the woman he was enamored with. We have not heard of him since. You would remember him, Jaheira… it was Beador.~
== ~JAHEIJ~ ~Beador… yes… yes, I remember him. And I see he is still the hotheaded fool he once was… ~
END
++ ~Who is this Beador, Jaheira?~ EXTERN ~JAHEIJ~ JAQU6.1
++ ~I thought you were in hurry, Jaheira? Cut the chatter and let us go! ~ EXTERN ~JAHEIJ~ JAQU6.2

CHAIN JAHEIJ JAQU6.1
~He was a… an old friend of mine. That is all you need to know, <CHARNAME>.~
== ~KHALIJ~ IF ~InParty("Khalid")~ THEN ~I'll advise you n-not to pry any f-further, <CHARNAME>… f-for your own sake. ~
== ~JAHEIJ~ IF ~InParty("Khalid")~ THEN ~You are a wise man, Khalid, my love… and this wisdom has served you well. Now, <CHARNAME>, we should start moving into the depths of Cloakwood, if we are to save my friends.~
END
IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",5) SetGlobal("AldethMove","GLOBAL",1) GiveItemCreate("POTN09",Player1,1,0,0) AddexperienceParty(500) ActionOverride("aldeth",EscapeArea())~ EXIT
IF ~Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",8) AddexperienceParty(500)~ EXIT

CHAIN JAHEIJ JAQU6.2
~Hmph. Very well, <CHARNAME>, let us march on, then. I will have you know that I am dissatisfied with your attitude, but I hope that being confronted with the Shadow Druids will make you realize that you have made the right choice. ~
== ~SENIYA~ ~I am glad that you have reconsidered. Good luck to you!~
== ~SENIYA~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~And you… get out of my sight, defiler of nature. Be glad that Jaheira's word is valued so highly, lest I would insist on your foul presence until the deed is carried out.~
== ~ALDETH~ IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN ~Y-yes, thank you for your assistance, strangers… If you ever travel to Baldur's Gate, come to the Merchants' League and I will aid you in any way I can. Take now this small token of my appreciation.~
END
IF ~Global("X#JaheiraSen","GLOBAL",4)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",5) SetGlobal("AldethMove","GLOBAL",1) AddexperienceParty(500) ActionOverride("aldeth",EscapeArea())~ EXIT
IF ~Global("X#JaheiraSen","GLOBAL",3)~ THEN DO ~SetGlobal("X#SenBeador","GLOBAL",1) SetGlobal("X#JaheiraSen","GLOBAL",8) AddexperienceParty(500)~ EXIT


APPEND ~SENIYA~

IF ~Global("X#JaheiraSen","GLOBAL",9)~ PCShadowDruid
SAY ~Jaheira, I am dissappointed in you! For siding with the criminals you shall die yourself!~
IF ~~ THEN DO ~Shout(1) Enemy() SetGlobal("X#JaheiraSen","GLOBAL",10)  AddexperienceParty(5000) SetGlobal("KilledDruids","GLOBAL",4) SetGlobal("HelpAldeth","GLOBAL",1)~ EXIT
END

IF ~Global("X#JaheiraSen","GLOBAL",7)~ SenAllLeave
SAY ~You showed some reason by aiding us in killing this filthy hunter, but your lack of concern for our course and your reluctance to aid your own friends appalls me. Leave this wood now, I have lost my patience with you!~
IF ~~ THEN DO ~EscapeArea() AddexperienceParty(2000)~ EXIT
END

IF ~OR(2) Global("X#JaheiraSen","GLOBAL",5) Global("X#JaheiraSen","GLOBAL",8)~ SenQuestPrompt
SAY ~I urge you to look for Beador and Maretha if you are friends to the Druids of Cloakwood.~
IF ~~ THEN EXIT
END

IF ~GlobalGT("X#JaheiraSen","GLOBAL",27) GlobalLT("X#JaheiraSen","GLOBAL",35)~ SeniyadReward
SAY ~Ah, there you are! I hear that you have administered a fitting punishment for those vile mockers of our true beliefs. Maretha told me everything as well as the names of two high-standing members in our own order, connected with the Shadow Circle. Their punishment was swift and sound. We have dealt a huge blow to the Shadow Druids, and reclaiming our sacred forest shall now be only a matter of time.~
+~Class(Player1,DRUID_ALL)~ + ~I am glad to have helped you and Jaheira, Seniyad. ~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",35)~ + SEReward1.1D
+~!Class(Player1,DRUID_ALL)~ + ~I am glad to have helped you and Jaheira, Seniyad. ~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",35)~+ SEReward1.1
++ ~Yes, yes, that's really wonderful. Jaheira mentioned that you might have a reward for us…~ DO ~SetGlobal("X#JaheiraSen","GLOBAL",35)~ + SEReward1.2
END

IF ~~ SEReward1.1D
SAY ~You have proven to be a good ally, <CHARNAME>. For that you will be rewarded with the allegiance of the druids of the Cloakwood and a free, undisturbed passage through our woods. Jaheira's guidance has apparently helped us to find another steadfast allyof our cause... you would do well by continuing to listen  to her wisdom and experience, you can learn much from her.~
= ~And let me add something else as well… this enchanted club was found in the possessions of one of the traitors. I trust you or Jaheira will make a good use of it. ~
IF ~~ THEN DO ~AddexperienceParty(5000) GiveItemCreate("X#JACLUB",Player1,1,0,0) SetGlobal("SeniyadXP","GLOBAL",1) Shout(3) EscapeArea()~ EXIT
END

IF ~~ SEReward1.2
SAY ~Do you imply that the allegiance of the druids of Cloakwood, a safe passage through our forests and the personal aid of one of nature's most devoted warriors, is not enough of a reward?~
+~Class(Player1,DRUID_ALL)~ + ~Err… well, I…~ +  SEReward1.3D
+~!Class(Player1,DRUID_ALL)~ + ~Err… well, I…~ + SEReward1.3
+~Class(Player1,DRUID_ALL)~ + ~Alright, this is the last time I trust or help a druid…~ +  SEReward1.3D
+~!Class(Player1,DRUID_ALL)~ + ~Alright, this is the last time I trust or help a druid…~ + SEReward1.3
++ ~Fair enough, Seniyad and well met.~ + SEReward1.4
END

IF ~~ SEReward1.3D
SAY ~I was merely jesting, <CHARNAME>. Of course, you will be rewarded for this service. Jaheira's guidance has apparently helped us to find another steadfast ally to our course... you would do well by continuing to listen in her wisdom and experience, you can learn so much from her.~
= ~This enchanted club was found in the possessions of one of the traitors. I trust you or Jaheira will make a good use of it.~
IF ~~ THEN DO ~AddexperienceParty(5000) GiveItemCreate("X#JACLUB",Player1,1,0,0) SetGlobal("SeniyadXP","GLOBAL",1) Shout(3) EscapeArea()~ EXIT
END

IF ~~ SEReward1.4
SAY ~You have a noble heart, <CHARNAME>. I recognize Jaheira's influence. It seems that she helped us to find another steadfast ally to our course... you would do well by continuing to listen in her wisdom and experience, since you can learn much from her.~
= ~I have something for you, Jaheira - this club is a powerful weapon and it should be weilded by a wiser person than its previous owner - one of the traitors we have discovered with your help.~
IF ~~ THEN DO ~AddexperienceParty(10000) GiveItemCreate("X#JACLUB","Jaheira",1,0,0) SetGlobal("SeniyadXP","GLOBAL",1) Shout(3) EscapeArea()~ EXIT
END

END

CHAIN3 SENIYA SEReward1.1
~You have proven to be a good ally, <CHARNAME>. For that you will be rewarded with the allegiance of the druids of the Cloakwood and a free, undisturbed passage through our woods. And let me add something else as well… this enchanted club was found in the possessions of one of the traitors. It will be a powerful tool in Jaheira's hands. ~
== JAHEIJ ~You have my assurances that it will be put to a good use in maintaining the balance and crushing the nature's enemies, Seniyad.~
== SENIYA ~Yes, you have once again proven your devotion as a druid, Jaheira. It was good seeing you and your friends again, but now we must part. Farewell <CHARNAME>, farewell Jaheira!~
DO ~AddexperienceParty(5000) GiveItemCreate("X#JACLUB",Player1,1,0,0) SetGlobal("SeniyadXP","GLOBAL",1) Shout(3) EscapeArea()~
EXIT

CHAIN3 SENIYA SEReward1.3
~I was merely jesting, <CHARNAME>. Of course, you will be rewarded for this service. This enchanted club was found in the possessions of one of the traitors. It will be a powerful tool in Jaheira's hands.~
== JAHEIJ ~You have my assurances that it will be put to a good use in maintaining the balance and crushing the nature's enemies, Seniyad.~
== SENIYA ~ Yes, you have once again proven your devotion as a druid, Jaheira. It was good seeing you and your friends again, but now we must part. Farewell <CHARNAME>, farewell Jaheira!~
DO ~AddexperienceParty(5000) GiveItemCreate("X#JACLUB",Player1,1,0,0) SetGlobal("SeniyadXP","GLOBAL",1) Shout(3) EscapeArea()~
EXIT
