BEGIN ~X#Garar~

IF ~!InParty("Garrick")~ THEN BEGIN BogOffCharname
SAY ~Get out of my way, rascal! Bog off!~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END

IF ~InParty("Garrick")~ THEN BEGIN ArchibaldIntro
SAY ~Books, books, books. Out of the way you young rascals! In my day the youth were much more respectful of their elders... And much better versed in great literature too. Oh yes. Bah.~
IF ~~ THEN REPLY ~Yeah? Well Yah Boo to you too old man!~ GOTO Arch1
IF ~~ THEN REPLY ~Um, sorry Sir.~ GOTO Arch2
IF ~~ THEN REPLY ~It seems Faerun is full of crazy old men these days. Let's move along. Quickly.~ GOTO Arch1
END

IF ~~ THEN BEGIN Arch1
SAY ~Ha! Like I said, disrespectful. Perhaps you could've learnt something from my countless years of wisdom, not to mention my books. But I guess you were just too brash to take the hint.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN Arch2
SAY ~Manners eh! So perhaps modern living hasn't completely eroded the last vestiges of decency from you. Perhaps I can help you...~
IF ~~ THEN REPLY ~Help me? How?~ GOTO Arch3
IF ~~ THEN REPLY ~I doubt an old man has much to offer me. Maybe I'll be off now.~ GOTO Arch1
END

IF ~~ THEN BEGIN Arch3
SAY ~Well, I'm a librarian. Or well I used to be, though now I'm selling off my collection to finance my long-overdue retirement.~
IF ~~ THEN REPLY ~Oh really? Doing anything nice?~ GOTO Arch4
IF ~~ THEN REPLY ~(sit and listen)~ GOTO ArchGarri
IF ~~ THEN REPLY ~Yadda yadda yadda... Get on with it.~ GOTO ArchGarri
END

IF ~~ THEN BEGIN Arch4
SAY ~I'm glad you asked me that actually, I'm thinking of going further south in Amn, perhaps to the Umar Hills or somewhere...~
= ~I don't believe all this talk of impending war. As far as I'm concerned it's a nice quiet place where nothing happens. Nothing unexpected, no adventurers or anything. Zilch. I'll have a nice, quiet life. And best of all, no more books!~
= ~Now you may disagree, but I have quite a good sense of judgement about these things. Anyway, that's beside the point. You're distracting me.~
IF ~~ THEN REPLY ~Yeah, sorry. You were saying?~ GOTO ArchGarri
END

CHAIN X#Garar ArchGarri
~Yes, I'm selling my collection, though actually I've made enough money to live on now. I have but a few books left. Perhaps you'd be interested in this one- The Ultimate Compendium Of Famous Little-Known Heroes, by an old friend of mine, one Saemon Schama.~
== ~GarriJ~ ~Wow, could it really be The Ultimate Compendium Of Famous Little-Known Heroes, by Saemon Schama? Please, <CHARNAME>, this is a great book! I'd really love to have it!~
== ~X#Garar~ ~Ah, you would be a scholar then, my boy?~
== ~GarriJ~ ~A bard, Sir... I've always wanted a copy of that, since I was knee-high to a gnome. It is one of the classics- the author is a genius!~
== ~QuaylJ~ IF ~InParty("Quayle") !Dead("Quayle")~ THEN ~Though he's not quite up to my level, he is a fairly intelligent character, <CHARNAME>. I mean, for a human, of course, anything he's written is probably worth at least a quick peek.~
== ~X#Garar~ ~Well then, if it pleases you, I'll give it to you for free. It's rare to meet such well-mannered types as yourselves. Good business to you, now if you'll excuse me I have my retirement to be getting on with. And one last bit of advice: Things read in books can often prove very useful. Oh yes.~
== ~EdwinJ~ IF ~InParty("Edwin") !Dead("Edwin")~ THEN ~Oh, a senile librarian gives an important tome to an eager young adventuring bard? Please, what is this? What did I do to deserve such idiots for companions?~
== ~GarriJ~ ~You're a good man, Sir. I won't forget this.~
END
IF ~~ THEN DO ~SetGlobalTimer("X#GarrickBookTalk","GLOBAL",10)
ActionOverride("X#Garar",GiveItem("X#garbk",Player1))
ActionOverride("X#Garar",EscapeArea())
SetGlobal("X#GarrickQuest","GLOBAL",1)~
EXIT

APPEND ~GarriJ~

IF WEIGHT #-2 ~CombatCounter(0) !See([ENEMY])GlobalTimerExpired("X#GarrickBookTalk","GLOBAL") Global("X#GarrickReadBook","GLOBAL",0)~ THEN BEGIN GarrickReadBook
SAY ~Hey, <CHARNAME>! There's a passage in this book about the long-dead half-elven bard Myr'Cutio, who is said to roam undead the valleys around a place called Ulcaster looking for further tales of adventure. Hey, there's rough directions, it's sort of close, east of Beregost! Perhaps we could go check it out?~
IF ~~ THEN REPLY ~I see no harm in that. Who knows, if true we may learn something.~ GOTO BookQuestOK
IF ~~ THEN REPLY ~I thought that crazy old librarian was bad enough Garrick, but if you don't shut up then I'll shove that book where the sun don't shine. If you catch my drift...~ GOTO GarrickBookNo
END

IF ~~ THEN BEGIN BookQuestOK
SAY ~Wow! Thanks, <CHARNAME>.~
IF ~~ THEN JOURNAL ~Travelling Librarians.

Today we met a doddering old librarian named Archibald at the Nashkel Carnival. He gave us a copy of The Ultimate Compendium Of Famous Little-Known Heroes by Saemon Schama, which has an interesting section detailing the now-undead bard Myr'Cutio, who is said to haunt the Ulcaster region to the rough east of Beregost. Garrick is keen to take a look.~ EXIT
END

IF ~~ THEN BEGIN GarrickBookNo
SAY ~Fine, but I bet we'll regret if we don't go...~
IF ~~ THEN JOURNAL ~Travelling Librarians.

Today we met a doddering old librarian named Archibald at the Nashkel Carnival. He gave us a copy of The Ultimate Compendium Of Famous Little-Known Heroes by Saemon Schama, which has an interesting section detailing the now-undead bard Myr'Cutio, who is said to haunt the Ulcaster region to the rough east of Beregost. Garrick is keen to take a look.~ EXIT
END

END
