APPEND ~FALDOJ~

// Killed bear

IF WEIGHT #-2 ~Global("X#FalBear","GLOBAL",1)~ THEN BEGIN FABE01
SAY ~Listen, you imbecile townling! Bears only attack if you jump on them. Walk carefully and we would not have to assassinate the poor beasts.~
++ ~Yes, ma'am.~ DO ~SetGlobal("X#FalBear","GLOBAL",2)~ EXIT
++ ~I was just hunting, Faldorn. Natural-like. How could Shadow Druids possibly be against it?~ DO ~SetGlobal("X#FalBear","GLOBAL",2)~ + FABE1
++ ~I have no time for tip-toeing around bears, Faldorn!~ DO ~SetGlobal("X#FalBear","GLOBAL",2)~ + FABE2
++ ~I just like killing bears. Makes me feel so much superior to the dumb beasts.~ DO ~SetGlobal("X#FalBear","GLOBAL",2)~ + FABE3
++ ~Why don't you keep watch, Faldorn? Then you can prevenue us in time and we'd avoid slaying innocent beasts?~DO ~SetGlobal("X#FalBear","GLOBAL",2)~+ FABE4
END

IF ~~ FABE1
SAY ~Ignorance is no excuse! You eat what you kill, <CHARNAME>. Next time you shoot a bear I will make you swallow it whole!~
++ ~*Grin* See that you do, druid, see that you do.~ DO ~SetGlobal("X#FalBear","GLOBAL",3)~ EXIT
++ ~Please, be reasonable... well, as reasonable as you *can*. We stalk through the forest. Sometimes we disturb a beast and have to kill it... I have no time for tip-toeing around bears, Faldorn!~  + FABE2
++ ~Why don't you keep watch, Faldorn? Then you can prevenue us in time and we'd avoid slaying innocent beasts?~ + FABE4
END

IF ~~ FABE2
SAY ~MAKE time, <CHARNAME>. It's an innocent life we are talking about!~
IF ~~ THEN EXIT
END

IF ~~ FABE3
SAY ~You are only pretending to be Nature's friend! I will not shame myself by guiding you through the forest!~
IF ~~ THEN DO ~LeaveParty() EscapeArea()~ EXIT
END

IF ~~ FABE4
SAY ~Well spoken, <CHARNAME>. *nodds* So be it.~
IF ~~ THEN DO ~SetGlobal("X#FalBear","GLOBAL",3)~ EXIT
END

IF WEIGHT #-2 ~Global("X#FalBear","GLOBAL",4)~ THEN BEGIN FABE02
SAY ~I warned you!~
= ~Where are you going? The carcass is right here. Sit down and have your dinner!~
++ ~Uhm... Faldorn, I am sorry about the bear, but you cannot really expect me to eat this one?~ DO ~SetGlobal("X#FalBear","GLOBAL",5)~ + FABE5
++ ~Alright. Hey, everyone, set up the camp! We are having a feast!~ DO ~SetGlobal("X#FalBear","GLOBAL",5)~+ FABE6
+ ~Gender(Player1, MALE)~+ ~Only if you fry it for me, cookie...~ DO ~SetGlobal("X#FalBear","GLOBAL",5)~+ FABE5
++ ~I'm not going to obey some crazy kid with twigs in her hair!~ DO ~SetGlobal("X#FalBear","GLOBAL",5)~+ FABE7
END

IF ~~ FABE5
SAY ~You will eat it, and you will eat it raw!~
++ ~Alright. Hey, everyone, set up the camp! We are having a feast!~ DO ~SetGlobal("X#FalBear","GLOBAL",5)~+ FABE6
++ ~I'm not going to obey some crazy kid with twigs in her hair!~ DO ~SetGlobal("X#FalBear","GLOBAL",5)~+ FABE7
END

IF ~~ FABE6
SAY ~Grr! It was supposed to be a lesson, not an excuse for burning more trees...~
= ~But what can one expect from a townling? Grr!~
IF ~~ THEN EXIT
END

IF ~~ FABE7
SAY ~You have exhausted my good will! Defend yourself, Nature's enemy!~
IF ~~ THEN DO ~LeaveParty() Enemy()~ EXIT
END

