APPEND ~Halbaz~

IF WEIGHT #-5 ~PartyHasItem("X#garch")
Global("X#HalbTalk","LOCALS",0)
~ THEN BEGIN Upgrade1
SAY ~What is that armour I see you possess? The quality of the stitching and interweaving of leather and mail is unsurpassed... Where could you have got such a well-crafted suit? Never mind, each man must have his secrets, and I am an abjurer, not a diviner, by trade.~
= ~I am, of course, talking about that pleasantly-coloured suit of chainmail you own. By the looks of it, it would be a bard's garb? I can imagine it must allow freedom of movement enough so at to not restrict spellcasting. Very useful...~
IF ~!PartyHasItem("MISC47")~ THEN REPLY ~Thanks for the compliment.~ DO ~SetGlobal("X#HalbTalk","LOCALS",1)~ GOTO Upgrade2
IF ~PartyHasItem("MISC47")~ THEN REPLY ~Thanks for the compliment.~ DO ~SetGlobal("X#HalbTalk","LOCALS",1)~ GOTO Upgrade3
IF ~~ THEN REPLY ~I've come to buy something, actually...~ DO ~StartStore("STO0703",Protagonist)~ EXIT
IF ~~ THEN REPLY ~I'd better be going.~ EXIT
END

IF WEIGHT #-5
~PartyHasItem("X#garch")
Global("X#HalbTalk","LOCALS",1)
~ THEN BEGIN Upgrade7
SAY ~Hello again. Have you changed your mind on my offer? I do believe that the armour would be most beneficial.~
IF ~PartyHasItem("MISC47") PartyGoldGT(999)~ THEN REPLY ~Yes, I have. Please, improve my armour.~ GOTO Upgrade6
IF ~~ THEN REPLY ~Not at this time, thank you. May I see your wares?~ DO ~StartStore("STO0703",Protagonist)~ EXIT
IF ~~ THEN REPLY ~Not today. Farewell.~ EXIT
END

IF ~~ THEN BEGIN Upgrade2
SAY ~Now, the pair of us may be to help each other out. In exhange for letting me look at the suit, that I may perhaps come to understand the manner of construction and nature of enchantments on it, I will further strengthen it's protective abilities. For a modest fee, of course...~
IF ~~ THEN REPLY ~That sounds great!~ GOTO Upgrade4
IF ~~ THEN REPLY ~What's the catch?~ GOTO Upgrade4
IF ~~ THEN REPLY ~I'd really rather just buy something, actually.~ DO ~StartStore("STO0703",Protagonist)~ EXIT
IF ~~ THEN REPLY ~Sorry, but I have to be going.~ EXIT
END

IF ~~ THEN BEGIN Upgrade4
SAY ~All I require is 1,000 gold... And a pair of Golden Pantaloons. If you bring them to me, it should only take a matter of minutes.~
IF ~~ THEN REPLY ~I'll bear that in mind. In the meantime, can I see your wares?~ DO ~StartStore("STO0703",Protagonist)~ EXIT
IF ~~ THEN REPLY ~I'll be back later, then.~ EXIT
END

IF ~~ THEN BEGIN Upgrade3
SAY ~Now, the pair of us may be to help each other out. In exhange for letting me look at the suit, that I may perhaps come to understand the manner of construction and nature of enchantments on it, I will further strengthen it's protective abilities. For a modest fee, of course...~
IF ~~ THEN REPLY ~That sounds great!~ GOTO Upgrade5
IF ~~ THEN REPLY ~What's the catch?~ GOTO Upgrade5
IF ~~ THEN REPLY ~I'd really rather just buy something, actually.~ DO ~StartStore("STO0703",Protagonist)~ EXIT
IF ~~ THEN REPLY ~Sorry, but I have to be going.~ EXIT
END

IF ~~ THEN BEGIN Upgrade5
SAY ~All I require is 1,000 gold... And that pair of Golden Pantaloons I see. If you are willing, it should only take a matter of minutes.~
IF ~~ THEN REPLY ~I'll bear that in mind. In the meantime, can I see your wares?~ DO ~StartStore("STO0703",Protagonist)~ EXIT
IF ~~ THEN REPLY ~I'll think about it. Farewell.~ EXIT
IF ~PartyGoldGT(999)~ THEN REPLY ~That sounds great!~ GOTO Upgrade6
END

IF ~~ THEN BEGIN Upgrade6
SAY ~Excellent! Then I shall begin...~
=
~Almost done...~
=
~There. Protection, style, service with a smile. It was good doing business with you, my <LADYLORD>~
IF ~~ THEN DO ~TakePartyGold(1000)
ActionOverride(Player1,DestroyItem("X#garch"))
ActionOverride(Player2,DestroyItem("X#garch"))
ActionOverride(Player3,DestroyItem("X#garch"))
ActionOverride(Player4,DestroyItem("X#garch"))
ActionOverride(Player5,DestroyItem("X#garch"))
ActionOverride(Player6,DestroyItem("X#garch"))
ActionOverride(Player1,DestroyItem("MISC47"))
ActionOverride(Player2,DestroyItem("MISC47"))
ActionOverride(Player3,DestroyItem("MISC47"))
ActionOverride(Player4,DestroyItem("MISC47"))
ActionOverride(Player5,DestroyItem("MISC47"))
ActionOverride(Player6,DestroyItem("MISC47"))
GiveItemCreate("X#garch2",Player1,1,0,0)~ EXIT
END

END

