BEGIN ~X#GarWyl~

IF
~OR(2)
!InParty("Garrick")
Dead("Garrick")~ THEN MyrCutioNoGarrick
SAY ~One can always find a tale somewhere, if one knows where to look...~
IF ~~ THEN EXIT
END

CHAIN
IF ~InParty("Garrick")
!Dead("Garrick")~ THEN X#GarWyl MyrCutioGarrickChain
~Pray tell, who goes there? Be thee adventurers?~
== ~GarriJ~ ~It is the party of <CHARNAME> and I, the brave Sir Garrick.~
== ~TiaxJ~ IF ~InParty("Tiax") !Dead("Tiax")~ THEN ~And Tiax, who rules over all!~
== ~QuaylJ~ IF ~InParty("Quayle") !Dead("Quayle")~ THEN ~Hey, Garrick, you forgot to mention me! I mean, I *am* undoubtedly the one this group should be presenting as a figurehead...~
== ~X#GarWyl~ ~I see, Sir Garrick. I am Myr'Cutio. Or, at least I was, before I, well, died... Tell me, wherefore hast thou come here?~
== ~GarriJ~ ~We come seeking tales of your wisdom and adventures, noble spirit.~
== ~X#garz01~ ~Uhhhh...~
== ~X#GarWyl~ ~Alas, I have not had many adventures these recent years. Mine companions bear not the undead condition as well as I, and, begging mine pardon, art now rather dull.~
== ~X#garz04~ ~Now, that's not terribly fair, old chap!~
== ~X#garz02~ ~Guhhhh...~
== ~TiaxJ~ IF ~InParty("Tiax") !Dead("Tiax")~ THEN ~Uhhhh...~
== ~TiaxJ~ IF ~InParty("Tiax") !Dead("Tiax")~ THEN ~What? Tiax wanted to join in! When he rules, *all* shall have the conversational skills of zombies!~
== ~X#garz04~ ~Ok, on second thoughts I'll concede that point... It must be rather dull for you, Myr'Cutio.~
== ~GarriJ~ ~Hey! You can, well, talk?!?~
== ~X#garz04~ ~Yes, of course! Uh, I mean, duhhhh...~
== ~XzarJ~ IF ~InParty("Xzar") InParty("Montaron") !Dead("Xzar")~ THEN ~Mummy always used to tell me that drybones weren't the best conversationalists. Still, I always find plenty to talk with them about! Right, Monty?~
== ~X#garz03~ ~Duhhhh...~
== ~MontaJ~ IF ~InParty("Xzar") InParty("Montaron") !Dead("Xzar")~ THEN ~Shut yer cakehole, damn fool wizard...~
== ~GarriJ~ ~Uh, I see.~
== ~X#GarWyl~ ~Truth be told I, too, tire of this unlife. Mayhap for mine final adventure I could be put to rest by this brave band of fellows I see before mine eyes.~
== ~AjantJ~ IF ~InParty("Ajantis") !Dead("Ajantis")~ THEN ~All undead are abominations! By Helm, it is time for you to meet your maker!~
== ~BranwJ~ IF ~InParty("Branwen") !Dead("Branwen")~ THEN ~Glorious battle for Tempus!~
== ~GarriJ~ ~I'm not sure I...~
== ~X#GarWyl~ ~Yes. Come, once more unto the breach dear friends! And so ends here either the tale of Myr'Cutio, or <CHARNAME>... We shall see.~
END
IF ~~ THEN DO ~ActionOverride("X#GarWyl",Enemy())
ActionOverride("X#Garz01",Enemy())
ActionOverride("X#Garz02",Enemy())
ActionOverride("X#Garz03",Enemy())
ActionOverride("X#Garz04",Enemy())~ JOURNAL ~So much for literary greats.

We encountered the spirit of the fabled Myr'Cutio and defeated him in battle, thus ending the epic story of his life and adding to ours. It seems you can learn useful things from books after all.~
EXIT

BEGIN ~X#Garz01~

BEGIN ~X#Garz02~

BEGIN ~X#Garz03~

BEGIN ~X#Garz04~

APPEND ~GARRIJ~

IF ~AreaCheck("AR9800")
PartyHasItem("X#GARCH")
Global("X#PostMyrChat","LOCALS",0)~ THEN BEGIN PostMyrChat
SAY ~I agree that the artistic greats should have immortality through their works... Though I think this shows that, uh, it's probably best to let their bodies decay after their natural time has expired. I don't think I should ever want to be a ghost, like that...~
=
~Still, this armour *is* very stylish.~
IF ~~ THEN EXIT
END

END