//Fergus
IF WEIGHT #-2 ~Global("X#FaldornFergus","GLOBAL",1)~ THEN FaldornFergus
SAY ~Grr!~
++ ~I take it, you do not approve? Heh, I can see why. The air is so thick with love, one can brew a potion out of it!~ DO ~SetGlobal("X#FaldornFergus","GLOBAL",2)~ + FAFE1.1
++ ~Keep your grrs to yourself!~ DO ~SetGlobal("X#FaldornFergus","GLOBAL",2)~ EXIT
END

IF ~~ FAFE1.1
SAY ~HA! Take it from the druid, <CHARNAME>, there is no such thing as love elixir! Since the whole *love* thing was invented by civilized folk to substitute for their natural urges, which they thought 'inappropriate'! Only a charlatan would claim to induce that which does NOT exist!~
+ ~Gender(Player1,MALE)~ + ~Well, one of those days you should show me how to do it the RIGHT 'natural' way *wink*~ + FAFE1.2
++ ~If love did not exist, Faldorn, it was well worth inventing it. Not that you'd understand.~ EXIT
++ ~Yes, yes, I know - mating is what *you* dream of on starry nights...~ + FAFE1.3
++ ~Illuminating. Now let's go.~ EXIT
+ ~Gender(Player1,MALE)~ + ~When I look at a certain lady... I'd settle for a lust elixir, Faldorn...~ + FAFE1.4
+ ~Gender(Player1,FEMALE)~ + ~When I look at a certain man... I'd settle for a lust elixir, Faldorn...~ + FAFE1.4
END

IF ~~ FAFE1.2
SAY ~I'll call for mates when the time comes, like every other bitch. Fight for me then. Words now will do you no good.~
IF ~~ THEN EXIT
END

IF ~~ FAFE1.3
SAY ~Dream? *She howls* What I am - a townling?~
IF ~~ THEN EXIT
END

IF ~~ FAFE1.4
SAY ~One part powder of cassia, three damiana leaves, one part of lotus petals-~
= ~Argh, forget it. If you ever need one - I'll do it for you. Moon teas brewed improperly can leave a person forever cold...~
IF ~~ THEN EXIT
END

//Peter
IF ~~ THEN FaldornPeter
SAY ~No you aren't! You are a beast-torturer! The wrath of Shadow Druids have found you! ~
IF ~~ THEN EXTERN ~COKSMTH~ 3
END

//Entering FW0400

IF WEIGHT #-2 ~Global("FaldornM400","GLOBAL",1) ~ THEN BEGIN FALDOM400
SAY ~ Beautiful land... if only it was uninhabited! Grr! It smells foul! ~
IF ~~ THEN DO ~SetGlobal("FaldornM400","GLOBAL",2) ~ EXIT
END

// Faldorn, At Seeing The Firewine Ruins
IF WEIGHT #-2 ~Global("FASTFWR","GLOBAL",1)~ THEN BEGIN FASTFWR1
SAY ~Ruins. *Nods approvingly* That’s the state I’d like to see all the civilizations in. The sooner the forest claims this land back, the better.~
IF ~~ THEN DO ~SetGlobal("FASTFWR","GLOBAL",2)~ EXIT
END

//FaldornAnkhegs

IF WEIGHT #-2 ~Global("X#FaldornAn10","FW1400",1)~ THEN BEGIN X#FalAn10
SAY ~Grr! Do not you dare to slay one more! That last one, it was with a babe, I swear!~
IF ~~ THEN DO ~SetGlobal("X#FaldornAn10","FW1400",2)~ EXIT
END

IF WEIGHT #-2 ~Global("X#FaldornAn11","FW1400",1)~ THEN BEGIN X#FalAn11
SAY ~Can’t you count, you fool?! Another innocent death here and I will off you for your rape of the Great Mother!~
IF ~~ THEN DO ~SetGlobal("X#FaldornAn11","FW1400",2)~ EXIT
END

