INTERJECT_COPY_TRANS ~ELMINS4~ 3 AjantisDoplegangers
== ~AJANTJ~ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~By Helm, the lies and the hide of these fiends reek of evil. Let us prepare for battle!~
END

INTERJECT_COPY_TRANS ~BGWILLIA~ 10 ManyInt10
== ~AJANTJ~ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) Gender(Player1,FEMALE) !Global("X#AjantisRomanceActive","GLOBAL",3) 
Global("X#AjantisRomanceMatch","GLOBAL",1)~ THEN ~Lady <CHARNAME> in the buff, on a bearskin rug - that's a charming thought...~
= ~...Thinking of you as a baby, of course, my lady. (*blushes*)~
= ~My lady, if you want my opinion, you're still cute as a bug. And that was meant as a compliment.~
== ~BGWILLIA~ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) Gender(Player1,FEMALE) !Global("X#AjantisRomanceActive","GLOBAL",3) 
Global("X#AjantisRomanceMatch","GLOBAL",1)~ THEN ~Of course she's a baby...~
END

//Bjornin, the hurt paladin in Beregost
I_C_T2 ~BJORNI~ 1 X#AjantisBjorninTalk1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We will surely do that, my friend. Soon those ogres won't be a threat any longer.~ DO  ~SetGlobal("X#AjantisHelpBjornin","GLOBAL",1)~
END

I_C_T2 ~BJORNI~ 2 X#AjantisBjorninTalk2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Not yet, my friend, but I am sure <CHARNAME> will lead us there soon.~ DO  ~SetGlobal("X#AjantisHelpBjornin","GLOBAL",1)~
END

//Mirianne in Beregost, who is waiting for a letter from her husband
I_C_T2 ~MIRIAN~ 0 X#AjantisMirianneTalk1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We will seek for signs of your husband, my lady. I hope this will diminish your worries.~ DO ~SetGlobal("X#AjantisMiriannePromise","GLOBAL",1)~ 
END

//Keldath Ormlyr: Bassilus quest
I_C_T2 ~KELDDA~ 8 X#AjantisKaldathBassilus
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~"Killing any innocents that happen along his path"?! What kind of devil is that! We have to stop him!~ DO ~SetGlobal("X#AjantisBassilusQuest","GLOBAL",1)~ 
END

//Bassilus
I_C_T2 ~BASSIL~ 0 X#AjantisBassilus1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) 
Global("X#AjantisBassilusQuest","GLOBAL",1)~ THEN ~This must be the criminal Bassilus they mentioned in the temple! We have to stop his evil doings!~
END

I_C_T2 ~BASSIL~ 0 X#AjantisBassilus2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)
!Global("X#AjantisBassilusQuest","GLOBAL",1)~ THEN ~What kind of devil is that! We have to stop him!~ 
END

//if Brage was brought to Oublek
I_C_T2 ~OUBLEK~ 3 X#AjantisBrageToOublek
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Now justice was brought to this case, and yet... it leaves a bad taste in the mouth.~ 
END

//if Brage was brought to Nalin (temple)
I_C_T2 ~NALIN~ 3 X#AjantisNalinBrage
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Your words show great wisdom and give way to a lot of hope. Thank Helm we decided to bring this poor soul here.~ 
END

//Phandalyn, paladin in Baldur's Gate
INTERJECT_COPY_TRANS2 ~PHANDA~ 1 X#AjantisPhandalyn
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Thank you, my friend. May Helm be with you.~ 
END

//nashkell mine quest (Berrun)
I_C_T2 ~BERRUN~ 8 X#AjantisBerrun1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Your call for help won't go unheard. We will do what we can to find the reasons for the evil occurrences in your mine!~ 
END

I_C_T2 ~BERRUN~ 11 X#AjantisBerrun2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Your call for help won't go unheard. We will do what we can to find the reasons for the evil occurrences in your mine!~ 
END

I_C_T2 ~BERRUN~ 12 X#AjantisBerrun3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Your call for help won't go unheard. We will do what we can to find the reasons for the evil occurrences in your mine!~ 
END

I_C_T2 ~BERRUN~ 13 X#AjantisBerrun4
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Your call for help won't go unheard. We will do what we can to find the reasons for the evil occurrences in your mine!~ 
END 

//help dryade: Talk to Caldo and Krumm
I_C_T2 ~CALDO~ 8 X#AjantisHelpDryadCaldo1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, don't let these scoundrels hurt this old mighty tree! It is the home of a dryad!~ 
END

I_C_T2 ~CALDO~ 6 X#AjantisHelpDryadCaldo2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, I am taken aback by your plan to help these scoundrels cut down this old mighty tree! It is the home of a dryad!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

//if PC cheats the way into the bandit is camp. (1st bandit)
I_C_T2 ~TEVEN~ 5 X#AjantisTeven1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~(*Whispers*) <CHARNAME>, do we have to play this game? There must be a honorable way to get into the bandit is camp!~
END

I_C_T2 ~TEVEN~ 9 X#AjantisTeven2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~(*Whispers*) <CHARNAME>, do we have to play this game? There must be a honorable way to get into the bandit is camp!~
END

//if PC cheats the way into the bandit is camp. (2nd bandit)
I_C_T2 ~RAIKEN~ 5 X#Ajantisraiken1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~(*Whispers*) <CHARNAME>, do we have to play this game? There must be a honorable way to get into the bandit is camp!~ 
END

I_C_T2 ~RAIKEN~ 9 X#Ajantisraiken2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~(*Whispers*) <CHARNAME>, do we have to play this game? There must be a honorable way to get into the bandit is camp!~ 
END

//Minsc 
INTERJECT_COPY_TRANS2 ~MINSC~ 5 X#AjantisMinsc
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Strange as your attitude seems, my friend, I have the impression you are a capable fighter for good. Let us go and help your lady out of her distress!~
END

//Dynaheir hostile leave if attacked
INTERJECT_COPY_TRANS2 ~DYNAHE~ 10 X#AjantisDynaheir
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~By Helm! <CHARNAME>, can't you see that this is a fight of good against evil? I am not at your side with this! My honor tells me to defend this woman!~ DO ~LeaveParty() Enemy() SetGlobal("X#AjantisRomanceActive","GLOBAL",3)~
END

//Eldoth, after joining the group
I_C_T2 ~ELDOTH~ 7 X#AjantisEldoth2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, I hope you don't seriously consider carrying out this false plan?~ 
END

//Eldoth, before "kidnapping" Skie
I_C_T2 ~ELDOTH~ 10 X#AjantisEldoth1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, I can't believe you are planning to participate in this deception!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

//Gullykin
INTERJECT_COPY_TRANS2 ~GANDOL~ 13 X#AjantisGandolar1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Your city is threatened by kobolds? I am sure this will be no problem for us to solve... <CHARNAME>?~ 
END

INTERJECT_COPY_TRANS2 ~GANDOL~ 11 X#AjantisGandolar2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~I am glad you decided that way, <CHARNAME>. -Gandolar, when we investigate the ruins, we will kill those kobolds for you.~ 
END

INTERJECT_COPY_TRANS2 ~GANDOL~ 4 X#AjantisGandolar3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, I am disappointed of your rudeness against this little man! He is the leader of this town, after all!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

//don't kill Shoal (deadly kissing mermaid)
INTERJECT_COPY_TRANS2 ~SHOAL~ 5 X#AjantisShoal1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~You are bound to the will of the owner of your shawl?~ 
END

INTERJECT_COPY_TRANS2 ~SHOAL~ 6 X#AjantisShoal2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Yes, we will fight this ogre that surpresses you, beautiful creature. But we expect our companion to be put back to life once we have succeeded!~ 
END

//no lying to Laskal (shadow druid)
INTERJECT_COPY_TRANS2 ~LASKAL~ 4 X#AjantisLaskal1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Now you see what comes from such needless lying, <CHARNAME>! We are fighting someone that could have been our friend!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

