BEGIN X#XZFSP1
BEGIN X#XZFSP2
BEGIN X#XZFSP3

//Item making

// Halbaz
ADD_TRANS_TRIGGER HALBAZ 0 ~!PartyHasItem("X#XZDRIA")~

EXTEND_BOTTOM HALBAZ 0
+~Global("X#XzarMakeRing","GLOBAL",1) PartyHasItem("X#XZDRIA") !PartyHasItem("X#XZMIRI")~ + ~Let's see what you have, then.~ DO ~StartStore("STO0703",LastTalkedToBy(Myself))~ EXIT
+~Global("X#XzarMakeRing","GLOBAL",1) PartyHasItem("X#XZDRIA") !PartyHasItem("X#XZMIRI")~ +~Perhaps another time.~ EXIT
IF ~!InParty("xzar") PartyHasItem("X#XZDRIA") Global("X#XzarMakeRing","GLOBAL",0)~ GOTO NoXzarDriad

IF ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING) 
Global("X#XzarMakeRing","GLOBAL",0) PartyHasItem("X#XZDRIA") !PartyHasItem("X#XZMIRI")~ EXTERN XZARJ MakeRingChain1

IF ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING) 
Global("X#XzarMakeRing","GLOBAL",0) PartyHasItem("X#XZDRIA") PartyHasItem("X#XZMIRI")~ EXTERN XZARJ MakeRingChain2

IF ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING) 
PartyGoldGT(1000) Global("X#XzarMakeRing","GLOBAL",1) PartyHasItem("X#XZDRIA") PartyHasItem("X#XZMIRI")~ EXTERN XZARJ MakeRingChain3

IF ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING)
OR(2) Global("X#XzarNags","GLOBAL",3) Global("X#XzarNags","GLOBAL",4) Global("X#XZRingMade","GLOBAL",0)
PartyGoldGT(1000)~ GOTO MakeRingChain4

IF ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING)
Global("X#XZRingPayed","GLOBAL",0) GlobalGT("X#XzarNags","GLOBAL",0) 
Global("X#XZRingMade","GLOBAL",1) !PartyGoldGT(1000)~ GOTO NoMoney

IF ~Global("X#XZRingMade","GLOBAL",1)
Global("X#XZRingPayed","GLOBAL",1) GlobalTimerExpired("X#XzarRingTime","GLOBAL")~ GOTO XzarRingReady1

IF ~Global("X#XZRingMade","GLOBAL",3) GlobalTimerExpired("X#XzarRingTime","GLOBAL") 
PartyGoldGT(500)~ GOTO XzarRingReady2

IF ~Global("X#XZRingMade","GLOBAL",3) GlobalTimerExpired("X#XzarRingTime","GLOBAL")
!PartyGoldGT(500)~ GOTO XzarRingReady3

+ ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING) Global("X#XzarMakeRing","GLOBAL",1) Global("X#XZRingPayed","GLOBAL",0)
!PartyGoldGT(1000) PartyHasItem("X#XZMIRI")~ +~Let's see what you have, then.~ DO ~StartStore("_STO0703",LastTalkedToBy(Myself))~ EXIT
+ ~InParty("xzar") !Dead("xzar") !StateCheck("xzar",STATE_SLEEPING) Global("X#XzarMakeRing","GLOBAL",1) Global("X#XZRingPayed","GLOBAL",0)
!PartyGoldGT(1000) PartyHasItem("X#XZMIRI")~ + ~Perhaps another time.~ EXIT
END

APPEND ~HALBAZ~

IF ~PartyHasItem("X#XZDRIA") Global("X#XzarMakeRing","GLOBAL",0)~ THEN BEGIN NoXzarDriad
SAY ~Well, gentles, may I … ack! What've you got there?~
++ ~This, sir, is the necromantically preserved essence of…~ DO ~SetGlobal("X#XzarMakeRing","GLOBAL",1)~ + NoXzarDriad1
END

IF ~~ NoXzarDriad1
SAY ~It's a necromantic slime ball! Kill the necromancer if you haven't already but get that muck out of my establishment.~
++ ~But we have… ~ + NoXzarDriad2
END

IF ~~ NoXzarDriad2
SAY ~No stories! Out! Out! OUT!!! ~
IF ~~ THEN DO ~ActionOverride(Player1,DestroyItem("X#XZDRIA"))
ActionOverride(Player2,DestroyItem("X#XZDRIA"))
ActionOverride(Player3,DestroyItem("X#XZDRIA"))
ActionOverride(Player4,DestroyItem("X#XZDRIA"))
ActionOverride(Player5,DestroyItem("X#XZDRIA"))
ActionOverride(Player6,DestroyItem("X#XZDRIA"))~ EXIT
END

IF ~~ MakeRingChain4
SAY ~From the eager look on your friend's face I assume that you want the ring made? Return in five days, my friends and it's yours!~
IF ~~ THEN EXTERN ~XZARJ~ MakeRingChain4.1
END

IF ~~ AcceptedOfferXzar
SAY ~Return in five days, my friends.~
IF ~~ THEN DO ~ActionOverride(Player1,DestroyItem("X#XZDRIA"))
ActionOverride(Player2,DestroyItem("X#XZDRIA"))
ActionOverride(Player3,DestroyItem("X#XZDRIA"))
ActionOverride(Player4,DestroyItem("X#XZDRIA"))
ActionOverride(Player5,DestroyItem("X#XZDRIA"))
ActionOverride(Player6,DestroyItem("X#XZDRIA"))
ActionOverride(Player1,DestroyItem("X#XZMIRI"))
ActionOverride(Player2,DestroyItem("X#XZMIRI"))
ActionOverride(Player3,DestroyItem("X#XZMIRI"))
ActionOverride(Player4,DestroyItem("X#XZMIRI"))
ActionOverride(Player5,DestroyItem("X#XZMIRI"))
ActionOverride(Player6,DestroyItem("X#XZMIRI"))
TakePartyGold("1000")
SetGlobal("X#XZRingMade","GLOBAL",1) SetGlobal("X#XZRingPayed","GLOBAL",1)
SetGlobalTimer("X#XzarRingTime","GLOBAL",36000)~ EXIT
END

IF ~~ NoMoney
SAY ~Ah, you are the ones that have the dryad's blood, but no money?~
IF ~~ THEN GOTO CruelCharRing
END

