APPEND ~MONTAJ~

IF WEIGHT #-2 ~Global("MontaronWinery","GLOBAL",1)~ THEN BEGIN MoWinery
SAY ~SSNNNIFFFF! Ah, say as ye would, and I've said most on it, they's nothin' like to a true halflin' brew house.~
++ ~Smells like an outbuilding overdue for a move if you ask me.~ DO ~SetGlobal("MontaronWinery","GLOBAL",2)~ + MOINT6.1
+ ~Race(Player1,HALFLING)~ + ~Aye! My nose knows one when it smells it... SNNNIFFF!~ DO ~SetGlobal("MontaronWinery","GLOBAL",2)~ + MOINT6.1
++ ~Yes, it's... quite... aromatic.~  DO ~SetGlobal("MontaronWinery","GLOBAL",2)~ + MOINT6.1
END

IF WEIGHT #-2 ~Global("MontaronMarl","GLOBAL",5)~ THEN BEGIN MoMarl2
SAY ~Hey, <CHARNAME>, now look ye here...~
++ ~No, you look. We've got a job to do. We don't need acres of dead locals complicating it. Right?~ DO ~SetGlobal("MontaronMarl","GLOBAL",6)~ + MOINT5.1
++ ~Leave me be.~ DO ~SetGlobal("MontaronMarl","GLOBAL",6)~ EXIT
END

IF ~~ MOINT5.1
SAY ~Without sayin' yer wrong there, ye could've been more politer 'bout it.~
++ ~Would *your* temper have *heard* anything politer?~ + MOINT5.2
++ ~I should, but I did not. So shut up.~ EXIT
++ ~Now, look at this courtier!~ + MOINT5.2
END

IF ~~ MOINT5.2
SAY ~Heh. Ye gotta point there. I'll gives ye that un fer free, then.~
IF ~~ THEN EXIT
END

IF WEIGHT #-2 ~Global("MontaronMarl","GLOBAL",2)~ THEN BEGIN MoMarl1
SAY ~Even let ye dung-stinkin' grub-farmers in!~
++ ~Easy, Monty. We don't want any trouble here. ~ DO ~SetGlobal("MontaronMarl","GLOBAL",3)~ + MOINT4.1
++ ~Back off, Montaron! This isn't cutting time!~ DO ~SetGlobal("MontaronMarl","GLOBAL",3)~+ MOINT4.1
++ ~Shut up, runt.~ DO ~SetGlobal("MontaronMarl","GLOBAL",4) StartTimer(1,10)~ EXTERN ~_DUNKIN~ 0
END

IF ~~ MOINT4.1
SAY ~Bullocks!~
IF ~~ THEN DO ~ActionOverride("marl",Enemy()) ActionOverride("dunkin",Enemy())~ EXIT
END

IF WEIGHT #-2 ~Global("MOMeilum","GLOBAL",1)~ THEN BEGIN MoMeilum
SAY ~Sic transit gloria mundi.~
++ ~What's that supposed to mean?~ DO ~SetGlobal("MOMeilum","GLOBAL",2)~ + MOINT3.1
++ ~Whatevar...~ DO ~SetGlobal("MOMeilum","GLOBAL",2)~ EXIT
++ ~Indeed, the glory of this world passes away. ~DO ~SetGlobal("MOMeilum","GLOBAL",2)~ EXIT
END

IF ~~ MOINT3.1
SAY ~I'm not for certain, t'be honest. Heard some preacher say that when I was a kid, dippin' at a service for some big shot. I'd guess he meant that even the toughest bastard ain't proof agin a shiv in the kidneys.~
IF ~~ THEN EXIT
END

IF WEIGHT #-2 ~Global("MontaronKillsEnder","GLOBAL",2)~ THEN BEGIN MontyKillsSai
SAY ~Ya not goin' anywher', elf.~
++ ~What the hell did you do that for? He was on our side!~ DO ~SetGlobal("MontaronKillsEnder","GLOBAL",3)~ + MOINT2.1
++ ~Did you have a reason for that, Montaron, or was it just a sudden exuberance?.~ DO ~SetGlobal("MontaronKillsEnder","GLOBAL",3)~ + MOINT2.1
++ ~Good job... now come back here and clean the blade.~ DO ~SetGlobal("MontaronKillsEnder","GLOBAL",3)~ EXIT
END

