BEGIN ~X#ALORA~

//PC talk Script

APPEND ~ALORAJ~

IF WEIGHT #-2 ~
Global("AlFriendTalk","GLOBAL",1)
~ THEN BEGIN ALPC1
SAY ~Hey <CHARNAME>, next tavern we go in, lets have a party!~ [ALORA99]
IF ~InParty("IMOEN2")~ THEN EXTERN BIMOEN2 ALPCwIM
IF ~!InParty("IMOEN2")~ THEN GOTO AL1PCTALK
END 

IF ~~ AL1PCTALK
  SAY ~What d'ya say? Pleease...let's have a party!~
  IF ~InParty("KIVAN") !InParty("XAN")~ THEN REPLY ~Sure, why not?~ DO ~SetGlobal("ALPC1","LOCALS",1)~ GOTO ALPC1.1KIV
IF ~InParty("XAN") !InParty("KIVAN") ~ THEN REPLY ~Sure, why not?~ DO ~SetGlobal("ALPC1","LOCALS",1)~ GOTO ALPC1.1XAN
IF ~InParty("XAN") InParty("KIVAN") ~ THEN REPLY ~Sure, why not?~ DO ~SetGlobal("ALPC1","LOCALS",1)~ GOTO ALPC1.1KX
IF ~!InParty("XAN") !InParty("KIVAN")~ THEN REPLY ~Sure, why not?~ DO ~SetGlobal("ALPC1","LOCALS",1)~ GOTO ALPC1.1
IF ~~ THEN REPLY ~Heh, why would you want a party? ~ DO ~SetGlobal("ALPC1","LOCALS",1)~ GOTO ALPC1.2
IF ~~ THEN REPLY ~Don't be so ridiculous.~ DO ~SetGlobal("ALPC1","LOCALS",1)~ GOTO ALPC1.3
END

IF ~~ ALPC1.1KIV
SAY ~Great! We really need to cheer up that ol' misery guts, Kivan.~
IF ~~ THEN REPLY ~Yeah, I know what you mean.~  GOTO ALPC1.4
IF ~~ THEN REPLY ~Hey! Give him a break, Alora. He is still in mourning for his wife, you know~ GOTO ALPC1.5
IF ~~ THEN REPLY ~If you say so. But lets concentrate on the quest for now, okay?~ GOTO ALPC1.6
END

IF ~~ ALPC1.1XAN
SAY ~Great! We really need to cheer up that ol' misery guts, Xan.~
IF ~~ THEN REPLY ~Yeah, I know what you mean.~  GOTO ALPC1.4
IF ~~ THEN REPLY ~Hey! Give him a break, Alora. That's just the way he is.~ GOTO ALPC1.5
IF ~~ THEN REPLY ~If you say so. But lets concentrate on the quest for now, okay?~ GOTO ALPC1.6
END

IF ~~ THEN BEGIN ALPC1.1KX
SAY ~Great! We really need to cheer up those two misery guts, Kivan and Xan, you've got following us around!~
IF ~~ THEN REPLY ~Yeah, I know what you mean.~  GOTO ALPC1.4
IF ~~ THEN REPLY ~Hey! Give them a break, Alora. Kivan's still in mourning for his wife, and Xan's just... Xan.~ GOTO ALPC1.5
IF ~~ THEN REPLY ~If you say so. But lets concentrate on the quest for now, okay?~ GOTO ALPC1.6
END

IF ~~ THEN BEGIN ALPC1.1
SAY ~Great! We really need to cheer up some of those misery guts you've got following us around!~
IF ~~ THEN REPLY ~Yeah, I know what you mean.~  GOTO ALPC1.4
IF ~~ THEN REPLY ~Hey! Give them a break, Alora. I'm sure they all have their reasons.~ GOTO ALPC1.5
IF ~~ THEN REPLY ~If you say so. But lets concentrate on the quest for now, okay?~ GOTO ALPC1.6
END

IF ~~ THEN BEGIN ALPC1.2
SAY ~We haven't had any fun in a while... well, those of us who don't get their fun out of killin' stuff haven't, anyway!~
IF ~InParty("KIVAN") !InParty("XAN")~ THEN REPLY ~Heh, you have a point... sure, why not?~ GOTO ALPC1.1KIV
IF ~InParty("XAN") !InParty("KIVAN")~ THEN REPLY ~Heh, you have a point... sure, why not?~ GOTO ALPC1.1XAN
IF ~InParty("XAN") InParty("KIVAN")~ THEN REPLY ~Heh, you have a point... sure, why not?~ GOTO ALPC1.1KX
IF ~!InParty("XAN") !InParty("KIVAN")~ THEN REPLY ~Heh, you have a point... sure, why not?~ GOTO ALPC1.1
IF ~~ THEN REPLY ~Fun? The entire Sword Coast is in danger and you want to have fun?~ GOTO ALPC1.3
END

IF ~~ THEN BEGIN ALPC1.3
SAY ~Hey, it was only an idea. Don't tell me you're gonna be a misery guts too!~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN ALPC1.4
SAY ~Hey everyone, <CHARNAME> says we're gonna have a party!~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN ALPC1.5
SAY ~ *Pouts* Well, that's all the more reason to cheer everyone up with a bit o' fun then, isn't it?~
IF ~~ THEN REPLY ~Fun? The entire Sword Coast is in danger and you want to have fun?~ GOTO ALPC1.3
IF ~~ THEN REPLY ~Yeah, I know what you mean.~  GOTO ALPC1.4
END


IF ~~ THEN BEGIN ALPC1.6
SAY ~Well you can, but I've gotta start planning this thing... Where to start?~
IF ~~ THEN GOTO NPC_React
END
END

