ADD_STATE_TRIGGER ~RIELTA~ 1 ~!InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~
ADD_STATE_TRIGGER ~RIELTA~ 2 ~!InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~
ADD_STATE_TRIGGER ~RIELTA~ 4 ~!InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~
ADD_STATE_TRIGGER ~RIELTA~ 5 ~!InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~
ADD_STATE_TRIGGER ~RIELTA~ 6 ~!InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~
ADD_STATE_TRIGGER ~RIELTA~ 7 ~!InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~

// Ogre-Mage Torturer in the Cloakwood Mines
INTERJECT_COPY_TRANS ~OGRMA2~ 0 YOMTCM
  == ~YESLIJ~  IF ~InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~ THEN ~Ye sick fiend... ye've made a pain-house out o' me home! DIE, YE FILTH!~
END

// Yeslick, On meeting Davaeorn
INTERJECT_COPY_TRANS ~DAVAEO~ 0 YOMD
  == ~YESLIJ~  IF ~InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~ THEN ~One name o' ours ye know, at least, mage - Yeslick Orothiar I am, an' it sickens me ta think that ye're goin' ta share the same grave as me kin. Prepare fer the Abyss, Davaeorn!~
  == ~DAVAEO~  IF ~InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~ THEN ~Well, well... the fool escapes, does he? Then let us see whose graves shall be filled!~
END

//Rieltar
EXTEND_BOTTOM ~RIELTA~ 0
IF ~InParty("yeslick") !Dead("yeslick") !StateCheck("yeslick",STATE_SLEEPING)~ EXTERN ~BYESLI~ YWMR1
END

// Yeslick, When meeting Rieltar
CHAIN
IF ~~ THEN ~BYESLI~ YWMR1
~Manners, is it? Like the manners that ye're not s'posed to enter a dwarf's home if he doesn't invite ye in? Or the good nature to not trample over the graves of his kin? How about the common courtesy ta not lock him away and torture him fer days, Rieltar? Are those the manners that make ye? Are they, ye filth?~
== RIELTA ~Yeslick?!? Then - Cloakwood *has* fallen... Damn you, Dwarf! There may be safety for you in this library but I assure you, outside of here, there will be nowhere to hide for you!~
== BYESLI ~Me safety's not what I'm thinkin' of, scum! I say ye draw steel now, and by Clangeddin's will get cut down like the dog ye are! At them, <CHARNAME>!~ DO ~SetGlobal("YWMRFTFT","GLOBAL",1)~
END
++ ~No, Yeslick! This isn't the way to avenge anything!~ EXTERN ~YESLIJ~ YWMR2B20
++ ~We're with you, Yeslick!~ EXTERN ~YESLIJ~ YWMR2B5 //(go to block five)

CHAIN
IF ~~ THEN ~YESLIJ~ YWMR2B20
~Ye... nay... but...~
= ~I...~
= ~*sigh* Ye speak the truth, ye do... much as it grieves me ta say so. Rieltar... ye'll see me again, an' then yer time will come.~
== RIELTA ~My time is coming, dwarf... but not in the way you might think. Now scurry off while you still have legs!~
== BYESLI ~Gah! If I'm not gonna break his skull, praps we'd best find the masters o' this place an' get him arrested, or thrown out - that might jus' make our lives that little bit easier.~
EXIT

APPEND ~RIELTA~
// If Rieltar wins, and survived
IF WEIGHT #-1 ~Global("IRWAS","GLOBAL",2)~ IRWAS1
SAY ~That takes care of one annoyance... As for you - there may be safety for you in this library but I assure you, outside of here, there will be nowhere to hide for you!~
++ ~Your time is coming, Rieltar. The Iron Throne will not succeed!~ DO ~SetGlobal("IRWAS","GLOBAL",3)~ + IRWAS11
++ ~You... kllled Yeslick! Prepare to die, you swine!~ DO ~SetGlobal("IRWAS","GLOBAL",3)~ + IRWAS12
END

IF ~~ IRWAS12
SAY ~Some fight in you after all, eh? Then come - to your deaths!~
IF ~~ THEN DO ~Enemy() ActionOverride("Brunos",Enemy()) ActionOverride("Tuth",Enemy()) ActionOverride("Kestor",Enemy())~ EXIT //(Rieltar turns hostile)
END

