BEGIN X#KETH

BEGIN X#SAHA01

BEGIN  X#IHTIA
APPEND X#IHTIA

IF ~Dead("x#keth")~ SeasnakeLeaves
SAY ~Crabfood? A pity.~
IF ~~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",7) EscapeArea() ActionOverride("seasnake",DestroySelf()) ~ EXIT
END

// Scene 3 (if did not help Jozzi, she shows up with 5 other Sahuagin) 

IF ~Global("X#KivanSea","GLOBAL",8)~ SEAL3.1
SAY ~Here be more drylanders ready for eating. Let us feast!~
= ~Regretting our meeting, did I not tell you that you be, drylander?~
IF ~~ THEN DO ~SetGlobal("SeasnakeAttack","GLOBAL",2)
ActionOverride("seasnake",Enemy()) 
ActionOverride("seasnake",Attack([PC]))
CreateCreature("X#SAHA01",[-1.-1],0)
CreateCreature("X#SAHA02",[-1.-1],0)
CreateCreature("X#SAHA02",[-1.-1],0)
CreateCreature("X#SAHA01",[-1.-1],0)
CreateCreature("X#SAHA02",[-1.-1],0)
CreateCreature("X#SAHA02",[-1.-1],0)
ActionOverride("X#SAHA01",Attack([PC]))
ActionOverride("X#SAHA02",Attack([PC]))
 ~ EXIT
END

IF ~Global("X#KivanSea","GLOBAL",1)~ StartKivanSeaElfQuest
SAY ~You... You do be beings of the dryland? ~
++ ~I guess so. Who are you?~ EXTERN KIVANJ SEAELF1.1
END


IF ~~ SEAL1.2
SAY ~Splashing. Do be following me.~
IF ~~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",2)~ EXIT
END

IF ~~ SEAL1.3
SAY ~He be crabfood then. Wait. If I do be telling you he be a drylander, would you be helping?~
++ ~A drylander? How's that possible?~ + SEAL1.1
++ ~Be he an avariel, I would not risk my life!~ EXTERN KIVANJ SEAL1.7
END

IF ~~ SEAL1.4
SAY ~He be crabfood then, and seaweed your hearts do be.~
IF ~RandomNum(2,1)~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",4)~ EXTERN KIVANJ SEKIReconsider
IF~RandomNum(2,2)~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",4)~ EXTERN KIVANJ SEAL1.7
END

IF ~~ SEAL1.5
SAY ~If netting you I wanted, I could. Sounds swim slower here than in water, but my shouting would swim fast enough to reach the raiding party. Bah. You do be skinnier than sardines, drylanders.~
IF ~~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",4)~ EXTERN KIVANJ SEKIReconsider
END

IF ~~ SEAL1.6
SAY ~Why do I be knowing? Dressing in seafoam be more useful then talking to you.~
= ~Be you helping me, drylander? The tide do be coming.~
++ ~I will not risk a battle with Sahuagin to free a murderer!~ + SEAL1.4
++ ~I will help you.~+ SEAL1.2
++ ~I still think it's a trap!~ + SEAL1.5
END
END

CHAIN KIVANJ SEKIReconsider
~Wait, <CHARNAME>. I understand your hesitation. Perhaps it is a trap - we have no way of knowing. But the bait is an Elven life. I cannot abandon him to his fate - even if a traitorous Malenti's word is all I have to go on.~
END
++ ~Elven life? Have not you heard what she said? He killed his own kin. I will not risk a battle with Sahuagin to free a murderer!~ EXTERN _KIVANJ KivanQuits
++ ~You are right - I might live to regret it, but I will regret more not helping. Lead on, Malenti. And woe to you if you betray us!~ EXTERN X#IHTIA SEAL1.2

CHAIN KIVANJ KivanQuits
~You will not? I will. Tonight we fight together, Malenti.~
== X#IHTIA ~Splashing. Strength it do be or foolishness, I do be not knowing... but I do be greatful that you do possess it, land elf.~
END
IF ~~ THEN DO ~ActionOverride("kivan",LeaveParty()) ActionOverride("kivan",EscapeArea())ActionOverride("seasnake",EscapeArea())~ EXIT