INTERJECT_COPY_TRANS2 ~LASKAL~ 5 X#AjantisLaskal2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~You showed a great sense of courage and honor, <CHARNAME>! The temptation of lying to receive a message dedicated to our enemies didn't overwhelm you.~ 
END

//Laurel, fighting gibberlings
INTERJECT_COPY_TRANS2 ~LAUREL~ 7 X#AjantisLaurel
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~It was an honor to fight at your side, my friend. Farewell.~ 
END 

//Viconia 
INTERJECT_COPY_TRANS2 ~FLAM2~ 0 X#AjantisFlamingFist
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, this drow is evil, and accused of murder. Protecting her means to stand in the way of law!~ 
END

INTERJECT_COPY_TRANS2 ~FLAM2~ 3 X#AjantisViconiaNoHelp
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~It is was the right choice not to ally with this evil creature, <CHARNAME>!~ 
END

INTERJECT_COPY_TRANS2 ~FLAM2~ 4 X#AjantisViconiaHelp
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~*You* sentence us to death? Are you authorized to do this? Let us talk, there is no need for bloodshed.~
END

INTERJECT_COPY_TRANS2 ~VICONI~ 9 X#AjantisViconiaJoining
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Fine words, drow, but be careful not to forget them. I will watch your steps carefully.~ 
END

//Lena
INTERJECT_COPY_TRANS2 ~LENA~ 5 X#AjantisLena
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Don't be afraid, miss. We will get him there as fast as possible.~ DO ~
SetGlobalTimer("X#AjantisSamuel","GLOBAL",TWO_DAYS)~
END

//Help Farmer Brun (changes PC decision) 
INTERJECT ~FARMBR~ 4 X#AjantisHelpBrun
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~But I can't close my ears to such a misery! Do tell about the burden you are carrying, good man.~ 
END ~FARMBR~ 6

//give Brun money...
INTERJECT_COPY_TRANS2 ~FARMBR~ 9 X#AjantisBrunMoney
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, we have to talk to this poor man again and see whether we can help him. We can't leave him like this!~ 
END

//Thieves Guild, Alatos
INTERJECT_COPY_TRANS2 ALATOS 10 X#AjantisAlatos
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We will be working for the *thieves guild*? <CHARNAME>, I have problems reconciling this with my duties as a paladin!  But, I will use this fact to have a close look at what is going here and I surely hope you have other motivations for this cooperation than only to increase your wealth by illegal actions.~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

//Brevlik and the telescope
INTERJECT_COPY_TRANS2 BREVLI 17 X#AjantisBrevlik
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, this robbery is nothing but common thievery! I can't believe you accepted this inquiry!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

//Varci
//If help plea is rejected
INTERJECT_COPY_TRANS2 ~VARCI~ 4 X#AjantisVarci1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, why did you turn that child away? He seemed in desperate need for help!~ DO ~SetGlobal("X#AjantisRejectedVarci","GLOBAL",1) IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

//If help plea was accepted
INTERJECT_COPY_TRANS2 ~VARCI~ 5 X#AjantisVarci2A
== AJANTJ IF ~Global("X#AjantisRejectedVarci","GLOBAL",1) InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, I am glad you changed your mind and decided to help that boy!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",-1)~
END

INTERJECT_COPY_TRANS2 ~VARCI~ 5 X#AjantisVarci2B
== AJANTJ IF ~!Global("X#AjantisRejectedVarci","GLOBAL",1) InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Yes, show us the way. We will see what we can do to help you.~
END

//Tremain 
INTERJECT_COPY_TRANS2 ~TREMAI~ 8 X#AjantisTremain
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~To stand between two churches - the poor father! This was not an easy decision, <CHARNAME>, but I think we are doing the right thing. Let us find this child's body!~
END

//Sonner, Treman, Jebado (fishermen in conflict with Umberlee priestess)
INTERJECT_COPY_TRANS2 ~SONNER~ 5 X#AjantisUmberlee
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, Umberlee is a cruel and evil deity, but her priestesses wouldn't harass fishermen without provocation. I have the feeling there is more to this story than we were told.~ 
END

//Pheirkas, who wants to have a stolen cloak
INTERJECT_COPY_TRANS2 PHEIRK 1 X#AjantisPheirkas
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Committing a crime by stealing! I can't believe this scum is asking passers-by to do his abominable deeds for him!~ 
END

//Neb!
INTERJECT_COPY_TRANS2 ~NEB~ 1 X#AjantisNeb1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Cruel murderer, you deserve your sentence! Get out of my sight!~ 
END

INTERJECT_COPY_TRANS2 ~NEB~ 8 X#AjantisNeb2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Be assured, murderer, if you ever happen to cross my way again I will bring justice to those little souls you killed!~ 
END

//help ill Eltan
INTERJECT_COPY_TRANS2 ~DELTAN~ 12 X#AjantisHelpEltan
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Duke Eltan, be assured that we will do all that is within our power to stop the foul play of these evil men and prevent this needless and brutal war!~
END

//beggar
INTERJECT_COPY_TRANS2 ~BEGGBA~ 8 X#AjantisBeggar1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Helm would be pleased to see you commiserate with the poor and the ones in need, <CHARNAME>!~ 
END

INTERJECT_COPY_TRANS2 ~BEGGBA~ 9 X#AjantisBeggar2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Helm would be pleased to see you commiserate with the poor and the ones in need, <CHARNAME>!~ 
END

//Angelo 
INTERJECT_COPY_TRANS2 ~ANGELO~ 3 X#AjantisAngelo1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Helm be with us! A henchman of our worst enemy being the commander of the Flaming Fist! There must be a way of disproving his position and rebuting the sentence he put on us!~ 
END

INTERJECT_COPY_TRANS2 ~ANGELO~ 4 X#AjantisAngelo2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Helm be with us! A henchman of our worst enemy being the commander of the Flaming Fist! There must be a way of disproving his position and rebuting the sentence he put on us!~ 
END 

//Edwin
INTERJECT_COPY_TRANS2 ~EDWIN~ 8 X#AjantisEdwin
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, you aren't seriously considering to kill a person you have never met before and which you don't know what she is accused of? Don't let us raise our weapons against this Dynaheir before we have heard the whole story!~ 
END

//Ardrouine (looks for her son threatend by Worgs)
INTERJECT_COPY_TRANS2 ARDROU 0 X#AjantisArdrouine
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Don't fear no more, good woman! It will be an easy task for us to kill those Worgs that are threatening your son!~ 
END

//Quinn (in BG, looking for Nestor's knife which can be found by an Ankheg) 
INTERJECT_COPY_TRANS2 QUINN 1 X#AjantisQuinn1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We will seek for signs of your friend, lad.~ DO ~SetGlobal("X#AjantisQuinnPromise","GLOBAL",1)~ 
END

//Brielbara
INTERJECT_COPY_TRANS2 BRIELB 6 X#AjantisBrielbara1
== AJANTJ IF ~IsValidForPartyDialog("ajantis")~ THEN ~Don't worry, dear woman. We will find that spellbook to save your daughter.~
END

//Drizzt hostile leave if attacked
INTERJECT_COPY_TRANS2 DRIZZT 1 X#AjantisDrizzt1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, this is Drizzt Do'Urden, a well known honorable ranger! Don't be misled by his looks. If he is in need, we should help him defeat his attackers!~ 
END

INTERJECT_COPY_TRANS2 DRIZZT 3 X#AjantisDrizzt3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~By Helm! Now you reveal your true intentions! I am not at your side in this fight! <CHARNAME>, raise your weapon as my honor tells me to defend this elf!~ DO ~LeaveParty() Enemy() SetGlobal("X#AjantisRomanceActive","GLOBAL",3)~ 
END

