//Interjections

I_C_T LIIA 8 X#ImoenLiia
== IMOEN2 IF ~InParty("imoen2") !Dead("imoen2") !StateCheck("imoen2",STATE_SLEEPING)~ THEN ~Whate'er you decide, I'm with ya, <CHARNAME>!~
END

I_C_T2 ~GALLOR~ 2 X#ImoenGallor1
== IMOEN2 IF ~InParty("imoen2") !Dead("imoen2") !StateCheck("imoen2",STATE_SLEEPING)~ THEN ~Huh, this man gave me creeps. I mean, pickin' a pocket is one thing, but killin' a dozen of workers to steal some stupid artifact is... horrible!~
END

I_C_T ANGELO 0 X#ImoenAngelo1
== IMOEN2 IF ~InParty("imoen2") !Dead("imoen2") !StateCheck("imoen2",STATE_SLEEPING)~ THEN ~Hey, back off! We did nothin' wrong!~
END

I_C_T2 VARCI 5 X#ImoenVarci1
== IMOEN2 IF ~InParty("imoen2") !Dead("imoen2") !StateCheck("imoen2",STATE_SLEEPING)~ THEN ~I'm glad ya agreed ta help out, <CHARNAME>. By Mask, I hoped enough times that someone'd bail *me* outta troubles when I was of an age with Varci!~
END

I_C_T2 ARDROU 2 X#ImoenArdrouine1
== IMOEN2 IF ~InParty("imoen2") !Dead("imoen2") !StateCheck("imoen2",STATE_SLEEPING)~ THEN ~O, sorry for scarin' your son an' all, ma'am. Hope he's alright! Ya tell him that some adventurers do good things, like helpin' other folk at need.~
END

I_C_T ~SPENGIL~ 2 X#ImoenSpen1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Firewine Bridge… that sounds familiar… where did I heard it? Uhm… In any case, ruins ALWAYS are full of treasure! And since we're experienced adventurers,  we've nothin' ta worry 'about. Let's go there one day.~
END

I_C_T2 ~FIREBE~ 1 X#FirebeardImoen1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Heya, Mr. E! Remember me? I'm the *second* kid of Candlekeep. We're goin' get ya book, no problem…~
== ~FIREBE~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Imoen! Glad to see you, lass. Forgive me for not recognizing you immediately; but you have changed!~
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Sure thin', Sir!  No more aprons and bonnets for Imoen the Magnificent. Well, unless someone offers me a dragon's treasure horde to wear one.~
= ~We're goin' get ya book, no problem, Mr.E… ~
= ~It's good to see a familiar face, eh, <CHARNAME>?~
END


I_C_T ~RALEO~ 0 RaleoImoen
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~One thing I've learned is that you hear more interesting stories on the road than staying in an inn. *sighs* When I was er... staying in the inn, as soon as some traveller from afar would start a good tale, everyone else would shout for ale and food... and I never would hear the whole story. I had to fill in all the missin' nits on my own.~
END

I_C_T2 ~SILKE~ 2 SilkeImoen2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Less than brilliant?! Tee-hee, it's good t'adventure with friends! At least ya wouldn't call me 'less than brilliant' and get away with it!~
END

I_C_T2 ~SILKE~ 1 SilkeImoen1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Garrick is not little! Good thing ya are an actress, not a painter; would have been a problem bein' blind, huh. 'Cause if ya don'y see for yourself how tall he is, ya sure are blind!~
END

I_C_T2 ~GARRIC~ 7 ImoenGarrick2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Of course!~
= ~I mean, <CHARNAME>, he can join us, right? *Giggles* He is cute and he is a real bard! Someone gotta write ballades about my beauty and bravery, ya know?~
END

I_C_T2 ~GARRIC~ 6 ImoenGarrick1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~yaah, that was real rotten thing she tricked <CHARNAME> into doing!~
= ~Ya will be much better off with us...~
= ~<CHARNAME>, he can join us, right? *Giggles* He is cute and he is a real bard! Someone gotta write ballades about my beauty and bravery, ya know?~
END

I_C_T ~JAHEIR~ 5 X#JaheiraImoenJoin
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Isn't it great, <CHARNAME>? We made it through the forest full of gibberlings and wolves, and now we are meeting *real* adventurers! Things are lookin' up!~
= ~Hey, Auntie Jaheira, I am Imoen! A friend of <CHARNAME>'s… Actually more like a guardian, than a friend, ya know? Lookin' after <PRO_HIMHER> and all that.~
== ~JAHEIR~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Adventurers generally do not call each other 'auntie', Imoen. But enough distractions. Gorion had mentioned you in his correspondence, praising your fast friendship with his ward. You are welcome to come along.~
END

I_C_T ~FRIEND~ 0 X#ImoenFAIGuard
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Nope! But from the look of ya they must be on the dreadfully borin' side!~
END