IF WEIGHT #-2 ~Global("X#FaldornAn12","FW1400",1)~ THEN BEGIN X#FalAn11
SAY ~You are defiling nature, townling. I can stomach it no more. I can't stand against you but nor will I aid you further till you come to your senses. Find me in my grove if you change your ways.~
IF ~~ THEN DO ~SetGlobal("X#FaldornAn12","FW1400",2) LeaveParty() ActionOverride("faldorn",LeaveAreaLUA("FW1600","",[670.2900],3))~ EXIT
END

END


I_C_T ~MAPLE~ 0 X#FaldornMaple
== ~FALDOJ~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Grr, I wish your name had imprinted one of the trees' virtues on you - their sage quietude.~
END

I_C_T ~VOLTIN~ 1 FaVoltine1
== ~FALDOJ~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~A townling is badmouthing a servant of nature? Death to him! Wait, why are you in town, druid? Are you one of those perverted druids who teach us that cities- Nevermind for now. First to killing the mage!~
END

I_C_T2 ~VOLTIN~ 4 FaVoltine2
== ~FALDOJ~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Blind fool! I will not let you kill a druid to defend on a word of some mageling!~
DO ~LeaveParty() Enemy()~
END

EXTEND_BOTTOM ~CORSON~ 6
IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN EXTERN ~FALDOJ~ FaldornCorsone
END

CHAIN
IF ~~
THEN ~FALDOJ~ FaldornCorsone
~You are among friends, Corsone. Well done! Apart from pretending that is.~
== ~CORSON~ ~Where the beast walks-~
== ~FALDOJ~ ~- and shadows dance.~
== ~CORSON~ ~I am glad to meet you, sister. I was alone for so long among these so called druids, who talk about compromises while the forests dissappear.~
== ~FALDOJ~ ~Walk to the West, brother, and you'd come to my grove. Tell the tale of your accomplishements there and you will find yourself among friends.~
== ~CORSON~ ~Thank you, sister.~
DO ~EscapeArea() AddXPObject("faldorn",200) ~
EXIT


//Faldorn Osmadi

I_C_T ~OSMADI~ 0 X#FaldornOsmadi
== ~FALDOJ~ IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Do not look at me, <CHARNAME>! I *wish* I could claim such a fit! But I did not kill the pseudo-druids here!~
END

//Faldorn doppleg

INTERJECT_COPY_TRANS~GORION3~0 FALDODOPPLEGANGER
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN ~*Snorts* There is nothing magical about poisons like that. You take a leaf of durman-flower and -~
==~GORION3~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN ~Perhaps, that what it was, druid.~
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN ~Grr! Mages! A druid would have recognized the difference between a magical potion and a natural brew!~
END

//Faldorn Izefia ICT
 
INTERJECT_COPY_TRANS~IZEFIA~1 X#FALDORNIZEFIA1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~I promise you that the poor cubs would feast on his corpse!~
==~IZEFIA~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Hatchlings, rather than cubs, but it makes no difference. Go, Faldorn. Come talk to me afterwards.~
DO ~SetGlobal("X#ReportIzefia","GLOBAL",1)~
END
 
CHAIN
IF WEIGHT #-1 ~Global("X#ReportIzefia","GLOBAL",1) Dead("x#peter") InParty("faldorn")~
THEN ~IZEFIA~ X#IzeFaldo2
~How did it go?~
== ~FALDOJ~ ~It saddens me to report that the cruel man had perverted the nature of wyverns and they have attacked us who came to deliver them from thralldom.~
== ~IZEFIA~ ~The hatchlings are dead then? A pity. But what of the human?~
== ~FALDOJ~ ~He was returned to the Great Mother so she could remold him into a natural being.~
== ~IZEFIA~ ~That is good to hear. You have done well, Faldorn.~
DO ~SetGlobal("X#ReportIzefia","GLOBAL",2)  AddXPObject("faldorn",100) GiveItemCreate("POTN08","faldorn",1,0,0) GiveItemCreate("POTN20","faldorn",1,0,0)~
EXIT

//Faldorn Amarande
 
INTERJECT_COPY_TRANS~AMARAN~5 FALDOAMARAN1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Archdruid Amarande, I will lead them into the mines. ~
==~AMARAN~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~The intention is noble, but until I see the results of your expedition, I am wary of these folk. They reek of civilizations, and their weapons are of cured metal.~
= ~Return to me once you have destroyed the mines and I might reconsider my opinion of you.~
DO ~SetGlobal("X#ReportAmarande","GLOBAL",1)~
END
 
 
//Faldorn Amarande after Mines flooded