IF ~~ CruelCharRing
SAY ~Tell you what. I'll make the ring as a spec item. If you decide you want it for 500 gold, it's yours. If not, I'm sure I'll find another buyer. Return in five days.~
IF ~~ THEN DO ~ActionOverride(Player1,DestroyItem("X#XZDRIA"))
ActionOverride(Player2,DestroyItem("X#XZDRIA"))
ActionOverride(Player3,DestroyItem("X#XZDRIA"))
ActionOverride(Player4,DestroyItem("X#XZDRIA"))
ActionOverride(Player5,DestroyItem("X#XZDRIA"))
ActionOverride(Player6,DestroyItem("X#XZDRIA"))
ActionOverride(Player1,DestroyItem("X#XZMIRI"))
ActionOverride(Player2,DestroyItem("X#XZMIRI"))
ActionOverride(Player3,DestroyItem("X#XZMIRI"))
ActionOverride(Player4,DestroyItem("X#XZMIRI"))
ActionOverride(Player5,DestroyItem("X#XZMIRI"))
ActionOverride(Player6,DestroyItem("X#XZMIRI"))
SetGlobal("X#XZRingMade","GLOBAL",3)
SetGlobalTimer("X#XzarRingTime","GLOBAL",36000)~ EXIT
END

IF ~Global("X#XZRingMade","GLOBAL",1)~ XzarRingReady1
SAY ~Ah, you're here for your ring, no doubt. Here you are and a fine bit of work it is.~
IF ~InParty("Xzar")~ THEN DO ~SetGlobal("X#XZRingMade","GLOBAL",2) GiveItemCreate("X#XZRING","xzar",1,0,0)~ EXTERN XZARJ XzarHasRing
IF ~!InParty("Xzar")~ THEN DO ~SetGlobal("X#XZRingMade","GLOBAL",2) GiveItemCreate("X#XZRING",Player1,1,0,0)~ EXIT
END

IF ~Global("X#XZRingMade","GLOBAL",3)~ XzarRingReady2
SAY ~Ah, you're here for your ring, no doubt. Here you are and a fine bit of work it is. For only 500 this fine item is yours!~
+ ~PartyGoldGT(500)~ + ~Well, we will take it.~ DO ~TakePartyGold("500")  SetGlobal("X#XZRingPayed","GLOBAL",1) SetGlobal("X#XZRingMade","GLOBAL",4) GiveItemCreate("X#XZRING","xzar",1,0,0)~ EXTERN XZARJ XzarHasRing
++ ~Forget it. Just show us your usual wares.~ DO ~SetGlobal("X#XZRingMade","GLOBAL",4) StartStore("STO0703",LastTalkedToBy(Myself))~ EXTERN XZARJ XzarRefusedRing
END

IF ~Global("X#XZRingMade","GLOBAL",3)~ XzarRingReady3
SAY ~Your ring is ready, but I wager that you still do not have enough gold to pay for it. Well, well... perhaps another day.~
++ ~Just show us your usual wares.~ DO ~StartStore("STO0703",LastTalkedToBy(Myself))~ EXIT
++ ~We will come back when we have 500 gold.~ EXIT
END

END

CHAIN3 XZARJ MakeRingChain1
~Why good sir, I have in my possession the rarest and most wondrous of items. Here, have a look.~
DO ~SetGlobal("X#XzarMakeRing","GLOBAL",1)~
== HALBAZ ~Ulp! That's disgus…eh…it is finely preserved though. Dryad, isn't it?~
== XZARJ ~See!?!? See, <CHARNAME>, I told you, I told you!…ahem. Now good sir, as my adventuring career comes first (of course it does), I unfortunately lack mundane necessaries to complete this enchantment suitably myself. Can you inform me what else might be required to distil this magnificent essence into a ring, ring, ring, ring-ring-aroooo?~
== HALBAZ ~Well, a mithril ring would serve as a container to receive the magic of your…ugh…specimen. Unfortunately, I have no such thing is stock at the moment, myself. If you were to provide such an ideal container, then…let’s see…the scroll, my time…for…nine hundred…call it one thousand gold pieces, I could produce a magical ring to resist enchantments – maybe even cast a minor one – in four…make it five days. Are you interested?~
== XZARJ ~Oooh! Let’s do it! We must! Can we? Can we, <CHARNAME>? Puh-leeeze?!? ~
END
++ ~I don’t know. If we find some such…container, then we can think about it. ~ + MakeRingChain1.1

CHAIN XZARJ MakeRingChain1.1
~We will! If we must strip the Sword Coast entire to its fundament of bare stone, WE WILL DO IT!!! ~
END
++ ~Uh…sure, Xzar. But…uh…that sounds like a pretty big job, so we better get going. Right?~  + MakeRingChain1.2

CHAIN _XZARJ MakeRingChain1.2
~ Absotively!!!~
END
++ ~Huh?~ + MakeRingChain1.3


CHAIN XZARJ MakeRingChain1.3
~ Oh, sorry. I meant ‘posilutely’…ahhh, let us be at the doing, not this interminable talking about doing! Let us cease to prate and posture… ~
END
++ ~Xzar? Shut up!!!~ + MakeRingChain1.4

CHAIN XZARJ MakeRingChain1.4
~ My sediment precisely.~
EXIT


CHAIN3 XZARJ MakeRingChain2
~Why good sir, I have in my possession the rarest and most wondrous of items. Here, have a look.~
DO ~SetGlobal("X#XzarMakeRing","GLOBAL",1)~
== HALBAZ ~Ulp! That's disgus…eh…it is finely preserved though. Dryad, isn't it?~
== XZARJ ~See!?!? See, <CHARNAME>, I told you, I told you! …ahem. Now good sir, as my adventuring career comes first (of course it does), I unfortunately lack mundane necessaries to complete this enchantment suitably myself. Can you inform me what else might be required to distil this magnificent essence into a ring, ring, ring, ring-ring-aroooo?~
== HALBAZ ~Well, a mithril ring would serve. Costs three… uh…four hundred to enchant it to contain the essence. With that and your …uh…component, I could create a ring that'd let you shrug off charms, for certain. Maybe even let you throw one back, if I'm undisturbed for the five days labor needed. Let's see... the scroll, my time, it'd cost nine…a thousand gold, altogether. What do you say?~
== XZARJ ~Ooooohhhh! Could we? Could we, <CHARNAME>? Please, please, please, please, pretty please with gnats on top? Just THINK how it would please Mummy!~
END
+ ~PartyGoldGT(1000)~+ ~Oh, go ahead.~ GOTO X#XZRING1
+~!PartyGoldGT(1000)~+ ~Uh, we don't have that much cash right now, Xzar.~ GOTO X#XZRING2
++ ~No way. It's nowhere near worth it and we've got better stuff already.~ GOTO X#XZRING3