// Joseph's wife
INTERJECT FTOWN2 0 X#AjantisWomanNashkell0
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~My good woman, the sadness radiates from your face. Do tell me, what is the burden you are carrying on your shoulders? Has it something to do with the happenings in the mine?~
== FTOWN2 IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Such kind words from a stranger! Maybe you could... it is only, that... My husband works in the mines, and he hasn't come home for weeks now. Every day there are men going missing down there, and I am very worried...~
END 
++ ~Maybe we could help you. We are going to investigate the mines. Give us a description of your husband, maybe we'll see him down there.~ EXTERN FTOWN2 3
++ ~Sad. We have to go now.~ EXIT


//If help is offered
INTERJECT_COPY_TRANS2 FTOWN2 3 X#AjantisWomanNashkell3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We will keep our eyes open for your husband, my lady.~ DO ~SetGlobal("X#AjantisWomanNashkellPromise","GLOBAL",1)~ 
END

//If ring is "hidden" from her (Joseph's wife)
INTERJECT FTOWN2 5 X#AjantisWomanNashkell5
== AJANTJ IF ~PartyHasItem("RINGJOS") InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, why are you hiding the ring we found? This woman is in desperate need of news from her husband! Why keep her in suspence?~
= ~Good lady, here is a ring that matches your description. We found it on a body... Please accept my condolences, good woman, for in all probability, your husband is dead.~ DO ~TakePartyItem("RINGJOS")~
END FTOWN2 6

//If ring is not given to her
INTERJECT_COPY_TRANS2 FTOWN2 7 X#AjantisWomanNashkell7
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>! How can you be so heartless! This ring is of so much more value for the widow than it could ever be for you. It belongs to her, strictly speaking!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END


//Oublek
ADD_TRANS_TRIGGER ~OUBLEK~ 2 ~!InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~

EXTEND_BOTTOM ~OUBLEK~ 2
IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) 
Global("X#AjantisNotGreywolf","GLOBAL",0)~ EXTERN AJANTJ not_greywolf
END

//Prism
EXTEND_BOTTOM ~PRISM~ 3
IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) Global("X#AjantisProtectPrism","GLOBAL",0)~ THEN EXTERN AJANTJ protect_prism
END

APPEND ~PRISM~
IF ~~ THEN BEGIN no_help
SAY ~No! I have to finish my work! Ellesime!~
COPY_TRANS ~PRISM~ 3
END
END

//Dryads
ADD_TRANS_TRIGGER DRYAD 4 ~!InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~
ADD_TRANS_TRIGGER DRYAD 10 ~!InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~

EXTEND_BOTTOM DRYAD 4 10
IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) 
Global("X#AjantisProtectDryade","GLOBAL",0)~ EXTERN AJANTJ protect_dryad
END

APPEND DRYAD
IF ~~ THEN BEGIN no_help
SAY ~So shall it be. May the spirits of the forest haunt you.~
COPY_TRANS DRYAD 4
END
END


//Rill
EXTEND_BOTTOM SLAVLEAD 3
IF ~PartyGoldGT(99) InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) 
Global("X#AjantisHelpRill","GLOBAL",0)~ EXTERN AJANTJ help_rill
END

// Gallor
ADD_TRANS_TRIGGER GALLOR 1 ~!InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~

EXTEND_BOTTOM GALLOR 1
IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) Global("X#AjantisNoHelpGallor","GLOBAL",0)~ EXTERN AJANTJ gallor_chain
END

CHAIN AJANTJ gallor_chain
~This man is talking about *killing* the archaeologist and all helpers and *stealing* some magical item. Get you gone, rascal!~
== GALLOR IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) Global("X#AjantisNoHelpGallor","GLOBAL",0)~ THEN ~Hey, I was talking to *<HIMHER>*, or is it you who makes the decisions?~
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING) Global("X#AjantisNoHelpGallor","GLOBAL",0)~ THEN ~<CHARNAME> is our leader, but I am a paladin in the name of Helm and I won't tolerate such a treachery!~ DO ~SetGlobal("X#AjantisNoHelpGallor","GLOBAL",1)~
END
++ ~Ajantis is absolutely right. We won't do such a thing as you intended!~ EXTERN GALLOR 2
++ ~Er.. Ajantis? I would like to listen to what this man is actually suggesting.~ EXTERN GALLOR no_help
++ ~Ajantis, keep your mouth shut! *I* make the decisions, all right?  And I think this man has a very interesting proposal that I would like to hear.~ EXTERN GALLOR no_help

APPEND GALLOR
IF ~~ THEN BEGIN no_help
SAY ~Ah, no, no - forget it. I don't think you are of much help in this case. Damn! Well, I will find someone else who'll help me to turn this into a success. You better be gone!~ 
COPY_TRANS GALLOR 2
END
END

//#####################################################################
// un-proofread I_C_T2

//help dryad
I_C_T2 KRUMM 1 X#AjantisKrumm1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~You scoundrels won't have a chance to cut down this mighty tree - the home of a dryad! If the respect for fairy folk can not stop you from performing this evil act, then we have to protect this forest spirit! Defend yourself!~
END

I_C_T2 KRUMM 3 X#AjantisKrumm3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~You scoundrels won't have a chance to cut down this mighty tree - the home of a dryad! If the respect for fairy folk can not stop you from performing this evil act, then we have to protect this forest spirit! Defend yourself!~
END

//Eldoth, if rejected
I_C_T2 ELDOTH 6 X#AjantisEldoth6
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~What an insidious person! I am very glad you turned him away, <CHARNAME>! Maybe we should warn this Duke of Baldur's Gate before this scoundrel finds other helpers for his false plan.~
END

//Rill (slave leader in mines, after giving him money
I_C_T2 SLAVLEAD 4 X#AjantisRill4
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~What a relief to know that all these poor souls will have a chance to escape! Let us move on and clarify what is going on in this mine.~
END

//Alatos, thieves guild, if rejected
I_C_T2 ALATOS 3 X#AjantisAlatos3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Now they show their true faces! I second your decision not to cooperate with these people. Let us fight these criminals, we are doing the city a favour by cleaning this den of thieves!~
END

I_C_T2 ALATOS 8 X#AjantisAlatos8
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Now they show their true faces! I second your decision not to cooperate with these people. Let us fight these criminals, we are doing the city a favour by cleaning this den of thieves!~
END

//Brevlik and the telescope
I_C_T2 BREVLI 6 X#AjantisBrevlik6
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Illegal! <CHARNAME>, we are here to put an end to the bandit activities threatening the Sword Coast. You are not seriously going to listen to what this man has to offer on illegal actions? The only appropriate reaction to his words would be calling the town guards!~
END

I_C_T2 BREVLI 5 X#AjantisBrevlik5
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Illegal! <CHARNAME>, we are here to put an end to the bandit activities threatening the Sword Coast. You are not seriously going to listen to what this man has to offer on illegal actions? The only appropriate reaction to his words would be calling the town guards!~
END

I_C_T2 BREVLI 6 X#AjantisBrevlik6
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Illegal! <CHARNAME>, we are here to put an end to the bandit activities threatening the Sword Coast. You are not seriously going to listen to what this man has to offer on illegal actions? The only appropriate reaction to his words would be calling the town guards!~
END

//if rejected
I_C_T2 BREVLI 3 X#AjantisBrevlik3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, I am glad you turned that man down. He seemed to be a villain like so many we met on our travels.~
END

//interjection for "good" reaction to Joseph's wife 
INTERJECT_COPY_TRANS2 FTOWN2 8 X#AjantisWomanNashkell8
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~At least we could bring you the news of his death and his wedding ring as keepsake, even if this might be of little consolation to you now. Be assured of my deepest feelings of sorrow and grief, my lady.~
= ~<CHARNAME>, I am very glad you took the time to return the ring to this poor widow. At least now she knows the sad truth.~
END

//Interjection for Teynga

INTERJECT_COPY_TRANS2 TEYNGA 0 X#AjantisTEYNGA0
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~What a ridiculous threat! We are none of those helpless merchants you might meet here normally! In fact we are strong enough to end your condemnable existence!~
END