IF ~~ MOINT2.1
SAY ~Ye divine’ed that by his honest face, did yer?~
++ ~Ah. My enemy’s enemy is my enemy also. I hadn’t thought you so much of a philosopher.~ + MOINT2.2
++ ~Being bound up in the tent of the bandit chief might indicate that he was an ally, you know.~ + MOINT2.3
++ ~If he were in any condition to return to Baldur’s Gate, he might have alerted the dukes so we could have had some help from them.~ + MOINT2.4
++ ~Directing us to the seat of bandit activity in the Cloakwood hardly seems a hostile act!~ + MOINT2.5
END

IF ~~ MOINT2.2
SAY ~Ain’t no full-o-nothin’. But this un was fool enough to get caught and that eager to talk, he’d of said anyfing to anybody. And I couldn’t think of nothin’ he could say to anybody’d make OUR lives any easier.~
++ ~Being bound up in the tent of the bandit chief might indicate that he was an ally, you know.~ + MOINT2.3
++ ~If he were in any condition to return to Baldur’s Gate, he might have alerted the dukes so we could have had some help from them.~ + MOINT2.4
++ ~Directing us to the seat of bandit activity in the Cloakwood hardly seems a hostile act!~ + MOINT2.5
END

IF ~~ MOINT2.3
SAY ~Don’t know nothin’ o’ the sort. What I do know is how these things’re done. If he were tooken as a spy, he wouldn’t be sittin’ cozy on a leash, he’d be roasted over a bed o’ coals ‘fore now. Depend on it, he were one o’ theirs, got caught with his dippers where they shouldn’t o’ been likely, so they tied him up nice ‘til the boss gets back to see to him.~
IF ~~ THEN EXIT
END

IF ~~ MOINT2.4
SAY ~He might. More like though, he’d might uv got to the Iron Throne at the Gate, help set up their warm welcome for us.~
IF ~~ THEN EXIT
END

IF ~~ MOINT2.5
SAY ~If that’s where they is. Course, while we’re wild goosin’ around them woods, hopin’ not to get et by big toothy critters, he’s snug back at the Gate, laughin’ at us as he plots the while.~
IF ~~ THEN EXIT
END


IF WEIGHT #-2 ~Global("MontyBaldurGate","GLOBAL",2)~ THEN BEGIN MontyBaldurComplain
SAY ~Eh, <CHARNAME>, I dislikes gruntin’ outa turn but ...uh...~
++ ~Grunt away. I’ll let you know if you’re out of place.~ DO ~SetGlobal("MontyBaldurGate","GLOBAL",3)~ + MOINT1.1
++ ~Speak up. You know I value input from my underlings.~ DO ~SetGlobal("MontyBaldurGate","GLOBAL",3)~ + MOINT1.1
++ ~No need to ask permission. Nobody else does.~ DO ~SetGlobal("MontyBaldurGate","GLOBAL",3)~ + MOINT1.1
++ ~Then don’t!~ DO ~SetGlobal("MontyBaldurGate","GLOBAL",3)~ + MOINT1.5
END

IF ~~ MOINT1.1
SAY ~Well, the Nashkell mines’re down for the count, most of the miners bein’ dead’s they are, the Cloakwood pit’s washed out fer good ‘n’ all whilst the guys who did that’re still runnin’ around loose...~
++ ~And your point is?~ + MOINT1.2
++ ~Yeah?~ + MOINT1.2
END

IF ~~ MOINT1.2
SAY ~What in Nine Hells are we footlin’ wi’ this cocky-locky errand for!?! Let’s get the bastards!~
++ ~Stow it! You’re here to kill and rob, not think.~ + MOINT1.4
++ ~We know where they are and their plans are greatly disrupted. This diversion will throw them off our track as well.~ + MOINT1.4
++ ~My dear fellow. You omit to consider that we are – as a matter of actual fact – here and can hardly be elsewhither at the same time.~ + MOINT1.4
++ ~Our enemies are powerful and well organized. Looting this place will give us the power to beat them.~ + MOINT1.4
END

IF ~~ MOINT1.4
SAY ~I hopes ye knows what ye’re up to. Ye’d better!~
IF ~~ THEN EXIT
END