CHAIN3 XZARJ MakeRingChain3
~We are here... about the ring!~
DO ~SetGlobal("X#XzarMakeRing","GLOBAL",2)~
== HALBAZ ~What's your decision?~
END
+ ~PartyGoldGT(1000)~+ ~Oh, go ahead.~ GOTO X#XZRING1
++ ~No way. It's nowhere near worth it and we've got better stuff already.~ GOTO X#XZRING3

APPEND ~XZARJ~

IF ~~  XzarHasRing
SAY ~Calloo-callay, my beamish boy! ‘Tis done! And it is mine!~
IF ~~ THEN EXIT
END

IF ~~ XzarRefusedRing
SAY ~FORGET it!?! NEVER!!! Your meanness is unmatched, <CHARNAME>! I have not been so unjustly deprived since I was denied the award for First Student in Eyeball Laboratory!~
IF ~~ THEN EXIT
END

//MontaronCharmingSceme

IF WEIGHT #-2 ~Global("XzarCharmMontaron","GLOBAL",1)~ THEN BEGIN MontyCharming1
SAY ~It sparkles so lovely, like little dead stinky fishes on the shore.~
= ~Arrrr! I can't wait! I can't wait any longer!~
IF ~~ THEN DO ~SetGlobal("XzarCharmMontaron","GLOBAL",2)~ EXIT
END

IF ~~ MakeRingChain4.1
SAY ~AHA! Vindication of my genius AT LAST!~
IF ~~ THEN DO ~ActionOverride(Player1,DestroyItem("X#XZDRIA"))
ActionOverride(Player2,DestroyItem("X#XZDRIA"))
ActionOverride(Player3,DestroyItem("X#XZDRIA"))
ActionOverride(Player4,DestroyItem("X#XZDRIA"))
ActionOverride(Player5,DestroyItem("X#XZDRIA"))
ActionOverride(Player6,DestroyItem("X#XZDRIA"))
ActionOverride(Player1,DestroyItem("X#XZMIRI"))
ActionOverride(Player2,DestroyItem("X#XZMIRI"))
ActionOverride(Player3,DestroyItem("X#XZMIRI"))
ActionOverride(Player4,DestroyItem("X#XZMIRI"))
ActionOverride(Player5,DestroyItem("X#XZMIRI"))
ActionOverride(Player6,DestroyItem("X#XZMIRI"))
TakePartyGold(1000)
SetGlobal("X#XZRingMade","GLOBAL",1)
SetGlobalTimer("X#XzarRingTime","GLOBAL",36000)~ EXIT
END

IF ~~ X#XZRING1
SAY ~AHA! Vindication of my genius AT LAST!~
IF ~~ THEN EXTERN ~HALBAZ~ AcceptedOfferXzar
END

IF ~~ X#XZRING2
SAY ~To the streets then! We must absorb the good red gold as the sponge absorbs wine.~
IF ~~ THEN DO ~SetGlobalTimer("X#XzarRingNag","GLOBAL",ONE_DAY) SetGlobal("X#XzarNags","GLOBAL",1)~ EXIT
END

IF WEIGHT #-2 ~Global("X#XzarNags","GLOBAL",2)~ THEN BEGIN XzarRingNag1
SAY ~<CHARNAME>! What, if I might make so bolo, is the present status of our financial surplus?~
++ ~Dammit! We're fighting for our lives here! Pay attention!~ + XzarNag1.1
++ ~Uh…lemme just finish up here and I'll check, OK?~ + XzarNag1.2
++ ~ Still on about that ring, huh? Well, we've got the gelt. As soon as we kill our way clear here…~ + XzarNag1.3
++ ~There is none and never will be! Not for that stupid ring. Now get to work here!~ + XzarNag1.4
END

IF ~~ XzarNag1.1
SAY ~Really, <CHARNAME>, had I thought you incapable of dealing with such trivialities independently, I should hardly have permitted you to remain in my company.~
IF ~~ THEN DO ~RealSetGlobalTimer("X#XzarRingNag2","GLOBAL",900) SetGlobal("X#XzarNags","GLOBAL",3)~ EXIT
END

IF ~~ XzarNag1.2
SAY ~Then cease presenting your impression of a statue in the square and GET BUSY!~
IF ~~ THEN DO ~RealSetGlobalTimer("X#XzarRingNag2","GLOBAL",900) SetGlobal("X#XzarNags","GLOBAL",3)~ EXIT
END

IF ~~ XzarNag1.3
SAY ~Oooh! You promised. You PROMISED! I'll kill them all for you! Just watch me!~
IF ~~ THEN DO ~RealSetGlobalTimer("X#XzarRingNag2","GLOBAL",900) SetGlobal("X#XzarNags","GLOBAL",3)~ EXIT
END

IF ~~ XzarNag1.4
SAY ~Pish-Tosh! You may fiddle your drum here if you wish. *I* have more pressing matters to iron out!~
IF ~~ THEN DO ~TakePartyItem("X#XZMIRI") TakePartyItem("X#XZDRIA") TakePartyItem("X#XZSLIM") GiveGoldForce(-200) LeaveParty() EscapeArea() ActionOverride("montaron",LeaveParty()) ActionOverride("montaron",EscapeArea())~ 
EXIT
END

IF WEIGHT #-2 ~Global("X#XzarNags","GLOBAL",4)~ THEN BEGIN XzarRingNag2
SAY ~ Have we got enough money for the ring now? Are we ready? Can we GO? ~
++ ~*sigh* Oh, all right.~ + XzarLoop1
++ ~I'm a little busy right now. Get back to me, will you?~ GOTO Xzar2_nag1
+ ~PartyGoldLT(1000)~ + ~ Sorry, we're not there yet.~ GOTO Xzar2_nag2
++ ~We'll check when we get back there, OK?~ GOTO Xzar2_nag2
++ ~Drop it, Xzar. It isn't going to happen.~ + XzarNag1.4
END

IF ~~ Xzar2_nag1
SAY ~You have the priorities of a baboon. With an 'oon' at each end.~ 
IF ~~ THEN DO ~RealSetGlobalTimer("X#XzarRingNag2","GLOBAL",900) SetGlobal("X#XzarNags","GLOBAL",3)~ EXIT
END

IF ~~ Xzar2_nag2
SAY ~Phyeh!~
IF ~~ THEN DO ~RealSetGlobalTimer("X#XzarRingNag2","GLOBAL",15000) SetGlobal("X#XzarNags","GLOBAL",3)~ EXIT
END

