BEGIN ~X#SAFANA~

//////INTERJECTION IN ARKUSHULE

INTERJECT ~ARKUSH~ 5 SafArkush5
== ~SAFANJ~ IF ~IsValidForPartyDialogue("SAFANA")~ THEN
~A gypsy who wouldn't take the money? Wait! What did you see?~
== ~ARKUSH~ IF ~IsValidForPartyDialogue("SAFANA")~ THEN
~Leave me!~
END
IF ~~ THEN DO ~EscapeArea() SetGlobal("SafArkush5","GLOBAL",1)~
EXIT



INTERJECT ~ARKUSH~ 8 SafArkush8
== ~SAFANJ~ IF ~IsValidForPartyDialogue("SAFANA")~ THEN
~What is it, old woman? What is <CHARNAME>'s fate?~
== ~ARKUSH~ IF ~IsValidForPartyDialogue("SAFANA")~ THEN
~No names! I don't want to know names! Do not come nearer!~
END
IF ~~ THEN DO ~SetGlobal("SafArkush8","GLOBAL",1) Enemy() ~
EXIT

APPEND ~BSAFAN~

IF WEIGHT #-2 ~
Global("SaFriend5Talk","GLOBAL",1)
Global("SafArkush5","GLOBAL",1)
Global("SAPC1","LOCALS",0)~ THEN BEGIN SAPC1
SAY ~Now what was all that fuss about? What about your past could have frightened Arkushule so much?~ [SAFANA99]
IF ~~ THEN REPLY ~She was obviously deranged. It was probably nothing.~ DO ~SetGlobal("SAPC1","LOCALS",1)~ GOTO SAPC1.1
IF ~~ THEN REPLY ~I don’t know, but it was fun watching her cower.~ DO ~SetGlobal("SAPC1","LOCALS",1)~ GOTO SAPC1.2
IF ~~ THEN REPLY ~I have no idea. I wish she had told me.~ DO ~SetGlobal("SAPC1","LOCALS",1)~ GOTO SAPC1.1
END

IF ~~ THEN BEGIN SAPC1.1
SAY ~Well, whatever it was, she was obviously scared. Makes me wonder a bit about the company I’m keeping these days. Are you sure you didn’t forget to tell me something, darling?~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN SAPC1.2
SAY ~What a … charming thought, <CHARNAME>. I’ll be sure to remember that.~
IF ~~ THEN EXIT
END

IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])See(Player1)
Global("SaFriendTalk","GLOBAL",1)
Global("SafArkush8","GLOBAL",1)
Global("SAPC2","LOCALS",0)~ THEN BEGIN SAPC2
SAY ~Now what was all that fuss about? What about your past could have frightened Arkushule so much?~ [SAFANA99]
IF ~~ THEN REPLY ~She was obviously deranged. It was probably nothing.~ DO ~SetGlobal("SAPC2","LOCALS",1)~ GOTO SAPC2.1
IF ~~ THEN REPLY ~I don’t know, but it was fun watching her cower.~ DO ~SetGlobal("SAPC2","LOCALS",1)~ GOTO SAPC2.2
IF ~~ THEN REPLY ~I have no idea. I wish she had told me.~ DO ~SetGlobal("SAPC2","LOCALS",1)~ GOTO SAPC2.1
IF ~~ THEN REPLY ~Well, unfortunately she’s dead now, so we’ll probably never know. Unless we go to a Necromancer next.~ GOTO SAPC2.3
END

IF ~~ THEN BEGIN SAPC2.1
SAY ~Well, whatever it was, she was obviously scared. Makes me wonder a bit about the company I’m keeping these days. Are you sure you didn’t forget to tell me something, darling?~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN SAPC2.2
SAY ~What a … charming thought, <CHARNAME>. I’ll be sure to remember that.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN SAPC2.3
SAY ~Well, whatever it was, she was scared enough to try to kill you. Makes me wonder a bit about the company I’m keeping these days. Are you sure you didn’t forget to tell me something, darling?~
IF ~~ THEN EXIT
END


END

///DREAM SCRIPT
CHAIN
IF WEIGHT #-2 ~
Global("SASK_shopping","LOCALS",1)~ THEN ~SAFANJ~ SASK1
~Skie, I’m finding my wardrobe to be a bit … lacking, these days. You have a wonderful eye for clothes; where do you recommend looking?~ [SAFANA99]
DO ~SetGlobal("SASK_shopping","LOCALS",2)~
== ~BSKIE~ ~Ooh, let’s see. There’s a simply marvelous seamstress near my father’s house.~
= ~She does an amazing job with silks, velvets, even leather, which might be more to your taste. Would you like me to show you where she is?~
== ~BSAFAN~ ~Mmm, yes. <CHARNAME>, darling, Skie and I have some, ah, emergency errands to run. And we need a coin or two...~
DO ~TakePartyGold(100)~
EXIT



CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("AJANTIS")
See("AJANTIS")
!StateCheck("AJANTIS",STATE_SLEEPING)
Global("SAAJ1","LOCALS",0)~ THEN ~BSAFAN~ SAAJ1
~Oof!~ [SAFANA99]
DO ~SetGlobal("SAAJ1","LOCALS",1)~
== ~BAJANT~ ~What is it, my lady? Are you in pain?~
== ~BSAFAN~ ~I ... I just suddenly feel ... faint. This pack seems to be getting heavier and heavier. Perhaps I just need to sit down for a bit.~
== ~BAJANT~ ~That does look too heavy for you, my lady. Please, let me carry some of that.~
== ~BSAFAN~ ~Truly, having such a gallant knight in the party is so conven--er, I mean, delightful. Whatever would I do without a strong young man like you around? Here, pick it up, Ajantis.~
DO ~GiveItemCreate("X#SABOX","Ajantis",1,0,0)~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("BRANWEN")
See("BRANWEN")
!StateCheck("BRANWEN",STATE_SLEEPING)
Global("SABR1","LOCALS",0)~ THEN ~BSAFAN~ SABR1
~I was just talking to <CHARNAME> and I heard a most remarkable tale.~ [SAFANA99]
DO ~SetGlobal("SABR1","LOCALS",1)~
== ~BBRANW~ ~Another remarkable tale from you, Safana? I trust it will be a little more believable than the story of the shipwreck.~
== ~BSAFAN~ ~I’ll allow you to be the judge. It is a tale of a warrior-priestess firm in her convictions, hardened by her years of trial into a pillar of virtue.~
== ~BBRANW~ ~I do like the sound of this. Tempus has taught us many such inspirational tales to guide us in our daily lives.~
== ~BSAFAN~ ~Indeed? Well this tale treats of a statuesque beauty faced with a question of honor versus love--nay, between hard-headedness and hard-heartedness.~
= ~A question that ultimately left her petrified, unable to do more than beseech her god.~
== ~BBRANW~ ~I can only hope that honor won out in this case, for love can be fleeting, while honor is the rock on which a soul finds purchase.~
== ~BSAFAN~ ~I couldn’t have said it better myself, Branwen.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
!StateCheck("CORAN",STATE_SLEEPING)
Global("SACO_flirt","LOCALS",1)~ THEN ~SAFANJ~ SACO1
~Coran, you seem to be a man who knows something of the world. Tell me, what would a beautiful young woman, such as myself, be doing in a place like this?~[SAFANA99]
DO ~SetGlobal("SACO_flirt","LOCALS",2)~
== ~BCORAN~ ~Would the lady prefer some place a little quieter?~
== ~BSAFAN~ ~If the elf is good, and remains alive through this little wyvern ordeal, perhaps he will see what the lady prefers.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
AreaType(CITY)
!StateCheck("CORAN",STATE_SLEEPING)
Global("SACO2","LOCALS",0)~ THEN ~BSAFAN~ SACO2
~Perhaps now would be a good time to buy a round of drinks. My thirst is becoming intolerable.~[SAFANA99]
DO ~SetGlobal("SACO2","LOCALS",1)~
== ~BCORAN~ ~I do quite agree. On more than one occasion, sweet wine has been just the oil to loosen tightly locked lips.~
== ~BSAFAN~ ~We had a saying about loose lips when I was at sea, but I cannot for the life of me remember it. I think it may have had something to do with impertinent elves though.~
== ~BCORAN~ ~Impertinent? Lady, I was merely commenting on the finer points of lock picking.~
== ~BSAFAN~ ~I’m sorry, did you say something, Coran? I was distracted by that wanton gleam in your eye.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
Alignment("CORAN",CHAOTIC_NEUTRAL) Global("BRIEL_STAY","GLOBAL",2)
!StateCheck("CORAN",STATE_SLEEPING)
Global("SACO3","LOCALS",0)~ THEN ~BSAFAN~ SACO3
~I am a little shocked at Briel's lack of discretion in such matters. I do not think I would simply approach a man with a group of strangers on the street and announce that I was a cast-off tramp.~[SAFANA99]
DO ~SetGlobal("SACO3","LOCALS",1)~
== ~BCORAN~ ~I don’t even know…~
== ~BSAFAN~ ~No, I think I would perhaps find such a man in a quiet place, remove his purse, and leave him in various pieces around the city.~
== ~BCORAN~ ~Uh, Safana, this is possibly some kind of…~
== ~BSAFAN~ ~That’s just me though, no possible relevance to this situation. Right, darling? No possible relevance to our situation?~
== ~BCORAN~ ~No, of course not. Perhaps we should go?~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("DYNAHEIR")
See("DYNAHEIR")
!StateCheck("DYNAHEIR",STATE_SLEEPING)
Global("SADY1","LOCALS",0)~ THEN ~BSAFAN~ SADY1
~Dynaheir, does your knowledge of magic include making potions?~[SAFANA99]
DO ~SetGlobal("SADY1","LOCALS",1)~
== ~BDYNAH~ ~Nay, Safana. In mine homeland, the creation of magical items is the sole domain of the Vremyonni, the men-wizards. Why dost thou ask?~
== ~BSAFAN~ ~In the last tavern, it seemed that all this traveling has taken its toll--I only had seven men offer to buy me a drink, instead of the usual full dozen. So I thought you might have a complexion cream or something similar.~
== ~BDYNAH~ ~A complexion cream? Even if I had the skill I would’st not stoop to using it for such a base reason. Mine arts magical art not for thy vanity, but for the good of the group.~
== ~BSAFAN~ ~Oh, no need to worry about that, darling. I’ve been told I’m *very* good.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("SAED1","LOCALS",0)~ THEN ~BSAFAN~ SAED1
~Edwin, you remind me of one of my father's advisors when I was young. I believe he was a Red Wizard like you.~[JAHEI99]
DO ~SetGlobal("SAED1","LOCALS",1)~
== ~BEDWIN~ ~Really? It surprises me that your father would be wise enough to seek the knowledge of our sect.~
== ~BSAFAN~ ~Yes, well, he had a penchant for using our servant girls for honing his sensual arts, if you take my meaning.~
== ~BEDWIN~ ~Practice is necessary to keep the skills sharp.~
== ~BSAFAN~ ~One day, when I was twelve, he decided that he would try and educate me. He lured me into the larder with a promise of showing me a magic trick and attempted to force me onto the table.~
= ~I escaped, but he ripped my favorite skirt in the process.~
== ~BEDWIN~ ~I imagine you ran to your father, who, not understanding the importance of a liberal education, had the man beheaded. (Well, perhaps she was a bit young for it, but still ...unenlightened fools.)~
== ~BSAFAN~ ~Actually, I crept into his room later that evening when he was sleeping and slit his throat. I really loved that skirt.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
InParty("SKIE")
Global("SAEL1","LOCALS",0)~ THEN ~BSAFAN~ SAEL1
~I find your airs and manner most fascinating, Eldoth. You put me in mind of a tale of passion and intrigue, of tender embraces and sweet promises.~ [SAFANA99]
DO ~SetGlobal("SAEL1","LOCALS",1)~
== ~BELDOT~ ~You arouse my … interest, my charming girl. Your audience awaits breathlessly.~
== ~BSAFAN~ ~Once upon a time, a pretty little lark lived in a gilded cage. Young and innocent, she sang to all passersby of her thoughts of freedom and adventure.~
= ~Then one day, a rogue happened upon the lark. He cared not for her beauty or her song, but only for the bars of gold that held her captive. He charmed the foolish lark and murmured sweet words to her, promising all of her heart’s desires.~
= ~She surrendered everything to him, never realizing that she had merely exchanged a cage of gold for a cage of deceit.~
= ~Fortunately for the lark, a falcon discovered her and took pity on her. She watched the rogue night and day for further signs of falseness.~
== ~BELDOT~ ~What an interesting fable! But from one talespinner to another, your moral is rather heavy-handed.~
== ~BSAFAN~ ~I feared that subtlety would go wasted on you, bard.~
== ~BELDOT~ ~I would also point out that as long as that little lark still sings for her master whenever he pleases, it matters not if the falcon knows. And that falcon’s claws are surely as dull as your wit.~
== ~BSAFAN~ ~Were I the master, I should have a care. Someday he may learn just how sharp her talons are.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("FALDORN")
See("FALDORN")
!StateCheck("FALDORN",STATE_SLEEPING)
AreaType(FOREST)
Global("SAFA1","LOCALS",0)~ THEN ~BSAFAN~ SAFA1
~Don’t you ever get tired of the woods, Faldorn?~ [SAFANA99]
DO ~SetGlobal("SAFA1","LOCALS",1)~
== ~BFALDO~ ~Blasphemy! The forest is one of Nature’s finest creations.~
== ~BSAFAN~ ~Well, yes, trees are much nicer than boring old desert or the open sea. But I can’t ever get a decent night’s rest sleeping on sticks and pine cones.~
= ~I’d much rather be in a cozy tavern, sharing a glass of wine and perhaps other delights with a handsome lad.~
== ~BFALDO~ ~You disgust me. It shall be a joyous day when the Shadow Druids finally rid this land of your ilk.~
== ~BSAFAN~ ~Do come looking for me that day, darling--I’ll be the one curled up on the plumpest featherbed in town.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("SAGA1","GLOBAL",0)~ THEN ~BSAFAN~ SAGA1
~Garrick, I have heard tales of your lyric prowess and I’ve decided that I would like to commission a song from you.~ [SAFANA99]
DO ~SetGlobal("SAGA1","GLOBAL",1)~
== ~BGARRI~ ~Commission? Why, I wouldn't dream of accepting money from you--the mere sight of your beauty is payment enough. In fact, I have already been working on an ode to your grace. Would you, uh, like to hear it?~
== ~BSAFAN~ ~Really? I would love to hear it. Although, I must inform you that this isn't the first song written about me. In fact, aboard the Exzesus I was immortalized in one of the bawdiest chanteys ever written.~
== ~BGARRI~ ~Well, that's a lot to live up to, but I shall endeavor to do my best:~
= ~I look into my soul, but see only emptiness.
For the wine has been drunk to ease pain, 
leaving only a green bottle and sediment,
like dried blood coating my insides.~
= ~I search for the cork to refill the bottle and find
crystals, shining in the light and know
that from emptiness comes beauty.~
== ~BSAFAN~ ~That was interesting, Garrick. Here I was expecting something more along the lines of "There once was a man from Beregost…"~
== ~BGARRI~ ~Uh, ok. Well, how about:~
= ~There once was a man from Beregost
Who wandered around as if lost,
When he met a fair maid,
And a fair sum she was paid
But he has yet to determine the cost.~
== ~BSAFAN~ ~Now that was inspired, pet. That was *truly* inspired!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("SAGA1","GLOBAL",1)
Global("SAGA2","GLOBAL",0)~ THEN ~BSAFAN~ SAGA2
~So, Garrick, how is the song coming?~ [SAFANA99]
DO ~SetGlobal("SAGA2","GLOBAL",1)~
== ~BGARRI~ ~Safana, I’m afraid to say that I’m at a loss to express what I’m feeling.~
== ~BSAFAN~ ~What? There are plenty of words that rhyme with "lust." Crust, must, trust, or… bust! I seem to have a knack of my own for lyrics, wouldn’t you say, bard?~
== ~BGARRI~ ~Well, yes, I suppose you do. But, that’s not the quandary I find myself in. See, I’m finding it difficult to craft anything that is more than a shadow of my true feelings toward you. I simply have lost the will to work.~
= ~I mean, sure, simple battle hymns are no problem, but when I try to unlock my heart I founder on the rocks of your beauty and find myself utterly alone and tortured by something that even I cannot name. (Now that was eloquent)~
== ~BSAFAN~ ~Perhaps we should concentrate more on rhyming with "lust," pumpkin, and see where that takes you.~
== ~BGARRI~ ~Ah, yes! I mean, I believe that may be a better approach....~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("SAGA2","GLOBAL",1)
Global("SAGA3","GLOBAL",0)~ THEN ~BSAFAN~ SAGA3
~Garrick, I hope that you’ve been able to get over that little mental block that you were having.~ [SAFANA99]
DO ~SetGlobal("SAGA3","GLOBAL",1)~
== ~BGARRI~ ~Safana, I have spent the time since our last conversation trying to find a way to express myself, and I’ve determined that it’s either you or my life’s work. I cannot abide this division in my inspiration.~
= ~Since I feel like I am nothing but a toy for you, I have to ask you to stop playing with me and leave me be.~
== ~BSAFAN~ ~You’re no fun anymore, Garrick. Anyway, I didn’t ask you to unload all of your "empty bottle" stuff on me.~
= ~I’ll be glad to leave you alone, but I will truly miss the neck massages. You may have missed your calling in that regard.~
EXIT