CHAIN
IF ~Global("X#ReportAmarande","GLOBAL",1) Global("Flooded","GLOBAL",1) InParty("faldorn")~
THEN ~AMARAN~ AmaranFald2
~Report, Faldorn!~
== ~FALDOJ~ ~The mines were flooded, Archdruid Amarande. ~
== ~AMARAN~ ~So this blight on the Toril's fair face is gone? A small but a courageous one and can serve as a good example that our efforts are not in vain.~
== ~FALDOJ~ ~If I may, Archdruid... ~
== ~AMARAN~ ~I listen to you.~
== ~FALDOJ~ ~Mines had fallen, but to make it complete I must go further and enter Baldur's Gate itself, find the layer of the Iron Throne and exact my vengeance! My companions here are prepared to do just that... ~  
== ~AMARAN~ ~You have my permission. Let the new allegiance be forged. As a sign of Shadow Druid's favor let me bestow this gift upon you.~
DO ~SetGlobal("X#ReportAmarande","GLOBAL",2) GiveItemCreate("X#FASH01","faldorn",1,0,0)~
EXIT

//end corrections

INTERJECT_COPY_TRANS~LASKAL~0 FALDORNLASKAL1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~I abhor having to leave peaceful forests and having to walk into the desecrated bowels of the Great Mother. But I will do what I must to purge the parasites from the Mines and I will see the Iron Throne punished for what they have done! ~
END
 
INTERJECT_COPY_TRANS~TAKIYAH~1 FALDORNTAKIYAH1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Glad you recognized me! I have not been away yet... and you already refer to me in the third person!~
==~TAKIYAH~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Child, what does your name mean in the Great Cycle of Nature? Nothing. Now hurry, and do not forget to oppose civilization at every turn!~
END
 
INTERJECT_COPY_TRANS~BHEREN~1 FALDORNBHEREN1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~To kill the cat? To kill the cat?! To kill that tormented poor hunter locked in the stone bag of the city?! Grr! Do not you even think of doing it, <CHARNAME>!~
END
 
INTERJECT_COPY_TRANS~TIBER~4 FALDORNTIBER1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Grr! Carry a message to your mother - keep the cubs away from the temptations of the man-made world, and they'd be safe.~
==~TIBER~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Those were the spiders that killed him... ~
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Your brother trusted a *thing* made by a smith's hand more than his kin's judgment. The arrogant fool deserved his death.~
==~TIBER~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~May...maybe, but what does it matter now?! ~
END


INTERJECT_COPY_TRANS~MELICA~1 FALDORNMELICAMP1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~<CHARNAME>! It's a wolf chasing a chicken... we should not intervene in the cycle of life... WAIT A MINUTE! It's TALKING! Abhorrent humans! Could not leave poor chick to his clucking! Tell me creature who - NO! Do not *tell* me anything! I would not encourage you to act in an unnatural way! ~
==~MELICA~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Buc-becaw-kill-the-wolf! Buc-becaw-stupid! ~
END
 
INTERJECT_COPY_TRANS~THALAN~32 FALDORNTHALANTYR1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Always remember that because of you a wolf had died. ~
==~MELICA~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~And good thing it is... ~
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~What?! How dare you?! This noble beast was worth ten of your kind! Perhaps I can even the score by sending you after the wolf! ~
==~MELICA~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Er... of course. I.. I apologize, druid.~
==~THALAN~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~You have a remarkable gift for angering people, Melicamp.~
END
 
INTERJECT_COPY_TRANS~ARKION~1 FALDORNARKION1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Your trade is an affront to Nature, necromancer! On the other hand, the stench from the sewers is so foul that the bodies must be rotting there. I care not that they poison the city's water supply, but they pollute the Sea of Swords itself.~  
=~ Grr! Let us do the dung-beetles work this once, <CHARNAME>! ~
END
 