IF ~~ XzarLoop1
SAY ~AHA! Vindication of my genius AT LAST!~
IF ~~ THEN DO ~RealSetGlobalTimer("X#XzarRingNag2","GLOBAL",15000) SetGlobal("X#XzarNags","GLOBAL",3)~ EXIT
END


IF ~~ X#XZRING3
SAY ~You are a cruel <PRO_MANWOMAN>, <CHARNAME>, without heart or soul.~
IF ~ReputationGT(Player1,12)~ THEN DO ~LeaveParty() EscapeArea() ActionOverride(Player1,DestroyItem("X#XZDRIA"))
ActionOverride(Player2,DestroyItem("X#XZDRIA"))
ActionOverride(Player3,DestroyItem("X#XZDRIA"))
ActionOverride(Player4,DestroyItem("X#XZDRIA"))
ActionOverride(Player5,DestroyItem("X#XZDRIA"))
ActionOverride(Player6,DestroyItem("X#XZDRIA"))
ActionOverride(Player1,DestroyItem("X#XZMIRI"))
ActionOverride(Player2,DestroyItem("X#XZMIRI"))
ActionOverride(Player3,DestroyItem("X#XZMIRI"))
ActionOverride(Player4,DestroyItem("X#XZMIRI"))
ActionOverride(Player5,DestroyItem("X#XZMIRI"))
ActionOverride(Player6,DestroyItem("X#XZMIRI"))
ActionOverride("montaron",LeaveParty()) ActionOverride("montaron",EscapeArea())~ EXIT
IF ~!ReputationGT(Player1,12)~ THEN DO ~ReallyForceSpellRES("X#XZSPL","xzar")~ EXTERN HALBAZ CruelCharRing
END

//Nag after the ring was made

IF WEIGHT #-2 ~Global("X#XzarNags","GLOBAL",6)~ THEN BEGIN XzarNag4
SAY ~Oh, the ring. Let me see! GIVE IT TO ME!~
+ ~Gender(Player1,MALE)~ + ~Sure. Here you go. I'm going to put it on your finger in just a moment. Heh, makes me feel like I got meself a gentle bride or something.~ DO ~SetGlobal("X#XzarNags","GLOBAL",7) SetGlobalTimer("X#XzarNagsTime","GLOBAL",900)~ EXIT
+ ~Gender(Player1,FEMALE)~ + ~Sure. Here you go. I'm going to put it on your finger in just a moment. Heh, makes me feel like I got meself a bridegroom or something.~ DO ~SetGlobal("X#XzarNags","GLOBAL",7) SetGlobalTimer("X#XzarNagsTime","GLOBAL",900)~ EXIT
++ ~In a minute. It cost enough, I want to look at it a moment.~ GOTO Xzar4_nag2
++ ~Tough luck being you. I paid and I'm keeping it.~ GOTO Xzar4_nag3
END

IF ~~ Xzar4_nag2
SAY ~Oh, very well. Unnnhhh! That's long enough!~
IF ~~ THEN GOTO XzarNag4
END

IF ~~ Xzar4_nag3
SAY ~My ring, <CHARNAME>. I require it… now!~
++ ~No hysterical fits? You must really want it. Take it then...~ DO ~SetGlobal("X#XzarNags","GLOBAL",7) SetGlobalTimer("X#XzarNagsTime","GLOBAL",900)~ EXIT
++ ~I like you better crazed. Bugger off.~ GOTO Xzar4_nag4
END

IF ~~ Xzar4_nag4 
SAY ~I see.~
IF ~~ THEN DO ~SetGlobalTimer("X#XzarGuards","GLOBAL",ONE_DAY) SetGlobal("X#XzarNags","GLOBAL",9)~ EXIT
END

IF ~Global("X#XzarNags","GLOBAL",8)~ THEN BEGIN XzarNag5
SAY ~My ring. Where is it? I want it!~
++ ~I already gave it to you, Xzar.~ + XzarNag5.1
END

IF ~~ XzarNag5.1
SAY ~Nonsense. Look at my hands. *He shakes his fingers under your nose* Do you see it anywhere? No?~
IF ~~ THEN DO ~SetGlobalTimer("X#XzarNagsTime","GLOBAL",300) SetGlobal("X#XzarNags","GLOBAL",7)~ EXIT
END

//Xzar Charmed Montaron

IF WEIGHT #-2 ~Global("XzarCharmMontaron","GLOBAL",7)~ THEN BEGIN AfterCharm
SAY ~Oh! Er...now don't upset yourself, <CHARNAME>. I've taken it off now. See?~ 
++ ~Give me that ring, you lunatic!~ DO ~SetGlobal("XzarCharmMontaron","GLOBAL",8)~ + XZACHRM1.1
++ ~OK, now you've had your fun, give that to me for safekeeping.~ DO ~SetGlobal("XzarCharmMontaron","GLOBAL",8)~+ XZACHRM1.2
++ ~Try that on me and you're lawn food. Understand?~ DO ~SetGlobal("XzarCharmMontaron","GLOBAL",8)~ + XZACHRM1.3
++ ~*sigh* Why, Xzar, couldn't you have tried that out on a beggar? Or a lamp post?~ DO ~SetGlobal("XzarCharmMontaron","GLOBAL",8)~ + XZACHRM1.4
END

IF ~~ XZACHRM1.1
SAY ~This ring is *mine*.~
++ ~That ring is *ours*. And *I* want to share it. *NOW*! ~ + XZACHRM1.5
++ ~ALL of us paid for that and I don't want you wasting its charge on a whim. Give it to me and you can have it back when you've calmed down.~+ XZACHRM1.6
++ ~Well, its charge is used up today and by tomorrow, you'll be used to it. I hope.~+ XZACHRM1.7
END

IF ~~ XZACHRM1.2
SAY ~Of course. Upon the understanding that I may have it back when necessary.~
IF ~~ THEN DO ~GiveItem("X#XZRING",Player1)~ EXIT
END

IF ~~ XZACHRM1.3
SAY ~Heeheehee! I'll never be deceived into the belief that you like lawns again, dear <PRO_MANWOMAN>.~
IF ~~ THEN DO ~GiveItem("X#XZRING","xzar")~ EXIT
END

IF ~~ XZACHRM1.4
SAY ~ Silly! Beggars are charmed by their wants in any case. And a lamp post? *Could* one charm a lamp post? Perhaps to darken on cue? That *is* a thought... ~
IF ~~ THEN DO ~GiveItem("X#XZRING","xzar")~ EXIT
END

IF ~~ XZACHRM1.5
SAY ~ Very well. 'Study it quickly'; that would be my advice to you, *dear* <CHARNAME>!~
IF ~~ THEN DO ~GiveItem("X#XZRING",Player1)~ EXIT
END