I_C_T ~JOIA~ 1 X#ImoenJoia1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Of course we will bash some heads for ya! If ya want we can make 'em hobgoblins come back t'ya and say they're sorry they took ya father's ring!~
END

I_C_T ~JOIA~ 3 X#ImoenJoia2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~*Pushes you in the ribs* Our finesse is unappreciated here, my good <PRO_LADYLORD>.~
END

I_C_T ~CHASE~ 0 ImoenChase1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Hey, ya know what? <CHARNAME> over 'ere was just locked out of <PRO_HISHER> home-town without a penny and some monsters killed <PRO_HISHER> father. If anyone here should be jumping cliffs it's <PRO_HIMHER>! And d'ya see <PRO_HIMHER> jumpin'? So what's ya problem?~
END

I_C_T2 ~CHASE~ 1 ImoenChase2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Heh.  What a queer fellow.~
END

I_C_T2 ~CHASE~ 2 ImoenChase3
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~I'm glad you tried to talk him outta it <CHARNAME>, even if he was just lookin' for attention.~
END

I_C_T2 ~CHASE~ 3 ImoenChase4
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Ya could of at least tried to talk him out of it <CHARNAME>, even if he was just lookin' for attention.~
END

I_C_T2 ~BINKOS~ 0 ImoenBinkos
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Another caravan raided?! Wow, that's no good! Remember those Flamin' Fists passin' by Candlekeep last week? They said there was at least two missing! I think we should keep our eyes peeled or we'll be killed by bandits fer nothin'!~
= ~Excitin' though... Caravans, bandits, road... like an adventure from a book!~
END

I_C_T ~DESSLO~ 0 ImoenKolssed1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Heya, I'm Imoen, and that's my friend <CHARNAME>. We just got out of Candlekeep and startin' out on a grand adventure, avenging that great mage and all… uhm, <CHARNAME>, why are ya standing with your mouth shut as a clam when the tide is out? Ya know more than I 'bout that fightin' thing anyway. So go tell 'bout it! That's what adventurers do! Famous ones anyway. Or how would they ever get into bard's songs?~
END

I_C_T ~DESSLO~ 2 ImoenKolssed2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Ya hear him? "Like minded companions"! That'd me! Ya doin' alright, despite bein' thicker than Candlekeep's walls! Imoen the Magnificent is gonna yat make an adventurer out of ya!~
END

I_C_T ~ELMIN1~ 0 ImoenElmin1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Heh, I... or do I need ta say "Ti"? I mean if "you" is "thou"... or was it "thee"? Uhm... in any case I'm not desperate and not deranged. I'm excited! I am going to be a famous adventurer, like Elminster!~
== ~ELMIN1~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~*Smiles from behind his moustaches* Thou art a spirited girl, Imoen. Now what of thy companion?~
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Wait, wait! How do'ya know my name?~
== ~ELMIN1~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~One can aquire such knowledge in more ways than one, child. But let the quiet one speak.~
END

I_C_T ~XZAR~ 3 ImoenXzar1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Psst, <CHARNAME>, the mage speaks like he's layin' honey on bread, but I dunno... I don't like his eyes a single bit!~
END

I_C_T2 ~XZAR~ 10 ImoenXzar2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Um, <CHARNAME>, shouldn't we go to the Friendly Arm Inn first?  We should probably find Gorion's friends like he wanted you to.~
END

I_C_T2 ~XZAR~ 12 ImoenXzar3
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~I don't like the looks of these two jokers, <CHARNAME>.  Nope.  I don't.  Not at all.~
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Let's get to the Friendly Arm Inn soon, huh?  I'd like to have some people I can trust traveling with us.~
END

I_C_T ~AOLN~ 0 ImoenAoln
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Hey, ya grouch... we weren't shoutin' at all. We are adventurers and understand such things, ya know. Tell him, <CHARNAME>.~
END