INTERJECT_COPY_TRANS~OGRMA2~0 FALDORNOGRMAN1
==~FALDOJ~IF~InParty("Faldorn")~THEN~Here, <CHARNAME>, here is another awful consequence of civilization! A wild beast finishes his kill and eats it! But "cultured" beings satisfy their hunger by slaughtering enslaved cows and pigs - so their natural instinct to kill for food gets perverted into a desire to murder and cause pain! ~
END
 
INTERJECT_COPY_TRANS~ABELA~7 FALDORNABELA1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~We'd all be better off to avoid company of town-minded men for some time... not all of us as fortunate as you and may take their leave straight away.  ~
==~ABELA~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Despair not sister, you will soon return to the starlit woods. ~
END
 
INTERJECT_COPY_TRANS~FAHRIN~1 FALDORNFAHRINGTON1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Grr! Wisdom cannot be imparted from a scroll! It is a natural thing, not an oatmeal recipe! ~
END
 
INTERJECT_COPY_TRANS~FAHRIN~2 FALDORNFAHRINGTON2
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Grr! Wisdom cannot be imparted from a scroll! It is a natural thing, not an oatmeal recipe! ~
END
 
EXTEND_BOTTOM ~COKSMTH~ 0
IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN EXTERN ~FALDOJ~ FaldornPeter
END


INTERJECT_COPY_TRANS~CORDYR~1 FALDORNCORDYR1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~If you shared the beach with them as a normal beast would, but not tried to take more than your share of the sea bounty with your nets out and sell in this rotten city, you'd not have been chased away! ~
END
 
INTERJECT_COPY_TRANS~DESRET~0 FALDORNDESRETA1
==~FALDOJ~IF~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~THEN~Grr! Your eyes are death! Cold gaze, cold! Stay back you fools. ~
END

// Faldorn, Drizzt’s Encounter After Fighting The Gnolls
INTERJECT_COPY_TRANS ~DRIZZT~ 5 FaldornDrizzt
 == ~FALDOJ~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Grrr! The drow’s scimitars are pretty and sharp, but the Emerald Ray scimitar is what I want. That’s the proper weapon for a druid. Did I tell you that it was forged from Kador’s the Burner sickle? Kador was a famous Shadow Druid...if only I had it!~
== ~DRIZZT~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~For the good cause, druid, I would fight with my bare hands.~
 == ~FALDOJ~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Or with boulders... yes, boulders are good.~
 == ~DRIZZT~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~(smiles) If you are of the giantkin.~
END


INTERJECT_COPY_TRANS ~DRYAD~ 0 FaldornDryad1
 == ~FALDOJ~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Grr! Lead us, dryad, and I swear that the enemies of nature will be destroyed!~
 END

INTERJECT_COPY_TRANS ~DRYAD~ 4 FaldornDryad2
  == ~BFALDO~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~You... you brought dishonor upon me! I am not *welcome* in the wood! I HATE you <CHARNAME>! Grrr! I will show you the proper way!~
  == ~DRYAD~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~Please, help me, druid!~
  DO ~SetGlobal("FaDryadQuit","GLOBAL",1)~
  END
  
  INTERJECT_COPY_TRANS ~CALDO~ 6 FaldornCaldo
  == ~BFALDO~ IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~You... you are a trickster! I HATE you <CHARNAME>! Grrr!~
DO ~SetGlobal("JaiDryadHostile","GLOBAL",1)  ActionOverride("faldorn",LeaveParty()) ActionOverride("faldorn",Enemy())~
END

// Faldorn, Anakeg Farm - Lady Who Warns About Hunting Limit
INTERJECT_COPY_TRANS GERDE 0 FAFLWWAHL
  == FALDOJ  IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~GRRR! Luckily anakegs do not have the limit for killing hunters. Stupid townling! Anakegs do not destroy land, it’s the farmers who do with their cruel plows and gluttonous beasts!~
END

// Faldorn, Albert (The Boy With The Doggie)
INTERJECT_COPY_TRANS ALBERT 1 FATBWTD
  == FALDOJ  IF ~InParty("faldorn") !Dead("faldorn") !StateCheck("faldorn",STATE_SLEEPING)~ THEN ~*Sniffs* You stink unnatural-like, worst than townlings with their perfume. Stay in the woods, boy, take my advice.~
END