IF ~~  XZACHRM1.6
SAY ~ *That* is one promise I shall not forget, <CHARNAME>.~
IF ~~ THEN DO ~GiveItem("X#XZRING",Player1)~ EXIT
END

IF ~~  XZACHRM1.7
SAY ~  Hmm? Oh, yes. It's as dead as a roc now. If it does not replenish itself on the morrow, I shall hold you fully accountable, <CHARNAME>.~
++ ~Me?!? Who zapped Montaron, you or me? ~+ XZACHRM1.8
END

IF ~~  XZACHRM1.8
SAY ~I did. But *you* should have known I would try some such foolishness and prevented my doing so. Really, <CHARNAME>, I sometimes worry about your impracticality. It is a grave handicap in a leader.~
IF ~~ THEN DO ~GiveItem("X#XZRING","xzar")~ EXIT
END

//Xzar Finale

IF WEIGHT #-2 ~Global("X#XzarNags","GLOBAL",15)~ THEN BEGIN XzRingFinal1
SAY ~Stupid dryad.~
++ ~Huh?~ DO ~SetGlobal("X#XzarNags","GLOBAL",16)~ + XzRingFinal1.1
END

IF ~~ XzRingFinal1.1
SAY ~Why did not she inform me she was so weak? She needn't have died at all.~
++ ~What's got into you?~ + XzRingFinal1.2
END

IF ~~ XzRingFinal1.2
SAY ~That one - reposing soggily over there - I tried this inane ring…and nothing!~
++ ~Well, being dead and all…~ + XzRingFinal1.3
END

IF ~~ XzRingFinal1.3
SAY ~BEFORE death, you idiot. The first time this gaud misfired, I thought it chance…just bad luck. But now I'm certain! The dryad, oak or no, was herself too frail a reed from which to form great magicks. I'll have no more to do with this worthless bauble!~
IF ~~ THEN DO ~DropItem("X#XZRING",[-1.-1])~ EXIT
END

END

//Flaming Fist Scene

BEGIN X#XZGU01
APPEND X#XZGU01

IF ~Global("X#XzarNags","GLOBAL",11)~ THEN BEGIN XzOfficer1
SAY ~Iron, eh? I believe, <PRO_SIRMAAM>, it's me dooty to ask yer to turn out yer belongings.~
++ ~Is it your duty to harass innocent citizens over the ravings of an obvious lunatic, officer?~ DO ~SetGlobal("X#XzarNags","GLOBAL",12)~ GOTO XzOfficer1.1
END

IF ~~ XzOfficer1.1
SAY ~Not normally, no. But iron's a tetchy subject these days. And you're a shifty-looking lot what I never seen before. So I believe I'm going to insist.~
++ ~I'll see you in the Nine Hells first!~ DO ~
ActionOverride("X#XZGU01",Enemy())
ActionOverride("X#XZGU02",Enemy())
ActionOverride("X#XZGU03",Enemy())
ActionOverride("Xzar",LeaveParty())
ActionOverride("Xzar",Enemy())
ActionOverride("Montaron",LeaveParty())
ActionOverride("Montaron",Enemy())
ActionOverride(Player1,DestroyItem("X#XZRING"))
ActionOverride(Player2,DestroyItem("X#XZRING"))
ActionOverride(Player3,DestroyItem("X#XZRING"))
ActionOverride(Player4,DestroyItem("X#XZRING"))
ActionOverride(Player5,DestroyItem("X#XZRING"))
ActionOverride(Player6,DestroyItem("X#XZRING"))
 GiveGoldForce(-200)
~ EXIT
++ ~Oh, very well. This madman is disputing my ownership of this ring but it's innocent enough as you can see for yourself.~ DO ~DestroyItem("X#XZRING") ActionOverride("Xzar",MoveToObject("X#XZGU01"))~ EXTERN XZARJ XzarOfficerChain
END

END

CHAIN IF ~Global("X#XzarNags","GLOBAL",12)~ THEN XZARJ XzarOfficerChain
~ *To your surprise, Xzar leaps forward and snatches the ring from the fingers of the astonished Fist.*~
DO ~SetGlobal("X#XzarNags","GLOBAL",13)~
== ~XZARJ~ ~My Precious! I thank you, officer, for your able, if half-witting, assistance in the recovery of my property. Come, Montaron! We shall away to pastures new."~
DO ~ GiveGoldForce(-200) 
ActionOverride("Xzar",LeaveParty())
ActionOverride("Xzar",EscapeArea())
ActionOverride("Montaron",LeaveParty())
ActionOverride("Montaron",EscapeArea())
ActionOverride(Player1,DestroyItem("X#XZRING"))
ActionOverride(Player2,DestroyItem("X#XZRING"))
ActionOverride(Player3,DestroyItem("X#XZRING"))
ActionOverride(Player4,DestroyItem("X#XZRING"))
ActionOverride(Player5,DestroyItem("X#XZRING"))
ActionOverride(Player6,DestroyItem("X#XZRING"))~
== X#XZGU01 ~Whew! I believe I'm going to leave this little affair out of me report tonight. That feller's still in the city tomorrow, someone else can have the pleasure.~
END
++ ~I believe that is a wise decision, sir.~ DO ~ActionOverride("X#XZGU01",EscapeArea()) ActionOverride("X#XZGU02",EscapeArea()) ActionOverride("X#XZGU03",EscapeArea())~
EXIT

CHAIN IF ~OR(2) Global("XzarCharmMontaron","GLOBAL",5) Global("XzarCharmMontaron","GLOBAL",1)~ THEN XZARJ XzarCharmMonty2
~It worked! I DID IT! I, Xzar, the allegedly repellant necromancer, have CHARMED someone! And not just anyone but the homicidal, psychopathic halfling, Montaron!~
== ~MONTAJ~ ~I'm hungry. Where's the walrus titties at?~
== ~XZARJ~  ~HA! HA! HA! HA! HA!~
DO~SetGlobal("XzarCharmMontaron","GLOBAL",6)~ EXIT


ADD_STATE_TRIGGER ~DRYAD~ 6 ~OR(2) !InParty("Xzar") Dead("Xzar")~
ADD_STATE_TRIGGER ~DRYAD~ 7 ~OR(2) !InParty("Xzar") Dead("Xzar")~
ADD_STATE_TRIGGER ~DRYAD~ 8 ~OR(2) !InParty("Xzar") Dead("Xzar")~