I_C_T ~KEEPER~ 2 ImoenKeeper1
== ~IMOEN2~ IF ~GlobalLT("Chapter","GLOBAL",4) IsValidForPartyDialogue("imoen2")~ THEN ~But Keeper!  Gorion and <CHARNAME> were attacked just outside the keep, near the Coastway.  Gorion...he...he's dead.  <CHARNAME> just managed to escape.  I saw it all! Don't you think you could make an exception?  You've known <CHARNAME> for years!~
== ~KEEPER~ IF ~GlobalLT("Chapter","GLOBAL",4)IsValidForPartyDialogue("imoen2")~ THEN ~I...I am saddened to hear of Gorion's death, <CHARNAME>.  Your father was a good man and my friend. I'll inform most high Ulrant and Tethtoril of his passing.  This is grave news indeed. However, I do hope you understand that I just cannot allow you in <CHARNAME>.  My hands are tied in this matter.~
= ~Here, please take this.  It's not much but I hope it will be of some small help.~
DO ~GiveGoldForce(100)~
== ~KEEPER~ IF ~GlobalLT("Chapter","GLOBAL",4) IsValidForPartyDialogue("imoen2")~ THEN ~Imoen, you however, are free to enter if you wish.  Winthrop is quite worried over your disappearance.~
== ~IMOEN2~ IF ~GlobalLT("Chapter","GLOBAL",4) IsValidForPartyDialogue("imoen2")~ THEN ~Oh no!  <CHARNAME> and I are in this together, through thick and thin! Puffguts has my letter.  And he taught me a thing or two...ol' Imoen can stay outta trouble!~
= ~Tell him I love him, though, will ya?  And tell him not to worry 'bout little old me.~
== ~KEEPER~ IF ~GlobalLT("Chapter","GLOBAL",4) IsValidForPartyDialogue("imoen2")~ THEN ~ I will Imoen.  Take care, both of you.  And <CHARNAME>?  Be wary of strangers and don't be too quick to give out your name. Just a bit of advice.  Safe travels.~
END

I_C_T ~WINTHR2~ 0 ImoenWinth1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Nine Hells, it's good ta be home! Winthrop, my ol' man!~
== ~WINTHR2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~An' you, littl' missus owe me a long account, for all my worries after you had run off!~
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~I do... *her eyes water* I know... O, damn, I'm so glad to se ya, Puffguts!~
END

I_C_T ~WINTHR2~ 1 ImoenWinth2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~<PRO_HESHE> hasn't changed a touch, Pugffguts! And we'd been up to... up to so many things... I promise I come tell ya all that this bore would miss out!~
== ~WINTHR2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~ya do that, my dear, ya sure'd do that.~
END

I_C_T ~WINTHR2~ 6 ImoenWinth3
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~*giggles* It's sure fun ta see <PRO_HIMHER> jump at an innocent joke... Just like good ol' times...~
END

I_C_T ~HULL2~ 0 ImoenHull
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~Oh, Hull, so many things had happened since... Both good and bad... but nothin' was worst than ol' Gorion's being killed. <CHARNAME>, I think we should drink his memory while we're here in Candlekeep with out friends.~
END

I_C_T ~FULLER2~ 0 ImoenFuller1
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~*A* tale?! Thousands more like! The things we've seen and done... would get even Nessa's excited!~
END

I_C_T2 ~FULLER2~ 3 ImoenFuller2
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2")~ THEN ~We sure know what we're doin'! And take it from me, Fuller, those Iron Throne people are villains here!~
END

APPEND ~IMOEN2~

IF WEIGHT #-2 ~Global("X#IMDiamond","GLOBAL",1)~ THEN BEGIN ImDiamond
SAY ~Wow! And Winthrop used ta tell me that diamonds don't grow on trees! Sure in Candlekeep they don't! Hey, <CHARNAME>, cheer up! Tymora favours us, seems ta me.~
IF ~~ THEN DO ~SetGlobal("X#IMDiamond","GLOBAL",2)~ EXIT
END

IF WEIGHT #-2 ~ Global("X#IMGBody","GLOBAL",1)~  THEN BEGIN ImoenGorionBody
SAY ~Is that... Gorion?~
++ ~yes. He died saving me from some...thing.~ DO ~SetGlobal("X#IMGBody","GLOBAL",2)~ GOTO IMINT1.1
++ ~yes, it *was* Gorion. He died while protecting me from an attack.~ DO ~SetGlobal("X#IMGBody","GLOBAL",2)~ GOTO IMINT1.1
++ ~*Push the body with a toe of your foot* Right. The *great* mage Gorion! Could not even stand his ground against a couple of ogres and a scare-crow!~ DO ~SetGlobal("X#IMGBody","GLOBAL",2)~ + IMINT1.1A
END

IF ~~ IMINT1.1A
SAY ~Hey! Ya were hiding ya butt under a bush, while he was fighting all these monsters, aren't ya?~
IF ~~ THEN GOTO IMINT1.1
END

IF ~~ IMINT1.1
SAY ~Don'tcha even know what attacked you? Whatever it was, looks like it was vicious.~
++ ~I was scared out of my wits! What do you expect!~ GOTO IMINT1.2
++ ~It was too dark to see much, but it was humanoid, although I couldn't see a face. His eyes glowed though... like hells' fire! And he would have went straight for me, if Gorion, gods rest his soul had not barred his way!~ GOTO IMINT1.3
++ ~I can't remember much about last night.... or ... much about the attacker. But I do remember that he... that it spoke.~ GOTO IMINT1.4
++ ~Ogres, some girl with a mace and a huge man in spiked armour. I did not stick around long enough to take a closer look, you know. With Gorion shouting at me to run, that man demanding my head and all...~ GOTO IMINT1.3
END

