APPEND TIAXJ
// Tiax, Solianna - Werewolf Island (just after washing up on shore)
IF WEIGHT #-2 ~Global("TSWIJAWUOS","GLOBAL",1)~ TSWIJAWUOS1
SAY ~*gasp*.....*cough*.....By Cyric, Tiax will never get on a boat again once he leaves this island! Tiax HATES water! When Tiax rules, he will have his slaves lay in the water and make a land-bridge to wherever he wishes to go!~
IF ~~ THEN EXTERN SOLIA1 0
END
END

// Tiax, Shaella - Baldur's Gate, SouthEast District (Blade 'n' Stars)
INTERJECT_COPY_TRANS SHAELL 0 TSBGSED
  == TIAXJ  IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN ~Then Shaella sees clearly indeed, for Shaella sees Tiax, future ruler of all things, and his band of slaves!~
  == SHAELL IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN ~What insolence from one so young. Shaella sees not clearly but dimly, ever peering through the mists of Leira. I am pleased, however, that you have been touched by Leira's gift of blindness and illusion.~
END

// Tiax, Tartusse - Baldur's Gate, North District
INTERJECT_COPY_TRANS TARTUS 0 TTartBGND
  == TIAXJ  IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN ~Nobles should be more worried about how they'll stay alive when Tiax rules. He tires of noble whining, and Tiax will break more than your mirror should he see you again! Now, away from your future master, for he has greater matters to pontificate!~
  == TARTUS IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN ~My word! How RUDE! First my mirror breaks, and now I am verbally assaulted by smelly commoners in the streets. What is this city coming to!?~
END

// Tiax, Tick - Baldur's Gate, North District
INTERJECT_COPY_TRANS TICK 0 TTickBGND
  == TIAXJ IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN ~Tiax has flayed his slaves alive for less than that! You will respect his power, his MAJESTY, or you shall suffer the fate of all his enemies!~ 
  == TICK  IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN ~Hey, no offense, folks. Sewers are just the urban man's dungeon, you get it? And you folks don't look like you're here on no fancy-dancy shopping trip.~
END


EXTEND_BOTTOM SHEP 0  //TSBGND // Tiax, Shep - Baldur's Gate, North District
IF ~InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ EXTERN BTIAX TSBGND1
END

// Tiax, Shep - Baldur's Gate, North District
CHAIN
IF WEIGHT #-1 ~~ THEN BTIAX TSBGND1
~BLASPHEMY!!! Tiax stinks of world conqueror, not adventurer! You will lose your nose when Tiax rules, peasent, for surely it is leading you down the path of your own demise!~
== ~SHEP~ ~My nose was just fine until ye entered my favorite tavern and filled it's common room with yer stench. I know adventurer when I smell it, for it has the reak of stupidity and lust for ill-gotten treasure. Now begone, for while yer stench is powerful, yer wit is weak, and I don't spar with children.~
EXIT

// Tiax, Bartender - Baldur's Gate, Southeast District, Blade And Stars Inn
CHAIN
IF WEIGHT #-1 
~Global("TBBGSEDBASI","GLOBAL",0) InParty("tiax") !Dead("tiax") !StateCheck("tiax",STATE_SLEEPING)~ THEN INNKE3 TBBGSEDBASI1
~Oh no! You've outstayed your welcome here, Tiax. Thank you, find lodging somewhere else please, goodbye!~
== ~BTIAX~ ~Tiax is refused service!? Blasphemy! Tiax will not be thrown out by such as you! Only Cyric himself could budge him from this spot, should he desire to stay!~
== ~INNKE3~ ~If I have to summon the guard here, I will. You are no longer welcome in my inn.~
DO ~SetGlobal("TBBGSEDBASI","GLOBAL",1)~
END
++ ~What is it, exactly, that Tiax has done?~ + TBBGSEDBASIB2 //(go to Block Two)
++ ~He's welcome so long as I'm here. I'll not be thrown out on the streets by a lowly innkeep, and I have the power to back up my desire to stay.~ + TBBGSEDBASITB3 //(go to Block Three)
++ ~Alright, alright, we get the message. Come on, Tiax, let's go.~ + TBBGSEDBASIB4 //(go to Block Four)