IF ~~ MOINT1.5
SAY ~*As* I were sayin’…if’n ye *don’t* mind… ~
++ ~*sigh* Go ahead.~ + MOINT1.1
++ ~Then why ask?  Just say it, whatever it is.~ + MOINT1.1
++ ~Ah, but I *do* mind!  I said shut up and I meant it!~ + MOINT1.6
END

IF ~~ MOINT1.6
SAY ~I’ll surprise ye.  I’ll shut up.  And *pack* up and get *out* o’ this here fairy tale whilst they’s still time t’do so.~
++ ~*deep sigh*  But you’d really rather run your tongue than your feet though.  Say your piece then.~ + MOINT1.1
+ ~InParty("Xzar")~ + ~Fine!  Beat it while you still can.~ EXTERN ~XZARJ~ MOINT1_XZ  
+ ~!InParty("Xzar")~ + ~Fine!  Beat it while you still can.~ DO ~LeaveParty() EscapeArea()~ EXIT
++ ~No.  Knowing all you do you about me and my plans – no.  I don’t believe I can permit that.~ + MOINT1.7
END

IF ~~ MOINT1.7
SAY ~Ye’ll b’lieve me at yer funeral then!~
IF ~~ THEN DO ~LeaveParty() Enemy() ActionOverride("xzar",LeaveParty()) ActionOverride("xzar",Enemy())~
EXIT
END

END


INTERJECT_COPY_TRANS ~GORPEL~ 0 MontaronGorpel
== ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Uh-oh. The Happiness Boys. Grab hold o’ yer wallets ‘n’ loosen yer blades.~
== ~GORPEL~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Ha! Ha! A smart fellow with excellent survival instincts. No need to exercise them now, though. We’re still drinking our last score. Won’t start thinking about our next one ‘til we sober up.~
== ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Wouldn’t mind a half, then. T’ start with.~
END

INTERJECT_COPY_TRANS ~MINEC2~ 10 MontaronMineFlooded
== ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~So, 're ye talkin' or 're ye pullin' the plug?~
== ~MINEC2~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~It's not that easy... the key is... stuck...~
== ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Ye bother... Gimme that thing!~
== ~MINEC2~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Oh... You have a handy companion...~
DO ~SetGlobalTimer("MontyMineBaldur","GLOBAL",TEN_DAYS)~
END

INTERJECT_COPY_TRANS ~GREYWO~ 5 MontaronGreywolf
== ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Nay, but he be worth *your* life t’ me. Bounty on ‘im is at least.~
== ~GREYWO~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Die!~
END

INTERJECT_COPY_TRANS ~PERDUE~ 7 MontaronPerdue
 == ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN  ~Humiliatin’ excuse for a halflin’! Only way *this* hairfoot’s losin’ a blade is it’s too deep in somthin’s ribs to pull out in time.~
 == ~PERDUE~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN  ~Bugger off... just find me sword.~
END

INTERJECT_COPY_TRANS ~PERDUE~ 8 MontaronPerdue2
 == ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN  ~Humiliatin’ excuse for a halflin’! Only way *this* hairfoot’s losin’ a blade is it’s too deep in somthin’s ribs to pull out in time.~
== ~PERDUE~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN  ~Bugger off... just find me sword.~
END

INTERJECT_COPY_TRANS ~GANDOL~ 0 MontaronGandolar
== ~MONTAJ~ IF ~InParty("montaron") !Dead("montaron") !StateCheck("montaron",STATE_SLEEPING)~ THEN ~Our bussiness is our own to mind, and ye better be keepin' ye nose to yerself..~
DO ~SetGlobal("MontyGandolar","GLOBAL",1)~
END

INTERJECT ~MARL~ 0 MontaronMarl
 == ~MONTAJ~ IF ~InParty("Montaron")~ THEN ~Why for?!? Bar's free to all. ~
END
IF ~~ DO ~SetGlobal("MontaronMarl","GLOBAL",1)~
EXIT

INTERJECT ~ENDER~ 6 MontaronEnder1
 == ~MONTAJ~ IF ~InParty("Montaron")~ THEN ~*You were making notes in your journal, when you noticed a sudden motion out of the corner of your eye.*~