IF ~~ IMINT1.2
SAY ~Really? I'm glad I wasn't right there. I've seen you get surprised and jump before, but never ever afraid. I-I don't even want to think 'bout of what could scare you.~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.3
SAY ~I see. Hmm... so he wasn't after Gorion, but you.~
IF ~~ THEN GOTO IMINT1.5
END

IF ~~ IMINT1.4
SAY ~So ya remember what it said?~
++ ~Not really, just that it wanted to kill me.~ GOTO IMINT1.6
++ ~Well, it did not say much... besides obviously wanting my corpse to be where Gorion's is now (or atleast alongside it) it mentioned it had been looking for me.~ GOTO IMINT1.7
END

IF ~~ IMINT1.5
SAY ~I don't like this <CHARNAME>, don't like it at all.~
++ ~I don't either, but I have to find out what's going on and why I was attacked. I don't want to drag you into this though, Imoen.~ GOTO IMINT1.8
++ ~I don't either, but what's done is done. Gorion's spirit won't come back now. I doubt even a High Cleric of Helm could restore him to life with a body this torn up. No, we best move on now Imoen.~ GOTO IMINT1.9
++ ~I didn't want Gorion to die, but I will avenge him Imoen. Just you wait.~ + IMINT1.10
++ ~Heh, things are just starting to get interesting. Don't get me wrong, I wish Gorion were here, but this is how great adventures start Imoen!~ GOTO IMINT1.11
++ ~Have I asked your opinion, brat?~ + IMINT1.5A
END

IF ~~ IMINT1.5A
SAY ~Nope, 'cause you're so stupid!~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.6
SAY ~That seemed obvious from what you've said earlier.~
= ~*shrugging her shoulders and grinning* Well, we'll just have ta deal with 'em when it they come again, but this time, it'll be their bodies rottin' in the sun.~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.7
SAY ~Well aren't ya the popular one?~
= ~Sorry, just tryin' to liven things up here. Anyways if that thing was lookin' for ya, it'll come for ya 'gain. Don'tcha worry though! This time with Imoen the Megnificent will be at your side you can't lose!~
++ ~Heh. Thanks Imoen.~ EXIT
++ ~Imoen the *Meg*nificent?~ GOTO IMINT1.12
+ ~Class(Player1,THIEF_ALL)~ + ~Magnificent? You're okay, but I wouldn't go that far.~ GOTO IMINT1.13Thief
+ ~!Class(Player1,THIEF_ALL) Gender(Player1, MALE)~ + ~Magnificent? You're okay, but I wouldn't go that far.~ GOTO IMINT1.13Male
+ ~!Class(Player1,THIEF_ALL) Gender(Player1, FEMALE)~ + ~Magnificent? You're okay, but I wouldn't go that far.~ GOTO IMINT1.13Male
++ ~And can Imoen the Magnifecent liven up *this* thing here? *point at Gorion's body*~ GOTO IMINT1.9A
END

IF ~~ IMINT1.8
SAY ~Leave? And if I did who would keep ya entertained? Who would keep your spirits lifted in the darkest hour? And who would keep up the practical jokes?~
= ~Leave! Hah! You'll have ta force me ta leave ya now!~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.9
SAY ~You sure? At least we could give him a proper burial, y'know. It's not like I like doin' it, but I know I'd like someone to bury me as well.~
IF ~~ THEN GOTO IMINT1.14
END

IF ~~ IMINT1.9A
SAY ~No... no I can't. But speakin' of bodies... The least we could do is t'give Gorion a proper burial, y'know. It's not like I like doin' it, but I know I'd like someone to bury me as well.~
IF ~~ THEN GOTO IMINT1.14
END

IF ~~ IMINT1.10
SAY ~Right then! I'll be with ya all the way!~
= ~But you think first we should bury Gorion? I mean it's not proper to leave him out like this.~
++ ~I suppose your right.~ GOTO IMINT1.14
END

IF ~~ IMINT1.11
SAY ~Right... well, before we start this adventure, shouldn't you bury Gorion, at least what's left of him?~
++ ~I suppose you're right. Besided all great adventures start off after burying someone the cared for.~ + IMINT1.14A
++ ~yes, you are right, Imoen. Let us bury Gorion.~ GOTO IMINT1.14
++ ~*Suddenly you cannot speak, tears welling in your eyes. You nod your agreement.*~ + IMINT1.14B
END

