BEGIN ~X#Viconia~

APPEND ~BVICON~

IF WEIGHT #-2 ~
Global("ViFriendTalk","GLOBAL",1)
Global("VIPC1","LOCALS",0)~ THEN BEGIN VIPC1
SAY ~The light! It burns!~  [VICON99]
= ~Among the drow, we have a saying ... ssussun pholor dos: brightness upon you. And it's considered a powerful curse. <CHARNAME>, I've told you before that I would go where you wish, so long as you keep me from this accursed sun. I ... Truly, I cannot bear its gaze.~  [VICON99]
IF ~~ THEN REPLY ~Sorry, Viconia. We can't always travel by night, but I can try to be a bit more accommodating.~  DO ~SetGlobal("VIPC1","LOCALS",1)~ GOTO VIPC1.1
IF ~~ THEN REPLY ~You know, Viconia, if you're going to live on the surface, you're going to have to get used to the sun.~  DO ~SetGlobal("VIPC1","LOCALS",1)~ GOTO VIPC1.2
IF ~~ THEN REPLY ~Could you stop wailing like that? Do you think the rest of us enjoy hearing that?~ DO ~SetGlobal("VIPC1","LOCALS",1)~ GOTO VIPC1.3
END

IF ~~ THEN BEGIN VIPC1.1
SAY ~I should hope so. If not I will surely wilt under the burning oppression of your ... daylight.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN VIPC1.2
SAY ~Pfeh, the thought is utterly repulsive to me. I simply don't know if I'll ever feel at home beneath this burning blaze.~
IF ~~ THEN REPLY ~It should come with time. Just stick it out.~  GOTO VIPC1.4
IF ~~ THEN REPLY ~No. Maybe you won't. But either way you've got live with it.~  GOTO VIPC1.4
IF ~~ THEN REPLY ~Cut the melodrama, would you? Suffer more quietly, for the sake of my sanity.~  GOTO VIPC1.3
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN VIPC1.3
SAY ~My apologies. I have overstepped my bounds, it seems. I yet have much to learn about this world of yours…~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN VIPC1.4
SAY ~I believe there may be wisdom in your words, <CHARNAME>. Though it burns me all the same, perhaps I can grow to tolerate it. I need not be so insufferably weak, in any case.~
IF ~~ THEN EXIT
END

IF WEIGHT #-2 ~
Global("ViFriendTalk","GLOBAL",3)
Global("VIPC2","LOCALS",0)~ THEN BEGIN VIPC2
SAY ~Your surface notions of companionship are yet very foreign to me, <CHARNAME>. Your Imoen, for example. I ... away from prying ears, I must comment that I truly don't think that, were the decision mine to make, I would bring the girl along as you have.~
= ~While she has her functions, I'm not of the mind that they are truly worth the trouble of her. Then again, I acknowledge that I am drow, and think differently from you. What is the reasoning, <CHARNAME>? Why do you take the girl along?~  [VICON99]
IF ~~ THEN REPLY ~Imoen's much more than a member of the party. She's an old friend.~  DO ~SetGlobal("VIPC2","LOCALS",1)~ GOTO VIPC2.1
IF ~~ THEN REPLY ~Maybe she can be obnoxious, but she's useful enough to outweigh that.~ DO ~SetGlobal("VIPC2","LOCALS",1)~ GOTO VIPC2.2
IF ~~ THEN REPLY ~She's like a sister to me, and there's a devotion there that goes beyond any concerns of how useful or annoying she is.~  DO ~ SetGlobal("VIPC2","LOCALS",1)~ GOTO VIPC2.3
IF ~~ THEN REPLY ~It's a good question. I don't know why I do take her along.~  DO ~SetGlobal("VIPC2","LOCALS",1)~ GOTO VIPC2.4
END

IF ~~ THEN BEGIN VIPC2.1
SAY ~An old friend? Pfeh, truly <CHARNAME>, do you expect me to believe that you would consider her value to you as a ... a "friend" before you would consider her stake in keeping us alive?~
IF ~~ THEN REPLY ~Yes. What's so hard to believe about that?~  GOTO VIPC2.8
IF ~~ THEN REPLY ~Viconia, I care for Imoen. Maybe that's difficult for a drow to understand, but that's how it is.~ GOTO VIPC2.8
IF ~~ THEN REPLY ~Yes, I would. And I won't have you evaluating Imoen like this, or bringing any harm to her.~ GOTO VIPC2.7
IF ~~ THEN REPLY ~Heh, well, not really. ~ GOTO VIPC2.4
END

IF ~~ THEN BEGIN VIPC2.2
SAY ~I would beg to differ, personally. I don't see her putting forth any contributions worth the strain she puts on my nerves. But you are in charge of this party, <CHARNAME>, and it's your judgment to make in that regard.~
= ~Truly, then? You keep the girl around for her talents?~
IF ~~ THEN REPLY ~Yes. She is a skilled member of this party.~  GOTO VIPC2.5
IF ~~  THEN REPLY ~What more can I say? She does her job well.~ GOTO VIPC2.5
IF ~~  THEN REPLY ~Well, she's not here for her skill alone, I suppose.~ GOTO VIPC2.6
END

IF ~~ THEN BEGIN VIPC2.3
SAY ~Sister, you say? Devotion? You'll have to understand when I tell you that surface ways do seem utterly foolish.~
= ~In my home, my dalninilen -- my sisters, as you say -- certainly bore no devotion to me, nor I to them. We were rivals at best, and bitter enemies at worst.~
IF ~~ THEN REPLY ~That was the Underdark. Things are different here.~  GOTO VIPC2.8
IF ~~ THEN REPLY ~Well, Imoen and I aren't like your siblings. We're close friends, and loyal to each other. ~ GOTO VIPC2.8
IF ~~ THEN REPLY ~Don't get any ideas about such competition. I won't have you harming Imoen.~ GOTO VIPC2.7
END