INTERJECT_COPY_TRANS2 TEYNGA 1 X#AjantisTengya1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Well decided, <CHARNAME>! Now these scums will be treated the way they deserve!~
END

INTERJECT_COPY_TRANS2 TEYNGA 2 X#AjantisTengya2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Well decided, <CHARNAME>! Now these scums will be treated the way they deserve!~
END

INTERJECT_COPY_TRANS2 TEYNGA 3 X#AjantisTengya3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, why did you give in to those bandits! We fought against far more dangerous enemies, I am sure we could have beaten those villains. Now they are gone threatening other travellers - having our treasure!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END 

//Scar on the bridge
INTERJECT_COPY_TRANS2 SCAR 2 X#AjantisScar2
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~This sounds serious, <CHARNAME>! If the second in command of the Flaming Fist asks for help from some 'passers-by', as we might seem, this is something we should listen to!~
END

//Scar in the flaming fist
INTERJECT_COPY_TRANS2 SCAR 21 X#AjantisScar21
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We should accomplish what we had in mind and return quickly to Scar to be led to the Grand Duke Eltan! This meeting seems to be important for our own search, too!~
END

//INTERJECT_COPY_TRANS2 SCAR 22 X#AjantisScar22
//== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~It is not common to get a meeting by a Grand Duke! Let us see what Eltan wants from us and what information we will gather by this audience.~
//END

//TIBER Cloakwood forest, waiting for his brother
INTERJECT_COPY_TRANS2 TIBER 1 X#AjantisTiber1
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~<CHARNAME>, why did you turn that man down? This seemed to be a serious plea!~ DO ~IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~
END

INTERJECT_COPY_TRANS2 TIBER 3 X#AjantisTiber3
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~We will scan this apalling forest for signs of your brother, lad!~
= ~By Helm, <CHARNAME>, if this Chelak is really the unexperienced young man I imagine him to be, I don't think he had a chance. Let us see whether my words will be proven wrong!~ DO ~SetGlobal("X#AjantisTiberHelp","GLOBAL",1)~
END

//after giving Brun money (good hint, Bren)
INTERJECT_COPY_TRANS2 FARMBR 10 X#AjantisBrun10
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~That was an honorable deed, <CHARNAME>! The money will help Farmer Brun to maintain his farm without his son.~
= ~And very clever of you, too! Pretending that we do *not* mean to give money to him was the only way to make this proud man accept the donation!~
END

//after giving Brun money (good hint, Bren)
INTERJECT_COPY_TRANS2 FARMBR 11 X#AjantisBrun11
== AJANTJ IF ~InParty("ajantis") !Dead("ajantis") !StateCheck("ajantis",STATE_SLEEPING)~ THEN ~Hm. What a proud old man! I am deeply impressed. But he won't be able to cope without aid. Maybe there is a better way of offering it to him, <CHARNAME>!~
END 


APPEND ~AJANTJ~

//Ajantis 20 rep

IF WEIGHT #-2  ~Global("X#AjantisBestReputationTalk","GLOBAL",1)~ THEN BEGIN Ajantis_goodreputation_talk
SAY ~<CHARNAME>, your actions are in the true spirit of honor and righteousness! I am exulted to be in this group and to fight at your side!~ [AJANT04]
IF ~~ THEN DO ~SetGlobal("X#AjantisBestReputationTalk","GLOBAL",2)~ EXIT
END

//Ajantis-Dyna hostile

IF WEIGHT #-2  ~Global("X#AjantisDynaHostile","GLOBAL",1)~ THEN BEGIN attacking_dynaheir
SAY ~By Helm! <CHARNAME>, can't you see that this is a fight of good against evil? I am not at your side with this! My honor tells me to defend this woman!~
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisDynaHostile","GLOBAL",2) LeaveParty() Enemy() ~ EXIT
END

//Ajantis-Drizzt hostile

IF WEIGHT #-2  ~Global("X#AjantisDrizztHostile","GLOBAL",1)~ THEN BEGIN attacking_drizzt
SAY ~By Helm! Now you reveal your true intentions! I am not at your side in this fight! <CHARNAME>, raise your weapon as my honor tells me to defend this honorable drow!~ 
IF ~~ THEN DO ~LeaveParty() Enemy() SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisDrizztHostile","GLOBAL",2)~ EXIT
END

//If husband's ring in mine is found
IF WEIGHT #-2  ~Global("X#AjantisWomanNashkellPromise","GLOBAL",2)~ THEN ajantis_husband_ring
SAY ~<CHARNAME>, this is the wedding ring of that Joseph. Poor fellow, he was a victim of the evil afflicting these mines. Let us bring this ring to his widow once we are back. The least we can do for her is to bring her certainty about his fate.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisWomanNashkellPromise","GLOBAL",3)~ EXIT
END


IF ~~ THEN BEGIN help_rill
SAY ~Wait a moment! Of course we will give you the money you need to save all those pour souls! Take it and get yourself and the others out of here as soon as possible!~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisHelpRill","GLOBAL",1) IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~ EXTERN SLAVLEAD 4
END

IF ~~ THEN BEGIN protect_dryad
SAY ~Wait, wondrous forest spirit, don't go away. <CHARNAME>, I can't agree with your decision to let this plea for help go unheard. Protecting the tree of this dryad won't cost us much effort, but will save the life of an ancient forest creature.~
++ ~OK, OK, now that my companions make the decisions for me... I'll help you. Show the way!~ DO ~SetGlobal("X#AjantisProtectDryade","GLOBAL",1)~ EXTERN DRYAD 3
++ ~Ajantis, we don't have time for things like that.  I said no, and that decision is final.~ DO ~SetGlobal("X#AjantisProtectDryade","GLOBAL",1) IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~ EXTERN DRYAD no_help
END

IF ~~ THEN BEGIN not_greywolf
SAY ~Keep your money to yourself, dear man. <CHARNAME> was joking, I guess. There is no man called Greywolf in this group.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisNotGreywolf","GLOBAL",1) SetGlobal("Greywolf","GLOBAL",0)~ EXTERN ~OUBLEK~ 1
END

IF ~~ THEN BEGIN protect_prism
SAY ~There is no need for your curse, good man. I am sure <CHARNAME> will agree that we have enough time to wait that little moment. If it means so much to you, we will let you finish your work.~ 
++ ~(*Sigh*) All right then, go on.~ DO ~SetGlobal("X#AjantisProtectPrism","GLOBAL",1)~ EXTERN ~PRISM~ 4
++ ~No! I said we will take him along *now* and that's what we'll do!~ DO ~SetGlobal("X#AjantisProtectPrism","GLOBAL",1) IncrementGlobal("X#AjantisRomanceBadDecision","GLOBAL",1)~ EXTERN ~PRISM~ no_help
END

//If Nester's dagger was found
IF WEIGHT #-2  ~Global("X#AjantisNestorsDagger","GLOBAL",1)~ THEN BEGIN ajantis_nestors_dagger
SAY ~<CHARNAME>, this looks like a special dagger. Maybe it belonged to that little gnome who was killed by ankhegs.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisNestorsDagger","GLOBAL",2)~ EXIT
END

//Kozah idol
IF WEIGHT #-2  ~Global("X#AjantisKozahStatue","GLOBAL",1)~ THEN BEGIN ajantis_kozah_statue
SAY ~<CHARNAME>, after all that has happened here, you are taking the artifact with you? Kozah was a very powerful god of chaos and destruction, nothing good will arise from this!~
IF ~~ THEN DO ~SetGlobal("X#AjantisKozahStatue","GLOBAL",2)~ EXIT
END

//Dopplegangers
IF WEIGHT #-2  ~Global("X#AjantisNobleDopple","GLOBAL",1)~ THEN BEGIN ajantis_protect_duke
SAY ~Betrayal! We have to protect Duke Belt and Duchess Liia at all costs!~
IF ~~ THEN DO ~SetGlobal("X#AjantisNobleDopple","GLOBAL",2)~ EXIT
END