IF ~~ IMINT1.12
SAY ~'Course! It's the perfect name for me, someone who has so many talents!~
= ~Well let's be off then. It just wouldn't do to have this magnificent talent of mine wasted, y'konw?~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.13Female
SAY ~OKAY!? Perhaps ya don't remember how many times they showed ya the evidence for a prank you never committed or the times your possessions would go missing, only to be found somewhere else in your room, or the time your dress turned transparent in the middle of the town square? I'm sure the guards at Candlekeep could remember that last one. Prolly even some of them crusty ole scholars as well. That took lots of planning, strategy and finesse...~
= ~*giggling* Just thinking of that...~
++ ~*Blushing* I-I don't know what you're talking about. It must have been someone else...~ + IMINT1.15
++ ~*Fuming red-angry* THAT WAS YOU!? COME HERE BEFORE YOU REGRET IT.~ GOTO IMINT1.16
++ ~So, you've pulled a few on me when we were young. Big stinking deal. We are grown-ups now, Imoen, and we have to commit *real* deeds to call ourselves Magnificent.~ GOTO IMINT1.15
++ ~And what about that time when all forks in Mr.Winthrop's inn went missing and everyone thought it was your fault? And that favorite book of yours which you could not open no matter how you tried? Or the carpet that rolled itself up every time you tried to hit it with your beater? Ha! I got you a couple of times too!~ GOTO IMINT1.15
END

IF ~~ IMINT1.13Male
SAY ~OKAY!? Perhaps ya don't remember how many times they showed ya the evidence for a prank you never committed or the times your possessions would go missing, only to be found somewhere else in your room, or the time you dropped your trousers in the middle of the town square? I'm sure almost everyone remembers that. The guards got a good laugh as did many of those… er… younger-than-one-hundred-years-old-last-supper girls! Even that one you sorta had a crush on...um...what's her name? Ah, doesn't matter.~
= ~*giggling* Just thinking of that...~
++ ~*Blushing* I-I don't know what you're talking about. It must have been someone else...~ + IMINT1.15
++ ~*Fuming red-angry* THAT WAS YOU!? COME HERE BEFORE YOU REGRET IT.~ GOTO IMINT1.16
++ ~So, you've pulled a few on me when we were young. Big stinking deal. We are grown-ups now, Imoen, and we have to commit *real* deeds to call ourselves Magnificent.~ GOTO IMINT1.15
++ ~And what about that time when all forks in Mr.Winthrop's inn went missing and everyone thought it was your fault? And that favorite book of yours which you could not open no matter how you tried? Or the carpet that rolled itself up every time you tried to hit it with your beater? Ha! I got you a couple of times too!~ GOTO IMINT1.15
END

IF ~~ IMINT1.13Thief
SAY ~*glare* OKAY!? Listen, I know you were always trying to best me, y'know, but you know why you were alwasys the one blamed and never me? Why you were the one stuck doing all those extra chores and not me? Well do ya?~
++ ~I did kind of wonder.~ GOTO IMINT1.17
++ ~Doesn't matter anymore. 'Sides now we're out here and there's no one else to go to...~ GOTO IMINT1.18
++ ~It's not exactly true, Imoen. what about that time when all forks in Mr.Winthrop's inn went missing and everyone thought it was your fault? And that favorite book of yours which you could not open no matter how you tried? Or the carpet that rolled itself up every time you tried to hit it with your beater? Ha! I got you a couple of times too! But... we're not in Candlekeep anymore, Imoen. There's no one else here to go to... so let us not waste our time with silly contests.~ GOTO IMINT1.18
END

IF ~~ IMINT1.14A
SAY ~*rolls eyes* Whatever...~
IF ~~ THEN GOTO IMINT1.14
END

IF ~~ IMINT1.14B
SAY ~You... you poor soul... I'm sorry... but I think we should burry Gorion, <CHARNAME>.~
IF ~~ THEN GOTO IMINT1.14
END

IF ~~ IMINT1.15
SAY ~Heh. Well say what you want. I am Imoen the Magnificent.~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.16
SAY ~*sweatdrop* Um, well, I gotta go... somewhere. See ya!~
IF ~~ THEN DO ~SetGlobal("X#IMORUN","GLOBAL",1) ActionOverride("imoen2",JumpToPoint([3498.3684])) MoveViewPoint([3498.3684],INSTANT)~ EXIT
END

IF ~Global("X#IMORUN","GLOBAL",2)~ THEN BEGIN IMINT1.20
SAY ~*panting* 'Kay, you...win...for...now.... But...see...now...you...don't....so...depressed.... You...should...be...thanking...me...~
IF ~~ THEN DO ~SetGlobal("X#IMORUN","GLOBAL",3)~
EXIT
END

IF ~~ IMINT1.17
SAY ~Well you can keep on wonderin' cuz Imoen the Magnificent never reveals her secrets, unless there's something in it for her. And then she doesn't reveal ALL of her secrets.~
IF ~~ THEN EXIT
END

IF ~~ IMINT1.18
SAY ~*sweatdrop* Y'know that was all kids stuff don'tcha? You wouldn't hold a grudge to me this long?~
++ ~No, but don't think you can get away with stuff you do now so easily.~ EXIT
+ ~!Alignment(Player1,LAWFUL_GOOD)~ + ~Perhaps. We'll see. It depends on how good of a helper you are.~ GOTO IMINT1.19
END