IF ~~ THEN BEGIN VIPC2.4
SAY ~So you see the foolishness of your ways? Truly, <CHARNAME>, I can see why you might bear ... fondness ... for the child, but she is more of a liability to us all. Perhaps she should be let go.~
IF ~~ THEN REPLY ~Maybe you're right. I'll think on it.~  EXIT
IF ~~ THEN REPLY ~No, Viconia. Imoen's staying, and I'll not have you bringing any harm to her.~ GOTO VIPC2.7
END

IF ~~ THEN BEGIN VIPC2.5
SAY ~Hm. Interesting. This world may not, after all, be so very different from my home than I had once thought.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN VIPC2.6
SAY ~What is it then? What merits your continued acceptance of her?~
IF ~~ THEN REPLY ~Imoen's much more than a member of the party. She's an old friend.~  GOTO VIPC2.1
IF ~~ THEN REPLY ~She's like a sister to me, and there's a devotion there that goes beyond any concerns of how useful or annoying she is.~ GOTO VIPC2.3
IF ~~ THEN REPLY ~It's a good question. I don't know why I do take her along.~  GOTO VIPC2.4
END

IF ~~ THEN BEGIN VIPC2.7
SAY ~... calm yourself, <CHARNAME>. I won't think of harming your girl, so long as none of you would harm me. Feh! Let us move on. Quickly.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN VIPC2.8
SAY ~Surface notions are so very peculiar. I am a drow ... perhaps I am not meant to understand them. ~
IF ~~ THEN EXIT
END

///dream script///
IF WEIGHT #-2 ~
Global("VIPC3","LOCALS",1)~ THEN BEGIN VIPC3
SAY ~I suppose that I've never offered you the proper thanks, <CHARNAME>, for having rescued me and taken me in as you have. I've been very ... thoughtless in that regard.~ [VICON99]
= ~Bel'la dos, ussta abbil. Here's to a fruitful companionship. May our enemies fall before our might!~
IF ~~ THEN REPLY ~You're most welcome, Viconia.~ DO ~SetGlobal("VIPC3","LOCALS",2)~ GOTO VIPC3.1
IF ~~ THEN REPLY ~You're welcome. Just be sure you pull your weight, or you're out.~ DO ~SetGlobal("VIPC3","LOCALS",2)~ GOTO VIPC3.2
IF ~Gender(Player1,MALE)~ THEN REPLY ~Thank me? I've heard of ways the drow might repay debts.~ DO ~SetGlobal("VIPC3","LOCALS",2)~ GOTO VIPC3.3
IF ~~ THEN REPLY ~And if they do not fall, they'll at least tremble. I'm liking you already, drow.~ DO ~SetGlobal("VIPC3","LOCALS",2)~ GOTO VIPC3.4
END

IF ~~ THEN BEGIN VIPC3.1
SAY ~Welcome? I am welcome. It has a pleasing ring to it, <CHARNAME>.~
= ~Ulu z'hin maglust dal qu'ellar lueth valsharess zhah ulu z'hin wund lil phalar. Though I walk now apart from House and Queen, my pairing with this group may yet keep me from the grave. <CHARNAME> ultrin!~
IF ~~ THEN DO ~RestParty()~
EXIT
END

IF ~~ THEN BEGIN VIPC3.2
SAY ~But surely. I would certainly not expect free shelter from you. Rest assured, my skills will serve you well.~
= ~Ulu z'hin maglust dal qu'ellar lueth valsharess zhah ulu z'hin wund lil phalar. Though I walk now apart from House and Queen, my pairing with this group may yet keep me from the grave. <CHARNAME> ultrin!~
IF ~~ THEN DO ~RestParty()~
EXIT
END

IF ~~ THEN BEGIN VIPC3.3
SAY ~*She pauses for a moment, as if the suggestion has caught her off guard. A sigh of disdain escapes her, but by the time her eyes meet <CHARNAME>'s, her expression is taken over by wicked bemusement.*~
= ~Of course. I had forgotten how the surfacers' minds are ever captivated by my kind. Very well, <RACE>, you may have your repayment, if you so wish.~
IF ~~ THEN DO ~RestParty()~
EXIT
END

IF ~~ THEN BEGIN VIPC3.4
SAY ~Such is the spirit that will keep m- ... keep us alive.~
= ~Ulu z'hin maglust dal qu'ellar lueth valsharess zhah ulu z'hin wund lil phalar. Though I walk now apart from House and Queen, my pairing with this group may yet keep me from the grave. <CHARNAME> ultrin!~
IF ~~ THEN DO ~RestParty()~
EXIT
END

END

///////////////////////Dream Script///////////////////////////////
CHAIN
IF WEIGHT #-2 ~Global("VISA1","LOCALS",1)~ THEN ~BVICON~ VISA1
~Jaluk! Male! I thirst. Fetch me another drink!~ [VICON99]
DO ~SetGlobal("VISA1","LOCALS",2)~
== ~BSAFAN~ ~Viconia, darling, perhaps you've had a bit too much.~
== ~BVICON~ ~Pfeh, nonsense! I've not felt so empowered since before I left my old home ... Where has that jaluk gone?~
== ~BSAFAN~ ~He's probably run off in terror like the others. I might have too, had a drow sworn at me and told me she would cut out my tongue. You're losing your knack, dear, perhaps you should sleep this off.~
== ~BVICON~ ~For his own good, he should run as fast as possible. That one's insolence was intolerable, and I truly will cut out his tongue should he bring it back here once again.~
= ~I *do* tire of the company of these rivven, Safana. You may be right: I should get some rest.~
== ~BSAFAN~ ~Don't forget the hard-earned spoils, now.~
== ~BVICON~ ~Of course not. Nindolen rivven phuul ji waelen...~ 
DO ~CreateItem("AMUL10",0,0,0)
CreateItem("RING12",0,0,0)
RestParty()~
EXIT