CHAIN IF ~Dead("caldo") Dead("krumm") Global("AskedDryad","GLOBAL",0) InParty("Xzar") !Dead("Xzar") Global("X#XzarDryad","GLOBAL",0)~ THEN ~DRYAD~ X#XZDRYAD0
~Thanks be to you! ~
== ~XZARJ~ ~Lovely, isn't she? Do you know, <CHARNAME>, I believe I still have - I do! Here it is! - a container that has been specifically enchanted to preserve the blood essence of creatures such as this.~
= ~It's employment would be most apposite at this juncture, would it not?~
== JAHEIJ IF ~InParty("jaheira") !Dead("jaheira") !StateCheck("jaheira",STATE_SLEEPING)~ THEN ~<CHARNAME>! I cannot let this Zhent murder a creature of the woods! I do not relish breaking my oath to Gorion so do not agree to this atrocity!~
== KHALIJ IF ~InParty("jaheira") !Dead("jaheira") !StateCheck("jaheira",STATE_SLEEPING) IsValidForPartyDialogue("Khalid")~ THEN ~I will always stand by Jaheira’s side in this.~
== FALDOJ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Grr! It's long past time that Nature's fury found you, necromancer! Show whose side you are on, <CHARNAME>!~
== KIVANJ IF ~InParty("kivan") !Dead("kivan") !StateCheck("kivan",STATE_SLEEPING)~ THEN ~I will not stand idly if you should not restrain this evil man, <CHARNAME>.~
== MINSCJ IF ~InParty("minsc") !Dead("minsc") !StateCheck("minsc",STATE_SLEEPING)~ THEN ~Aargh! The small stinky man wants to hurt a beautiful dryad! Boo's shaking in outrage!~
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~In the name of Good, I will not let you conspire to slaughter this innocent spirit! My honour tells me to defend the forest creature!~
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~The vileness of his intent is clear, <CHARNAME>. Thou must stop this madman.~
END
++ ~Leave her be. She's not hurting anyone.~ DO ~SetGlobal("X#XzarDryad","GLOBAL",1)~ EXTERN ~XZARJ~ X#XZDRYAD1
++ ~Yeah! Let's do it!~ DO ~SetGlobal("X#XzarDryad","GLOBAL",2)~ EXTERN ~DRYAD~ X#XZDRYAD2

CHAIN IF ~Global("X#XzarDryad","GLOBAL",2)~ THEN ~DRYAD~ X#XZDRYAD2
~But…why…you helped me! Why?~
== ~XZARJ~ ~One help for another, blithe spirit. You owe me a life and I shall use it well!~
END
IF ~~ THEN DO ~SetGlobal("X#XzarDryad","GLOBAL",4)~
EXIT


APPEND ~DRYAD~ 

IF ~Global("X#XzarDryad","GLOBAL",5)~ THEN BEGIN X#DryadDeath
SAY ~No... no... my lifeblood... my soul... I am dying...~
IF ~~ THEN DO ~SetGlobal("X#XzarDryad","GLOBAL",6) Enemy()
ActionOverride("jaheira",LeaveParty()) ActionOverride("jaheira",Enemy())
ActionOverride("kivan",LeaveParty()) ActionOverride("kivan",Enemy())
ActionOverride("faldorn",LeaveParty()) ActionOverride("faldorn",Enemy())
ActionOverride("minsc",LeaveParty()) ActionOverride("minsc",Enemy())
ActionOverride("khalid",LeaveParty()) ActionOverride("khalid",Enemy())
ActionOverride("ajantis",LeaveParty()) ActionOverride("ajantis",Enemy())
ActionOverride("dynaheir",LeaveParty()) ActionOverride("dynaheir",Enemy())
  SetGlobal("X#SummonForest","GLOBAL",1)
~ SOLVED_JOURNAL ~Xzar, my companion, draind blood of a Dryad in the Cloudpeak mountains. She then attacked us, stupid cow.~
EXIT
END
END

APPEND XZARJ

//Forest Spirits
IF ~Global("X#SummonForest","GLOBAL",2)~ THEN BEGIN X#DryadDeath1
SAY ~Ah-hah! The tree dies and the crystal glows like burning maggots…I have done it!~
IF ~~ THEN DO ~SetGlobal("X#SummonForest","GLOBAL",3)~ EXIT
END

IF ~Global("X#SummonForest","GLOBAL",6)~ THEN BEGIN X#DryadDeath2
SAY ~Did you hear that? Isn’t that wonderful?~
++ ~What? Wonderful that they’re going to call a pack of wolves, come and chew our legs off?~ DO ~SetGlobal("X#SummonForest","GLOBAL",7)~ + XZFS1
END

IF ~~ XZFS1
SAY ~Really, <CHARNAME>! Weren’t you *listening*?~
++ ~Well, they agreed you collected your dryad gunk effectively. But you already knew that.~ + XZFS2
END

IF ~~ XZFS2
SAY ~No, no, no! Those were *ghosts*! The first I have ever seen - in an unsummoned, unfettered condition, that is. Their existence here – and their concerns – suggests the whole lyrical cycle of Nature; life to death, death eternally begetting life in an oscillating rhythm of immense beauty and power. ~
++ ~Huh? I’d have never guessed that *you* would be so moved by all this.~ + XZFS3
END

IF ~~ XZFS3
SAY ~Who could not be? Why, do you realize that by a very simple extension of the process with the dryad, I could capture *all* this in…well, I should need a larger container of course.~
++ ~Ah, that sounds more like yourself, Xzar. But tell me, what would be left of these natural beauties after your ritual?~ + XZFS4
END

IF ~~ XZFS4
SAY ~*Shrug* The biggest stones, I suppose. Perhaps little blackened, ashen bits of things. What would *I* care if I could master such power?~
= ~*sigh* But that must be for later. For now, <CHARNAME>, let us continue our travels, our travails and our pursuit of dreams.~
IF ~~ THEN EXIT
END

//Found Mithril Ring
IF ~Global("X#XzarMithrilRing","GLOBAL",1)~ THEN BEGIN XZMithril1
SAY ~Toor-a-loor-a-loor-ay… ~
++ ~Uh…Xzar, what are looking for there?~ DO ~SetGlobal("X#XzarMithrilRing","GLOBAL",2)~ + XZMI1.1
END

IF ~~ XZMI1.1
SAY ~Looking for? Nothing…well, the crushed neck bones of a hanged man would be nice.~
++ ~Found anything?~ + XZMI1.2
END

IF ~~ XZMI1.2
SAY ~No...but you may have. That gaud…may I see it? Yes, mithril, I judge…I have seen them before. So useful if I…that is, *we*…should want to enchant anything.~
++ ~Is it magical?~ + XZMI1.3
END