IF ~~ IMINT1.19
SAY ~Uhm... I don't like that term 'helper'...~
IF ~~ THEN EXIT
END

//2

IF WEIGHT #-2 ~Global("X#IMNeira","GLOBAL",1)~ THEN BEGIN IMINT2
SAY ~Wh-who was that?~
++ ~Another assassin. Not the same one who killed Gorion though. If it were, we'd not be standing here right now.~ DO ~SetGlobal("X#IMNeira","GLOBAL",2)~ GOTO IMINT2.1
+ ~Dead("Karlat") !Dead("tarnesh")~ + ~Another assassin. This is the fourth. I met with two before leaving Candlekeep. One right after leaving Candlekeep. And now this...…~DO ~SetGlobal("X#IMNeira","GLOBAL",2)~ GOTO IMINT2.2
+ ~Dead("Karlat") !Dead("tarnesh")~ + ~Another assassin. This is the fifth. I met with two before leaving Candlekeep. One right after leaving Candlekeep. And that dwarf in the 'Red Sheaf'…~DO ~SetGlobal("X#IMNeira","GLOBAL",2)~ GOTO IMINT2.2
+ ~!Dead("Karlat") Dead("tarnesh")~ + ~Another assassin. This is the fifth. I met with two before leaving Candlekeep. One right after leaving Candlekeep. And that mage on the doorsteps of the Friendly Arm Inn…~DO ~SetGlobal("X#IMNeira","GLOBAL",2)~ GOTO IMINT2.2
+ ~Dead("karlat") Dead("tarnesh")~ + ~Another assassin. This is the sixth. I met with two before leaving Candlekeep. One right after leaving Candlekeep. And that mage on the doorsteps of the Friendly Arm Inn… And the dwarf in the 'Red Sheaf'.~ DO ~SetGlobal("X#IMNeira","GLOBAL",2)~ GOTO IMINT2.2
END

IF ~~ IMINT2.2
SAY ~You mean even inside the walls of Candlekeep you were attacked!? Why didn't ya tell me this before you left? ~
++ ~I didn't want to worry you and have you tag along with me, like you're doing right now.~ GOTO IMINT2.5
+ ~Gender(Player1,MALE)~+ ~I tried to, but you said you were too busy.~ GOTO IMINT2.6Male
+ ~Gender(Player1,FEMALE)~+ ~I tried to, but you said you were too busy.~ GOTO IMINT2.6Female
END

IF ~~ IMINT2.4
SAY ~What do you mean… disturbing?~
++ ~Disturbing means disturbing. Let's just get moving…~ GOTO IMINT2.7
++ ~Think about it for a second. Whoever it was knew to attack me when we left Candlekeep, as if they were expecting me to flee. Next, whoever it was knew I was heading for the Friendly Amn Inn and placed an ambush at the inn's doorway. Now this. Gorion made sure no one else knew about the Friendly Amn Inn and no one here had any idea that we'd be heading to Nashkel. yat another assassin waits here…~ GOTO IMINT2.8
END

IF ~~ IMINT2.5
SAY ~Heh, yap. I'm stuck to ya like brick and mortar! We'll 'nough chattin' here, let's go get a room so that I can get a nice warm bath.~
IF ~~ THEN EXIT
END

IF ~~ IMINT2.6Female
SAY ~Pfft! And you let that stop you! You really need to get a backbone girl! If you can't stand up to me, how you expect to stand up to your husband?~
++ ~Whatever. Let's go.~ EXIT
++ ~Husband? What brought this on?~ GOTO IMINT2.9
++ ~Husband, huh? I could say the same thing about you, Imoen.~ GOTO IMINT2.9
END

IF ~~ IMINT2.6Male
SAY ~Pfft! And you let that stop you! You really need to get a backbone if you expect to get a wife one day, at least if ya do not want her ta keep ya under her thumb!~
++ ~Whatever. Let's go.~ EXIT
++ ~Wife, huh? Don't worry, I got plenty of that backbone thing.~ GOTO IMINT2.10
++ ~I don't have to worry about that. The person I'd want for a wife is right in front of me.~ GOTO IMINT2.11
END

IF ~~ IMINT2.7
SAY ~Hmph. Alright, but you better explain it to me later.~
IF ~~ THEN EXIT
END

IF ~~ IMINT2.8
SAY ~I see…~
++ ~But that's not all. Why wouldn't that black man come in person again? Why send lowly assassins when he was willing to come himself for the first time? What made it different enough to warrant sending imbeciles?~ GOTO IMINT2.8A
++ ~Alright, standing here does not help any. Let's go.~ EXIT
++ ~It just doesn't make sense, unless...no...dammit! I can't figure it out!~ EXIT
END

