REPLACE_STATE_TRIGGER ~KAGAIJ~ 3 ~Global("KickedOut","LOCALS",1)~

//kobolds

INTERJECT_COPY_TRANS ~DINK~ 0 X#KagainDink
 == ~KAGAIJ~ IF ~InParty("kagain") !Dead("kagain") !StateCheck("kagain",STATE_SLEEPING)~ THEN ~And who'd pay for delivery?~
END

APPEND ~KAGAIJ~

//Kagain, Nashkel mines after talking to Dink

IF WEIGHT #-2 ~Global("X#KagainKobold","GLOBAL",1)~ THEN BEGIN KagainKobold
SAY ~*sniff* Y'know, <CHARNAME>, bein' a topsider, you wouldn't know but there's a stink here that ain't natural to mines.~
++ ~Oh, you're a bloodhound now? What do you smell then?~ DO ~SetGlobal("X#KagainKobold","GLOBAL",2)~ + KaKob1.1
END

IF ~~ KaKob1.1
SAY ~Only thing I ever knew like it was at the Rivenbridge works when they was infested by kobolds.~
++ ~Kobolds? That'd be a relief. Better than fighting demons, anyway.~ + KaKob1.2
END

IF ~~ KaKob1.2
SAY ~Mebbe. All I know's that the little lizard-rats carry scant gold 'n' poor goods and they swarms like any other vermin. Best to be wary until we're for certain.~
IF ~~ THEN EXIT
END

//Entry to the Undercity

IF WEIGHT #-2 ~Global("KagainMaze","GLOBAL",1)~ KagainMaze
SAY ~I wonder now...nah.~
++ ~What is it? It might be important.~ DO ~SetGlobal("KagainMaze","GLOBAL",2)~ + KaMaze1
END

IF ~~ KaMaze1
SAY ~Well, them custom officers here got sticky fingers. I was just thinking that a bargeload of goods might dock here and stay shy of 'em. But there's thieves up the stairs and the river runs the wrong way for my trade, so it don't matter.~
++ ~I see. And what has that to do with our mission here?~ + KagainMaze2
END

// Kagain, Bridge To Baldur’s Gate
IF WEIGHT #-2 ~Global("KBTBG","GLOBAL",1)~ THEN KBTBG1
SAY ~For a big 'un, that Baldur must of had some sense. If he didn't hire dwarves for this here stonework, I'm a kobold's granny.~
IF ~~ THEN DO ~SetGlobal("KBTBG","GLOBAL",2)~ EXIT
END

//KagainBaldurEntry

IF WEIGHT #-2 ~Global("KagainBaldur","GLOBAL",1)~ THEN KagainBaldur1
SAY ~Wealth atop wealth and all torn from the bleeding lips of the starving poor!~
++ ~Huh? I never knew you cared about the poor.~ DO ~SetGlobal("KagainBaldur","GLOBAL",2)~ + KagainBaldur2
END

IF ~~  KagainBaldur2
SAY ~I've a great care not to become one of them. This place has its snares to drop you down amongst 'em, too, so let's watch where we step, eh?~
IF ~~ THEN EXIT
END

//KagainCandlekeepEntry

IF WEIGHT #-2 ~Global("KAGCandlekeep","GLOBAL",1)~ THEN KagainCK1
SAY ~Bah! All this folderol and the only practical fella here, I'd wager, is him that winches the gate up and down.~
IF ~~ THEN DO ~SetGlobal("KAGCandlekeep","GLOBAL",2)~ EXIT
END


IF ~~ KagainMaze2
SAY ~Nothin'. I was just ruminating 'bout later on, is all.~
IF ~~ THEN EXIT
END

//Oublek reaction

IF WEIGHT #-2 ~Global("KagainOublek","GLOBAL",1)~ THEN BEGIN KagainOublek1
SAY ~I'm no gem-master, <CHARNAME>, but I'd say we got took there. Them green stones was worth twice what we got, nevermind the killings.~
IF ~~ THEN DO ~SetGlobal("KagainOublek","GLOBAL",2)~ EXIT
END

END