//If baby Peladan was found
IF WEIGHT #-2  ~Global("X#AjantisPeladan","GLOBAL",1)~ THEN BEGIN ajantis_babyp
SAY ~<CHARNAME>, this is the child of the young Mandalee. I can't believe these creatures abducted a small infant such as this! He is in good health, but we should bring him back to his mother as soon as possible!~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisPeladan","GLOBAL",2)~ EXIT
END

// Thieve's guild
IF WEIGHT #-2  ~Global("X#AjantisThievesGuild","GLOBAL",1)~ THEN BEGIN ajantis_thief_guild
SAY ~So, here we are at the thieves guild! What a place of lawlessness and treachery! I advise you to watch out, <CHARNAME>, and I expect us to leave as soon as possible!~ 
++ ~Thanks for the warning, Ajantis. I don't feel very comfortable here myself.~ DO ~SetGlobal("X#AjantisThievesGuild","GLOBAL",2)~ EXIT
++ ~I came here because I got... invited. Let us have a look around, Ajantis.~ DO ~SetGlobal("X#AjantisThievesGuild","GLOBAL",2)~ EXIT
++ ~Ajantis, you are generalizing. Not all thieves are bad people. You should judge people on their deeds, not on their chosen profession. If there were no thieves, who would disarm the traps that could harm us? Who would pick the locks to free the next slaves we find?~ DO ~SetGlobal("X#AjantisThievesGuild","GLOBAL",2)~ + thief_guild_01 
END

IF ~~ THEN BEGIN thief_guild_01
SAY ~I agree to your words, <CHARNAME>, and I respect a person having the profession and choosing the right path. Yet someone like that is to be found in the minority. This guild is an alliance of heartless, power seeking thieves without morals, earning their living by performing illegal actions.~ 
IF ~~ THEN EXIT
END

//Nathan's dead body
IF WEIGHT #-2  ~Global("X#AjantisNathanFound","GLOBAL",1)~ THEN BEGIN ajantis_nathan_found
SAY ~This seems to be the son of that old farmer. Poor soul! The ankhegs must have brought him here.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisNathanFound","GLOBAL",2)~ EXIT
END

//Ajantis reminder about Samuel
IF WEIGHT #-2  ~Global("X#AjantisBringSamuel","GLOBAL",1)~ THEN BEGIN ajantis_bring_samuel
SAY ~<CHARNAME>, this Samuel is getting sicker and sicker. I don't know how much longer he will survive. We have to get him to the Temple of Wisdom in the Friendly Arm Inn right away or he'll die.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisBringSamuel","GLOBAL",2)~ EXIT
END

//Mirianne's letter found
IF WEIGHT #-2  ~Global("X#AjantisMirianneLetter","GLOBAL",1)~ THEN BEGIN ajantis_mirianne_letter
SAY ~This seems to be a letter from Mirianne's husband! We should give it to her as soon as possible!~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisMirianneLetter","GLOBAL",2)~ EXIT
END

//reputation below 12
IF WEIGHT #-2  ~Global("X#AjantisBadReputationWarning","GLOBAL",1)~ THEN BEGIN Ajantis_badreputation_warning
SAY ~<CHARNAME>, I can't agree to where you are leading us! We are not following the path of good and righteousness!~ [AJANT06] 
++ ~Ajantis, I don't like that myself, but it is only a temporary thing. It will change soon.~ DO ~SetGlobal("X#AjantisBadReputationWarning","GLOBAL",2)~ + Ajantis_badreputation_warning_01
++ ~Ajantis, calm down! It is not that bad! Keep in mind that we are doing this for the high goals we are aiming at!~ DO ~SetGlobal("X#AjantisBadReputationWarning","GLOBAL",2)~ + Ajantis_badreputation_warning_02
END

IF ~~ THEN BEGIN Ajantis_badreputation_warning_01
SAY ~I am relieved to hear this. Let us move on and make your words come true by our actions!~ 
IF ~~ THEN EXIT
END 

IF ~~ THEN BEGIN Ajantis_badreputation_warning_02
SAY ~High goals don't excuse everything. From now on, make sure we proceed on the right path!~
IF ~~ THEN EXIT
END 

//Bjornin ogres:
//enter area
IF WEIGHT #-2  ~Global("X#AjantisBjorninArea","GLOBAL",1)~ THEN BEGIN ajantis_bjornin_area
SAY ~Watch out, <CHARNAME>, we are now in the area the paladin Bjornin mentioned. We should keep our eyes open for those ogres he was talking about!~
IF ~~ THEN DO ~SetGlobal("X#AjantisBjorninArea","GLOBAL",2)~ EXIT
END

//killed ogres
IF WEIGHT #-2  ~Global("X#AjantisBjorninOgresKilled","GLOBAL",1)~ THEN BEGIN ajantis_bjornin_ogreskilled
SAY ~Well done, <CHARNAME>, that was the last of those ogres. We should go back to Beregost and tell Bjornin that his injuries have been avenged.~
IF ~~ THEN DO ~SetGlobal("X#AjantisBjorninOgresKilled","GLOBAL",2)~ EXIT
END

//Entrance to CK library (should be called before the iron throne bosses are met)
IF WEIGHT #-2  ~Global("X#AjantisLibraryCK","GLOBAL",1)~ THEN BEGIN ck_library
SAY ~Now we are here at the famous Candlekeep library! All this wisdom and knowledge condensed in these halls!~
= ~But we are not here for knowledge. Alas! It is the presence of shameless criminals that brings us here. Let us find them and clean these mighty halls from their evil presence!~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisLibraryCK","GLOBAL",2)~ EXIT
END

//Know Bhaal talk
IF WEIGHT #-2  ~Global("X#AjantisKnowBhaalTalk","GLOBAL",1)~ THEN BEGIN knowbhaal_talk
SAY ~<CHARNAME>, You... You are an offspring of *Bhaal*, God of Murder?!~
+ ~ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~I didn't know that myself, Ajantis!~ DO ~SetGlobal("X#AjantisKnowBhaalTalk","GLOBAL",2)~ + bhaalknow_02
+ ~OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~I didn't know that myself, Ajantis!~ DO ~SetGlobal("X#AjantisKnowBhaalTalk","GLOBAL",2)~ + bhaalknow_03
++ ~So it seems, indeed.~ DO ~SetGlobal("X#AjantisKnowBhaalTalk","GLOBAL",2)~ + bhaalknow_01
END

IF ~~ THEN BEGIN bhaalknow_01
SAY ~You are saying this as if this information wouldn't move you at all! Did you know that already?~ 
++ ~No, I got this information just now, Ajantis.~ + bhaalknow_03
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Why is this of interest to you, Ajantis?~ + bhaalknow_05
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Why is this of interest to you, Ajantis?~ + bhaalknow_06
END

IF ~~ THEN BEGIN bhaalknow_02
SAY ~You didn't know that yourself... Yes, I believe you. What a perplexing discovery! What a heritage you are carrying!~ 
IF ~~ THEN + bhaalknow_04
END

IF ~~ THEN BEGIN bhaalknow_03
SAY ~Well, I guess I have to believe you. What a perplexing discovery! What a heritage you are carrying!~ 
IF ~~ THEN + bhaalknow_04
END