IF ~~ XZMI1.3
SAY ~No, not magical…yet. That is its merit. No one has botched it already, you see.~
++ ~Either way, it’s party treasure. Give it back.~ + XZMI1.4
END

IF ~~ XZMI1.4
SAY ~I think not. You might lose it…or sell it for food at a time when I, personally, am not even hungry.~
++ ~ALL treasure is the common property of *all* of us. *No* hoarding.~ + XZMI1.5
+ ~!PartyHasItem("X#XZDRIA")~ + ~Uh-huh. When – and into what – do *you* propose to enchant it?~ + XZMI1.6
+ ~PartyHasItem("X#XZDRIA")~ + ~Uh-huh. When – and into what – do *you* propose to enchant it?~ + XZMI1.7
END

IF ~~ XZMI1.5
SAY ~Hmph! Here then! Just be certain – very certain – that it is available when wanted, *dear* <CHARNAME>!~
IF ~~ THEN EXIT
END

IF ~~ XZMI1.6
SAY ~The 'what' will see to itself. We meet so many delightful creatures such as the one whose sloshy remains even now are staining my footwear.~
= ~'When' will depend upon a bit more silence from yourself; a cessation of your usual silly questions and pointless nagging. Honestly, <CHARNAME>, most days I should rather talk to my socks. Especially the left one which is becoming rather damp at the moment.~
++ ~Just move your stupid foot. Okay?~ + XZMI1.5
++ ~I’d rather trust me with it. *You* would drop it in a leprechaun’s ear for safekeeping.~ + XZMI1.8
++ ~Have it then. I am actually curious to see what *you* will make of it.~ + XZMI1.9
END

IF ~~ XZMI1.7
SAY ~The 'when', dear <CHARNAME>, shall depend upon yourself. Upon your extremely limited ability to keep silence during another’s interval of study and reflection.~
= ~As to 'what'... *Xzar holds aloft the dryad’s blood* This Nature essence will blend wonderfully well with the mineral if I am any prophet.~
++ ~Uh-huh. *I* prefer profit to prophets, myself.~ + XZMI1.5
++ ~I’d rather trust me with it. *You* would drop it in a leprechaun’s ear for safekeeping.~ + XZMI1.8
++ ~Have it then. I am actually curious to see what *you* will make of it.~ + XZMI1.10
END

IF ~~ XZMI1.8
SAY ~Don’t be silly, <CHARNAME>. Every child knows that there are no such things as leprechauns.~
IF ~~ THEN DO ~GiveItem("X#XZMIRI",Player1)~ EXIT
END

IF ~~ XZMI1.9
SAY ~Don’t be silly, <CHARNAME>. I would never embark upon so vital a thaumaturgy without…Guidance.~
IF ~~ THEN DO ~GiveItem("X#XZMIRI","xzar")~ EXIT
END

IF ~~ XZMI1.10
SAY ~Why, an artifact to make all living Nature shriek with pain and horror in the face of immanent and irreversible Death, of course. Why else would I bother? ~
IF ~~ THEN DO ~GiveItem("X#XZMIRI","xzar")~ EXIT
END

END

CHAIN IF ~Global("X#SummonForest","GLOBAL",4)~ THEN X#XZFSP1 ForestSpiritsMourn
~Alas! Another to mourn. Another to mourn.~
== X#XZFSP2 ~But we cannot. Our sister's spirit is yet enslaved, even in Death.~
== X#XZFSP3 ~It is so. We must inform our mortal friends of this outrage.~
END
IF ~~ THEN
DO ~CreateVisualEffectObject("SPFLSRIN","XZFSPIRIT1")
Wait(1)
CreateVisualEffectObject("SPFLESHS","XZFSPIRIT1")
ActionOverride("XZFSPIRIT1",DestroySelf())

CreateVisualEffectObject("SPFLSRIN","XZFSPIRIT2")
Wait(1)
CreateVisualEffectObject("SPFLESHS","XZFSPIRIT2")
ActionOverride("XZFSPIRIT2",DestroySelf())

CreateVisualEffectObject("SPFLSRIN","XZFSPIRIT3")
Wait(1)
CreateVisualEffectObject("SPFLESHS","XZFSPIRIT3")
ActionOverride("XZFSPIRIT3",DestroySelf())
SetGlobal("X#SummonForest","GLOBAL",5)~ EXIT


CHAIN IF ~Global("X#XzarDryad","GLOBAL",1)~ THEN ~XZARJ~ X#XZDRYAD1
~Not hurting? Well, no; but she's not helping us any, is she?~
== ~DRYAD~ ~Eeehh! These mortals be more wicked than the last!~
END
IF ~~ THEN DO ~SetGlobal("X#XzarDryad","GLOBAL",3)AddexperienceParty(500) EscapeAreaDestroy(5)
~ SOLVED_JOURNAL ~I tried to help a Dryad in the Cloudpeak mountains. Pleasing such nature spirits would normally bring me no end of luck, yet Xzar sort of mucked up the overoll impression....~  EXTERN _XZARJ XzarDryadLast1

CHAIN XZARJ XzarDryadLast1
~Oh, termite fudge! She’s gone now! *sigh* And so another research effort fails for want of proper support!~
EXIT


//Second Case

CHAIN IF ~Dead("caldo") Dead("krumm") Global("AskedDryad","GLOBAL",1)InParty("Xzar") !Dead("Xzar") Global("X#XzarDryad","GLOBAL",0)~ THEN ~DRYAD~ X#XZDRYADA
~I thank you, though grudgingly.~
== ~XZARJ~ ~Lovely, isn't she? Do you know, <CHARNAME>, I believe I still have - I do! Here it is! - a container that has been specifically enchanted to preserve the blood essence of creatures such as this.~
= ~It's employment would be most apposite at this juncture, would it not?~
== JAHEIJ IF ~InParty("jaheira") !Dead("jaheira") !StateCheck("jaheira",STATE_SLEEPING)~ THEN ~<CHARNAME>! I cannot let this Zhent murder a creature of the woods! I do not relish breaking my oath to Gorion so do not agree to this atrocity!~
== KHALIJ IF ~InParty("jaheira") !Dead("jaheira") !StateCheck("jaheira",STATE_SLEEPING) IsValidForPartyDialogue("Khalid")~ THEN ~I will always stand by Jaheira’s side in this.~
== FALDOJ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Grr! It's long past time that Nature's fury found you, necromancer! Show whose side you are on, <CHARNAME>!~
== KIVANJ IF ~InParty("kivan") !Dead("kivan") !StateCheck("kivan",STATE_SLEEPING)~ THEN ~I will not stand idly if you should not restrain this evil man, <CHARNAME>.~
== MINSCJ IF ~InParty("minsc") !Dead("minsc") !StateCheck("minsc",STATE_SLEEPING)~ THEN ~Aargh! The small stinky man wants to hurt a beautiful dryad! Boo's shaking in outrage!~
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~In the name of Good, I will not let you conspire to slaughter this innocent spirit! My honour tells me to defend the forest creature!~
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~The vileness of his intent is clear, <CHARNAME>. Thou must stop this madman.~
END
++ ~Leave her be. She's not hurting anyone.~ DO ~SetGlobal("X#XzarDryad","GLOBAL",1)~ EXTERN ~XZARJ~ X#XZDRYAD3
++ ~Yeah! Let's do it!~ DO ~SetGlobal("X#XzarDryad","GLOBAL",2)~ EXTERN ~DRYAD~ X#XZDRYAD2