IF ~~ IRWAS11
SAY ~My time is coming... but not in the way you might think. Now scurry off while you still have legs!~
IF ~~ THEN EXIT
END
END


APPEND ~YESLIJ~
// Yeslick, When Davaeorn Is Dead
IF WEIGHT #-1 ~Global("YWDID","GLOBAL",1)~ THEN YWDID1
SAY ~ An' the cruel bastard goes down! One line o' the grudge I owe the Throne... but not the last, not by a long shot. Come, let's search this place. Davaeorn had masters, an' those masters have an appointment wi' a warhammer I'd hate fer them ta miss.~
IF ~~ THEN DO ~SetGlobal("YWDID","GLOBAL",2)~ EXIT
END

// Yeslick, As The Party Reach The Upper Level Of The Cloakwood Mine, and the slaves have not been freed)

IF WEIGHT #-1 ~Global("X#YE_FreeSlaves","GLOBAL",1)~ THEN YATPRTULOTCM0
SAY ~Hold a moment. If'n we can, I would have us free the Throne's slaves afore we let free the water again. We should go back ta me cell... someone there can help us, I reckon.~
++ ~There's a chance to free these poor souls? Then we shall.~ DO ~SetGlobal("X#YE_FreeSlaves","GLOBAL",2)~ EXIT
++ ~I was forgetting... thank you for reminding me, Yeslick. To the lower levels!~ DO ~SetGlobal("X#YE_FreeSlaves","GLOBAL",2)~ EXIT
++ ~Someone in the cells? Well... hm, if you're sure.~ DO ~SetGlobal("X#YE_FreeSlaves","GLOBAL",2)~ EXIT
++ ~It would involve bribery, Yeslick - but we have not the money. We cannot.~ DO ~SetGlobal("X#YE_FreeSlaves","GLOBAL",2)~ + YATPRTULOTCM2
++ ~Bribery was the method suggested, I think - and I'm not coughing up cash for such pointless charity.~ DO ~SetGlobal("X#YE_FreeSlaves","GLOBAL",2)~ + YATPRTULOTCM3
++ ~We can't save them, Yeslick.~ DO ~SetGlobal("X#YE_FreeSlaves","GLOBAL",2)~ + YATPRTULOTCM4
END

IF ~~ YATPRTULOTCM2
SAY ~Aye, but that's easily solved! Davaeorn musta had a hoard o' gold or somethin' nearby... I'll bet if we find that, there'll be enough coin ta barter fer the freedom o' all these poor souls!~
++ ~Even so... I say we cannot free them.~ + YATPRTULOTCM4
++ ~Oh, very well! We'll go and see this prisoner you mention. Lead on, then...~ EXIT
++ ~I see nothing in these pathetic slaves worth the gold it would cost to save them.~ + YATPRTULOTCM6
END

IF ~~ YATPRTULOTCM3
SAY ~Ye canna be serious... I can hear yer jinglin' moneybags from here! How can ye not be willin' ta part with it ta save the lives o' these poor souls?~
++ ~Even so... I say we cannot free them.~ + YATPRTULOTCM4
++ ~Oh, very well! We'll go and see this prisoner you mention. Lead on, then...~ EXIT
++ ~I see nothing in these pathetic slaves worth the gold it would cost to save them.~ + YATPRTULOTCM6
END

IF ~~ YATPRTULOTCM4
SAY ~But... how can we flood the mine if we do not free all these men?~
++ ~This is the only working iron mine from Baldur's Gate to Nashkel, Yeslick... if we flood it, we could leave the Sword Coast starved of iron, even if the Throne do come back.~ + YATPRTULOTCM5
++ ~As long as we get out fine, I see no problem...~ + YATPRTULOTCM6
++ ~Oh, very well! We'll go and see this prisoner you mention, if it means so much.~ EXIT
END
IF ~~ YATPRTULOTCM5
SAY ~This ain't just some mine we're talkin' about here, this is the tomb o' me clan! I ain't jus' fought an' shed blood fer it ta be mined again! Ain't no-one goin' ta mine here, not ever, no more, no matter how short o' iron we get, ye understands?~ 
++ ~I'm sorry for my thoughtlessness, Yeslick. If you insist, then... lead on.~ EXIT
++ ~Apologies for your clan's undoubted suffering, Yeslick, but we need this place open and minable!~ + YATPRTULOTCM7
END
 