//////////DREAM SCRIPT/////
CHAIN
IF WEIGHT #-2 ~
Global("VIEL1","LOCALS",1)~ THEN ~BVICON~ VIEL1
~Male, fetch me something to eat.~ [VICON99]
DO ~SetGlobal("VIEL1","LOCALS",2)~
== ~BELDOT~ ~My dear, do pipe down. Some of the more civilized members of this party are trying to think. Don't interrupt us with your primitive search for food.~
== ~BVICON~ ~Were we in the Underdark, you would surely be killed for your arrogance. 'Tis a pity it cannot be so here. All the same, you would do well to watch your tongue, jaluk.~
== ~BELDOT~ IF ~InParty("SKIE")~ THEN ~Yes, yes, whatever you say, my dark little beauty. If you're truly interested in living on the surface, go consult with Skie on knitting or baking cakes or all the other things women love to cluck on about.~
== ~BELDOT~ IF ~!InParty("SKIE")~ THEN ~Yes, yes, whatever you say, my dark little beauty. If you're truly interested in living on the surface, perhaps you should take up knitting, or learn to bake. And, most importantly, never talk to a man unless asked first.~
== ~BVICON~ ~Pfeh! Be wary, jaluk. I won't be placed in your surface woman's subservience ... and I don't take insult lightly.~
DO ~RestParty()~
EXIT