CHAIN KIVANJ SEAL1.7
 ~I… I pity this woman, <CHARNAME>, despite vileness that I sense in her. I regret that you refused to help her.~
== X#IHTIA ~O, regretting it again you do be before the tide's turn.~
END
IF ~~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",4) ActionOverride("seasnake",JumpToPoint([1010.1638]))~
EXIT

CHAIN X#IHTIA SEAL1.1
 ~No time do I have for plots to fool even a fry. Already air hurts my innards.~
= ~I be Malenti - do explain who I be, dryland elf, spare my gills.~
== KIVANJ ~ A malenti? So it is true that your malicious kind exists.~
== X#IHTIA ~ *she nods impatiently*~
== KIVANJ ~ <CHARNAME>, malenti are rumored to be born in Sahuagin settlements, whenever a sea-elven village is located near-by. It is said that they are fully alike seafolk in appearance - but only in appearance. Their blood and hearts are that of Sahuagin. Seafolk deny their existence, as we would deny Drow's, if we could. Sahuagin usually kill them or if they let them live, they are used as spies. Are you... a spy? Are you leading us in a trap, vicious creature?~
== X#IHTIA ~Spying I did, but the sea-elf village I eeled my way into we did destroy. In our city I be, when capturing this ship we did, running it ashore thereafter. Our Prince be wanting knowledge of costal villages for raiding, so putting me with drylanders he did. In theirs air-filled prison, almost did a puff-fish out of me our Prince, he did. ~
= ~ Our Prince be making fights among prisoners till only one be left. He was the strongest one, the shark-hearted! Killed all in his school, he did. Did not wanting him to become crab food, told them that he has secret knowing of cache, I did.~
= ~But there do be too many of them guarding him for me to kill them alone. The drylander turned jellyfish once he got ashore. I did be certain he be stronger here and together killing them we would be...~
= ~Do you be helping me now?~
== KIVANJ ~I do not trust the Malenti, but I do not wish to not abandon my kin to Sahuagin.~
END
++ ~I will not risk a battle with Sahuagin to free a murderer!~ + SEAL1.4
++ ~I will help you.~+ SEAL1.2
++ ~I still think it's a trap!~ + SEAL1.5
++ ~Why did he… er… turned jelly-fish?~ + SEAL1.6


CHAIN KIVANJ  SEAELF1.1
~She is my kin, a Sea Elf. What chased you out of the sea? ~
== X#IHTIA ~Be needing help do I and Jozzi Seasnake be my name. Sahuagin - shark-men- killing my mate they be. He told them he does show them a secret cache on the broken ship - and there do be none. When they be finding this out...~
== KIVANJ ~I will try to help you, Jozzi, if I am able.~
= ~ <CHARNAME>, Sahuagin are sea monsters, incapable of mercy. They torture their prisoners, and when they are done with them, they feast on their corpses. *quietly* A doom worst even than Deheriana's was....~
= ~My sea kin are their sworn enemies... ~
== X#IHTIA ~Yes... we do be.~
END
++ ~How did you escape yourself, Elf? And why is there no chase?~ EXTERN X#IHTIA SEAL1.1
++ ~Wait, how did your mate know of the ship?~ EXTERN X#IHTIA SEAL1.1
++ ~We are coming to help!~ EXTERN X#IHTIA SEAL1.2
+~!Race(Player1,ELF)~+ ~You are on your own, pointy-eared!~ EXTERN X#IHTIA SEAL1.3
++ ~I cannot help you - Sahuagin are too dangerous to deal with. Be grateful that you have escaped with your own life, girl, and find yourself another mate. There are plenty under the sea.~ EXTERN X#IHTIA SEAL1.3