//////NEEDS SCRIPT WHICH ADDS 5% TO IMOEN's ABILITY TO OPEN LOCKS//////
CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("SAIM1","LOCALS",0)~ THEN ~BSAFAN~ SAIM1
~Imoen dear, I noticed that you were having a bit of trouble with one of those locks back there. When I was growing up, my father’s house was filled with locks just like that one, so I learned there was a special trick to tease them open. Would you like me to show you?~ [SAFANA99]
DO ~SetGlobal("SAIM1","LOCALS",1)~
== ~BIMOEN2~ ~Uh, sure, Safana. That’s awfully nice of you …~
== ~BSAFAN~ ~That’s right, you have the feel for it now. Such a clever girl, reminds me of another pretty young thing I once knew …~
DO ~ActionOverride("Imoen2",ReallyForceSpellRES("SPWI250",Myself))~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("SAIM1","GLOBAL",1)
Global("SAIM2","GLOBAL",0)~ THEN ~BSAFAN~ SAIM2
~Imoen, child, your hair is simply frightful today. Come, let me fix it for you.~ [SAFANA99]
DO ~SetGlobal("SAIM2","GLOBAL",1)~
== ~BIMOEN2~ ~I don’t get it, Safana. What’s with all the attention? Why are you being so nice to me?~
== ~BSAFAN~ ~My sweet little innocent, this is a cold, cruel world we live in. A girl must use whatever natural advantages she has, and you have more than most. It’s long past time that someone took you under her wing and helped you polish your charms.~
== ~BIMOEN2~ ~I dunno about the charm-school part, Safana, but I sure like the lockpicking tips. Can you show me more of those sometime?~
== ~BSAFAN~ ~Certainly, dear, but I think that learning to unlock men’s hearts will serve you better in the long run.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
Global("SAKH2","LOCALS",1)
Global("SAJA1","LOCALS",0)~ THEN ~BSAFAN~ SAJA1
~Khalid, darling, have you --~ [SAFANA99]
DO ~SetGlobal("SAJA1","LOCALS",1)~
== ~BJAHEI~ ~Safana, I suggest you find someone else to call "darling."~ 
== ~BSAFAN~ ~What’s this? A touch of jealousy perhaps?~
== ~BJAHEI~ ~Nonsense. I know my Khalid’s character, and he has never given me cause for concern.~ 
== ~BSAFAN~ ~Perhaps your jealousy is directed more at my sparkling wit, irresistible charm, and carefree nature?~
== ~BJAHEI~ ~"Carefree" is not exactly how I would describe you. "Irresponsible" and "selfish" seem more appropriate.~ 
== ~BSAFAN~ ~I’m greatly flattered by the amount of time you’ve spent thinking about me, Jaheira.~

EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("SAKA1","LOCALS",0)~ THEN ~BSAFAN~ SAKA1
~Kagain, you certainly handled your axe well in that last battle.~ [SAFANA99]
DO ~SetGlobal("SAKA1","LOCALS",1)~
== ~BKAGAI~ ~I'd be happy to show ye me other weapons sometime, if ye catch me meaning.~
== ~BSAFAN~ ~Is all of your equipment ... dwarf-sized?~
== ~BKAGAI~ ~It's not the size of the axe, wench, it's how you swing it.~
== ~BSAFAN~ ~Oh, technique is important, but I can assure you that size does matter, my pet.~
== ~BKAGAI~ ~Have ye 'ver noticed, wench, that the dwarf-forged weaponry is always larger than that of the "taller" races?~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
Global("SAKH1","LOCALS",0)~ THEN ~BSAFAN~ SAKH1
~You know, Khalid, you don’t seem nosy enough to be a Harper. We’ve been traveling together for some while and you have yet to even address me.~ [SAFANA99]
DO ~SetGlobal("SAKH1","LOCALS",1)~
== ~BKHALI~ ~I’m afraid I’m not one for b-bantering, Safana.~
== ~BSAFAN~ ~Why? Because of your stutter?~
== ~BKHALI~ ~Ah. You d-don't hesitate to be blunt, do you?~
== ~BSAFAN~ ~No sense in wasting time that could be spent on pleasurable activities, I always say. No, darling, if that’s why you’re so quiet around me, there’s no need to be shy.~
== ~BKHALI~ ~No, in f-fact it is not. I rarely find enjoyment in c-casual conversation, becau-~
== ~BSAFAN~ ~I’m glad we’ve gotten that straightened out. Now, enough about you, let’s talk about me…~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
Global("SAKH2","LOCALS",0)~ THEN ~BSAFAN~ SAKH2
~So, Khalid, aren’t you wondering what would take such a charming creature as myself so far from home?~ [SAFANA99]
DO ~SetGlobal("SAKH2","LOCALS",1)~
== ~BKHALI~ ~I'm s-sorry, Safana, I was thinking about something. What did you s-say?~
== ~BSAFAN~ ~Aren’t you wondering anything about me? Or are you completely blinded to my presence by your overseer?~
== ~BKHALI~ ~I d-don’t know what to ask you. And your interest in me is a little s-strange. Surely my d-devotion to Jaheira is no secret.~
== ~BSAFAN~ ~I do wonder, could you not have done better than Jaheira the Domineering? There’s not an hour that goes by that she doesn’t pick at you or snap at someone.~
== ~BKHALI~ ~Jaheira isn’t really d-d-do-dom *sigh* d-damn that sound - bossy. There are some things in our past that you d-don’t know about, Safana.~
== ~BSAFAN~ ~No? Well, I’m not really interested in the past. I keep my eyes on the future and--~
= ~Never mind, darling, I see her staring at us. We’ll continue this some other time.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KIVAN")
See("KIVAN")
!StateCheck("KIVAN",STATE_SLEEPING)
Global("SAKI1","LOCALS",0)~ THEN ~BSAFAN~ SAKI1
~Kivan, what was the name of your wife again?~
DO ~SetGlobal("SAKI1","LOCALS",1)~
== ~BKIVAN~ ~*Softly* Deheriana.~
== ~BSAFAN~ ~Ah, yes, that’s right. Your grief for her reminds me of my father’s when he lost my mother.~
== ~BKIVAN~ ~I am sorry to hear of your mother’s departure, Safana.~
== ~BSAFAN~ ~Well, it's interesting that you should put it that way, as in truth she may have only "departed." I’ve been fascinated by sirens and nymphs since I was very small, and my father used to tell me that my mother was a siren who had to return to the sea.~
= ~As I grew older, I thought it was only a tale to soften a child’s loss. But perhaps it wasn’t.~
= ~In any case, I look forward to helping you avenge Deheriana’s death.~
== ~BKIVAN~ ~Thank you, Safana.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MINSC")
See("MINSC")
!StateCheck("MINSC",STATE_SLEEPING)
Global("SAMI1","LOCALS",0)~ THEN ~BSAFAN~ SAMI1
~Tell me, Minsc, what’s a big strong fellow like you doing in a place like this?~ [SAFANA99]
DO ~SetGlobal("SAMI1","LOCALS",1)~
== ~BMINSC~ ~Boo says that <CHARNAME> wanted us to come here. Is there some other place we should be?~
= ~Boo is sure that there is Evil nearby. Soon we shall find it, and we shall apply my large boots and Boo's small ones to its backside.~
== ~BSAFAN~ ~Never mind, Minsc. Just carry my pack for me for a while, would you?~
== ~BMINSC~ ~Of course! Tell me, you are not secretly a mage, are you, little lady? Boo tells me I am being charmed but I feel no different.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MONTARON")
See("MONTARON")
!StateCheck("MONTARON",STATE_SLEEPING)
Global("SAMO1","LOCALS",0)~ THEN ~BSAFAN~ SAMO1
~<CHARNAME>, I don't suppose I ever told you about the time I single-handedly dispatched a score of halfling fighters who attempted to collect a bounty on me?~ [SAFANA99]
DO ~SetGlobal("SAMO1","LOCALS",1)~
== ~BMONTA~ ~There's halflins' as thinks they’re fighters, an' there's them as are. Reckon ye'd ken the diff'rence if I ever had a mind to show ye.~
== ~BSAFAN~ ~Go shave your feet, midge, I'm telling a story here.~
== ~BMONTA~ ~Wipin' 'em on yer corpse'll do fer their care. No need fer more.~
== ~BSAFAN~ ~<CHARNAME>, be a darling and tell the little one to shut his trap before I re-enact the ending of my tale.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SHARTEEL")
See("SHARTEEL")
!StateCheck("SHARTEEL",STATE_SLEEPING)
Global("SASH1","LOCALS",0)~ THEN ~BSAFAN~ SASH1
~Shar-Teel, I can’t help but notice that you don’t like men very much.~ [SAFANA99]
DO ~SetGlobal("SASH1","LOCALS",1)~
== ~BSHART~ ~Obviously <CHARNAME> picked you up for your brains.~
== ~BSAFAN~ ~Why, yes, darling, I do believe that’s why I’m part of this group. It’s so sweet of you to notice.~
= ~But back to the subject. I wonder why you hate them so. Haven’t you heard that honey catches more flies than vinegar?~
== ~BSHART~ ~I’m not interested in catching *flies*, just killing them.~
== ~BSAFAN~ ~Such hostility, dear. I just think there are easier, not to mention more enjoyable, ways to exploit men’s weaknesses than the path you’ve chosen.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SKIE")
See("SKIE")
!StateCheck("SKIE",STATE_SLEEPING)
InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("SASK2","LOCALS",0)~ THEN ~BSAFAN~ SASK2
~As the daughter of one of the dukes, Skie, you must have had many suitors. Tell me, what are the men of Baldur’s Gate like?~ [SAFANA99]
DO ~SetGlobal("SASK2","LOCALS",1)~
== ~BSKIE~ ~Well, none of them can hold a candle to Eldoth. The rest are so boring. They’re just interested in my father’s money.~
== ~BSAFAN~ ~Yes, certainly, darling, I’m sure Eldoth has no interest in your position or your wealth.~
== ~BSKIE~ ~Oh yes, he just loves me for myself. I’m so happy that we’re finally going adventuring together, just as he’s always promised!~
== ~BSAFAN~ ~Yes, I think some travels will broaden your horizons and open your eyes to how the world really works.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SKIE")
See("SKIE")
!StateCheck("SKIE",STATE_SLEEPING)
InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("SASK3","LOCALS",0)~ THEN ~BSAFAN~ SASK3
~Skie, darling, I remembered a story that I thought you might like to hear.~ [SAFANA99]
DO ~SetGlobal("SASK3","LOCALS",1)~
== ~BSKIE~ ~Ooh, I love your stories. What’s this one about?~
== ~BSAFAN~ ~There once was a daughter of a rich and powerful lord--a surpassingly beautiful girl, I might add. Her father provided for her every whim, but still her heart longed for adventure.~
== ~BSKIE~ ~Oh, I know just how she feels!~
== ~BSAFAN~ ~Yes, I thought you might, my dear. So one day she decided to run off with some dashing pirates.~
= ~But adventure turned out to be so much … messier, and more dangerous, than any of the tales had ever mentioned.~
== ~BSKIE~ ~That’s awful! Didn’t she have anyone to take care of her?~
== ~BSAFAN~ ~No, darling, she was by herself, with nothing but her wits and not inconsiderable charm.~
= ~She learned that she was a match for anyone and any challenge. She didn’t need a man.~
== ~BSKIE~ ~But it’s so much nicer with someone like Eldoth around. I never have to worry about anything.~
== ~BSAFAN~ ~Oh, men have their place, certainly … preferably rubbing my shoulders or fetching me something to drink.~
= ~But the girl in my tale learned not to confuse wanting a man with needing one. I do hope, darling, that you’ll think about my story.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("TIAX")
See("TIAX")
!StateCheck("TIAX",STATE_SLEEPING)
Global("SATI1","LOCALS",0)~ THEN ~BSAFAN~ SATI1
~Tiax, I've heard you mention world domination on several occasions. It reminds me of a tale I heard while at sea of an artifact most powerful. An artifact that should be only wielded by one of your, ah, stature.~ [SAFANA99]
DO ~SetGlobal("SATI1","LOCALS",1)~
== ~BTIAX~ ~The supreme ruler would be very interested in hearing such a tale.~
== ~BSAFAN~ ~It was when I was aboard the Exzesus. We had just sacked a village on the Amnish coast and set sail for the island of Brynnlaw to relieve ourselves of excess plunder.~
= ~I was spending the evening being attended to at one of the more infamous brothels, when I overheard a young mage and his leather-cladmistress refer to an "Amulet of the Dominatrix."~
= ~Apparently the wielder of such an item can enslave the world.~
== ~BTIAX~ ~Enslave the world? Tiax must know the location of this brothel! Tiax must have the amulet! Tiax will not be denied his destiny!~
== ~BSAFAN~ ~Yes, my pet, in due time. First, I'll need you to reach between my shoulder blades - I've got a simply unbearable itch...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("TIAX")
See("TIAX")
!StateCheck("TIAX",STATE_SLEEPING)
Global("SATI2","LOCALS",0)~ THEN ~BSAFAN~ SATI2
~I'm curious, Tiax. What is the opinion of human women among gnomes?~ [SAFANA99]
DO ~SetGlobal("SATI2","LOCALS",1)~
== ~BTIAX~ ~The noses of human women are disturbingly small, and they themselves are disturbingly tall!~
= ~Humans should learn to stop growing to unnecessary heights, and when Tiax rules he shall make certain that none are allowed to grow even an inch higher than Tiax himself!~
== ~BSAFAN~ ~Oh, come now. What could you possibly find attractive about a nose? Surely there are other....advantages which human women possess which no gnomish women could possibly hope for.~
== ~BTIAX~ ~Nothing outweighs the importance of the well-formed nose! NOTHING! A gnomish woman's nose is a testament to her beauty!~
= ~Just thinking of a well-formed female nose, it's tremendous length extending a foot or more from the face, it's nostrils expanding, its sleek curvature.....*eyes glaze over*~
== ~BSAFAN~ ~I think I've pressed much farther than intended into this subject. At the next inn, I'll see if I can arrange a cold bath for you, Tiax.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("VICONIA")
See("VICONIA")
!StateCheck("VICONIA",STATE_SLEEPING)
Global("SAVI1","GLOBAL",0)~ THEN ~BSAFAN~ SAVI1
~Viconia, I can't help but noticing how you‘ve continued to hide that beautiful face since we rescued you. Do you still fear for your life among such heroes as these?~ [SAFANA99]
DO ~SetGlobal("SAVI1","GLOBAL",1)~
== ~BVICON~ ~I'm afraid that old habits die hard, rivvil. When you've lived in hiding as long as I have, passing unnoticed becomes second nature.~
== ~BSAFAN~ ~Yes, but you are still a drow, and exercising your powers as a woman should still be first nature, shouldn't it?~
= ~I don't know much about drow culture, but I think I've learned a little about you, and I hate to see such a proud creature hiding behind her cowl.~
== ~BVICON~ ~There is some truth in what you say. Beneath the surface, I commanded vastly more authority than I do here, and it does sicken me to be reduced to such a mewling state.~
= ~You are but a rivvil, yet your words are ... enticing. I may consider them.~
== ~BSAFAN~ ~That's the spirit, darling! Now, let's go see if we can get some sucker to buy us a couple of drinks. Between the two of us, we should be able to drain most of the pockets in the next tavern.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XAN")
See("XAN")
!StateCheck("XAN",STATE_SLEEPING)
Global("SAXA1","LOCALS",0)~ THEN ~BSAFAN~ SAXA1
~Considering that your specialty is enchantment, Xan, I wonder why you aren’t more, er, effervescent.~ [SAFANA99]
DO ~SetGlobal("SAXA1","LOCALS",1)~
== ~BXANNN~ ~What does my realistic outlook on life have to do with being an enchanter?~
== ~BSAFAN~ ~Well, most enchanters that I’ve met try to charm others with their personality as well as their spells.~
= ~I’ve met a few people who find depression attractive, but really, darling, it’s easier to coax people to do what you want with a smile.~
== ~BXANNN~ ~Why make the effort, when a spell will do the job?~
== ~BSAFAN~ ~Some of us don’t have quite the acumen that you have, dear. Though I’ve often thought that if I were to study to become a mage, my natural skills would probably lead me to be an enchantress.~
= ~Perhaps you could teach me a trick or two that I could use to enhance my own natural charms?~
== ~BXANNN~ ~Why waste your time and mine? By the time this little misadventure is over, we'll both be dead.~
== ~BSAFAN~ ~Forget it. I think I'll leave you to brood in peace.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XZAR")
See("XZAR")
!StateCheck("XZAR",STATE_SLEEPING)
InParty("MONTARON")
See("MONTARON")
!StateCheck("MONTARON",STATE_SLEEPING)
Global("SAXZ1","LOCALS",0)~ THEN ~BSAFAN~ SAXZ1
~I’ve noticed that you’ve been avoiding me ever since <CHARNAME> has brought us together. Can my form be that displeasing to you?~ [SAFANA99]
DO ~SetGlobal("SAXZ1","LOCALS",1)~
== ~BXZAR~ ~Yes ... your form is delightfully fleshy. Yet it is so corrupted by vitality, and that lascivious stench it exudes … simply appalling! But I do judge that it should make rather an attractive corpse.~
== ~BSAFAN~ ~Ah, as I suspected, a necrophiliac, else you should long ago have come panting to my door.~
= ~Has not a single living woman brought you pleasure? Perhaps your mother? I heard you calling to her in your sleep last night…~
== ~BXZAR~ ~Mummy!? Oh, but Mummy *is* dead. And she’s so much nicer to me now! Sometimes…sometimes I miss the lovely things she’d say to me, had she but the tongue to do so.~
== ~BSAFAN~ ~And just where is dear Mummy's tongue now?~
== ~BXZAR~ ~Monty certainly made a fine casserole last night.~
== ~BSAFAN~ ~Hm. I fear my question and your answer are not unrelated, my voracious little necromancer.~
EXIT