CHAIN
IF ~~ THEN INNKE3 TBBGSEDBASIB2
~Oh, I'll tell you what he did! He nearly killed one of our guests, and damn near destroyed my inn!~ = ~There was a peaceful group of merchants here not long ago, drinking and socializing, minding their own business. Then this little runt of a gnome barges in and demands immediate service, claiming that if he didn't get his drink fast enough he would "torture us for all eternity" when he "ruled all." One of the merchants cracked a joke, and the other merchants laughed; it was obviously meant in fun.~ = ~Then, this....this psychotic, delusional gnome comes up and wallops him over the head with a mace!~ = ~Fortunately, it only knocked him unconsious, but he wasn't done yet, oh no! The other merchants scattered, and yet he kept chasing them, swinging his mace and destroying half the common room in the process!~
== ~BTIAX~ ~Bah! The impudent fool claimed that Tiax would be too short to torture anything above the knee caps! Such stupidity will be punished properly when Tiax rules, but for now Tiax had no choice but to mete out justice to his enemies! None DARE to mock Tiax!~
== ~INNKE3~ ~Personally, I have to wonder at the sanity of anyone who would travel with this lunatic. To each his own, I suppose. However, I would suggest you kindly take him OUTside of my Inn, thank you!~
END
++ ~I'm terribly sorry for all the trouble he's caused. How much are the damages? I'll pay them for him.~ + TBBGSEDBASIB5 //(Block Five)
++ ~You're throwing us out over a few whining merchants who can't handle a barroom brawl? Please. Serve us or a mace over the head will seem like a blessing when we're done with you.~ + TBBGSEDBASITB3
++ ~Well, I can understand why you'd be upset. We'll just find someplace else to stay.~ + TBBGSEDBASIB4 //(Block Four)

APPEND INNKE3
IF ~~ TBBGSEDBASITB3 // Block Three
SAY ~I'll not be threatened in my own bar. Your welcome here has been worn out, just like your friend's has. Out! Out!~ //(end conversation, if Bartender talked to again go to Block Six)~
IF ~~ DO ~SetGlobal("TBBGSEDBASITB","GLOBAL",1)~ EXIT
END

IF ~~ TBBGSEDBASIB4 // Block Four
SAY ~I'm glad you're more understanding than your diminutive friend. Have a nice day.~ //(end conversation, if Bartender talked to again go to Block Six)
IF ~~ THEN DO ~SetGlobal("TBBGSEDBASITB","GLOBAL",1)~ EXIT
END

IF ~~ TBBGSEDBASIB5 // Block Five
SAY ~The total is 300 gold pieces. Take it or leave it, but until it's paid no one who travels with that gnome will be allowed to stay here.~
+ ~PartyGoldGT("300")~ + ~I've got enough. Here, take the 300 and my apologies on behalf of Tiax.~ + TBBGSEDBASIB7 //(Block Seven, option only available if party has over 300 gold)
++ ~300 gold!?! For a few broken glasses!? You're a cheat if there ever was one!~ + TBBGSEDBASIB8 //(Block Eight)
++ ~Too rich for my blood. Thank you anyway, innkeep. We'll find someplace else to stay.~ + TBBGSEDBASIB4 //(Block Four)
END

IF WEIGHT #-1 ~Global("TBBGSEDBASITB","GLOBAL",1) InParty("Tiax")~ TBBGSEDBASITB6 // Block Six
SAY ~I have no more to say to you. As long as that gnome is with you, you are unwelcome. Kindly step outside.~ // (end dialogue, only if Tiax is still in group)
IF ~~ THEN EXIT
END

IF ~~ TBBGSEDBASIB7 // Block Seven
SAY ~Well, I'm happy to see there are still some honorable people left in the world. Why they would travel with HIM, I don't know. You're welcome to stay here so long as you keep the gnome on a short leash, and thank you for the help!~
IF ~~ THEN DO ~ReputationInc(1) StartStore("inn0105",LastTalkedToBy())~ EXIT //(end dialogue, standard bartender dialogue now, plus one reputation point)
END

IF ~~ TBBGSEDBASIB8 // Block Eight
SAY ~As I said, you can take it or leave it. Obviously, you've chosen to leave it. Kindly take your business elsewhere, please!~ //(end dialogue, go to Block Six if party tries to speak to Bartender again)
IF ~~ THEN DO ~SetGlobal("TBBGSEDBASITB","GLOBAL",1)~ EXIT
END
END