CHAIN IF ~Global("X#XzarDryad","GLOBAL",1)~ THEN ~XZARJ~ X#XZDRYAD3
~Not hurting? Well, no; but she's not helping us any, is she? And another research effort fails for want of proper support.~
== ~DRYAD~ ~Eeehh! These mortals be more wicked than the last!~
END
IF ~~ THEN DO ~SetGlobal("X#XzarDryad","GLOBAL",3)AddexperienceParty(500) EscapeAreaDestroy(5)
~ SOLVED_JOURNAL ~I tried to help a Dryad in the Cloudpeak mountains. Pleasing such nature spirits would normally bring me no end of luck, yet Xzar sort of mucked up the overall impression....~  EXTERN XZARJ XzarDryadLast1


//Third Case

CHAIN IF ~Dead("caldo") Dead("krumm") Global("AskedDryad","GLOBAL",2) InParty("Xzar") !Dead("Xzar") Global("X#XzarDryad","GLOBAL",0)~ THEN ~DRYAD~ X#XZDRYADB
~You have done as you said you would.~
== ~XZARJ~ ~Lovely, isn't she? Do you know, <CHARNAME>, I believe I still have - I do! Here it is! - a container that has been specifically enchanted to preserve the blood essence of creatures such as this.~
= ~It's employment would be most apposite at this juncture, would it not?~
== JAHEIJ IF ~InParty("jaheira") !Dead("jaheira") !StateCheck("jaheira",STATE_SLEEPING)~ THEN ~<CHARNAME>! I cannot let this Zhent murder a creature of the woods! I do not relish breaking my oath to Gorion so do not agree to this atrocity!~
== KHALIJ IF ~InParty("jaheira") !Dead("jaheira") !StateCheck("jaheira",STATE_SLEEPING) IsValidForPartyDialogue("Khalid")~ THEN ~I will always stand by Jaheira’s side in this.~
== FALDOJ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Grr! It's long past time that Nature's fury found you, necromancer! Show whose side you are on, <CHARNAME>!~
== KIVANJ IF ~InParty("kivan") !Dead("kivan") !StateCheck("kivan",STATE_SLEEPING)~ THEN ~I will not stand idly if you should not restrain this evil man, <CHARNAME>.~
== MINSCJ IF ~InParty("minsc") !Dead("minsc") !StateCheck("minsc",STATE_SLEEPING)~ THEN ~Aargh! The small stinky man wants to hurt a beautiful dryad! Boo's shaking in outrage!~
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~In the name of Good, I will not let you conspire to slaughter this innocent spirit! My honour tells me to defend the forest creature!~
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~The vileness of his intent is clear, <CHARNAME>. Thou must stop this madman.~
END
++ ~Leave her be. She's not hurting anyone.~ DO ~SetGlobal("X#XzarDryad","GLOBAL",1)~ EXTERN ~XZARJ~ X#XZDRYAD4
++ ~Yeah! Let's do it!~ DO ~SetGlobal("X#XzarDryad","GLOBAL",2)~ EXTERN ~DRYAD~ X#XZDRYAD2

CHAIN IF ~Global("X#XzarDryad","GLOBAL",1)~ THEN ~XZARJ~ X#XZDRYAD4
~Not hurting? Well, no; but she's not helping us any, is she? And another research effort fails for want of proper support.~
== ~DRYAD~ ~Eeehh! These mortals be more wicked than the last!~
= ~As... as for the price you have exacted...  Directions to the cache, and a cold farewell.  Do not stay long in my wood.  You are not welcome.  You will find the treasure cache in the wolf cave just hundred feet south of my tree.~
END
IF ~~ THEN DO ~SetGlobal("X#XzarDryad","GLOBAL",3)AddexperienceParty(500) EscapeAreaDestroy(5)
~ SOLVED_JOURNAL ~I have angered a Dryad near the Cloudpeaks, and have been warned out of "her" wood.  Xzar with his crazy ideas did not help any. Ah, well, it's of little concern.  She also directed me to look into a wolf cave just to the south, where a treasure cache hidden.~ EXTERN XZARJ XzarDryadLast1

// Druids

BEGIN ~X#BLACK~
APPEND X#BLACK
IF ~Global("X#XzarDruidsExist","GLOBAL",0)~ THEN BEGIN BlackFile
SAY ~Hi, I am Blackberry.~
IF ~~ THEN EXIT
END
END

BEGIN ~X#STORM~
APPEND X#STORM
IF ~Global("X#XzarDruidsExist","GLOBAL",0)~ THEN BEGIN StormFile
SAY ~Hi, I am Storm.~
IF ~~ THEN EXIT
END
END

BEGIN ~X#ZOSYA~
APPEND X#ZOSYA
IF ~Global("X#XzarDruidsExist","GLOBAL",0)~ THEN BEGIN ZosyaFile
SAY ~Hi, I am Zosya.~
IF ~~ THEN EXIT
END
END

CHAIN IF ~Global("X#XzarDruidsExist","GLOBAL",1)~ THEN X#BLACK X#DruidsXzarDialogue
~Stay your passage, travelers. We are investigating the foulest murder.~
== X#STORM ~Yes. These are the ones. I can smell dryad's blood on them.~
== X#ZOSYA ~You are as careless as you are evil for we followed you easily from the wreckage of the dryad's tree - the dryad whom you wantonly slew.~
== ~XZARJ~ ~The wretched woman lived in a tree. Without a door, even. How was I to know you'd take it personally?~
== X#ZOSYA ~You had confessed the crime. There can only be one punishment for killing a dryad and the sentient Oak  - death.~
== X#STORM ~I sense that the Great Mother herself is with us in this fight!~
DO ~SetGlobal("X#XzarDruidsExist","GLOBAL",2) ~
EXIT