IF ~~ YATPRTULOTCM7
SAY ~Ye cannot bend? Neither can I. Me honour demands I defend it, come what may. I'll free the slaves meself, then, an' when the Throne come ta me clan's restin' place again I'll slay them all too... Go on, get goin', get out. I got heads ta bust.~
IF ~~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

IF ~~ YATPRTULOTCM6
SAY ~I won't stand fer it! Not in me clan's tomb! Ye'll hep me free 'em, or so help me, I'll...~
++ ~Oh, alright, if it'll stop your grumbling. Let's go see this prisoner, then.~ EXIT
++ ~Let them all drown, for all I care.~ + YATPRTULOTCM8
++ ~You want a fight, Dwarf, I'll gladly give you one!~ DO ~Enemy()~ EXIT
END

IF ~~ YATPRTULOTCM8
SAY ~Ye're just as bad as the Throne! I'll not have it... if ye won't free them, then I'll do it meself, ye hear? An' may Clangeddin have mercy on yer souls!~
IF ~~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

//Follow up to Free slaves: If Yeslick remains in the party, then set a timer - in a day, if the mine has not been flooded, Yeslick says
IF WEIGHT #-1 ~Global("X#YeslickReminderFlood","GLOBAL",2)~ YATPRTULOTCM9
SAY ~Are we not goin' ta save the slaves, then? The Throne still have me mine!~
++ ~Yes, we're going!~ DO ~SetGlobal("X#YeslickReminderFlood","GLOBAL",3)~ EXIT
++ ~No. We will not.~ DO ~SetGlobal("X#YeslickReminderFlood","GLOBAL",3)~  + YATPRTULOTCM10
END

IF ~~ YATPRTULOTCM10
SAY ~*sigh* Ye cannot bend? Neither can I. Me honour demands I defend the tomb o' me clan, come what may. I'll save 'em by meself, an' when the Throne comes ta me clan's restin' place again I'll slay them all too... Go on, get goin'.~
IF ~~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

// if Yeslick stays in the party, set another timer, for two days - if, at the end of this, the mine has STILL not been flooded, Yeslick says:)

IF WEIGHT #-1 ~Global("X#YeslickReminderFlood","GLOBAL",5)~ YATPRTULOTCM12
SAY ~Damn you! Me clan's tomb stands full o' sufferin' and ye dawdle! I'll not stand fer it! I'm goin' back ta defend it, no matter what ye think!~
IF ~~ THEN DO ~SetGlobal("X#YeslickReminderFlood","GLOBAL",6) LeaveParty()EscapeArea()~ EXIT
END

// Yeslick, If the party flood the mine without freeing the slaves

IF WEIGHT #-1 ~Global("YITPFTMWFTS","GLOBAL",1)~ YATPRTULOTCM14
SAY ~Ye're just as bad as the Throne! I'll not have it... Clangeddin have mercy on yer souls!~
IF ~~ THEN DO ~SetGlobal("YITPFTMWFTS","GLOBAL",2) LeaveParty() Enemy()~ EXIT
END 

///////////////////////////////////////////////////////////////

// Yeslick, If the Party leave the mine, and it has not been flooded
IF WEIGHT #-1 ~Global("X#YE_Flood","GLOBAL",1)~ YITPLTMNF0
SAY ~Wait! We must return, and flood the mine! With it drowned once more, we can flush out the Throne rats and seal me clan's tomb off ta boot! Davaeorn had the key... with haste, quickly!~
++ ~This is the only working iron mine from Baldur's Gate to Nashkel, Yeslick... if we flood it, we could leave the Sword Coast starved of iron, even if the Throne do come back.~ DO ~SetGlobal("X#YE_Flood","GLOBAL",2)~ + YITPLTMNF1
++ ~There's a way to flood the mine? Lead on!~ DO ~SetGlobal("X#YE_Flood","GLOBAL",2)~ EXIT
++ ~I almost forgot... thank you for reminding me, Yeslick.~ DO ~SetGlobal("X#YE_Flood","GLOBAL",2)~ EXIT
END