IF ~~ THEN BEGIN bhaalknow_04
SAY ~Answer my questions honestly. What does this mean to you? How will you treat this heritage?~ 
+ ~!Alignment(Player1,MASK_EVIL) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~I loathe being an offspring of Bhaal! Evil won't have a chance on me. I will do all that is in my might not to carry on what my father left behind!~ DO ~SetGlobal("X#AjantisKeinErbe","GLOBAL",1)~ + bhaalknow_07
+ ~!Alignment(Player1,MASK_EVIL)
OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~I loathe being an offspring of Bhaal! Evil won't have a chance on me. I will do all that is in my might not to carry on what my father left behind!~
DO ~SetGlobal("X#AjantisKeinErbe","GLOBAL",1)~ + bhaalknow_08
++ ~I don't know... It is all happening so fast. I don't want to be involved in this! Best if this were a great misunderstanding!~ + bhaalknow_09
++ ~Hm... I have to think about it. This is actually providing some very interesting new possibilities...~ + bhaalknow_10
++ ~I am a god's child, Ajantis. I can sense the power that's in me! I have to use it, everything else would be wrong!~ + bhaalknow_11
END

IF ~~ THEN BEGIN bhaalknow_05
SAY ~Why this is of interest to me?! I am a paladin of Helm, and you... an offspring of Bhaal! I have to know how you will be dealing with your heritage!~ 
IF ~~ THEN + bhaalknow_04
END

IF ~~ THEN BEGIN bhaalknow_06
SAY ~Why this is of interest to me?! My love, I am a paladin of Helm, and you... an offspring of Bhaal! I... *have* to know how you will be dealing with your heritage!~
IF ~~ THEN + bhaalknow_04
END

IF ~~ THEN BEGIN bhaalknow_07
SAY ~I am very relieved and happy to hear that.~
IF ~~ THEN + bhaalknow_12
END

IF ~~ THEN BEGIN bhaalknow_08
SAY ~These are great words, but I doubt you will have the steadiness and willpower to make them come true.~
IF ~~ THEN + bhaalknow_12
END

IF ~~ THEN BEGIN bhaalknow_09
SAY ~It seems to be real, so you have to deal with it! Trying to hide from your godly heritage won't work, it will only leave you unprepared in times of need!~
IF ~~ THEN + bhaalknow_12
END

IF ~~ THEN BEGIN bhaalknow_10
SAY ~Possibilities?! Do you seriously consider using the powers of your bloody father for your own aims?~
++ ~No, I didn't mean it like that. It was only a general thought.~ + bhaalknow_12
++ ~Indeed! I am a god's child, Ajantis. I can sense the power that's in me! I have to use it, everything else would be wrong!~ + bhaalknow_11
END

IF ~~ THEN BEGIN bhaalknow_11
SAY ~What are you talking about! Bhaal was the deity of murder and destruction! Do you want those evil powers to become *yours*?~
+ ~Alignment(Player1,MASK_EVIL)~ + ~Sure! A lot of unexpected possibilities are coming my way... The more I think of it, the more I like the idea!~ + bhaalknow_36 
+ ~!Alignment(Player1,MASK_EVIL) !Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Sure! A lot of unexpected possibilities are coming my way... The more I think of it, the more I like the idea!~ + bhaalknow_14 
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Sure! A lot of unexpected possibilities are coming my way... The more I think of it, the more I like the idea!~ + bhaalknow_15
++ ~Do I have a choice? You know Alaundo's prophecies. I have to be the last, otherwise I will fall by the hand of one of my brothers or sisters.~ + bhaalknow_16
+ ~!Alignment(Player1,MASK_EVIL)~ + ~Not the *evil* forces, Ajantis. All I am talking about is the godly powers I hold in me. I will use them for my own purposes!~ + bhaalknow_13
END

IF ~~ THEN BEGIN bhaalknow_12
SAY ~You know Alaundo's prophecies. The offspring of Bhaal will fight each other for the throne of their father, bringing chaos and destruction to all around them. Where will you be when this happens, <CHARNAME>?~
+ ~Global("X#AjantisRomanceActive","GLOBAL",2) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)
!Alignment(Player1,MASK_EVIL)~ + ~You base those words on mortal translations of the prophecies. I am sure some of his offspring will fight for the throne, but I refuse to take an evil path simply because some... deity decided to impregnant my mother. And I will be wherever I need to be, in order to destroy it... before it can destroy me.~ + bhaalknow_29
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)
!Alignment(Player1,MASK_EVIL)~ + ~You base those words on mortal translations of the prophecies. I am sure some of his offspring will fight for the throne, but I refuse to take an evil path simply because some... deity decided to impregnant my mother. And I will be wherever I need to be, in order to destroy it... before it can destroy me.~ + bhaalknow_25
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3) !Alignment(Player1,MASK_EVIL)~ + ~You base those words on mortal translations of the prophecies. I am sure some of his offspring will fight for the throne, but I refuse to take an evil path simply because some... deity decided to impregnant my mother. And I will be wherever I need to be, in order to destroy it... before it can destroy me.~ + bhaalknow_26
+ ~Global("X#AjantisRomanceActive","GLOBAL",2) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3) !Alignment(Player1,MASK_EVIL)~ + ~You base those words on mortal traslations of the prophecies. I am sure some of his offspring will fight for the throne, but I refuse to take an evil path simply because some... deity decided to impregnant my mother. And I will be wherever I need to be, in order to destroy it... before it can destroy me.~ + bhaalknow_27
+ ~Global("X#AjantisRomanceActive","GLOBAL",2) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~I just can't accept this as my destiny! I don't want to fight for the throne of Bhaal, I don't want to spread chaos and destruction! I will remain true to my path, trying to do good!~ + bhaalknow_29
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~I just can't accept this as my destiny! I don't want to fight for the throne of Bhaal, I don't want to spread chaos and destruction! I will remain true to my path, trying to do good!~ + bhaalknow_25
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~I just can't accept this as my destiny! I don't want to fight for the throne of Bhaal, I don't want to spread chaos and destruction! I will remain true to my path, trying to do good!~ + bhaalknow_26
+ ~Global("X#AjantisRomanceActive","GLOBAL",2) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~I just can't accept this as my destiny! I don't want to fight for the throne of Bhaal, I don't want to spread chaos and destruction! I will remain true to my path, trying to do good!~ + bhaalknow_27
++ ~Well, if this is the will of the gods, I fear it will happen that way.~ + bhaalknow_16
+ ~!Global("X#AjantisKeinErbe","GLOBAL",1)~ + ~I have to fight this fight! It is the only way I will get my father's heritage which belongs to me!~ + bhaalknow_11
END

IF ~~ THEN BEGIN bhaalknow_13
SAY ~Are you that naive to think you could trick the true nature of your father and use his powers to do *good*?!~
++ ~Why should this be impossible? I am not evil, Ajantis. If it is my destiny to take my father's place - why not doing it in *my* way?~ + bhaalknow_17
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Who is talking about doing good, Ajantis?... Once I have the powers, I'll do whatever *I* want!~ + bhaalknow_14
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Who is talking about doing good, Ajantis?... Once I have the powers, I'll do whatever *I* want!~ + bhaalknow_15
END