CHAIN3 ~ALORAJ~ NPC_React
~Ooh I know, party hats! Yep!~
== ~BAJANT~ IF ~InParty("AJANTIS")~ THEN ~An excellent idea. Even a paladin needs his ale occasionally.~
== ~BBRANW~ IF ~InParty("BRANWEN")~ THEN ~It is about time we raised a tankard to Tempus, in celebration of our glorious deeds.~
== ~BCORAN~ IF ~InParty("CORAN")~ THEN ~You will be choosing a tavern with plenty of fine maids, I hope?~
== ~BDYNAH~ IF ~InParty("DYNAHEIR")~ THEN ~T'will be nice to relax for awhile.~
== ~BEDWIN~ IF ~InParty("EDWIN")~ THEN ~Finally! (it's about time those fools held a celebration in my honor!)~
== ~BELDOT~ IF ~InParty("ELDOTH")~ THEN ~Ah, it's about time! I'd almost forgotten the last time I had decent ale inside me.~
== ~BSKIE~ IF ~InParty("ELDOTH") InParty("SKIE")~ THEN ~You won't be having too many, I hope?~
== ~BELDOT~ IF ~InParty("ELDOTH") InParty("SKIE")~ THEN ~I shall drink as much as I like, woman.~
== ~BFALDO~ IF ~InParty("FALDORN")~ THEN ~Must you always come up with stupid excuses to prolong our stay in wretched settlements? Grrr! Beware, for the Oak Father frowns upon you now.~
== ~BGARRI~ IF ~InParty("GARRICK")~ THEN ~Wonderful! I shall have to compose a new ballad especially for the occasion!~
== ~BIMOEN2~ IF ~InParty("IMOEN2")~ THEN ~Ooh, I better start getting ready...~
== ~BJAHEI~ IF ~InParty("JAHEIRA") InParty("KHALID")~ THEN ~A party? Is this true, <CHARNAME>? I don't think we have time for this...~
== ~BKHALI~ IF ~InParty("JAHEIRA") InParty("KHALID")~ THEN ~N-nonsense Jaheira, dear! After all, was it not in an inn that we first met <CHARNAME>?~
== ~BJAHEI~ IF ~InParty("JAHEIRA") InParty("KHALID")~ THEN ~Well yes, but...~
== ~BJAHEI~ IF ~InParty("JAHEIRA") !InParty("KHALID")~ THEN ~A party? Is this true, <CHARNAME>? I don't think we have time for this... Especially not with Khalid... not with him...around *sobs*~
== ~BKAGAI~ IF ~InParty("KAGAIN")~ THEN ~About blasted time! Ya'd better find a tavern with some decent Dwarven ales though, 'cos I can't stand any of that human muck.~
== ~BKHALI~ IF ~!InParty("JAHEIRA") InParty("KHALID")~ THEN ~Please, <CHARNAME>, I'm n-not sure I could s-stand a party, not after Jaheira... after she...*sobs*~
== ~BKIVAN~ IF ~InParty("KIVAN")~ THEN ~You well deserve a moment of respite, comrades. I will stand watch to assure that you will not be caught unaware amongst the merriment.~
== ~BMINSC~ IF ~InParty("MINSC")~ THEN ~Drinks for all! Drinks for Minsc and Boo, and everyone else too!~
== ~BDYNAH~ IF ~InParty("DYNAHEIR") InParty("MINSC")~ THEN ~Minsc, I do not think t'would be wise of thee to gift thy hamster spirits...~
== ~BMINSC~ IF ~InParty("DYNAHEIR") InParty("MINSC")~ THEN ~Oh no, I would never give Boo anything but the finest spring water!~
== ~BMONTA~ IF ~InParty("MONTARON")~ THEN ~Aye, a decent ale's almost as good as a decent killin'...~
== ~BQUAYL~ IF ~InParty("QUAYLE")~ THEN ~The first round is on you, of course.~
== ~BSAFAN~ IF ~InParty("SAFANA")~ THEN ~Ooh, sounds wonderful, darling!~
== ~BSHART~ IF ~InParty("SHARTEEL")~ THEN ~I hope we will end up in a good bar fight after we are done drinking. Now that’s what I call fun!~
== ~BSKIE~ IF ~InParty("SKIE")~ THEN ~I remember sneaking out to the local tavern when I was still living at home. This should be fun!~
== ~BTIAX~ IF ~InParty("TIAX")~ THEN ~Yes, yes! An orgy of drink and food and other such things shall please Cyric greatly! Tiax will choose the sacrificial victim himself!~
== ~BVICON~ IF ~InParty("VICONIA")~ THEN ~It will be nice to relax for once... although nothing can compare with the orgies of Menzoberranzan...~
== ~BXANNN~ IF ~InParty("XAN")~ THEN ~Have you ever heard a tale of the feast during the plague outbreak and of the fate of its participants? It is said that the Black Death itself came amongst the empty-headed nobles who wanted to make merriment, ignoring it? It is a fine story, and perhaps I should recite it to you during this…feast the halfling is suggesting.~
== ~BXZAR~ IF ~InParty("XZAR")~ THEN ~Mummy said I shouldn't have parties when she's not there...~
== ~BMONTA~ IF ~InParty("MONTARON") InParty("XZAR")~ THEN ~Bah, yer mother's dead, ye stupid mage.~
== ~BXZAR~ IF ~InParty("MONTARON") InParty("XZAR")~ THEN ~No! You're lying! Mummy's still alive... and she still loves me too!~
== ~BYESLI~ IF ~InParty("YESLICK")~ THEN ~Aye! It's been too long since I heard fine words like that! Bring on the ale... it be time to wash away the cobwebs in me gullet!~
DO ~SetGlobal("AlFriendTalk","GLOBAL",2)~
EXIT

APPEND BIMOEN2

IF ~False()~ THEN BEGIN ALPCwIM
SAY ~Great idea! Can we, <CHARNAME>, please? PLEASE?~
IF ~~ THEN EXTERN ~ALORAJ~ AL1PCTALK
END
END

APPEND ~ALORAJ~

//PC Talk Script

IF WEIGHT #-2 ~
Global("AlFriendTalk","GLOBAL",3)
Global("ALIM3","LOCALS",0)~ THEN BEGIN ALIM3
SAY ~Hey Imoen!~ [ALORA99]
IF ~~ THEN EXTERN BIMOEN2 AL3IMCHAIN
END

IF ~False()~ THEN BEGIN AL3IMTALK
SAY ~Tee-hee! That I am!~
IF ~~ THEN REPLY ~Imoen?  What've you got there?~ GOTO ALIM1.1
IF ~~ THEN REPLY ~Cut it out you two, we've got work to do.~ GOTO ALIM1.2
IF ~~ THEN REPLY ~This is not the place for childish games.  Either grow up or leave.~ GOTO ALIM1.3
END

IF ~~ THEN BEGIN ALIM1.1
SAY ~Nothing!  Say, let's get back to work, eh? ~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN ALIM1.2
SAY ~Sure thing, boss!~
IF ~~ THEN EXIT
END
END

CHAIN3 ~ALORAJ~ ALIM1.3
~* Whispering * Is <PRO_HESHE> always this grumpy? Always this bossy?~
== BIMOEN2 ~Nah.  At least, <PRO_HESHE> wasn't before...~
EXIT

CHAIN3 BIMOEN2 AL3IMCHAIN
~Yeah?~
== ~BALORA~ ~Catch!~
== BIMOEN2 ~No fair, I wasn't looking!  What are y... Mr. Hunny Bunny!~
== ~BALORA~ ~Heh, I took him from your pack while you were sleeping.~
== BIMOEN2 ~Hmph.  I guess you must be an okay thief then.  I thought I had him pretty well-hidden in there..~
END  ~ALORAJ~ AL3IMTALK

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("AJANTIS")
See("AJANTIS")
!StateCheck("AJANTIS",STATE_SLEEPING)
!Class(Player1,"PALADIN")
Global("ALAJ1","LOCALS",0)~ THEN ~BALORA~ ALAJ1
~Ajantis, isn’t it? Wow, I've never met a paladin before!~ [ALORA99]
DO ~SetGlobal("ALAJ1","LOCALS",1)~
== ~BAJANT~ ~Indeed?~
== ~BALORA~ ~Yep.  If you don’t mind me saying, though, you seem a little serious.  Anyone who can’t have a bit of fun is pretty boring in my book!  Are other paladins like that?~
== ~BAJANT~ ~I am *not* boring!~
== ~BALORA~ ~Sure you are. You really need to lighten up a bit!~
== ~BAJANT~ ~*Sigh* I haven't the time for this.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("AJANTIS")
See("AJANTIS")
!StateCheck("AJANTIS",STATE_SLEEPING)
Global("ALAJ1","LOCALS",1)
Global("ALAJ2","LOCALS",0)~ THEN ~BALORA~ ALAJ2
~So what's it like being a big, brave knight, Ajantis?~ [ALORA99]
DO ~SetGlobal("ALAJ2","LOCALS",1)~
== ~BAJANT~ ~It's, uh... it's... beyond your comprehension, little one.~
== ~BALORA~ ~He-he, you just can't think of the right words, can you?~
== ~BAJANT~ ~Of course I can!  It's just that words cannot describe the way a paladin feels about his duty.~
== ~BALORA~ ~How do old paladins teach the new paladins what they're supposed to do then?~
== ~BAJANT~ ~Well they... that is... they just know, all right?~
== ~BALORA~ ~He-he, sure.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
!StateCheck("CORAN",STATE_SLEEPING)
Alignment("CORAN",CHAOTIC_NEUTRAL) Global("BRIEL_STAY","GLOBAL",2)
Global("ALCO1","LOCALS",0)~ THEN ~BALORA~ ALCO1
~So you're an elf, Coran?~[ALORA99]
DO ~SetGlobal("ALCO1","LOCALS",1)~
== ~BCORAN~ ~I would have thought that would be fairly obvious.  The ears, the hair and the fact that I'm not dog ugly...~
== ~BALORA~ ~Come on, not all humans are ugly!~
== ~BCORAN~ ~There are fair humans around, but I wasn't just meaning them.  I understand your mistake, though, for unless I was a particularly tall gnome, I could look a human in a halfling’s eyes. But to my original point, I've yet to meet an especially good-looking dwarf.~
== ~BALORA~ ~Or a halfling?~
== ~BCORAN~ ~I have already met one, sweet Alora.~
== ~BALORA~ ~*blushing * Umm, err, t-thanks.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
!StateCheck("CORAN",STATE_SLEEPING)
Global("ALCO1","LOCALS",1)
Alignment("CORAN",CHAOTIC_NEUTRAL) Global("BRIEL_STAY","GLOBAL",2)
Global("ALCO2","LOCALS",0)~ THEN ~BALORA~ ALCO2
~You know, Coran, the attitude of your kin towards other races...~[ALORA99]
DO ~SetGlobal("ALCO2","LOCALS",1)~
== ~BCORAN~ ~Yes, I really should apologize for it.  It is one of the few flaws of my people.~
== ~BALORA~ ~But don't you remember, you once told me how you found most non-elves to be ugly...~
== ~BCORAN~ ~An ill-advised jest, I assure you.  In truth, beauty is evident in all the world's creatures.~
== ~BALORA~ ~Urgh... even with something like beholders?~
== ~BCORAN~ ~To us such alien creatures seem disgusting, yes.  But beauty is... heh, beauty is in the eye of the beholder, I suppose.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("CORAN")
See("CORAN")
!StateCheck("CORAN",STATE_SLEEPING)
Alignment("CORAN",CHAOTIC_GOOD) Global("CoranHasBaby","GLOBAL",1)
Global("ALCO3","LOCALS",0)~ THEN ~BALORA~ ALCO3
~So, when are you going to make all your relatives happy and bring Namara to Tethyr? ~[ALORA99]
DO ~SetGlobal("ALCO3","LOCALS",1)~
== ~BCORAN~ ~I am not sure I am going to do that, Alora.~
== ~BALORA~ ~Huh, why? ~
== ~BCORAN~ ~You see, Namara is not an elf.~
== ~BALORA~ ~She sure looks elfin enough to me!~
== ~BCORAN~ ~I am afraid she would not be elf enough for my relatives.  Alora, in Tethyr, the relationships between humans and elves are not very warm, to say the least. Some among my kin would call me a racial criminal and a father of a half-breed.~
== ~BALORA~ ~Oh my!  Who would think like that?  They sound really horrible!~
== ~BCORAN~ ~It is a rather complicated issue, but these people, they do speak... no, they *think* the worst kind of nonsense, Alora. The kind that hurts.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("DYNAHEIR")
See("DYNAHEIR")
!StateCheck("DYNAHEIR",STATE_SLEEPING)
Global("ALDY1","LOCALS",0)~ THEN ~BALORA~ ALDY1
~You know, Miss Dynaheir, it must be exciting to hurl all that magic around.~[ALORA99]
DO ~SetGlobal("ALDY1","LOCALS",1)~
== ~BDYNAH~ ~Exciting?  Perhaps.  But with such power cometh great responsibility.~
== ~BALORA~ ~Err, yeah.  Hey, maybe you could teach me how to cast a magic missile or two?~
== ~BDYNAH~ ~Child, it taketh much studying to be able to correctly perform even the simplemost incantation.~
== ~BALORA~ ~Oh.  Well, I don't really have time for that, I guess.  I'll just have to stick to sneakin' and stuff.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("DYNAHEIR")
See("DYNAHEIR")
!StateCheck("DYNAHEIR",STATE_SLEEPING)
InParty("MINSC")
See("MINSC")
!StateCheck("MINSC",STATE_SLEEPING)
Global("ALDY2","LOCALS",0)~ THEN ~BALORA~ ALDY2
~Say, Dynaheir, you and Minsc are pretty close, eh?~[ALORA99]
DO ~SetGlobal("ALDY2","LOCALS",1)~
== ~BDYNAH~ ~Minsc is mine protector, Alora. It is his duty to stay close to me.~
== ~BALORA~ ~Has he always been this... umm, funny?~
== ~BDYNAH~ ~Girl, Minsc is a great warrior of Rashemen, not a circus clown!  Is that not right, Minsc?~
== ~BMINSC~ ~Aye, that is true Dynaheir. But Minsc can be funny too!~
== ~BALORA~ ~Go on, tell us a joke!~
== ~BMINSC~ ~Quickly Boo, think of something funny.  What's that?  Oh my!~
== ~BALORA~ ~So?  What's the joke?~
== ~BMINSC~ ~Minsc is thinking that you are too young to hear this one.  What?  Boo, stop it!  Hahahaha!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("ALED1","LOCALS",0)~ THEN ~BALORA~ ALED1
~So you're a mage?  I knew a mage once but he was pretty stuffy.  You're not like that.~[ALORA99]
DO ~SetGlobal("ALED1","LOCALS",1)~
== ~BEDWIN~ ~'Tis welcome you find no fault with one such as I.~
== ~BALORA~ ~Everyone is basically decent, once you get them to unwrinkle their faces.~
== ~BEDWIN~ ~If that is what you wish to believe, then... hold on... wrinkles? (It cannot be!)~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("ALED2","LOCALS",0)~ THEN ~BALORA~ ALED2
~Smile more often, Edwin.  It looks good on you.~ [ALORA99]
DO ~SetGlobal("ALED2","LOCALS",1)~
== ~BEDWIN~ ~(Her company is refreshing but I am surprised I find it so) I prefer a glare to a smile.  I find it's much more intimidating.~
== ~BALORA~ ~Hey, you're too nice to be intimidating!~
== ~BEDWIN~ ~If you truly knew me, you wouldn't be saying that (or would she? Hmm, I wonder...)~
== ~BALORA~ ~I'd like to get to know you, Edwin!~
== ~BEDWIN~ ~I usually don't have time for idle chatter.  But perhaps this once I'll make an exception (yes, I think I will).  Come, walk with me and listen awhile.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("ALED3","LOCALS",0)~ THEN ~BALORA~ ALED3
~Hey Edwin, I hope you've been keeping up with your studies in creative casting?~ [ALORA99]
DO ~SetGlobal("ALED3","LOCALS",1)~
== ~BEDWIN~ ~A master such as myself does not need to follow such useless routines!  Those banalities are meant for the moronic mages and the weak of mind! (How did she find those scrolls?  I thought I hid them well!)~
== ~BALORA~ ~Weeellllll.... in that case, maybe I could ask you a teeny-weeny little favour?~
== ~BEDWIN~ ~(I'm strangely curious about what she could possibly have in mind) That depends on what this 'favour is'... err, and how busy I am with other, more important matters, of course.~
== ~BALORA~ ~I was just wondering... could you teach me some magic tricks? Please? Please?!!~
== ~BEDWIN~ ~Well, a good mage (and obviously I am far more than just a *good* mage) needs a firm grasp of the theories behind the inner works of the Arts Magica as well as a quick mind to be able to cast even the simplest of spells.~
== ~BALORA~ ~Are you saying I'm too dumb to be able to cast a spell? *pouts*~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("ALED4","LOCALS",0)~ THEN ~BALORA~ ALED4
~Edwin... I like you, but it seems you always want to make yourself feel so... so superior to everyone else.  Why don't you just, you know, be nice to people?~ [ALORA99]
DO ~SetGlobal("ALED4","LOCALS",1)~
== ~BEDWIN~ ~Girl, I don't need to make myself feel superior to everyone else, I *am* superior. We, the Thayvians, have neither the inclination nor the time to be *nice* to people.~
== ~BALORA~ ~Can't you just... I dunno, sink to their level or something? Sometimes?~
== ~BEDWIN~ ~As I said, I do not have time to deal with the foolishness of others, and especially not to act like a fool myself.~
== ~BALORA~ ~Do you think I'm a fool then?~
== ~BEDWIN~ ~I didn't say that. The fact that I am apparently willing to listen to your blabbering, places you well above the others… And no, I do not have an explanation for it.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("EDWIN")
See("EDWIN")
!StateCheck("EDWIN",STATE_SLEEPING)
Global("ALED5","LOCALS",0)~ THEN ~BALORA~ ALED5
~Edwin? Edwin!~ [ALORA99]
DO ~SetGlobal("ALED5","LOCALS",1)~
== ~BEDWIN~ ~What?  What is so important that you feel the urge to interrupt my vital studies... I mean research?~
== ~BALORA~ ~Have you seen my Lucky Rabbit's foot?~
== ~BEDWIN~ ~No, I can't say that I have. Leave me be now.~
== ~BALORA~ ~You sure?  I had it just a few moments ago.  Did you take it?~
== ~BEDWIN~ ~I'll not have you accusing me of stealing that hairy thing! (And what would I want with a disembodied rabbit's foot anyway?)~
== ~BALORA~ ~I really, really need it!  I accidentally broke a mirror two years ago, and I still have to ward off five years of bad luck!~
== ~BEDWIN~ ~The amount of faith you put into silly superstitions amazes me.~
== ~BALORA~ ~Oh, no... oh, no!  It has to be here!  It has to be!~
== ~BEDWIN~ ~Come to your senses, silly girl!  Losing that damnable foot isn't the end of the world.  (To her, getting a hangnail would be the end of the world, I gather...)~
== ~BALORA~ ~Eddie!  Look! It's there!  You're sitting on it!~
== ~BEDWIN~ ~Eh?  (So that was why I have been so uncomfortable all this time...)~
== ~BALORA~ ~Thanks for finding it for me! *kisses Edwin on the cheek*~
== ~BEDWIN~ ~Oh... Well... I... We... It... Welcome... Very...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("ALEL1","LOCALS",0)~ THEN ~BALORA~ ALEL1
~Eldoth, your songs. They're alway so... so...~ [ALORA99]
DO ~SetGlobal("ALEL1","LOCALS",1)~
== ~BELDOT~ ~Brilliant?  Inspired?~
== ~BALORA~ ~No, that's not it...~
== ~BELDOT~ ~Wondrous?  Amazing?~
== ~BALORA~ ~No... they're... they're just awful!~
== ~BELDOT~ ~Hmmph.  I trust you are referring to their subject matter and not their musical form, for I can assure you that the latter is as near at perfection as can be.~
== ~BALORA~ ~It's the words... must you always sing about death, hatred and betrayal?~
== ~BELDOT~ ~Of course!  After all, are these not the certainties of life?~
== ~BALORA~ ~Hatred and betrayal are certainties to you?~
== ~BELDOT~ ~If you were not quite so naive, then they would be to you as well.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("ELDOTH")
See("ELDOTH")
!StateCheck("ELDOTH",STATE_SLEEPING)
Global("ALEL2","LOCALS",0)~ THEN ~BALORA~ ALEL2
~Have you ever... have you ever written a nice song, Eldoth?~ [ALORA99]
DO ~SetGlobal("ALEL2","LOCALS",1)~
== ~BELDOT~ ~"Nice?"~
== ~BALORA~ ~You know... about love, truth, justice... and things like that.~
== ~BELDOT~ ~Ha!  No.  I leave that sort of nonsense to the more foolish bards. Naive and ignorant whelps, all of them!~
== ~BELDOT~ IF ~InParty("GARRICK")~ THEN ~Garrick here is a prime example.~
== ~BGARRI~ IF ~InParty("GARRICK")~ THEN ~I sing what the people want to hear, Eldoth!~
== ~BELDOT~ IF ~InParty("GARRICK")~ THEN ~I think not. You serve lies so sweet and illusions iced with so much sugar, that is turns people to vomit.~
== ~BALORA~ IF ~InParty("GARRICK")~ THEN ~Well, I'm a person, and I want to hear Garrick's songs!~
== ~BELDOT~ IF ~InParty("GARRICK")~ THEN ~Your opinion hardly counts. You've already shown that your taste in music is extremely lacking.~
EXIT


CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("FALDORN")
See("FALDORN")
!StateCheck("FALDORN",STATE_SLEEPING)
Global("ALFA1","LOCALS",0)~ THEN ~BALORA~ ALFA1
~Do you really want to kill everyone, Faldorn?~ [ALORA99]
DO ~SetGlobal("ALFA1","LOCALS",1)~
== ~BFALDO~ ~No.  I wish to give everyone a chance to live, or live again.~
== ~BALORA~ ~But I thought that the Shadow Druids wanted to get rid of all the humans, and the dwarves, and the halflings... so that all the animals and plants could live in peace, or something. ~
== ~BFALDO~ ~The world is never at peace, Alora.  The struggle is everlasting, and that’s how the balance is maintained.~
= ~There are some that try to deny the rules of the Great Mother and corrupt the natural order of things.  They want the world only for themselves, and they invented efficient torture devices for this end.  They burn, dig, trash and multiply.~
= ~The balance demands that they be opposed. This is what Shadow Druids do.  We hunt the heretics, and if they do not abandon their vile ways... well, then we give them back to the Great Mother, praying that they come back changed... be it as beasts, birds, or a simple blade of grass.~
== ~BALORA~ ~Oh!  Okay then. I, um... I guess I'll speak to you later. ~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("FALDORN")
See("FALDORN")
!StateCheck("FALDORN",STATE_SLEEPING)
Global("ALFA2","LOCALS",0)~ THEN ~BALORA~ ALFA2
~Faldorn... I was just wondering... if there were no civilization, where would everyone live?~ [ALORA99]
DO ~SetGlobal("ALFA2","LOCALS",1)~
== ~BFALDO~ ~Just where they live now, girl. On Toril, as nature intended. Wild elves, forest gnomes or human barbarians live in harmony with nature, taking its gifts but not robbing it as the so-called civilized settlements do. ~
== ~BALORA~ ~And I suppose they wouldn't even be able to cut down branches to use as shelter or anything like that?~
== ~BFALDO~ ~Why not if it is needed for survival?  However, the wise will rather pick up a branch that was broken before cutting a fresh one.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("ALGA1","LOCALS",0)~ THEN ~BALORA~ ALGA1
~Ooh!  What was that song, Garrick?  It was wonderful!  So moving...~ [ALORA99]
DO ~SetGlobal("ALGA1","LOCALS",1)~
== ~BELDOT~ IF ~InParty("ELDOTH")~ THEN ~Wonderful? Bah! It was vile.~
== ~BGARRI~ IF ~InParty("ELDOTH")~ THEN ~You're simply jealous of my amazing music talent, Eldoth.~
== ~BELDOT~ IF ~InParty("ELDOTH")~ THEN ~If that is what you want to delude yourself with, then fine, go ahead.  I, however, will remain comfortable in the knowledge that you are utterly talentless.  Only those possessing an extreme lack of distaste could possibly find anything remotely 'wonderful' about your musical 'talent'.~
== ~BALORA~ IF ~InParty("ELDOTH")~ THEN ~Well I like Garrick's music!~
== ~BELDOT~ IF ~InParty("ELDOTH")~ THEN ~My point proven.~
== ~BALORA~ IF ~InParty("ELDOTH")~ THEN ~Hey! Let us be! So what was this song, Garrick?~
== ~BGARRI~ ~It's called, umm, let me see... dear me, I've gone and forgotten what it was!~
== ~BALORA~ ~Heh, don't worry about it, Garrick.~
== ~BGARRI~ ~Yes, okay, I won't... sorry, what did you say again?~
== ~BALORA~ ~He-he!  You're funny, Garrick!~
== ~BGARRI~ ~Umm, thanks... I think.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("GARRICK")
See("GARRICK")
!StateCheck("GARRICK",STATE_SLEEPING)
Global("ALGA2","LOCALS",0)~ THEN ~BALORA~ ALGA2
~Play your song again, Garrick.  That one I like.  Please?~ [ALORA99]
DO ~SetGlobal("ALGA2","LOCALS",1)~
== ~BELDOT~ IF ~InParty("ELDOTH")~ THEN ~Stop your whining, wench.~
== ~BGARRI~ IF ~InParty("ELDOTH")~ THEN ~Unlike yours, Eldoth, my music pleases and soothes.  I'd be delighted to play it again, sweet lady.~
== ~BGARRI~ IF ~!InParty("ELDOTH")~ THEN ~For you, sweet lady, anything.  I was taught at the college in Berdusk, you know...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("ALIM1","LOCALS",0)~ THEN ~BALORA~ ALIM1
~Hey Imoen, <CHARNAME> really keeps us on our toes, huh?~ [ALORA99]
DO ~SetGlobal("ALIM1","LOCALS",1)~
== ~BIMOEN2~ ~Oh boy, I'll say!~
== ~BALORA~ ~How long have you known <PRO_HIMHER>, anyway?~
== ~BIMOEN2~ ~Oooh, years an' years an' years... almost as long as I can remember.  We grew up together.~
== ~BALORA~ ~And you've been friends all this time?~
== ~BIMOEN2~ ~Pretty much.  There weren't many other kids at Candlekeep.~
== ~BALORA~ ~I haven't seen any of my childhood friends for ages.  In fact, I haven't had any real friends *at all* in ages.~
== ~BIMOEN2~ ~Well, who knows, maybe you and me could be friends, huh?~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("IMOEN2")
See("IMOEN2")
!StateCheck("IMOEN2",STATE_SLEEPING)
Global("ALIM2","LOCALS",0)~ THEN ~BALORA~ ALIM2
~Hey there, Immy!  Hey wait... stand next to me a minute... yeah, I was right, we could be sisters!~ [ALORA99]
DO ~SetGlobal("ALIM2","LOCALS",1)~
== ~BIMOEN2~ ~Well, I don't know about that, Alora.  I suppose, I could be the tall one.~
== ~BALORA~ ~Oh, we've got lots in common! *giggles* We're both girls!~
== ~BIMOEN2~ ~Well, yeah...~
== ~BALORA~ ~We're both adventurers!~
== ~BIMOEN2~ ~That too...~
== ~BALORA~ ~We're both thieves...~
== ~BIMOEN2~ ~I'm willing to bet that I'm a better thief than you are!~
== ~BALORA~ ~You really think so?  Well then, look what I found here!  My, my, my... Could it be a stuffed bunny?~
== ~BIMOEN2~ ~Hey, that's mister Hunny Bunny! You picked my pocket!~
== ~BALORA~ ~He-he, don't worry Immy.  You can have him back now... but maybe you'd better keep a closer eye your stuff next time!~
== ~BIMOEN2~ ~Thanks! *Hugs the toy *. Heh, you're pretty fun really, Alora!~
== ~BALORA~ ~And don't you forget it. *winks*~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
Global("ALJA1","LOCALS",0)~ THEN ~BALORA~ ALJA1
~Missus Jaheira?.~ [ALORA99]
DO ~SetGlobal("ALJA1","LOCALS",1)~
== ~BJAHEI~ ~Just Jaheira, if you don't mind.~ 
== ~BALORA~ ~Okay, Jaheira... how come you're so serious all the time?~
== ~BJAHEI~ ~Because this is a serious situation we're in.~ 
== ~BALORA~ ~So when this is all over, you'll actually let your hair down a bit?~
== ~BJAHEI~ ~Let my...?~
== ~BALORA~ ~You know, have a bit of fun.  Drinking, dancing and... stuff.~
== ~BJAHEI~ ~What I do when I've finished helping <CHARNAME> is my own business.~
== ~BALORA~ ~I was only asking.~
== ~BKHALI~ IF ~InParty("KHALID")~ THEN ~You know, J-Jaheira, she has a point.  M-maybe you should relax a b-bit. I can massage your shoulders...~
== ~BJAHEI~ IF ~InParty("KHALID")~ THEN ~Khalid, dear, not you too! You know full well that we do not have time for...relaxation right now.~
== ~BKHALI~ IF ~InParty("KHALID")~ THEN ~*Sighs * A p-pity, dear, a pity.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("ALKA1","LOCALS",0)~ THEN ~BALORA~ ALKA1
~So, Kagain, you like big axes then?~ [ALORA99]
DO ~SetGlobal("ALKA1","LOCALS",1)~
== ~BKAGAI~ ~Aye, so?  What of it, lassie?~
== ~BALORA~ ~Oh, nothing.  It's just that... nah, never mind.~
== ~BKAGAI~ ~What?~
== ~BALORA~ ~No, really.  It's nothing.~
== ~BKAGAI~ ~I don't like what ye are implying, girl.~
== ~BALORA~ ~But I didn't say anything!~
== ~BKAGAI~ ~I'm warning ye!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("ALKA1","LOCALS",1)
Global("ALKA2","LOCALS",0)~ THEN ~BALORA~ ALKA2
~Cheer up, Kagain!~ [ALORA99]
DO ~SetGlobal("ALKA2","LOCALS",1)~
== ~BKAGAI~ ~What?~
== ~BALORA~ ~You're always so grumpy.  You should try smiling for once!~
== ~BKAGAI~ ~I'll give you grumpy!  Perhaps you'd like a taste of my weapon?~
== ~BALORA~ ~Really!  I'm not that kind of Halfling!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("ALKA2","LOCALS",1)
Global("ALKA3","LOCALS",0)~ THEN ~BALORA~ ALKA3
~* giggles *~ [ALORA99]
DO ~SetGlobal("ALKA3","LOCALS",1)~
== ~BKAGAI~ ~* sighs heavily* Ye've obviously got something to say to me, girl, so say it.  But I'm warning ye, if yer gonna go on about me axe again, then I...~
== ~BALORA~ ~* giggles * Oh no, it isn't that. There's something I wanted to ask you.~
== ~BKAGAI~ ~Aye, go ahead an' ask, then.  I don't think I'll get any peace until ye do.~
== ~BALORA~ ~What would you do if you saw me drowning in a lake?~
== ~BKAGAI~ ~Laugh.~
== ~BALORA~ ~No, no, no!  Don't be grouchy! * giggles*  Come on, what would you do?~
== ~BKAGAI~ ~Point and laugh.~
== ~BALORA~ ~No, no, no, no, no!  I mean, would you jump into the water like the dashing hunky dwarf that you are to rescue little old me?~
== ~BKAGAI~ ~No... I'll be throwin' rocks at ye fer good measure, I'm sure.~
== ~BALORA~ ~And then you drag me to the shore where you give me mouth to mouth!~
== ~BKAGAI~ ~If I give ye mouth to mouth, you're sure to get hammered from the all the ale I drank the night before.~
== ~BALORA~ ~So you WILL give me mouth to mouth then? *winks*~
== ~BKAGAI~ ~Ermm, nay, NAY!  I meant...~
== ~BALORA~ ~*sings* Ha, ha, you love me!!!~
== ~BKAGAI~ ~I'd slash ye with my axe, but I don't want to get ye started on *that* again...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("ALKA3","LOCALS",1)
Global("ALKA4","LOCALS",0)~ THEN ~BALORA~ ALKA4
~Kagain?~ [ALORA99]
DO ~SetGlobal("ALKA4","LOCALS",1)~
== ~BKAGAI~ ~Damn it, girl, can’t ye just leave me be?~
== ~BALORA~ ~I was just wondering... Kagain, do ye... erm, I mean *you* love me or not?~
== ~BKAGAI~ ~NAY!  I don't!~
== ~BALORA~ ~Methinks thou doth protest too much... which means that you DO love me, but that are not prepared to admit it yet!~
== ~BKAGAI~ ~...that's not what I was saying.~
== ~BALORA~ ~* sings * Kagain loves me, Kagain loves me, Kagain loves me!~
== ~BKAGAI~ ~Argh, I just can't win...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KAGAIN")
See("KAGAIN")
!StateCheck("KAGAIN",STATE_SLEEPING)
Global("ALKA4","LOCALS",1)
Global("ALKA5","LOCALS",0)~ THEN ~BALORA~ ALKA5
~Oh, it's gonna be so great!  We're gonna buy a cute little burrow and have lots of longbearded kids!~ [ALORA99]
DO ~SetGlobal("ALKA5","LOCALS",1)~
== ~BKAGAI~ ~What are ye chatterin' about now?~
== ~BALORA~ ~I was just thinking about our future... how about we settle down in Gullykin, or even the Sunset Mountains?  I could take up a job of homemaker, like a good little halfling, and you'll get a job as town mercenary or something...Hey, do half-halfling and half-dwarf girls get beards?~
== ~BKAGAI~ ~Ach... I know how to deal with troublemakers... I know how to deal with lowlife, scum-suckin' bastards... I know how to deal with all manner of beasties... but I don't know how to deal with the likes of ye.~
== ~BALORA~ ~Hey!  I'm ready to give up adventuring for you!~
== ~BKAGAI~ ~Good!  Why don't ye settle down first and I'll join ye later... in about a century or two, and if ye be already dead an' buried.~
== ~BALORA~ ~Well, if you're going to be so nasty about it, you can forget it!  The wedding's off!~
== ~BKAGAI~ ~So I'm finally rid of ye?~
== ~BALORA~ ~ *sticks out her tongue* ~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("KHALID")
See("KHALID")
!StateCheck("KHALID",STATE_SLEEPING)
InParty("JAHEIRA")
See("JAHEIRA")
!StateCheck("JAHEIRA",STATE_SLEEPING)
Global("ALKH1","LOCALS",0)~ THEN ~BALORA~ ALKH1
~Khalid, how come you always let Jaheira boss you around?~[ALORA99]
DO ~SetGlobal("ALKH1","LOCALS",1)~
== ~BKHALI~ ~I d-don't.  It's j-just that she...~
== ~BALORA~ ~* giggles * You do it all the time!~
== ~BKHALI~ ~Well, maybe...~
== ~BJAHEI~ ~What's that you two are whispering about over there?~
== ~BKHALI~ ~Oh, we're d-discussing *that*, dear. Apparently it's Alora's t-turn to ask.~
== ~BJAHEI~ ~*snickers * Oh, *that*.  Carry on, dear, carry on.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MINSC")
See("MINSC")
!StateCheck("MINSC",STATE_SLEEPING)
Global("ALMI1","LOCALS",0)~ THEN ~BALORA~ ALMI1
~Awww!  It's just the cutest little hamsty-wamsty!  Who's a fuzzy Boo?~ [ALORA99]
DO ~SetGlobal("ALMI1","LOCALS",1)~
== ~BMINSC~ ~Boo likes you, for you are small like him.~
== ~BALORA~ ~Hey, I'm not *that* small!~
== ~BMINSC~ ~Well, Boo is not that small either.  You see, he is not an ordinary hamster, but a Miniature Giant Space Hamster!~
== ~BALORA~ ~Really?  Do you know where I can get one of my own?~
== ~BMINSC~ ~Alas, I do not.  Boo has not seen others of his kind for many years.  But if I or he hear anything, we will let you know!~
== ~BALORA~ ~Thanks, Minsc!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MINSC")
See("MINSC")
!StateCheck("MINSC",STATE_SLEEPING)
Global("ALMI2","LOCALS",0)~ THEN ~BALORA~ ALMI2
~Minsc, can I stroke Boo?~ [ALORA99]
DO ~SetGlobal("ALMI2","LOCALS",1)~
== ~BMINSC~ ~Of course!~
== ~BALORA~ ~Can I hold him?~
== ~BMINSC~ ~Nay, only Minsc may hold Boo.~
== ~BALORA~ ~What's the problem?  Can't he, I dunno, teleport back to you or something?~
== ~BMINSC~ ~Boo says that others of his kin could do that, but sadly he is not that kind of Miniature Giant Space Hamster.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("MINSC")
See("MINSC")
!StateCheck("MINSC",STATE_SLEEPING)
Global("ALMI3","LOCALS",0)~ THEN ~BALORA~ ALMI3
~Say Minsc... if I promise I won't try to steal Boo, will you let me hold him?  Please?~ [ALORA99]
DO ~SetGlobal("ALMI3","LOCALS",1)~
== ~BMINSC~ ~Minsc is no one to doubt a friend's word, but I am not sure that you mean what you say.~
== ~BALORA~ ~You don't trust me? * pouts *  Why not?~
== ~BMINSC~ ~Because you are holding my Boo in your hand right now!~
== ~BALORA~ ~What?  Oh, erm, how did that get there?  Heh heh... I'm sorry.  Thieves' reflex, I guess.  Here's Boo back.... fuzzy Boo... fuzzy, wuzzy, wuzzy Boo...~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("SHARTEEL")
See("SHARTEEL")
!StateCheck("SHARTEEL",STATE_SLEEPING)
AreaType(CITY)
Global("ALSH1","LOCALS",0)~ THEN ~BALORA~ ALSH1
~Isn't the city beautiful, Shar-Teel?  So many people a-hustling and a-bustling from place to place!  Even at night it's more alive than anywhere in the wilderness!  I can't think of any better place for an adventure!~ [ALORA99]
DO ~SetGlobal("ALSH1","LOCALS",1)~
== ~BSHART~ ~You naive little fool!  Why do you insist on pestering me with your stupidity? ~
== ~BALORA~ ~Wowz-louise, what a grouch!  Why are you always so mean to everyone?~
== ~BSHART~ ~I've got better things to do than humor an insipid twit and her sugary-sweet fantasies of adventure.  Those of us who truly know what we're doing, don't have time to nursemaid amateurs.~
== ~BALORA~ ~I'll show you, I will!  I'm as good at thievery as any halfling can be, in a pinch!  Which can come in handy for other uses, as well....~
== ~BSHART~ ~Are you still talking?  I thought I made myself abundantly clear that I'm not inte.....ohhhh hahahahaHAHAHAHAHA STOP THAT DAMN YOU!  Touch me again and I'll.... HAHAHAHA..... I'LL RIP YOUR HEART FROM YOUR CHEST!~
== ~BALORA~ ~Oooohhhh, I KNEW you were ticklish!  I made Shar-Teel smile and laugh!  Happy day!~
== ~BSHART~ ~<CHARNAME>, for now, I shall allow this halfling to live.  Should she try and tickle me again though, then consequences be damned! You have been warned, Alora!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("TIAX")
See("TIAX")
!StateCheck("TIAX",STATE_SLEEPING)
AreaType(FOREST)
Global("ALTI1","LOCALS",0)~ THEN ~BALORA~ ALTI1
~Look, Tiax, aren’t all the trees and flowers and stuff pretty?~ [ALORA99]
DO ~SetGlobal("ALTI1","LOCALS",1)~
== ~BTIAX~ ~When Tiax rules, the woods of this place shall be ripped apart to build a giant temple for Cyric!~
== ~BALORA~ ~Holy kittie cacophony!  Why would you want to do that?!~
== ~BTIAX~ ~Cyric is the great god!  He sees all, knows all, and punishes fools who believes in other weak-minded gods!  Your intelligence is truly low, and when Tiax rules, you'll be locked up for your ignorance in a cell in Tiax's Grand Castle!~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XAN")
See("XAN")
!StateCheck("XAN",STATE_SLEEPING)
Global("ALXA1","LOCALS",0)~ THEN ~BALORA~ ALXA1
~You know, Xan, you have a rather dreary outlook on life.~ [ALORA99]
DO ~SetGlobal("ALXA1","LOCALS",1)~
== ~BXANNN~ ~* sighing * What, exactly, is there to be excited about?~
== ~BALORA~ ~Oh, I don't know.  There's got to be something.  Anything!~
== ~BXANNN~ ~Well, there is one thing, I suppose.~
== ~BALORA~ ~Yes?~
== ~BXANNN~ ~An end to this conversation would cheer me up to no end.~
== ~BALORA~ ~He-he!~
== ~BXANNN~ ~What's so funny?~
== ~BALORA~ ~'An end'!  'No 'end'!~
== ~BXANNN~ ~* sighs *~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("XAN")
See("XAN")
!StateCheck("XAN",STATE_SLEEPING)
Global("ALXA2","LOCALS",0)~ THEN ~BALORA~ ALXA2
~Xan!  Hey Xan!  Cheer up, misery guts!~ [ALORA99]
DO ~SetGlobal("ALXA2","LOCALS",1)~
== ~BXANNN~ ~Excuse me?~
== ~BALORA~ ~You need to turn that frown upside down!~
== ~BXANNN~ ~What exactly is there to be happy about?~
== ~BALORA~ ~Well, life itself, for one thing.~
== ~BXANNN~ ~Let me tell you something about life, little one.  You know what is the one guarantee in life?~
== ~BALORA~ ~Puppies?~
== ~BXANNN~ ~Death.~
== ~BALORA~ ~Yes... ummm, but what about all the good stuff that comes before that?  Like love?~
== ~BXANNN~ ~Love is but a fleeting thing.  Once it's gone, there is only one thing to look forward to.~
== ~BALORA~ ~Uh, death?~
== ~BXANNN~ ~Precisely.~
EXIT

CHAIN
IF WEIGHT #-1 ~CombatCounter(0) !See([ENEMY])InParty("BRANWEN")
See("BRANWEN")
!StateCheck("BRANWEN",STATE_SLEEPING)
Global("ALBR1","LOCALS",0)~ THEN ~BALORA~ ALBR1
~Wow!  You sure are tough, Branwen.~ [ALORA99]
DO ~SetGlobal("ALBR1","LOCALS",1)~
== ~BBRANW~ ~Thank you, girl~
== ~BALORA~ ~You seem to like fighting almost as much as you like praying to your god... err, which one was it again?  Talos?~
== ~BBRANW~ ~No, halfling, 'tis not Talos I worship. I serve the mighty Tempus, the Lord of Battles.~
== ~BALORA~ ~Oh, right.  Sorry, all these human gods seem the same to me.~
== ~BBRANW~ ~Hmmm... I'd like to see what would happen if you told a priest of Cyric that his god is the same as Mystra or Lathander.~
== ~BTIAX~ IF ~InParty("TIAX")~ THEN ~Did Tiax hear mention made of his god?  Cyric rules all!~
== ~BBRANW~ IF ~InParty("TIAX")~ THEN ~Be quiet, heretic!  Hmmm... here's your chance, girl.~
== ~BALORA~ ~Err... I don't think I will...~
EXIT