IF ~~ YITPLTMNF1
SAY ~This ain't just some mine we're talkin' about here, this is the tomb o' me clan! I ain't jus' fought an' shed blood fer it ta be mined again! Ain't no-one goin' ta mine here, not ever, no more, no matter how short o' iron we get, ye understands?~
++ ~I'm sorry for my thoughtlessness, Yeslick. If you insist, then... lead on.~ EXIT
++ ~Apologies for your clan's undoubted suffering, Yeslick, but we need this place open and minable!~ + YITPLTMNF2
END

IF ~~ YITPLTMNF2
SAY ~Ye cannot bend? Neither can I. Me honour demands I defend it, come what may. When the Throne comes ta me clan's restin' place again I'll slay them all too... Go on, get goin'.~ 
IF ~~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

// Yeslick, if remains in the party, then set a timer - in a day, if the mine has not been flooded (part 2)

IF WEIGHT #-1 ~Global("X#YeslickFlood1","GLOBAL",2)~ YITPLTMNF4
SAY ~Are we not goin' ta flood me mine, then? The Throne could come back an' take it fer themselves at any moment!~
++ ~Yes, we're going!~ DO ~SetGlobal("X#YeslickFlood1","GLOBAL",3)~ EXIT
++ ~No. We will not.~ DO ~SetGlobal("X#YeslickFlood1","GLOBAL",3)~ + YITPLTMNF5
END

IF ~~ YITPLTMNF5
SAY ~*sigh* Ye cannot bend? Neither can I. Me honour demands I defend the tomb o' me clan, come what may. An' when the Throne comes ta me clan's restin' place again I'll slay them all too... Go on, get goin'.~
IF ~~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

// Yeslick, if stays in the party, set another timer, for four days - if, at the end of this, the mine has STILL not been flooded
IF WEIGHT #-1 ~Global("X#YeslickFlood1","GLOBAL",5)~ YITPLTMNF7
SAY ~Damn you! Me clan's tomb stands open and ye dawdle! I'll not stand fer it! I'm goin' back ta defend it, no matter what ye think!~
IF ~~ THEN DO ~SetGlobal("X#YeslickFlood1","GLOBAL",6) LeaveParty() EscapeArea()~ EXIT
END

//Yeslick flooded and freed 
IF WEIGHT #-1 ~Global("X#YeslickLiturgy","GLOBAL",1)~ THEN BEGIN YELIT
SAY ~Let me stand awhile in silence to remember my kin. Let them rest in peace in their watery grave with the Iron Throne dogs not disturbing 'em.~
= ~That was deftly done, <CHARNAME>, 'twas.~
IF ~~ THEN DO ~SetGlobal("X#YeslickLiturgy","GLOBAL",2)~ EXIT
END

////////////////////////////////////////////////

// Yeslick, upon coming to Baldur's Gate for the first time
IF WEIGHT #-2 ~Global("YUCTBGFTFT","GLOBAL",1)~ YUCTBGFTFT1
SAY ~Ah, the city of Balduran's Gate. About as bustlin' a city as ye gets hereabouts... an' somewhere within, Rieltar waits fer me hammer. 'Tis good.~
IF ~~ THEN DO ~SetGlobal("YUCTBGFTFT","GLOBAL",2)~ EXIT
END

//WithRieltar

IF ~~ YWMR2B2
SAY ~Clangeddin demands vengeance, <CHARNAME>! For Clan Orothiar!~
++ ~This is not the way! We will not fight these men as they stand unawares! We are not assassins!~ + YWMR4
++ ~We are in a monastery, Yeslick! To spill blood here is a crime for which we'll all hang!~ + YWMR4
++ ~This was my home once... I would see as little blood spilt here as possible.~ + YWMR4
END