IF ~~ IMINT2.8A
SAY ~I-I don't know...Anyways, this is giving me a headache trying to figure this out. I'll let you do all the complex thinking in that regard.~
+ ~OR(2) CheckStatGT(Player1,12,INT) CheckStatGT(Player1,12,WIS)~ + ~You know the answer, Imoen. As well as I do. Assassins were waiting for us and were of small caliber because they are *everywhere*. They chose quantity over quality, betting that someone, somewhere is bound to catch me unaware. So no matter where we should go…~ GOTO IMINT2.8B
++ ~Well, lucky you!~ EXIT
END

IF ~~ IMINT2.8B
SAY ~Stop it! You're scaring me!~
IF ~~ THEN EXIT
END

IF ~~ IMINT2.9
SAY ~Heh, don't worry I'm pushy enough as it is.~
++ ~You can say that again.~ GOTO IMINT2.12
++ ~*Walk away*~ EXIT
END

IF ~~ IMINT2.10
SAY ~Maybe when you're fightin' off beasts and whatnot, but not when it comes to women.~
IF ~~ THEN EXIT
END

IF ~~ IMINT2.11
SAY ~*looks around innocently* Huh? I don't see any other girls close enough... wait you not talking 'bout me, are you?!~
++ ~Heh, just yanking your chain!~ GOTO IMINT2.13
++ ~So you do not see anyone else? Neither do I...~ GOTO IMINT2.14
END

IF ~~ IMINT2.12
SAY ~Did you say something?~
++ ~Uh, yaa. We should go.~ GOTO IMINT2.15
++ ~Uh, nope, not a thing.~ GOTO IMINT2.15
END

IF ~~ IMINT2.13
SAY ~Here's for you being a jerk! *kicks <CHARNAME>*.~
++ ~Ouch! My grevious wounds!~ + IMINT2.16
END

IF ~~ IMINT2.16
SAY ~Then maybe you shouldn't be standing around making jokes. Stupid jokes!~
IF ~~ THEN EXIT
END

IF ~~ IMINT2.14
SAY ~Oh, I see an elven beauty, her hair like span gold and her eyes greener than emeralds. The sort all ya males drool after. *kicks <CHARNAME>*.~
++ ~Ouch! My grevious wounds!~ + IMINT2.17
END

IF ~~ IMINT2.17
SAY ~Then maybe you shouldn't be gawking and making jokes. Common, lover-boy. *sticks her tongue out*~
IF ~~ THEN DO ~IncrementGlobal("X#ImoenLove","GLOBAL",1)~ EXIT
END

IF ~~ IMINT2.15
SAY ~Hmph!~ 
IF ~~ THEN EXIT
END

//3

IF WEIGHT #-2 ~Global("X#IMCK","GLOBAL",1)~ THEN BEGIN IMINT3
SAY ~Candlekeep...never thought I'd be back here again, and especially this early on. Brings back all sorts of memories, doesn't it?~
++ ~yes, it does.~ DO ~SetGlobal("X#IMCK","GLOBAL",2)~ GOTO IMINT3.1
++ ~yes, like the time you pilfered that pie from Mr. Winthrop and gave it to me half-eaten just before he arrived to yall at me.~ GOTO IMINT3.2
++ ~yaa, but I'd rather not talk about them.~ DO ~SetGlobal("X#IMCK","GLOBAL",2)~ GOTO IMINT3.3
++ ~No time for reminiscing. We got work to do.~ DO ~SetGlobal("X#IMCK","GLOBAL",2)~ GOTO IMINT3.4
END

IF ~~ IMINT3.1
SAY ~yap. Why there's Hull! Let's go say hi to him!~
IF ~~ THEN EXIT
END

IF ~~ IMINT3.2
SAY ~Hey, I was just trying to share. How am I supposed to know Mr. Winthrop was coming by just then? Hmm?~
++ ~You always know.~ EXIT
++ ~It doesn't matter. I still got chewed out.~ EXIT
++ ~Oh lets just drop it. I don't feel like arguing today.~ EXIT
END

IF ~~ IMINT3.3
SAY ~ Still remembering that incident huh? Can't blame you though. I'd be remembering it too.~
++ ~Even though it wasn't in Candlekeep proper, it was the last memory I had about it, and it had a horrible outcome.~ EXIT
END

IF ~~ IMINT3.4
SAY ~Hells. You're really tight-mouthed today. I mean it's not everyday we come back to our hometown, y'know.~
IF ~~ THEN EXIT
END

END