IF ~~ THEN BEGIN bhaalknow_14
SAY ~I can't believe you are saying this. Stay away from me! I will stay with you, but only to watch your steps. Helm in his holy might will help me fight you, if this should become necessary!~
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN bhaalknow_15
SAY ~What... what are you saying there, my love! Please, tell me that you don't mean it... yet, you meant it seriously. Should I be so mistaken about you...~ 
= ~Stay away from me, my lady! I have knightly duties to fulfill! I will stay with you, but only to watch your steps. Helm in his holy might will help me fight you, if this should become necessary!~
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN bhaalknow_16
SAY ~So you are going to kill your brothers and sisters? You are going to spill their and other's blood over the soil of your country?~
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2) !Global("X#AjantisRomanceActive","GLOBAL",1)~ + ~I didn't say it is my *will*! All I am doing is accepting my destiny. If this is what the gods hold for me, I will play their game.~ + bhaalknow_28
+ ~OR(2) Global("X#AjantisRomanceActive","GLOBAL",2) Global("X#AjantisRomanceActive","GLOBAL",1) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~I didn't say it is my *will*! All I am doing is accepting my destiny. If this is what the gods hold for me, I will play their game.~ + bhaalknow_30
+ ~OR(2) Global("X#AjantisRomanceActive","GLOBAL",2) Global("X#AjantisRomanceActive","GLOBAL",1) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~I didn't say it is my *will*! All I am doing is accepting my destiny. If this is what the gods hold for me, I will play their game.~ + bhaalknow_31
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Indeed! I won't sit and wait until my power-seeking half-brothers and sisters are passing by, trying to get nearer to our father's throne by killing me!~ + bhaalknow_14
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Indeed! I won't sit and wait until my power-seeking half-brothers and sisters are passing by, trying to get nearer to our father's throne by killing me!~ + bhaalknow_15
+ ~!Alignment(Player1,MASK_EVIL) !Global("X#AjantisKeinErbe","GLOBAL",1) !Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~I will wade through their blood, and I will smile to that, Ajantis!~ + bhaalknow_14
+ ~!Alignment(Player1,MASK_EVIL) !Global("X#AjantisKeinErbe","GLOBAL",1) Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~I will wade through their blood, and I will smile to that, Ajantis!~ + bhaalknow_15
+ ~Alignment(Player1,MASK_EVIL) !Global("X#AjantisKeinErbe","GLOBAL",1)~ + ~I will wade through their blood, and I will smile to that, Ajantis!~ + bhaalknow_36
END

IF ~~ THEN BEGIN bhaalknow_17
SAY ~Because we mortals aren't born to have and *control* those powers, <CHARNAME>! Bhaal himself was a mortal, but he was wicked and power-hungry, and so were the godly powers he received. What you are talking about is to use and form these evil powers for your own, not evil purposes! How do you know you will be strong enough for that?~
+ ~!Class(Player1,PALADIN_ALL) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~I don't know it, Ajantis - but I will do all that is in my might to make it come true.~ + bhaalknow_19
+ ~!Class(Player1,PALADIN_ALL) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~I don't know it, Ajantis - but I will do all that is in my might to make it come true.~ + bhaalknow_20
+ ~Class(Player1,PALADIN_ALL)~ + ~I don't know it, Ajantis - but I will do all that is in my might to make it come true.~ + bhaalknow_21
+ ~!Class(Player1,PALADIN_ALL) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ + ~Of course I'll be strong enough! Didn't I choose the path of good already, despite my heritage?~ + bhaalknow_19
+ ~!Class(Player1,PALADIN_ALL) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ + ~Of course I'll be strong enough! Didn't I choose the path of good already, despite my heritage?~ + bhaalknow_20
+ ~Class(Player1,PALADIN_ALL)~ + ~Of course I'll be strong enough! Didn't I choose the path of good already, despite my heritage?~ + bhaalknow_21
++ ~Ah, poppycock! Time will tell. Why are you worried about it now?~ + bhaalknow_18
END

IF ~~ THEN BEGIN bhaalknow_18 
SAY ~I can't believe you are treating this so lightly! Get rational, <CHARNAME>! This is the power of a deity you are confronted with. It will form *you*, not the other way round. You have to be firm in faith, steady without the smallest hesitation on the path of good and righteousness, then there might be a chance to succeed!~
IF ~!Class(Player1,PALADIN_ALL) ReputationGT(Player1,13)
GlobalLT("X#AjantisRomanceBadDecision","GLOBAL",4)~ THEN + bhaalknow_19
IF ~!Class(Player1,PALADIN_ALL) OR(2) ReputationLT(Player1,14)
GlobalGT("X#AjantisRomanceBadDecision","GLOBAL",3)~ THEN + bhaalknow_20
IF ~Class(Player1,PALADIN_ALL)~ THEN + bhaalknow_21
END

IF ~~ THEN BEGIN bhaalknow_19
SAY ~Well, you seem to have stayed on the right path up to now... I see a chance for you to reach your goal.~
IF ~~ THEN + bhaalknow_22
END

IF ~~ THEN BEGIN bhaalknow_20
SAY ~You will fail, <CHARNAME>. You have already shown evil deeds on our travels. You are not on the right path, and your willpower isn't strong enough! The evil powers will overwhelm you!~
IF ~!Global("X#AjantisRomanceActive","GLOBAL",2)~ THEN + bhaalknow_23
IF ~Global("X#AjantisRomanceActive","GLOBAL",2)~ THEN + bhaalknow_24
END

IF ~~ THEN BEGIN bhaalknow_21
SAY ~You are definitely going on the path of righteousness, and I see a chance for you to reach your goal.~
IF ~~ THEN + bhaalknow_22
END

IF ~~ THEN BEGIN bhaalknow_22
SAY ~But how will you succeed? You know Alaundo's prophecies. The offspring of Bhaal will fight each other for the throne of their father, bringing chaos and destruction to all around them. Where will you be when this happens, <CHARNAME>?~
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~You base those words on mortal translations of the prophecies. I am sure some of his offspring will fight for the throne, but I refuse to take an evil path simply because some... deity decided to impregnant my mother. And I will be wherever I need to be, in order to destroy it... before it can destroy me.~ + bhaalknow_25
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~You base those words on mortal translations of the prophecies. I am sure some of his offspring will fight for the throne, but I refuse to take an evil path simply because some... deity decided to impregnant my mother. And I will be wherever I need to be, in order to destroy it... before it can destroy me.~ + bhaalknow_29
+ ~!Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~I just can't accept this as my destiny! I don't want to fight for the throne of Bhaal, I don't want to spread chaos and destruction! I will remain true to my path, trying to do good!~ + bhaalknow_25
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~I just can't accept this as my destiny! I don't want to fight for the throne of Bhaal, I don't want to spread chaos and destruction! I will remain true to my path, trying to do good!~ + bhaalknow_29
++ ~Well, if this is the will of the gods, I fear it will happen that way.~ + bhaalknow_16
END

IF ~~ THEN BEGIN bhaalknow_23
SAY ~I will stay with you... but only to watch your steps! Helm in his holy might will give me strength to fight you, if this should become necessary!~
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN bhaalknow_24
SAY ~Forgive me, my love. I have to end our relationship to be able to concentrate on my duties as a paladin. I will stay with you... but only to watch your steps! Helm in his holy might will give me strength to fight you, if this should become necessary!~
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN bhaalknow_25
SAY ~Your words let my doubts disappear. Let us move on, and be vigilant. I will fight at your side and assist you in your magnanimous plan as much as I can.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN bhaalknow_26
SAY ~You choose great words, but they can't make my doubts disappear. I will fight at your side and assist you in your magnanimous plan as long as you stay on the right path.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN bhaalknow_27
SAY ~You choose great words, my love, but they don't fit to your deeds so far. I was hoping I could overlook it, but the situation has changed...~
= ~Forgive me, my love. I have to end our relationship to be able to concentrate on my duties as a paladin. I will stay with you... but only to watch your steps! I will fight at your side and assist you in your magnanimous plan as long as you stay on the right path.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN bhaalknow_28
SAY ~I see. Let us move on and be vigilant. I will fight at your side and assist you as long as you stay on the right path.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN bhaalknow_29
SAY ~My love, your words let my doubts disappear. I am... very happy, because it means I can stay with you without having to neglect my duties as a paladin...~
= ~Yet I tremble at the thought of what might be waiting for you in the future. Let us move on and be vigilant. I will support you with all my might!~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN bhaalknow_30
SAY ~Don't accept destiny as given! It is not yet decided *how* things will happen. You can influence the path your future will take with your good powers! As a paladin I have to know how you will decide, once the day will come.~
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~Ajantis, I will try to stay on the path of good, no matter what the future will bring. Please believe me!~ + bhaalknow_29
+ ~Global("X#AjantisRomanceActive","GLOBAL",1)~ + ~Ajantis, I will try to stay on the path of good, no matter what the future will bring. Please believe me!~ + bhaalknow_25
+ ~Global("X#AjantisRomanceActive","GLOBAL",2)~ + ~When the day comes, I will do whatever destiny has prepared for me. If it means I have to kill other Bhaal offspring, then so be it.~ + bhaalknow_32
+ ~Global("X#AjantisRomanceActive","GLOBAL",1)~ + ~When the day comes, I will do whatever destiny has prepared for me. If it means I have to kill other Bhaal offspring, then so be it.~ + bhaalknow_33
END