IF ~~ YWMR4
SAY ~But... if we let them go now, they'll hire more assassins, an' guards, and our job will be so much the harder - an' my clan lies restless every day this scum goes unpunished!~
++ ~Yes... yes, our job will be harder. And no doubt Rieltar here will hire every bounty hunter and lowlife in the Realms to fight us. Because he's evil. And we're not. And we'll *still* win, do you hear me?~ EXTERN ~YESLIJ~ YWMR2B20
++ ~Your clan would not want to see you throw away the honour you have in their name, Yeslick. They - and we - can wait for this man's death.~ EXTERN ~YESLIJ~ YWMR2B20
++ ~Don't lose yourself to your anger, Yeslick!~ + YWMR2B3 //(go to block three)
++ ~If you fight him, you're on your own!~ + YWMR2B4 //(go to block four)
++ ~By the gods, you're right! Who needs all that? Prepare to die, Rieltar!~ + YWMR2B5 //(go to block five)
END

IF ~~ YWMR2B3
SAY ~I'd rather kill in the heat o' battle than in cold blood like *this* scum! Vengeance is here, Rieltar! FOR CLAN OROTHIAR!~
IF ~~ THEN DO ~SetGlobal("YRACTH","GLOBAL",1)~ EXIT //(Rieltar and company turn hostile)
END

IF ~~ YWMR2B4
SAY ~Ye... ye will not aid me? I... thought better of ye than this, <CHARNAME>, but so be it! Vengeance is here, Rieltar! FOR CLAN OROTHIAR!~
IF ~~ THEN DO ~LeaveParty() Attack("Rieltar") ActionOverride("Rieltar",Attack("Yeslick")) ActionOverride("Brunos",Attack("Yeslick")) ActionOverride("Tuth",Attack("Yeslick")) ActionOverride("Kestor",Attack("Yeslick")) SetGlobal("IRWAS","GLOBAL",1)~ EXIT //(Yeslick leaves party - fights Rieltar)
END

IF ~~ YWMR2B5
SAY ~Aye! Vengeance is here, Rieltar! FOR CLAN OROTHIAR!~
IF ~~ THEN DO ~SetGlobal("YRACTH","GLOBAL",1)~ EXIT //(Rieltar goes hostile)
END

// Yeslick, killed Rieltar, Brunos, Tuth, Kestor
IF WEIGHT #-2 ~Global("YKRBTK","GLOBAL",1)~ YKRBTK1
SAY ~*spit* Rot in yer own hell, merchant scum! Praise be to Clangeddin, me job's done, me grudges paid in full... an' no thanks ta ye, <CHARNAME>, none o' ye!~
++ ~What you have done is murder, Yeslick, pure and simple.~ DO ~SetGlobal("YKRBTK","GLOBAL",2)~ + YKRBTK2
++ ~What are you complaining about? You handled yourself pretty well on your own.~ DO ~SetGlobal("YKRBTK","GLOBAL",2)~+ YKRBTK2
++ ~Yeah, yeah, whatever. Now get back in line, we're moving on.~ DO ~SetGlobal("YKRBTK","GLOBAL",2)~+ YKRBTK2
END

IF ~~ YKRBTK2
SAY ~Perhaps. But *I* am goin', see? Me grudge is paid, I gots no more reason to hang around cowards an' yellow swine like ye!~ //(Yeslick leaves party)
IF ~~ THEN DO ~EscapeArea() LeaveParty()~ EXIT
END

// If Yeslick and the party fight Rieltar and win
IF WEIGHT #-2 ~Global("YRACTH","GLOBAL",3)~ YATPFRAW1
SAY ~*spit* Rot in yer own hell, merchant scum! Praise be to Clangeddin, me job's done, me grudges paid in full... and Rieltar lays there with his brain-pan open to the air! I thank ye, <CHARNAME>, all of ye, fer this...~
++ ~I'm glad we found justice for you, Yeslick. We'd better go, though.~ DO ~SetGlobal("YRACTH","GLOBAL",4)~ + YATPFRAW2 //(go to block two)
++ ~I hope this passes as justice wherever you'll end up, Yeslick. It feels like murder to me.~ DO ~SetGlobal("YRACTH","GLOBAL",4)~ + YATPFRAW3 //(go to block three)
++ ~You maniac! We'll be lucky if we get out of the keep now, let alone the gates!~ DO ~SetGlobal("YRACTH","GLOBAL",4)~ + YATPFRAW4 //(go to block four)
END

