BEGIN X#CHOP

IF ~Global("X#XanQuest1","GLOBAL",1)~ THEN BEGIN CHOP1
SAY ~Meat, shut up!~
IF ~~ THEN EXTERN ~X#CRU11~ CRU1
END

IF ~~ THEN BEGIN CHOP1.1
SAY ~SHUT UP!~
IF ~~ THEN EXTERN ~X#CRU11~ CRU2
END

IF ~~ THEN BEGIN CHOP2NORC
SAY ~Uhm. Yes. Good idea, small one. We not kill you. Go.~
IF ~~ THEN DO ~SetGlobal("X#XanQuest1","GLOBAL",2) ReputationInc(-4) Attack("X#DAVID") ActionOverride("X#CRU11", Attack("X#DAVID"))~
EXIT
END

IF ~~ THEN BEGIN CHOP2ORC
SAY ~Uhm. Good idea, for a half-breed. We not kill you. Go.~
IF ~~ THEN DO ~SetGlobal("X#XanQuest1","GLOBAL",2) ReputationInc(-4) Attack("X#DAVID") ActionOverride("X#CRU11", Attack("X#DAVID"))~
EXIT
END

IF ~Global("X#XanQuest1","GLOBAL",3)~ THEN BEGIN CHOPKILLEDDAVID
SAY ~Now we have fresh meat. We go.~
IF ~~ THEN DO ~EscapeArea() ActionOverride("X#CRU11", EscapeArea())~
EXIT
END


IF ~~ THEN BEGIN CHOP3
SAY ~Me not like this. All talk too much.~
IF ~~ THEN DO ~SetGlobal("X#XanQuest1","GLOBAL",2) Kill("X#DAVID") ReputationInc(-1) Enemy() ActionOverride("X#CRU11", Enemy())~
EXIT
END

IF ~~ THEN BEGIN CHOP4
SAY ~Fast food is no good for ye anyway, Cru. These ones are bigger and less fatty. Chop-chop-chop!~
IF ~~ THEN DO ~SetGlobal("X#XanQuest1","GLOBAL",2) Enemy() ActionOverride("X#CRU11", Enemy())~
EXIT
END

IF ~~ THEN BEGIN CHOPXAN4
SAY ~Um, grains? Vegetables? ~
IF ~~ THEN EXTERN ~X#DAVI~ DAVIXAN3
END

IF ~Global("X#XanQuest1","GLOBAL",7)~ THEN BEGIN CHOPXAN6
SAY ~Me eat this? *bites a turnip* Um...tastes a bit like xzvart...Try it, Cru...~
IF ~~ THEN EXTERN ~X#CRU11~ CRUXAN1
END

CHAIN3 X#CHOP CHOPXAN1
~*Sighs* Youse wish. How much tell youse, that we eat meat - only fresh, and in *small* portions? Or d’youse want to become as fat as Hrump-Grum? Off wid youse, meat, me willpower weakens.~
== ~XANJ~ ~It is both amusing and pathetic that our doom should be averted by an ogre’s consideration for her waistline.~
= ~*Sighs* Ironically, she does not realize that eating gnomes would ultimately lead to her own demise. ~
== X#CHOP ~What youse mean, puny elf?~
== ~XANJ~ ~Eating fresh meat exclusively may make you thinner, ogre, but you will die faster. What’s the point of looking slender in your coffin?~
== X#CHOP ~*The ogre throws a puzzled look at Xan like a rock* What's t'do?~
DO ~SetGlobal("X#XanQuest1","GLOBAL",4)~
END ~XANJ~ XANQU1.1

CHAIN3 X#CHOP CHOPXAN5
~Grain not speak: better meal. Do that, but hurry. Me getting hungry. ~
== X#CRU11 ~Me too.~
== X#DAVI ~Go, my noble friends. If I do remember aright, there was a trader who did not charge outrageously for his turnips at the Nashkel fare. Ever did Jansens suspect that their salvation lies in turnips!~
DO ~SetGlobal("X#XanQuest1","GLOBAL",6)~
EXIT