CHAIN3 ~IMOEN2~ IMINT1.14
~Well, why are we standin' about? Let us just... dig. Maybe one day we can return and add a small gravestone or somethin'...~
DO ~SetGlobal("X#IMGBody","GLOBAL",3) ActionOverride("gorion",DestroySelf())~
== ~BJAHEI~ IF ~IsValidForPartyDialogue("Jaheira")~ THEN ~He was a good man. Now both his spirit can rest and his body can return to nature peacefully. But by Silvanus, I swear his death will not go unpunished!~
== ~BKHALI~ IF ~IsValidForPartyDialogue("Khalid")~ THEN ~I k-knew him well. He will be sorely missed.~
== ~BGARRI~ IF ~IsValidForPartyDialogue("Garrick")~ THEN ~'Tis a sad thing we did this day, Sir. Perhaps I er... can spin a tale of his uhm... final battle into a fitting poem, one that will er... hopefully be remembered for tomorrow and beyond.~
== ~BDYNAH~ IF ~IsValidForPartyDialogue("Dynaheir")~ THEN ~I did not know Gorion, but from what <CHARNAME> sayath of him, he was a great man.~
== ~BMINSC~ IF ~IsValidForPartyDialogue("Minsc")~ THEN ~Boo say Gorion seems like he was very smart and brave. Minsc thinks Boo is right! Minsc would have liked to know him.~
== ~XANJ~ IF ~IsValidForPartyDialogue("Xan")~ THEN ~Not a day without us witnessing a burial of another poor soul destroyad by adventuring. *Sighs* I foresee that the hour of our own funeral draws near.~ 
== ~BYESLI~ IF ~IsValidForPartyDialogue("yaslick")~ THEN ~A shame. He would have made a fine Dwarf-friend.~
== ~BKAGAI~ IF ~IsValidForPartyDialogue("Kagain")~ THEN ~Dat be all you be buryin' him? C'mon man! Tain't a proper burial till he be at least ten feet under! Remind me te never be buried by ya upper wurlders.~
== ~BXZAR~ IF ~IsValidForPartyDialogue("Xzar")~ THEN ~Looks like the old man gets his final rest now. But why would not they let me take a finger or toe for a... momento?~
== ~BMONTA~ IF ~IsValidForPartyDialogue("Montaron")~ THEN ~Never und'stand ya fancy dancy rit'als. The dead be gun an ain't not'in left in 'em corpse woth a lickin fer any but em wiz'ns ta use.~
== ~IMOEN2~ ~I don't want to have to bury someone ever again. Don't you go and die on me now <CHARNAME>. I-I don't think I could handle it if I had to bury you as well.~
END
++ ~Don't worry Imoen, I won't. Let's go now and let Gorion rest in peace.~ EXIT
++ ~As long as you promise I won't have to bury you either.~ EXIT

CHAIN3 ~IMOEN2~ IMINT2.1
~Another one!? I knew she was after you once she attacked, but this...this is just too much for me. I mean I don't like this, not at all. First you get attacked in front of Candlekeep by some blazing maniac out for your blood and Gorion dies. Then 'gain outside the Friendly Amn Inn, even before we met up with Jaheria and Khalid! Now here as well! You got attacked and almost died on the doorsteps of yat another Inn! This is just too much!~
== ~KHALIJ~ IF ~InParty("Khalid") InParty("Jaheira")~ THEN ~H-had we known an assassin awaited you outside the inn we would have fought them as well, r-right Jaheria?~
== ~JAHEIJ~ IF ~InParty("Khalid") InParty("Jaheira")~ THEN ~Of course. Else we would have met you at the gate, but we cannot change the past. At least we were here with you this time.~
END
++ ~yaa I know it's difficult and yes I'm grateful for your help. As long as we stick together, no assassins will be able to defeat us…~ EXTERN ~IMOEN2~ IMINT2.3
++ ~This is disturbing. They knew I would be coming here... most disturbing indeed.~ EXTERN ~IMOEN2~ IMINT2.4

CHAIN3 ~IMOEN2~ IMINT2.3
~yaa! That's right! We're an unstoppable team!~
== ~IMOEN2~ IF ~InParty("Khalid") InParty("Jaheira")~ THEN ~Yup! Together with myself as the main support and Auntie Jaheria and Uncle Khalid villains don't stand a chance.~
== ~JAHEIJ~ IF ~InParty("Khalid") InParty("Jaheira")~ THEN ~Please, Imoen, you can call me Jaheria. No need to use 'aunt' in front of my name.~
== ~IMOEN2~ IF ~InParty("Khalid") InParty("Jaheira")~ THEN ~Okies Auntie Janeria.~
== ~IMOEN2~ ~C'mon, quit standin' there like you're waiting for another assassin to come get you!~
EXIT

INTERJECT_COPY_TRANS ~BGWILLIA~ 10 ManyInt14
== ~IMOEN2~ IF ~IsValidForPartyDialogue("imoen2") Gender(Player1,FEMALE)~ THEN ~Who did not see this one coming from a mile away? Now the boys be bantering for days... yap!~
== ~BGWILLIA~ IF ~IsValidForPartyDialogue("imoen2") Gender(Player1,FEMALE)~ THEN ~Ah, you are here too? Well, you were the quiet one of the pair, you were...~
END