IF ~~ YATPFRAW2
SAY ~Aye, it would do no good for any of us if we all ended up in a cell again.. come on, let's find the masters o' this place and tell 'em why we did this.~ 
IF ~~ THEN EXIT
END

IF ~~ YATPFRAW3
SAY ~Murder? Nay, justice this is, <CHARNAME>. This criminal tortured and killed and ruined fer nothin' more than gold. I'll sleep easy at night knowin' he's dead. Ye should too. Now, I think we'd best let th' heads o' this monastery what we've done, an' why, before the monks have time to disagree!~
IF ~~ THEN EXIT
END

IF ~~ YATPFRAW4
SAY ~What... what did ye think I was gonna do, <CHARNAME>? Bid him a good day? Shake the monster's hand? Ye thought he'd not recognise me if I did? This scum would have killed us all without a second thought if we stood against him! Best we finished it now, than wade through a tide of assassins all the way to Baldur's Gate! Come on, we'd better tell the heads o' this place what we've done an' why, eh?~
IF ~~ THEN EXIT
END

/////////////////////////////////////////////////////////////////
// Yeslick, Chapter Seven
IF WEIGHT #-2 ~Global("YChapter7","GLOBAL",1)~ YChapter71
SAY ~Ye find out, at last, whose hand did the deed o' th' killin' o Gorion, <CHARNAME>. Let us make haste, an' find this wretch who shares yer blood! Yer Clan calls for vengeance!~
++ ~But if he is my brother... what do dwarven laws say about killing one's own brother?~ DO ~SetGlobal("YChapter7","GLOBAL",2)~ + YChapter72 //(go to block two)
++ ~My 'clan' is no longer a simple matter of blood, Yeslick.~ DO ~SetGlobal("YChapter7","GLOBAL",2)~+ YChapter73 //(go to block three)
++ ~You did not know Gorion. He would not have wanted me to kill in his name.~ DO ~SetGlobal("YChapter7","GLOBAL",2)~ + YChapter74 //(go to block four)
++ ~Vengeance be damned. If he is the one who would stand in my way, then he will die.~ DO ~SetGlobal("YChapter7","GLOBAL",2)~+ YChapter75 //(go to block five)
++ ~Right you are, Yeslick. Onward! ~ DO ~SetGlobal("YChapter7","GLOBAL",2)~ EXIT
END

IF ~~ YChapter72
SAY ~In answer ta that, I reckon the letter o' dwarf law an' saga states: 'It don't matter if ye kill yer brother if he was an evil clan-killin' dishonourable bastard'. Don't ye worry about that, <CHARNAME>. We'll kill him, an' all who stand between us an' him... an' we'll let the Gods sort 'em out afterwards.~
++ ~Then that's what we'll do!~ EXIT
++ ~No... Gorion would not want me to kill a man in his name, no matter the circumstances.~ + YChapter74 //(go to block four)
++ ~We'll just have to see what happens.~ EXIT
END

IF ~~ YChapter73
SAY ~Twaddle, <PRO_GIRLBOY>. Ye may have the blood o' a god in yer veins, true... an' p'raps Gorion weren't yer true family after all. Blood may be thicker'n water, but by all that's sacred, he raised ye, armed ye with what knowledge he could, an' fought for ye. He kept his oaths ta ye, even if ye never heard him speak 'em. Honour is the tie that binds, an' that's what needs avengin', <CHARNAME>!~
++ ~You speak the truth. So be it, then.~ EXIT
++ ~No. Gorion would not have wanted me ta kill in his name.~ + YChapter74 //(go to block four)
++ ~We'll just have to do what he must.~ EXIT
IF ~~ EXIT
END