END
IF ~~ THEN DO ~SetGlobal("MontaronKillsEnder","GLOBAL",1)~
JOURNAL ~Things grow darker here, darker than I thought possible. In Tazok's tent, I came across a prisoner, Ender Sai. If he speaks true, and I suspect the documents he referred to in Tazok's chest will show he does, the bandits are being played as pawns by a power group called, tellingly enough, the Iron Throne. Tazok's orders are coming from some base of theirs within the Cloakwood and I have little doubt that it is there that I must journey next if I wish to peel back the next layer of this mystery. Something still seems very wrong in this. It haunts me, dancing endlessly along the periphery of my thoughts. What it is, however, I know not. ~
EXIT

INTERJECT ~ENDER~ 13 MontaronEnder2
 == ~MONTAJ~ IF ~InParty("Montaron")~ THEN ~*You were making notes in your journal, when you noticed a sudden motion out of the corner of your eye.*~
END
IF ~~ THEN DO ~SetGlobal("MontaronKillsEnder","GLOBAL",1)~
JOURNAL ~Things grow darker here, darker than I thought possible. In Tazok's tent, I came across a prisoner, Ender Sai. If he speaks true, and I suspect the documents he referred to in Tazok's chest will show he does, the bandits are being played as pawns by a power group called, tellingly enough, the Iron Throne. They meddle in the affairs of nations as if they were gods, pushing Amn and Baldur's Gate to the brink of war in order to line their pockets. They apparently maintain a base within the Cloakwood and I have little doubt that it is there that I must journey next if I wish to peel back the next layer of this mystery. Something still seems very wrong in this, however. It haunts me, dancing endlessly in the shadows, never coming into the light. What it is, however, I know not. ~
EXIT


CHAIN ~XZARJ~ MOINT1_XZ
~My dear chum!  As much as I respect your…um…practical sense, do you really think it prudent to abandon our dear colleague, <CHARNAME>, at this juncture? ~
== ~MONTAJ~ ~‘Tis and ye know it!  Or when matters be sorted back at headquarters, would ye *want* a little ‘correction’ cause ye fooled it here a month, stead o’ goin’ back t’ th’ Gate where *our* business is at?~
== ~XZARJ~ ~And I suppose you would see it sorted in that light… *sigh*  Ah well.  There is prudence and then Greater prudence… and little Prudence Fortnightly who lived over the hill and came so grievously unstuck.  All of them join me, sweet <CHARNAME>, in bidding you a most fond adieu.  May we meet again in happier times!~
DO ~LeaveParty() EscapeArea()  ActionOverride("montaron",LeaveParty()) ActionOverride("montaron",EscapeArea())~
EXIT

CHAIN3 ~MONTAJ~ MOINT6.1
~Didn't ask yer, did I? SNIFFF! Ah, wine here, beer yonder and mead up top o' them. Ahhhh, wunnerful!~
== ~ALVAHE~ ~Welcome, my son. It is always a pleasure to greet... ~
== ~BMONTA~ ~Ain't no son o' yers! Just admirin' yer tempral craft is all.~
== ~ALVAHE~ ~Yes. I believe that I may say, without vanity, that it is the finest of its sort in the region.~
== ~BMONTA~ ~Ye may say so fer me. Them casks be seventy year old, ain't they? ~
== ~ALVAHE~ ~Most are nearer one hundred, made by my grandfather and sound for a century yet to come.~
== ~BMONTA~ ~Know'd they was good uns. SNNNIFFF! Ah, I could settle in here, I swear it.~
== ~ALVAHE~ ~Then you'd have to leave off swearing. Clericking and brewing have passed together for generations here.~
== ~BMONTA~ ~Huh. No livin' in just the preachin', I 'spose.~
== ~ALVAHE~ ~We are a small, poor community. And, happily, the spiritual needs of the *residents* are light.~
== ~BMONTA~ ~Well, this sinnin' non-resident'll be back in two year an he's able. The red ye'll be tappin' then'll be worth the trip.~
== ~BMONTA~ IF ~Global("MontyGandolar","GLOBAL",1)~ THEN ~Well, <CHARNAME>, let's get them kobolds good. That Gandy Duckyfoot nigh were excuse enough to fergit this dump but lettin' they hoppin' lizards in this here winery - we can't do that!~
EXIT