/////////////////////////////////////////////_______NPC/NPC banters____________///////////////////////////////////////////

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("AJANTIS")
See("AJANTIS")
!StateCheck("AJANTIS",STATE_SLEEPING)
Global("VIAJ1","LOCALS",0)~ THEN ~BVICON~ VIAJ1
~Might I be correct, Ajantis, to assume that you have never seen one such as I?~ [VICON99]
DO ~SetGlobal("VIAJ1","LOCALS",1)~
== ~BAJANT~ ~I have seen all too many of your kind before. I know well the ways of the wicked.~
== ~BVICON~ ~You insipid fool, I was referring not to my place in your limited moral spectrum, but rather to my being a drow.~
== ~BAJANT~ ~Then the answer is no, though I still know your ways inside and out. You are irredeemably evil, and that will one day be your downfall. It weighs heavily on my heart to know this, but 'tis true all the same.~
== ~BVICON~ ~Your naivete will be *your* downfall, waela rivvil.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("BRANWEN")
See("BRANWEN")
!StateCheck("BRANWEN",STATE_SLEEPING)
Global("VIBR1","GLOBAL",0)~ THEN ~BVICON~ VIBR1
~I see in you a ferocity rivaling that of the yathren I once knew below the surface. Perhaps not all of the rivvil women are weak and fawning.~ [VICON99]
DO ~SetGlobal("VIBR1","GLOBAL",1)~
== ~BBRANW~ ~You speak to me of battle, drow? 'Tis rather unsettling to me that you see fit to group the talent of a warrior bold with the fearsome tactics of your kindred.~
== ~BVICON~ ~My words were intended as a compliment, priestess, and were you not so blinded by your hollow surface predeterminations you might have seen it for such.~
== ~BBRANW~ ~I know you meant good by your words, but I simply cannot draw honor from comparison to such notoriously cowardly ways.~
== ~BVICON~ ~It seems I may have been foolish in my evaluation of you.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("BRANWEN")
See("BRANWEN")
!StateCheck("BRANWEN",STATE_SLEEPING)
Global("VIBR1","GLOBAL",1)
Global("VIBR2","GLOBAL",0)~ THEN ~BVICON~ VIBR2
~I observed again the blind fervor with which you approach combat. It is an undeniably strange trait, to bear so much cheerful zeal in such situations.~ [VICON99]
DO ~SetGlobal("VIBR2","GLOBAL",1)~
== ~BBRANW~ ~All strong warriors revel in the heat of battle. There is nothing nobler.~
== ~BVICON~ ~You have failed to impart any sense upon the situation, rivvil, though I had not suspected you would. What is so noble to you about warfare? I had thought that most rivven at least feigned belief in the surface moral that slaughter is distasteful.~
== ~BBRANW~ ~On the field of battle, both parties know full well that their lives hang in the balance. They have placed them there willingly. 'Tis a sort of bravery that Tempus smiles upon, as do I.~
== ~BVICON~ ~And what of ... alternatives? What of other ways to settle disputes, outside of warfare?~
== ~BBRANW~ ~None are as virtuous as the valor felt on the battlefield.~
== ~BVICON~ ~So it seems that the death, the slaughter bothers you not, priestess. But you would still condemn the ways of my kind, I'm sure?~
== ~BBRANW~ ~Cowardice reigns in the dealings of your kind, Viconia. Your games, your cloak-and-dagger ... 'tis shameful! Battle, along with victory, is the only righteous end one may strive for!~
== ~BVICON~ ~Pfeh. I, alternatively, possess a mind, and as such will distance myself as far as possible from your fanatic dogma.~
== ~BBRANW~ ~In a war of virtues, thou art unarmed.~
== ~BVICON~ ~As are you, rivvil, in a war of wits.~
== ~BBRANW~ ~Do not mock me! 'Tis solely for the continued success of this group that I shall let your insult pass!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
!StateCheck("CORAN",STATE_SLEEPING)
Global("VICO1","LOCALS",0)~ THEN ~BVICON~ VICO1
~Male! Darthiir!~ [VICON99]
DO ~SetGlobal("VICO1","LOCALS",1)~
== ~BCORAN~ ~Female!~
== ~BVICON~ ~How dare you to interrupt me!~
== ~BCORAN~ ~Do not talk to me and you will not be interrupted, drow.~
== ~BVICON~ ~Why do you constantly avoid speaking with me? Are you afraid? Even the drow cannot kill with words alone, rath'argne darthiir.~
== ~BCORAN~ ~Oh, what an exciting piece of lore! What witticism are you going to bestow on me next? The usual “serve me you shall, jaluk” tune? And a chorus of repetitive insults with intricately woven in drow words, where you could not find an adequately offensive word in Common?~
== ~BVICON~ ~You would do well to hold your tongue, Coran! I do not take peaceable reaction to insults. If so much as one more word -~
== ~BCORAN~ ~So now you do not wish the "cowardly elf" to speak? Where did the enthusiasm go, I wonder? Viconia, I prefer to do pleasurable things. If I could choose between bathing in the fiery cracks of Nine Hells and associating with you, I would be enjoying a lava bubble bath right now.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("DYNAHEIR")
See("DYNAHEIR")
!StateCheck("DYNAHEIR",STATE_SLEEPING)
Global("VIDY1","LOCALS",0)~ THEN ~BVICON~ VIDY1
~You are one of the few among us whom I can respect.~ [VICON99]
DO ~SetGlobal("VIDY1","LOCALS",1)~
== ~BDYNAH~ ~Thou art fluent in compliments. Some might say effluent.~
== ~BVICON~ ~I do not understand your need to spurn me. I only wished to express my admiration for your ... strength, your pride. You give me hope yet for these rivven.~
== ~BDYNAH~ ~I thank thee for thy kind words. Yet I know 'twould be unwise to not search for the barb that doth likely lie therein.~
== ~BVICON~ ~I do not blame you for your mistrust. Such things are innately foolish, and the color of my skin does create certain expectations.~
== ~BDYNAH~ ~Lend me no justification for them, and all the more of my trust shall be thine.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("DYNAHEIR")
See("DYNAHEIR")
!StateCheck("DYNAHEIR",STATE_SLEEPING)
Global("VIDY2","LOCALS",0)~ THEN ~BVICON~ VIDY2
~I gather, magess, that in your homeland the women are of distinguished position.~ [VICON99]
DO ~SetGlobal("VIDY2","LOCALS",1)~
== ~BDYNAH~ ~'Tis verily so. The wychlaran do possess elevated status in Rashemen.~
== ~BVICON~ ~I might say that I'm very intrigued to think that -~
== ~BDYNAH~ ~Hold thy tongue for a moment, drow. I can clearly see the reasons for which though hast approached me with this matter. Think not to draw parallels between my people and yours.~
== ~BVICON~ ~But they exist, rivvil. I seek not to draw them, but only to make them evident.~
== ~BDYNAH~ ~You seek not *only* to make them evident, but also to present them in the light of thy own choosing.~
= ~Thou hast a sharp mind, Viconia, and an equally pointed ambition. Though perhaps not to others, thine motives and machinations are plainly evident to my mind.~
== ~BVICON~ ~I ... I know not what more I can say. You have cornered me, jalil. Well done.~
== ~BDYNAH~ ~'Tis not victory I seek! Though you dwell now upon the surface, thy mind still works like that of a drow. Ever busy, busy, busy.~  
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
HPPercentLT("EDWIN", 50)
Global("VIED1","LOCALS",0)~ THEN ~BVICON~ VIED1
~Waela jaluk! I grow weary of patching you up every time you make a blunder.~ [VICON99]
DO ~SetGlobal("VIED1","LOCALS",1)~
== ~BEDWIN~ ~(She speaks as though she does not enjoy the task...) Such is your role in this group, Viconia. I handle most of the battle with my magic, and you serve largely to heal after the fact.~
== ~BVICON~ ~Feh! You underestimate my contributions to this party, faern.~
== ~BEDWIN~ ~You are hardly making all contributions within your ... ability. (Though my clever innuendo is likely over this one's head.)~
== ~BVICON~ ~Mistake me not for some harlot, mageling. Beneath the surface men begged for my company ... would hang their lives on the very chance! You jaluken are weak. I have yet to meet one worthy of my submission in such a manner as you suggest, nor shall I ever.~
== ~BEDWIN~ ~(Bah! This one has resolve!) Of course, you have never met a Thayvian.~
== ~BVICON~ ~Until now. And I am unimpressed. Begone, male ... and do not address me again lest I permit it.~
EXIT



CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("FALDORN")
See("FALDORN")
!StateCheck("FALDORN",STATE_SLEEPING)
AreaType(FOREST)
Global("VIFA1","LOCALS",0)~ THEN ~BVICON~ VIFA1
~Feh. I will never understand this cursed filth of a surface world. The sprawling hills, the vibrant greens ... the endlessly gaping sky and its one burning eye. If it were not for the occasion of darkness, I could not stand it at all.~ [VICON 12]
DO ~SetGlobal("VIFA1","LOCALS",1)~
== ~BFALDO~ ~I have little patience for those like you, vile creature, who would defile nature with their criticisms.~
== ~BVICON~ ~* Are you prepared to defend your fanatic outburst, druid? Tell me just what reasons I have to share your undying love for this world.~
== ~BFALDO~ ~I need give you no reason to love Her. Only know that the Great Mother is the ultimate power behind all things, and that the natural order pervades all civilization and other such works of man.~
= ~You are, like all things, subject to the will of nature. That's all you need to know, drow.~
== ~BVICON~ ~Vith'os, jalil d'rivvil! I will never submit to this wretched world of yours...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("VIGA1","LOCALS",0)~ THEN ~BVICON~ VIGA1
~Garrick, you seek to inspire morale with your songs, do you not?~ [VICON99]
DO ~SetGlobal("VIGA1","LOCALS",1)~
== ~BGARRI~ ~Of course I do.~
== ~BVICON~  ~Then I should probably inform you that you have missed your goal by a terrible margin. My head throbs daily as you croon about glory, love, and heroism.~
== ~BGARRI~ ~I don't know if I really deserve your comments, Viconia ... but what would you rather I sing of?~
== ~BVICON~ ~*Of the things my Lady the Nightsinger tells me of. Of something more true to the world we walk through. Your idealistic blatherings are just that, and entirely without substance.~
== ~BGARRI~ ~I can't help but wonder if you know anything beyond pain and depression. I feel very sorry for you.~
== ~BVICON~ ~Keep your sympathies to yourself, fool, and put any ideas you've gotten about me out of your head. I'll not suffer being the subject of your next lovestruck ballad.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN")
See("IMOEN")
!StateCheck("IMOEN",STATE_SLEEPING)
Global("VIIM1","LOCALS",0)~ THEN ~BVICON~ VIIM1
~Child, I don't see why you insist upon shying away from me. Does my race truly repulse you to the point of such avoidance?~ [VICON99]
DO ~SetGlobal("VIIM1","LOCALS",1)~
== ~BIMOEN2~ ~No! Um...well...kinda. I read about the drow back in Candlekeep. Kinda nasty, from what I remember. Aren’t all drow out to conquer the world or something? Make slaves of us all?~
== ~BVICON~ ~It's true that my people in many ways deserve their grim reputation. But keep in mind that I am an outcast of my people, and I bear their ways no loyalty.~
= ~You and I are abbilen, companions. It's a word I could seldom use in the caverns of my home. Perhaps you'll offer me the chance to know the purpose of such a word here, in this world of yours.~
== ~BIMOEN2~ ~Ah, uhm, you make me feel like such a heel. I can't say you don't still give me just a bit of the heebie-jeebies, but I can say that I'll do my best to give you a chance.~
== ~BVICON~ ~That is all I would ask of you.~
EXIT

////////////////////////////////////NEEDS CHECKING///////////////////////////////
CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
HPPercentLT("IMOEN2", 50)
HaveSpell(CLERIC_CURE_LIGHT_WOUNDS)
Global("VIIM2","LOCALS",0)~ THEN ~BVICON~ VIIM2
~Stand still, girl. You're wounded.~ [VICON99]
DO ~SetGlobal("VIIM2","LOCALS",1)
Spell("IMOEN2", CLERIC_CURE_LIGHT_WOUNDS)~
== ~BVICON~ ~There. Do not be such a wael next time, lest you wind up dead.~
== ~BIMOEN2~ ~Um...thanks, Viconia. Y'know, for the healing and the advice.~
EXIT
//////////////////////////////////////

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("VIIM3","LOCALS",0)~ THEN ~BVICON~ VIIM3
~Am I to understand, Imoen, that you and <CHARNAME> grew up in a monastery? It's a sort of childhood I can scarcely even begin to identify with.~ [VICON99]
DO ~SetGlobal("VIIM3","LOCALS",1)~
== ~BIMOEN2~ ~Ah ... well, it wasn't that exciting or anything. Stuffy old monks, lotsa dusty tomes. But I guess the most fun probably came from all the trouble we'd get into, or from hangin' around old Puffguts.~
== ~BVICON~ ~... Puff ... guts?~
== ~BIMOEN2~ ~Yeah! Ol' Puffguts ran the inn there. He was kinda like a father to me. You know, like Gorion was to <CHARNAME>~
== ~BVICON~ ~And you referred to your "father" as ... Puffguts? I had thought that on the surface the ilharnen - the fathers - actually commanded a good measure of respect?~
== ~BIMOEN2~ ~Most of 'em do, but Puffguts was different. Real laid-back.~
== ~BVICON~ ~I suppose that a lack of authority could very well explain your present nature...~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
AreaType(CITY)
Global("VIJA1","LOCALS",0)~ THEN ~BVICON~ VIJA1
~Surface dwellers can be so stupid...!~ [VICON99]
DO ~SetGlobal("VIJA1","LOCALS",1)~
== ~BJAHEI~ ~As can your ilk, in addition to being notoriously maligned.~
== ~BVICON~ ~My words were not directed to you, druid, but rather to the idiocy that runs rampant in the masses here.~
== ~BJAHEI~ ~Be that as it may, drow, I don't think that you can honestly insist that those on the surface are so much more foolish than your own kin.~
== ~BVICON~ ~You ... speak rather wisely, to my great astonishment.~
== ~BJAHEI~ ~Hmph! As if she would be a judge of wisdom...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("JAHEIRA")
See("JAHEIRA")
InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
!StateCheck("JAHEIRA",STATE_SLEEPING)
Global("VIJA2","LOCALS",0)~ THEN ~BVICON~ VIJA2
~Are you sure there is no Drow blood in you, Jaheira?~ [VICON99]
DO ~SetGlobal("VIJA2","LOCALS",1)~
== ~BJAHEI~ ~There's none that I'm aware of. Why do you ask?~
== ~BVICON~ ~Because you treat your husband exactly as a Drow female would her current... lover.~
== ~BJAHEI~ ~Bah, do not speak such foolishness, Drow.~
== ~BVICON~ ~I speak only the truth.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
Global("VIKH1","LOCALS",0)~ THEN ~BVICON~ VIKH1
~Khalid, my observations of you have sparked some particular curiosities.~ [VICON99]
DO ~SetGlobal("VIKH1","LOCALS",1)~
== ~BKHALI~ ~I d-don't know if I should want to hear of them, or not. But d-do speak of them.~
== ~BVICON~ ~I cannot help but wonder what it might be like to live such a hodgepodge existence. When one's race is not even certain, rivvil or darthiir, I imagine doubt and confusion could become quite consuming.~
== ~BKHALI~ ~I s-sense an insult, Viconia. I am perfectly satisfied with my heritage, I'll th-thank you to note.~
== ~BVICON~ ~Truly? Then you are a braver sort than I had figured you for.~
== ~BKHALI~ ~... will th-that be all, drow?~
== ~BVICON~ ~It will. You are dismissed.~
== ~BKHALI~ ~... you would do well to d-dismiss your prejudices. They will serve you no good here. ~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KIVAN")
See("KIVAN")
!StateCheck("KIVAN",STATE_SLEEPING)
Global("VIKI1","GLOBAL",0)~ THEN ~BVICON~ VIKI1
~Greetings, darthiir. I know that you look upon me as an enemy, but perhaps we could ignore our differences. I am in need of allies in this world of yours, not enemies.~ [VICON 27]
DO ~SetGlobal("VIKI1","GLOBAL",1)~
== ~BKIVAN~ ~I see, drow, that you are no exception to the ways of your kindred. This is a vile ploy, a play for power, and it comes so naturally to your wretched heart that you don't even attempt to conceal its manipulative nature.~
== ~BVICON~ ~Iblith! If that is how you want things, then so be it. I'll waste no more time hoping for a fragile darthiir to see an appeal to reason.~ [VICON 28]
== ~BKIVAN~ ~How are we to ever trust one who venerates the Spider Queen? It's a vain pursuit you're engaged in, dark elf.~ [KIVAN 28]
== ~BVICON~ ~I worship Lolth no longer...~ [VICON 29]
== ~BKIVAN~ ~You have forsaken Lloth not for a kinder deity, Viconia. Your conversion means nothing to me. The day one trusts a Dark Elf, is the day of one's demise.~
== ~BVICON~ ~Then keep your distance from me, or that day will approach sooner than you should like!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KIVAN")
See("KIVAN")
!StateCheck("KIVAN",STATE_SLEEPING)
Global("KIVI3","GLOBAL",1)
Global("VIKI2","GLOBAL",0)~ THEN ~BVICON~ VIKI2
~Feeble darthiir, how did you keep your life? Deheriana is dead…~ [VICON99]
DO ~SetGlobal("VIKI2","GLOBAL",1)~
== ~BKIVAN~ ~Do not you ever dare to say her name, not you… I...I forbid it!~
== ~BVICON~ ~If you wouldn’t plod along like a half-wit, murmuring Deheriana this and Deheriana that, at every footfall I would not have asked, but what is one to expect from a frugal darthiir, but foolishness? So, why have you abandoned the female you have served to death and were not punished for that?~
== ~BKIVAN~ ~I did not serve Deheriana, Viconia. She was my wife in the eyes of gods and men. I love her.~
== ~BVICON~ ~"Jal ssinssrigg zhah waella". All love is foolish, darthiir.~
== ~BKIVAN~ ~You do not know what love is, Drow. The very word you used does not mean "love". It means lust.~
== ~BVICON~ ~There is no word for "love" in Drow.~
== ~BKIVAN~ ~There is. Your kin got rid of it thousands of years ago when they ripped everything good and true from their souls to please the Spider Queen.~
== ~BVICON~ ~That which does not exist shall not have a name.~
EXIT




CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("QUAYLE")
See("QUAYLE")
!StateCheck("QUAYLE",STATE_SLEEPING)
Global("VIQU1","LOCALS",0)~ THEN ~BVICON~ VIQU1
~, when I lived beneath the surface, I dealt often with creatures called the svirfneblin. They, much like you --~ [VICON99]
DO ~SetGlobal("VIQU1","LOCALS",1)~
== ~BQUAYL~ ~Yes, yes. I know all about the svirfneblin, or deep gnomes as they're often called. Don't bore my superior intellect with your trite explanations, just get to the point!~
== ~BVICON~ ~I'm beginning to wonder if this is a waste of my breath.~
== ~BQUAYL~ ~Of course it is. Your dull mind has very little to contribute to mine.~
== ~BVICON~ ~Iblith. I was remarking that they, much like you, thought themselves very clever, but when our parties descended upon them their trickery and illusions could only take them so far. Their bodies fell just as easily as any other.~
== ~BQUAYL~ ~Oh, so the drow's making threats now? Don't you worry, I'm at least ten times more intelligent and resourceful than the deep gnomes. You'll just see.~
== ~BVICON~ ~Oloth plynn jal... Shar, why must you make my existence such a mockery?~
EXIT



CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SKIE")
See("SKIE")
!StateCheck("SKIE",STATE_SLEEPING)
InParty("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("VISK2","LOCALS",0)
Global("VISK1","LOCALS",0)~ THEN ~BVICON~ VISK1
~Tell me that it is not as it seems, Skie. Do tell me that the jalilen d'rivven -- the surface women -- aren't as bound to servitude as you appear to be.~[VICON99]
DO ~SetGlobal("VISK1","LOCALS",1)~
== ~BSKIE~ ~I'm sorry, did I do something wrong?~
== ~BVICON~ ~Don't play stupid, girl. The way the jaluk pushes you around ... It's appaling!~
== ~BSKIE~ ~You don't need to go feeling sorry for me, Viconia. Eldoth loves me, and I love him. I guess if you can't understand this --~
== ~BVICON~ ~Oh, please child, don't mistake my irritance with you for concern. I'm unbearably close to retching, as it is. It would seem to me that your "love" is naught but a word the rivvil males have invented to bind the foolish rivvil women to their servitude.~
== ~BSKIE~ ~No, that's not it at all! It's just sad that you can't understand the way that ... ooh, I have a headache!~
== ~BELDOT~ ~Stay clear of her, wench. Her bile will poison your mind if you let it.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SKIE")
See("SKIE")
!StateCheck("SKIE",STATE_SLEEPING)
InParty("ELDOTH")
DEAD("ELDOTH")
Global("VISK1","LOCALS",0)
Global("VISK2","LOCALS",0)~ THEN ~BVICON~ VISK1
~Tell me that it is not as it seems, Skie. Do tell me that the jalilen d'rivven -- the surface women -- aren't as bound to servitude as you appear to be.~[VICON99]
DO ~SetGlobal("VISK1","LOCALS",1)~
== ~BSKIE~ ~I'm sorry, did I do something wrong?~
== ~BVICON~  ~Don't play stupid, girl. The way the jaluk pushed you around ... It's appaling!~
== ~BSKIE~ ~I can't believe you would say that! (sniffle) Do you need to be so mean all the time?~ 
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("TIAX")
See("TIAX")
!StateCheck("TIAX",STATE_SLEEPING)
Global("VITI1","LOCALS",0)~ THEN ~BVICON~ VITI1
~In Menzoberranzan we used to hunt your type for sport, yingil. The svirfneblin were not our most powerful enemies, but they wielded powers over the earth that made them challenging prey for the unwary. Have your people any similiar powers over stone?~ [VICON99]
DO ~SetGlobal("VITI1","LOCALS",1)~
== ~BTIAX~ ~Tiax has powers over stone, sky, and water, Drow! No element may escape Tiax's relentless domination!~
== ~BVICON~ ~I did not ask of you, wael, I asked of your people!~
== ~BTIAX~ ~My people!? Tiax has no peers! Tiax has moved beyond his petty heritage and achieved a state far beyond that of even the greatest of Rock Gnomes! No other race may DARE to claim kinship with Tiax, for he is a race unto himself! Let all the world tremble before his might!~
== ~BVICON~ ~*sigh* I sense that I waste my breath on you. So be it.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XAN")
See("XAN")
!StateCheck("XAN",STATE_SLEEPING)
Global("VIXA1","LOCALS",0)~ THEN ~BVICON~ VIXA1
~So tell me, darthiir, does your grim outlook on life result from any particular misfortune or merely from the dismal chore of having to live as a surface elf?~ [VICON99]
DO ~SetGlobal("VIXA1","LOCALS",1)~
== ~BXANNN~ ~Ugh, must you speak to me, drow? Your presence here alone suggests that our leader is a mad <PRO_MANWOMAN>, and that we're all doomed. Do I have to suffer your prattle, as well?~
== ~BVICON~ ~That doesn't necessarily answer my question, though it does confirm my suspicions to a degree. I can imagine that such a fragile life always beneath the sun could get depressing.~
== ~BXANNN~ ~Sentiments very similar to how I would hang myself for dismay at having to live my life crawling about in holes. But your current state doesn't give you much room to needlessly harass your companions. That is, unless you find your own doom to be an inviting thing.~
== ~BVICON~ ~Feh! Waela darthiir! You've made no attempt to conceal your disdain for me, and we would surely be at odds regardless of what I might say to you.~
== ~BXANNN~ ~True. I can imagine your position could get quite depressing.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XZAR")
See("XZAR")
!StateCheck("XZAR",STATE_SLEEPING)
Global("VIXZ1","LOCALS",0)~ THEN ~BVICON~ VIXZ1
~I have given some thought, wizard, to the advice you offered me. Addled as you seem, it occurs to me that your words might hold some merit after all.~ [VICON99]
DO ~SetGlobal("VIXZ1","LOCALS",1)~
== ~BXZAR~ ~Of course they do! Er...just what were they again?~
== ~BVICON~ ~I see. I should have expected such a response from you. Your very personage, your every action, is laden with a certain lunatic instability. The present occasion must be no exception. But that is not what --~
== ~BXZAR~ ~Tell me, pretty onyx, have you ever thought of becoming an exotic specimen? I've never seen anything with the quality of your flesh, so redolent of pure Evil within. Why, even in the stories Mummy tells me...not that I see those so often any more. Oh damn my cursed distracted eye!~
== ~BVICON~ ~What? Have you gone mad, jaluk?!?~
== ~BXZAR~ ~No. Perhaps only an ear? 'Twould make a dazzling specimen; lacquered, set on a stick, it could double as a backscratcher. Benefit us all. And, mind, in that case I would feel less urgency in collecting the rest of you until you're ... indisposed.~
== ~BVICON~ ~And to think, I gave consideration to words from this blathering fool! This one's use is limited to his novelty, it would seem...~
== ~BXZAR~ ~Bah. Such unaspiring timidity. What did you want, then? Something about one nonsense or another?~
== ~BVICON~ ~You're indeed an unstable sort of creature. Never mind what I wanted of you. It seems I was mistaken.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KIVAN")
See("KIVAN")
!StateCheck("KIVAN",STATE_SLEEPING)
Global("KIVI5","GLOBAL",1)
Global("VIKI3","GLOBAL",0)~ THEN ~BVICON~ VIKI3
~Kivan, must you murmur under your breath in such a manner? If there's something you desire to say, then say it. I'll waste no more of my time waiting for you to --~ [VICON 99]
DO ~SetGlobal("VIKI3","GLOBAL",1)~
== ~BKIVAN~ ~What do you want out of me, Viconia?!? My words are kept to myself for the continued good of this party. I respect <CHARNAME>'s leadership, even if I do not respect <PRO_HISHER> decision to harbor you.~
= ~Or would you rather I disregard all of that? I cannot deny that I hear the voice of Shevarash, who calls for me to end your existence. I am running out of reasons to disobey the Black Archer.~
== ~BVICON~ ~Don't threaten me, Kivan, it shall only lead to your death.~ [VICON 30]
== ~BKIVAN~ ~Don't make me warn you again, drow! ~ [KIVAN 30]
END  ~BVICON~ VIKI3PC

APPEND ~BVICON~

IF ~False()~ THEN BEGIN VIKI3PC
  SAY ~Feh! If you were to, for once, act upon one of your hollow threats, I for one would be elated.~
	IF ~~ THEN REPLY ~Calm down, both of you! I'll not have you fighting like this.~ GOTO VKFight1
	IF ~~ THEN REPLY ~Viconia, stop antagonizing Kivan. He didn't ask for any of this.~ GOTO VKFight2
	IF ~~ THEN REPLY ~Kivan, leave Viconia alone. She doesn't deserve your threats.~ GOTO VKFight3
	IF ~~ THEN REPLY ~Oh, either settle this or be quiet! I can't take all of this bickering.~ EXTERN ~BKIVAN~ VKResolve
	IF ~~ THEN REPLY ~(say nothing)~ EXTERN ~BKIVAN~ VKFight4
END

IF ~~ THEN BEGIN VKFight1
SAY ~If ... if you wish it, <CHARNAME>, it will be done. I can't help but wonder, though, how much longer I'll have to endure this one's insufferable torment!~
IF ~~ THEN EXTERN ~BKIVAN~ VKFight1KI
END



IF ~~ THEN BEGIN VKFight2
SAY ~<CHARNAME!> You ... do you *betray* me? Betray me to this belligerent darthiir?~
        IF ~~ THEN REPLY ~I'm not picking sides. You're both going to stop fighting, and that's all.~ GOTO VKFight1
	IF ~~ THEN REPLY ~You've pushed him far enough, Viconia. You're a divisive force in this group.~ GOTO VReject
END

IF ~~ THEN BEGIN VKFight3
SAY ~Phew.~
IF ~~ THEN EXTERN ~BKIVAN~ VKFight3KI
END

IF ~~ THEN BEGIN VKFight3VI
SAY ~Feh! The dartiir is feebleminded, <CHARNAME>.~
	IF ~~ THEN REPLY ~Look, I refuse to pick sides. Just stop fighting, both of you.~ GOTO VKFight1
	IF ~ReputationGT(Player1, 8)~ THEN REPLY ~I've had enough of your violent tendencies. I can't abide them any longer.~ EXTERN ~BKIVAN~ KReject1
	IF ~!ReputationGT(Player1, 8)~ THEN REPLY ~I've had enough of your violent tendencies. I can't abide them any longer.~ EXTERN ~BKIVAN~ KReject2
        END

IF ~~ THEN BEGIN VKFight4VI
SAY ~Oloth plynn dos, darthiir. Lil alurl! For Shar!~
IF ~~ THEN DO ~ActionOverride("Kivan",Attack("Viconia")) Attack("Kivan") SetGlobal("KiViFi","GLOBAL",1)~
EXIT
END

IF ~~ THEN BEGIN VReject
SAY ~Then it's true ... You have abandoned me. Jal khaless zhah waela. How true it is, and how blind I was to once believe otherwise.~
= ~Cursed was the day I met you, surface scum. Oloth plynn jal! Seek not to pursue me, lest I be tempted to strike in return.~
IF ~~ THEN DO ~LeaveParty()
EscapeArea()~
EXIT
END

IF ~~ THEN BEGIN VKResolveVI
SAY ~Feh! The darthiir is mad! As much as I would wish for you to reconsider his presence, <CHARNAME>, I can abide your decision.~
IF ~~ THEN EXIT
END

IF ~Global("KiViFi","GLOBAL",1)
Dead("KIVAN")
~ THEN BEGIN VVictory
SAY ~Vith'os, darthiir! It's no better a fate than you deserve!~
IF ~~ THEN GOTO VVictory2
END


IF ~Global("KiViFi","GLOBAL",1)
Dead("KIVAN")
~ THEN BEGIN VVictory2
SAY ~The darthiir was mad, <CHARNAME>! It's a relief to us all that he is gone.~
IF ~~ THEN EXIT
END
END

APPEND ~BKIVAN~

IF ~~ THEN BEGIN KReject1
SAY  ~It seems the dark one has her talons in you, after all. It's regrettable, <CHARNAME>, when people I once thought so deserving of my respect have fallen to such lengths. But if that's the way things have become ... then I have no choice but to take my leave. I can no longer stand by as this woman poisons your mind.~
= ~Farewell, <CHARNAME>. Beware of the drow...~
IF ~~ THEN DO ~LeaveParty()
EscapeArea()~
EXIT
END

IF ~~ THEN BEGIN KReject2
SAY  ~<CHARNAME>, this party has been spiraling into its doom for some time now. This is all the confirmation I need of the evils that walk alongside me. The drow has poisoned your minds in addition to her other crimes.~
= ~Stand and face me then, Viconia. My conscience can abide no less than to see to your end.~
IF ~~ THEN DO ~ActionOverride("Viconia",Attack("Kivan")) Attack("Viconia") SetGlobal("KiViFi","GLOBAL",1)
SetGlobal("KivanRejected","GLOBAL",1)~
EXIT
END


IF ~~ THEN BEGIN VKResolve
SAY ~Very well, <CHARNAME>. I will say not a word to the drow from now on.~
IF ~~ THEN EXTERN ~BVICON~ VKResolveVI
END

IF ~~ THEN BEGIN VKFight1KI
SAY ~Are you truly going to fall into her web of deceit? <CHARNAME>, we can no longer trust this one at our backs ... plotting and scheming as she's apt to do.~
	IF ~~ THEN REPLY ~Viconia ... Kivan is right. We can't trust you any longer.~ EXTERN ~BVICON~ VReject
	IF ~ReputationGT(Player1, 8)~ THEN REPLY ~Look, Kivan, you've harassed her long enough.~ GOTO KReject1
	IF ~ReputationLT(Player1, 9)~ THEN REPLY ~Look, Kivan, you've harassed her long enough.~ GOTO KReject2
	IF ~~ THEN REPLY ~I asked you two not to fight, and I meant it. I'd hate to see this resolved with force.~  GOTO VKResolve

END

IF ~~ THEN BEGIN VKFight3KI
SAY ~ The dark elf has laid her snare for you, CHARNAME. Don't become her victim.~
IF ~~ THEN EXTERN ~BVICON~ VKFight3VI
END

IF ~~ THEN BEGIN VKFight4
SAY ~No more of your taunts, drow!~
IF ~~ THEN EXTERN ~BVICON~ VKFight4VI
END

IF ~Global("KiViFi","GLOBAL",1)
Dead("VICONIA")
Global("KivanRejected","GLOBAL",1)
~ THEN BEGIN KVictory1
SAY ~Shevarash, another dark one will not savage the world any longer.~
IF ~~ THEN DO ~LeaveParty()
EscapeArea()~
EXIT
END

IF ~Global("KiViFi","GLOBAL",0)
Dead("VICONIA")
Global("KivanRejected","GLOBAL",0)
~ THEN BEGIN KVictory2
SAY ~Shevarash, another dark one will not savage the world any longer.~
IF ~~ THEN EXIT
END
END