IF ~~ YChapter74
SAY ~So says ye... I wonder what the man himself would say if he could. Well, then, if this Sarevok is the monster we all fear, an' he holds the Sword Coast in 'is grip, an' he is the centre of all this evil, <CHARNAME>... what then? Should he not deserve ta die?~
++ ~The only thing that matters now is our heritage. He wants the crown of the God of Murder - he'll have to fight me for it!~ + YChapter75 //(go to block five)
++ ~Yes... if he is the one who has done all this, then we shall kill him - and send him to the Abyss!~ + YChapter75
++ ~You or I cannot judge that, Yeslick. If I do kill him, I will kill him because I must... not because I want to.~ + YChapter74a
++ ~It's not about killing. It's about saving the lives of others, Yeslick.~ + YChapter74a
END

IF ~~ YChapter74a
SAY ~Ye think so...? Well, my way is Clangeddin's way, but... it seems ye've learned a lot on yer travels, <CHARNAME>. Remember this, then... ol' Yeslick is here, an' he's proud o' ye. I'll be by yer side when the final stroke needs ta fall.~ // (end)
IF ~~ EXIT
END

IF ~~ YChapter75
SAY ~Your voice is changed, <PRO_GIRLBOY>... an' I see a fey light in yer eyes when ye speak o' such things. Is that power all ye care about, now? I'd expected better. Beware... mortals were not meant ta covet such things, an' all those who have done have come ta bad ends... or gotten what they wished, an' suffered fer it.~
++ ~I... I'm sorry. I only mean to stop Sarevok from fulfilling the prophecies. But the taint is in me... I do not know what will happen.~ + YChapter75a
++ ~I think this is my destiny, Yeslick, whether I like it or not. If it is, I will not shie from it.~ + YChapter75a
++ ~Your wisdom is nothing but temerity. I will take what I can - I will not let this chance pass me by!~ + YChapter75a
END

IF ~~ YChapter75a 
SAY ~*sigh* So be it. Remember this, then, <CHARNAME>, as ye go ta the fight... ol' Yeslick is here, an' he'll do what's best fer ye. No matter what that may be...~ // (end)
IF ~~ EXIT
END


// Yeslick, When in the lower levels of Durlag's Tower
IF WEIGHT #-2 ~Global("YWITLLODT","GLOBAL",1)~ YWITLLODT1
SAY ~By Clangeddin... I... I never thought to see...~
++ ~Are you alright, Yeslick?~ DO ~SetGlobal("YWITLLODT","GLOBAL",2)~ + YWITLLODT2 //(go to block two)
++ ~What? What do you see, Yeslick? Danger?~ DO ~SetGlobal("YWITLLODT","GLOBAL",2)~ + YWITLLODT3 //(go to block three)
++ ~Some of us are trying to concentrate here, Yeslick. Be quiet.~ DO ~SetGlobal("YWITLLODT","GLOBAL",2)~ + YWITLLODT4 //(go to block four)
END

IF ~~ YWITLLODT2
SAY ~Aye, aye, I'm alright. It's this place that's not. It stinks of sorrow... it's everywhere. It's like an open grave. I never thought ta see a place that so reminds me of me home.~
IF ~~ EXIT
END

IF ~~ YWITLLODT3
SAY ~Danger? Nay... I can see more'n that. The workmanship o' the passages, excellent... the carvings on the walls, craftworthy... the bones on the floor, dwarven... and the sorrow. It's everywhere, this place stinks of it. Like an open grave. This place... reminds me o' home.~
IF ~~ EXIT
END

IF ~~ YWITLLODT4
SAY ~Oi, oi, keep yer hair on. Just more o' the old dwarf's nonsense, don't you worry 'bout it. Keep walkin'.~
++ ~Just stay alert, old dwarf! Ok?~ + YWITLLODT4a
++ ~I'm sorry, Yeslick. Places like this put me on edge.~ + YWITLLODT5 //(go to block five)
END

IF ~~ YWITLLODT4a
SAY ~Just ye keep yer own eyes on the path ahead, aye? I'll see ta me own, thank yer very much. *grumble*~
IF ~~ EXIT
END

IF ~~ YWITLLODT5
SAY ~*sigh* I can understand that, <CHARNAME>. This place stinks o' sorrow. S'like an open grave. This place... reminds me o' me home.~
IF ~~ EXIT
END
END