CHAIN IF ~Global("X#KivanSea","GLOBAL",3)~ THEN X#SAHA01 SahaChain1
~Where be the treasure, crabfood?~
== X#KETH ~In… in your… *he coughs up blood* innards. Open… open your white guts and you will find it. ~
== X#SAHA01 ~Seasnake? You did bring more drylanders? Do they be knowing of the treasure?~
== X#IHTIA ~Keth'sim Dwin'anea did be telling you where it hides. In your guts and I do be wanting to see it much!~
END
IF ~~ THEN DO ~ActionOverride("x#keth",JumpToPoint([1010.1638])) SetGlobal("X#KivanSea","GLOBAL",5)
ActionOverride("X#SAHA01",Enemy()) ActionOverride("X#SAHA01",Attack("seasnake")) ActionOverride("X#SAHA02",Enemy()) ActionOverride("X#SAHA01",Attack(Player1)) ChangeEnemyAlly("seasnake",GOODBUTBLUE) ~ EXIT


CHAIN IF ~Global("X#KivanSea","GLOBAL",6)~ THEN X#KETH SeasnakeFinal
 ~If I have my forfeited life back, I shall use it for one purpose only - killing this sea-monster!~
 END
 IF ~~ THEN DO ~MoveGlobalObject("kivan","x#keth") ActionOverride("seasnake",JumpToPoint([911.1409]))~  EXTERN KIVANJ SeasnakeFinal1
 
CHAIN KIVANJ SeasnakeFinal1
~*Kivan restrains him* You have your life back because of her, Keth'sim Dwin'anea.~
== X#KETH ~I guessed. But what do I need my life for if I have killed my own companions on the lie of the traitor?~
= ~Do you know what she is? She is a malenti! A vicious, merciless malenti! They look like sea-elves, but they are Sahuagin in truth.~
= ~Sahuagin use them as spies, so they threw this… witch in with us. Every day she told me that it would be her to fight the last of us, landfolk, and she looked so weak…. I thought that I would be the last man standing and let her kill me when we must fight. Perhaps Sahuagin then would spare her life, until their next catch. And meanwhile… meanwhile she might get help from her kin and escape.~
= ~Only it was a lie - and I understood it only today, when I saw her among them.~
= ~What cruel game did you play, Seasnake?~
== X#IHTIA ~*She shrugs one shoulder* More than one prisoner ashore they never would take. You to live I did want, not others. One life did I want to save.~
== X#KETH ~*Spits at her* What is one life if you have destroyed ten to do so? No, eleven… for I do not want to live after what I have done.~ 
== KIVANJ ~*quietly* One life… one life is worth everything when you love that person. Are you blind, Keth'sim Dwin'anea?~
== X#KETH ~It must be the blood of my comrades flowing into my eyes that blinds me.~
== X#IHTIA ~Seawater it do be. ~
== X#KETH ~*He laughs bitterly* Seawater. Yes, it is. Curse the sea and the monsters that live under it! I want you dead, Snake.~
== X#IHTIA ~*Jozzi starts walking into the sea, then turns her head and looks at Keth'sim Dwin'anea with unperturbed eyes.*~
= ~Dead I do be soon enough for your liking, drylander. Waters be telling what happened here, scents of blood it does carry quick. Sahuagin be killing me for living when pure sharkblood died. Your sea-kin do be thinking just like you. They do be knowing that I killed many, and saved but one. They do not be wanting me. With no school one does not live long under the sea. *She prepares to dive into the water* ~
== X#KETH ~ I… I am sorry.~
== X#IHTIA ~Live long you can, Keth'sim Dwin'anea. Do it. And step on sea-urchins may you not.~
== X#KETH ~I… I think I will never again come close to the sea. There are... some items in the stern of the ship that may be of interest to you, adventurers.~
= ~Forgive me for being so abrupt, but I must get away from the cruel sea.~
END
IF ~~ THEN DO ~SetGlobal("X#KivanSea","GLOBAL",7) EscapeArea() ActionOverride("seasnake",DestroySelf()) ~ EXIT