IF ~~ THEN BEGIN bhaalknow_31
SAY ~That means you *will* actively participate in making the prophecy come true...~
IF ~Global("X#AjantisRomanceActive","GLOBAL",2)~ THEN + bhaalknow_34
IF ~Global("X#AjantisRomanceActive","GLOBAL",1)~ THEN + bhaalknow_35
END

IF ~~ THEN BEGIN bhaalknow_32
SAY ~The readiness showing in your words frightens me, my love. And yet you would have the power to stay on the path of good...~
= ~I tremble at the thought of what might be waiting for you in the future. Let us move on and be vigilant. I will assist you as long as you stay on the right path.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN bhaalknow_33
SAY ~The readiness showing in your words frightens me. And yet you would have the power to stay on the path of good...~
= ~Let us move on and be vigilant. I will fight at your side and assist you, as long as you stay on the right path.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN bhaalknow_34
SAY ~My heart gets sad when considering this, my love. You have already shown evil deeds on our travels. I was hoping I could overlook it, but the situation has changed...~
= ~Forgive me, my love. I have to end our relationship to be able to concentrate on my duties as a paladin. I will stay with you... but only to watch your steps! I will fight at your side and assist you in your magnanimous plan, as long as you stay on the right path.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN bhaalknow_35
SAY ~My heart gets sad when considering this. You have already shown evil deeds on our travels... I have to concentrate on my duties as a paladin. I will keep my thoughts to myself, from now on.~ 
= ~Let us move on and be vigilant, my lady. I will fight at your side and assist you as long as you stay on the right path.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#AjantisRomanceInsult","GLOBAL",1)~ EXIT
END

IF ~~ THEN bhaalknow_36
SAY ~You evil creature! Now you reveal your true intentions! Raise your weapon, I won't let you go any further!~ [AJANT31]
IF ~~ THEN DO ~LeaveParty() Enemy() SetGlobal("X#AjantisRomanceActive","GLOBAL",3)~ EXIT
END 



//#################################################################
// un-proofread part of APPEND AJANTJ

//Ajantis recognises low rep of a freshly joined group
IF WEIGHT #-2  ~Global("X#AjantisBadRepJoinTalk","GLOBAL",1)~ THEN BEGIN Ajantis_badreputation_joining
SAY ~<CHARNAME>, I will follow you despite the reputation you have at the moment. Time will tell whether your deeds turn out to be better than the impression you are making right now. I expect us to stay on the path of good and rigteousness as we proceed. Let us go and chase those bandits that are pestering the streets!~
IF ~~ THEN DO ~SetGlobal("X#AjantisBadRepJoinTalk","GLOBAL",2)~  EXIT
END

//Ajantis recognises rep increase after former bad rep talk
IF WEIGHT #-2  ~Global("X#AjantisBadReputationIncrease","GLOBAL",1)~ THEN BEGIN Ajantis_reputation_increase
SAY ~<CHARNAME>, I see that we are on the right path now. What you just did was a very good deed. Let us move on and keep up this spirit!~ [AJANT04]
IF ~~ THEN DO ~SetGlobal("X#AjantisBadReputationIncrease","GLOBAL",2)~  EXIT
END

//Ajantis good rep talk for rep >17
IF WEIGHT #-2  ~Global("X#AjantisGoodReputationTalk","GLOBAL",1)~ THEN BEGIN Ajantis_goodreputation_talk
SAY ~<CHARNAME>, I am very content with our actions so far, and I think you are a very good leader. Our deeds show the spirit of good and righteousness! I thank Helm we combined our forces. Let us go and carry on, there will be still a lot of evil creatures waiting on our way.~ [AJANT04] 
IF ~~ THEN DO ~SetGlobal("X#AjantisGoodReputationTalk","GLOBAL",2)~  EXIT
END

//if the "wanted" letter is found on an opponent(SCRLKAR.ITM)
IF WEIGHT #-2  ~Global("X#AjantisWantedLetter","GLOBAL",1)~ THEN ajantis_wanted_letter
SAY ~What is this?! This is a "wanted" description of you, <CHARNAME>. An evil enemy wants you dead, so it seems! Let us carry on with our search and not be discouraged by such developments. We are on the right path, and this enemy will be defeated in the end.~
IF ~~ THEN DO ~SetGlobal("X#AjantisWantedLetter","GLOBAL",2)~ EXIT
END

//if dead Chelak is found
IF WEIGHT #-2   ~Global("X#AjantisTiberHelp","GLOBAL",2)~ THEN ajantis_chelak_found
SAY ~And here we have this Chelak, poor fellow. All we can do for him and his family is to return the body to his brother. Another grieving mother! I surely wished it would have been a happier ending.~ 
IF ~~ THEN DO ~SetGlobal("X#AjantisTiberHelp","GLOBAL",3)~ EXIT
END

IF WEIGHT #-2  ~Global("X#PartyAttackedDrizzt","GLOBAL",2)~ THEN BEGIN attacking_drizzt
SAY ~By Helm! Now you reveal your true intentions! I am not on your side in this fight! <CHARNAME>, raise your weapons, as my honor tells me to defend this valiant drow!~
IF ~~ THEN DO ~LeaveParty() Enemy() SetGlobal("X#AjantisRomanceActive","GLOBAL",3) SetGlobal("X#PartyAttackedDrizzt","GLOBAL",3)~ EXIT
END

END


//Undecellar
CHAIN 
IF ~Global("X#AjantisUndercellar","GLOBAL",1)~ THEN ~AJANTJ~ ajantis_undercellar
~So, these are the Undercellars of Baldur's Gate. Ah, this place stinks of crime and oppression.~
== AJANTJ IF ~!PartyHasItem("_SCRL2R") GlobalLT("Baldurian","GLOBAL",1)~ THEN ~This is nowhere a paladin should spend his time. <CHARNAME>, I expect us to leave this place immediately!~ DO ~SetGlobal("X#AjantisUndercellar","GLOBAL",2)~
== AJANTJ IF ~!PartyHasItem("_SCRL2R") GlobalGT("Baldurian","GLOBAL",0) GlobalLT("Baldurian","GLOBAL",4)~ THEN ~This is nowhere a paladin should spend his time. <CHARNAME>, I expect us to seek the person we are here for and then leave this place immediately!~ DO ~SetGlobal("X#AjantisUndercellar","GLOBAL",2)~
== AJANTJ IF ~PartyHasItem("_SCRL2R")~ THEN ~Would it that the evil-doers had enough decency to come out of the bowels and sewers, to face us squarely on the battle-field! But no, they prefer to dig themselves into filth and they seek sanctuary in the hovels of the disreputable women, not temples! No doubt, they hope that those of the nobler disposition would not want to stain their honor by associating with such and would not follow.~ DO ~SetGlobal("X#AjantisUndercellar","GLOBAL",2)~
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1) !Global("X#AjantisRomanceActive","GLOBAL",3) !Global("X#AjantisRomanceActive","GLOBAL",0)~ THEN ~The knightly honor is a strange thing... You feel dishonored when these hard-working maidens propose their simple charms to you in exchange for a hard coin.  Yet, you press your attentions on <CHARNAME>, for free and freely, expecting her to be honored by it...~
== AJANTJ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1) !Global("X#AjantisRomanceActive","GLOBAL",3) !Global("X#AjantisRomanceActive","GLOBAL",0)~ THEN ~*Reddens* This is something totaly different, elf, and I don't know what that remark was for. Better watch out not to loose your honor yourself - or even smudge <CHARNAME>'s!~
EXIT
