I_C_T2 ~VOLO~ 11  X#DynaheirVolo
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Master Volo? I am delighted to make this acquaintance. Thine 'Guide to the Sword Coast' served me well and true in mine travels.~
== VOLO IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Dear lady, I am delighted as well, for I have not expected to meet a fan in this small place. ~
END

I_C_T2 ~VOLO~ 12 X#DynaheirVolo
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Master Volo? I am delighted to make this acquaintance. Thine 'Guide to the Sword Coast' served me well and true in mine travels.~
== VOLO IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Dear lady, I am delighted as well, for I had no expectations of meeting a fan in this small place.~
END

I_C_T2 ~VOLO~ 13 X#DynaheirVolo
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Master Volo? I am delighted to make this acquaintance. Thine 'Guide to the Sword Coast' served me well and true in mine travels.~
== VOLO IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Dear lady, I am delighted as well, for I had no expectations of meeting a fan in this small place.~
END

I_C_T2 ~VOLO~ 14 X#DynaheirVolo
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Master Volo? I am delighted to make this acquaintance. Thine 'Guide to the Sword Coast' served me well and true in mine travels.~
== VOLO IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Dear lady, I am delighted as well, for I had no expectations of meeting a fan in this small place.~
END

I_C_T2 BERRUN 15 X#DynaheirBerrun1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Mark this young <PRO_MANWOMAN> well, mayor. I sense that 'tis not the last good deed of <PRO_HISHER> thou art hearing of.~
END

I_C_T2 BERRUN 16 X#DynaheirBerrun3
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Mark this young <PRO_MANWOMAN> well, mayor. I sense that 'tis not the last good deed of <PRO_HISHER> thou art hearing of.~
END

I_C_T2 BERRUN 17 X#DynaheirBerrun1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Mark this young <PRO_MANWOMAN> well, mayor. I sense that 'tis not the last good deed of <PRO_HISHER> thou art hearing of.~
END

I_C_T2 CYTHAN 6 X#DynaheirCythandria
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~So it appears. <CHARNAME>, I like not at all what I see. Dost not let Bhaal overwhelm thee as he has done with thy brother.~
END

I_C_T LIIA 8 X#DynaheirLiia1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~<CHARNAME>, the man Sarevok is a Spawn of Bhaal and he hath turned to madness. He must be stopped at all costs!~
END

I_C_T FARMBR 0 X#DynaheirBrun1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Indeed, we can spare a few hours to help thee, good farmer. Is not it so, <CHARNAME>?~
END

I_C_T FARMBR 1 X#DynaheirBrun2
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Indeed, we can spare a few hours to help thee, good farmer. Is not it so, <CHARNAME>?~
END

I_C_T FARMBR 2 X#DynaheirBrun3
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Indeed, we can spare a few hours to help thee, good farmer. Is not it so, <CHARNAME>?~
END

I_C_T2 FARMBR 4 X#DynaheirBrun4
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Dost thou have a stone, not a <PRO_RACE>'s heart in thine chest, <CHARNAME>?~
END

I_C_T2 FARMBR 6 X#DynaheirBrun5
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Thou had'st done well in accepting this task, <CHARNAME>.~
END

I_C_T2 FARMBR 10 X#DynaheirBrun6
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~O, <CHARNAME>, thou art a noble <PRO_MANWOMAN>!~
END

I_C_T GALLOR 1 X#DynaheirGallor1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Thou only mention theft in thy dishonest task, but in truth thou would'st make us murderers of Charleston and his men. <CHARNAME> surely would'st disagree to committing such atrocity.~
END

I_C_T2 GALLOR 6 X#DynaheirGallor2
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I would'st not be a part of this... enterprise!~
DO ~ActionOverride("dynaheir",LeaveParty()) ActionOverride("dynaheir",Enemy())  ActionOverride("minsc",LeaveParty()) ActionOverride("minsc",Enemy())~
END

I_C_T2 GALLOR 7 X#DynaheirGallor3
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I would'st not be a part of this... enterprise!~
DO ~ActionOverride("dynaheir",LeaveParty()) ActionOverride("dynaheir",Enemy())  ActionOverride("minsc",LeaveParty()) ActionOverride("minsc",Enemy())~
END

I_C_T Angelo 0 X#DynaheirAngelo
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~If I wert in the position, that thou claim as  thine, I would'st not be quick to accuse innocents.~
END

I_C_T VARCI 1 X#DynaheirVarci
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Mine advice is... <CHARNAME>, lend thine ear to this child's plea. 'Tis impossible to look at him without pity.~
END

I_C_T2 DELTAN2 0 X#DynaheirEltan1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Sarevok's actions art clumsy compared to the Red Wizard's politicking, but no less vile.~
END

I_C_T2 DELTAN2 1 X#DynaheirEltan2
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~We shalt do our uttermost to prevent such an evil thing, Duke Eltan.~
END

I_C_T2 ARDROU 2 X#DynaheirArdrouine1
== DYNAHJ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Thou didst good in helping this poor woman. Now we should'st return to our travails.~
END

I_C_T ~OCELLI~ 0 DynaOcelli
== ~DYNAHJ~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Already? I fear we would'st be late to avert the catastrophy.~
END

I_C_T ~HANNAH~ 0 DynahHannah
== ~DYNAHJ~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~A foul deed must this Ragefast have committed to cause such a strong reaction in someone of a noble descent. 'Tis my experience that they rarely care of the fate of the others. We would'st do good to make inquiries.~
END

INTERJECT_COPY_TRANS ~NEB~ 8 DynaheirNeb
== ~DYNAHJ~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~'Tis vile... so utterly vile! Fire and lightening! I urge thee to... to kill this gnome!~
END

INTERJECT_COPY_TRANS ~RAGEFA~ 6 DyRagefast
== ~DYNAHJ~ IF ~InParty("Dynaheir")~ THEN ~'Tis unexpected turn....~
 END

INTERJECT_COPY_TRANS ~NOBW8~ 8 DyAreana
== ~DYNAHJ~ IF ~InParty("Dynaheir")~ THEN ~I would'st caution thee against hiring thyself as a paid assassin to this woman. Matters like this one should'st not be settled by murder.~
 END

INTERJECT_COPY_TRANS ~MINEC2~ 8 DyMinersCW
== ~DYNAHJ~ IF ~InParty("Dynaheir") Global("FREESLAV","GLOBAL",0)~ THEN ~If thou art considering leaving these poor men to their death, thou'd better join them. Death by drowning would be nothing compared to mine treatment!~
 END

INTERJECT_COPY_TRANS ~TENYA~ 0 DyTENYA
== ~DYNAHJ~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~'Tis a very spirited child, but a child nontheless. I trust that thou hath concluded rightly who is in the wrong here.~
END

// Felonius Gist AR0719
INTERJECT_COPY_TRANS ~FELONI~ 0 DynaheirFGist
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I feel presence of foul enchantment here. I oppose vehemently forcing our way into the houses of goodly folk uninvited, but this one we perhaps should investigate.~
END

// Delorna
INTERJECT_COPY_TRANS ~DELORN~ 0 DynaheirDelorna
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I must apologize for our uncouth intrusion. <CHARNAME>, our purpose here is of no high moral regard. We would’st do better to leave these learned maidens to their studies, and forget of the Alatos’ foul request.~
END

//Beland
INTERJECT_COPY_TRANS ~BELAND~ 0 DynaheirBeland1
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I heard that many an artifact here was made but by the skillful hands and sharp minds, without the use of magic. Will it ever come to pass that the arcane and technical should’st come to a competition for fulfilling a sentient being’s need to do things new and wondrous?~
END

INTERJECT_COPY_TRANS ~BELAND~ 1 DynaheirBeland2
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I heard that many an artifact here was made but by the skillful hands and sharp minds, without the use of magic. Will it ever come to pass that the arcane and technical should’st come to a competition for fulfilling a sentient being’s need to do things new and wondrous?~
END

INTERJECT_COPY_TRANS ~BELAND~ 2 DynaheirBeland3
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I heard that many an artifact here was made but by the skillful hands and sharp minds, without the use of magic. Will it ever come to pass that the arcane and technical should’st come to a competition for fulfilling a sentient being’s need to do things new and wondrous?~
END

//Narcillius
INTERJECT_COPY_TRANS ~NARCIL~ 2 DynaheirNarcillius
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Whene'er I witness the follies of mages who practice in countries that place no demands on their skills, I wonder if idleness inevitably leads great minds to madness?~
END

//Entill

INTERJECT_COPY_TRANS ~ENTILL~ 10 DynaheirEntill1
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Thou would'st do well to take the advice. It not only cometh from a sage, but I also concede that haste is needed for the peaceful resolution of this grave matter.~
== ~ENTILL~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I could not have said better myself, lady.~
END

INTERJECT_COPY_TRANS ~ENTILL~ 11 DynaheirEntill2
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Thou would'st do well to take the advice. It not only cometh from a sage, but I also concede that haste is needed for the peaceful resolution of this grave matter.~
== ~ENTILL~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~I could not have said better myself, lady.~
END

//Arkushule
INTERJECT_COPY_TRANS ~ARKUSH~ 0 DynaheirArkushule
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Divination is a magic that is rarely practiced in Rashemen. Alas, by need, we place more import on battle spells. If thou would'st allow this lady to delve thy past and future, I would'st very much like to see how 'tis done.~
END

//Thalantyr
INTERJECT_COPY_TRANS ~THALAN~ 9 DynaheirThalantyr
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Thou art a mage of considerable learning. Thou should'st remember still the curiosity and ambition of youth, for without you would'st not have achieved thy present stature. 'Tis thy responsibility to ensure that thine apprentice hath no access to the magiks beyond his comprehension. Surely, a warding glyph is not beyond thy power and a padlock is not beyond thy means!~
= ~Thy master's absentmindedness however, doth not excuse thy disobedience, Melicamp. ~
== ~THALAN~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Go cut cheese with your tongue. Bothering me with advice of all things!~
END

//Iron11
INTERJECT_COPY_TRANS2 ~IRON11~ 0 DynaheirBhaal
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~A Dread Lord? 'Tis not a name I recognize, but with the passing of the lords of strife and murder, the Prince of Lies might well have claimed such a title.~
END

//CommonerBG
INTERJECT_COPY_TRANS ~FTOWBA~ 2 DynaheirHandsome
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Handsome? 'Tis quite shallow, though I suppose that a man of his breeding would possess a certain... dark attractiveness.~
END

//denak
INTERJECT_COPY_TRANS ~DENAK~ 1 DynaheirDenak
== ~DYNAHJ~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~Beware, <CHARNAME>. If those art indeed the Red Wizards of Thay, the truth of which I have no reasons to doubt, they art as skilled in arts arcane as they art devious.~
== ~DENAK~  IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~This accent... is all too familiar. You must be the Rashemi witch spotted in these parts by our friends. I can see that Edwin did not carry out his mission as ordered. Lasala, I suggest that we not tell him that we have done his job. The farther away he is, the less obstructions he creates to us.~
END

//brevlik
INTERJECT_COPY_TRANS ~BREVLI~ 14 DynaheirBrevlik
== ~DYNAHJ~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~This gnome's hunger for things magical is commendable, but the ways in which he wishes to sate it is not. <CHARNAME>, thou dost not truly command us to this... robbery?~
END

//Yago
INTERJECT_COPY_TRANS ~YAGO~ 1 DynaheirYago
== ~DYNAHJ~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~A mage who uses his knowledge to curse a child is to be condemned! Is there no shred of goodness in thine heart that thou would'st do such a thing? Thy wife and her lover wronged thee... but thou didst the most vile deed out of the three of ye involved!~
== ~YAGO~ IF ~InParty("dynaheir") !Dead("dynaheir") !StateCheck("dynaheir",STATE_SLEEPING)~ THEN ~A mage who does not use his knowledge as he pleases is a fool. And I think I know just how I want to apply mine right now!~
END


APPEND ~DYNAHJ~

IF WEIGHT #-2 ~Global("X#DYINT1","GLOBAL",1)~ THEN BEGIN DYINT1
SAY ~Tread with care, <CHARNAME> and dost not kill small crawling things. The local legend hath it that not all folk of Firewine had perished in the magical surge that hath destroyed their town. Some, they say wert transformed into such creatures as slugs or lizards… ~
++ ~What magical surge?~ DO ~SetGlobal("X#DYINT1","GLOBAL",2)~ + DYINT1.1
++ ~Well, much as I would not want to kill a prominent elf turned turtle… I am not a pixie to move without touching the ground.~ DO ~SetGlobal("X#DYINT1","GLOBAL",2)~ + DYINT1.2
++ ~Is there hard evidence to support this claim?~ DO ~SetGlobal("X#DYINT1","GLOBAL",2)~ + DYINT1.3
END
IF ~~ DYINT1.1
SAY ~I am surprised that thou dost not know the history of thine own land. Firewine was destroyed in a duel between two powerful mages. Their spells wert so potent, and so wild, that they leveled the unfortunate town and turned the river's course away. Now naught, but rubble remains as a reminder to those of mine profession not to exercise their talents for a childish strife. For a foul play can turn into a tragedy.~
IF ~~ THEN EXIT
END

IF ~~ DYINT1.2
SAY ~I am aware that thou art not a fey, but dost exercise caution…~
= ~'Tis in thine own interest.~
IF ~~ THEN GOTO DYINT1.3
END

IF ~~ DYINT1.3
SAY ~The locals say that a lass from Gullykin once freed a wizard by accident and ended up marrying him.~
= ~It could have been worse, I suppose.~
IF ~~ THEN EXIT
END

// Dynaheir, Shandalar's Girls Dead
IF WEIGHT #-2 ~Global("DSGD","GLOBAL",1)~ DSGD1
SAY ~I abhor helping thee in such carnage! Thou wilt not use my debt to thee again, to compel me to serve as a thief’s assassin.~
IF ~~ THEN DO ~SetGlobal("DSGD","GLOBAL",2)~ EXIT
END

// Dynaheir, Back At Candlekeep
IF WEIGHT #-2 ~Global("DBAC","GLOBAL",2)~ DBAC1
SAY ~Here stands the Keep which asks a traveler to pay for entry with knowledge, not golden coin... Indeed, I can only envy thee, <CHARNAME>, for thou hast grown in such a place of enlightenment. I wish greatly that I had time to study the collections.~
IF ~~ THEN DO ~SetGlobal("DBAC","GLOBAL",3)~ EXIT
END


// Dynaheir, Gazib Fled, Oopah Left
IF WEIGHT #-2 ~Global("DGFOL","GLOBAL",1)~ DGFOL1
SAY ~What hath happened here is a lesson for every charlatan who doth not show proper respect to the Arts magical.~
IF ~~ THEN DO ~SetGlobal("DGFOL","GLOBAL",2)~ EXIT
END
END

EXTEND_BOTTOM ~DENAK~ 3
IF ~InParty("DYNAHEIR")~ EXTERN ~DENAK~ DenakConflict
END

CHAIN
IF ~~ THEN ~DENAK~ DenakConflict
~But what do I see? You are not quite as useless as I have reported to Nevron time and again. You are worse! What part of "kill"  did you  not understand when you were ordered to assassinate the Rashemi witch? Has the stay in these barbaric lands softened your wits?~
== ~BEDWIN~ ~Au contraire, my most illustrious Denak. (Flattery never hurts... ) The cleverest, the most powerful, and infinitely wise Denak... I have devised a scheme worthy of thy most exquisite intellect. Indulge my most unworthy self a moment and I will explain... ~
== ~DENAK~ ~*Sighs* Let me guess - instead of killing the witch, you have captured her for questioning?~
== ~BEDWIN~ ~I knew that a man of your vast abilities would take but a moment to see to the core of my cunning ruse.~
== ~BDYNAH~ ~I would'st stand in as this overambitious youngling's prisoner for a few minutes, if that would'st spare us a battle. But I would'st *not* hand myself over to his ilk!~
== ~DENAK~ ~And did you think how wasteful it is to transport a prisoner back to Thay?~
== ~BEDWIN~ ~Er... I have foreseen that, of course. I have questioned the witch... most severely, and learned all that it is to know from her. I only brought the wretch here to er... ask if... if Nevron's orders did not change in regards to her and so that my most distinguished commanders could partake in the executions of the witch and her collaborators (now, that is the answer of a true genius!).~
END
++ ~Wait a minute! Edwin... I am not -~ EXTERN ~BEDWIN~ DYEDCON1
+ ~XPGT(Player1, 60000)~ + ~Right. I knew it was too good to last. I guess we will have to kill these wizards. The question is, if you are with us or against us, Edwin.~ EXTERN ~BEDWIN~ DYEDCON2.1
+ ~!XPGT(Player1, 60000)~ + ~Right. I knew it was too good to last. I guess we will have to kill these wizards. The question is, if you are with us or against us, Edwin.~ EXTERN ~BEDWIN~ DYEDCON2.2
++ ~He is lying through his teeth! I admit I refused to kill her as Edwin suggested. That I rescued her and she travels now as my companion is also true. However, I know nothing of the feud between you.~ EXTERN ~DENAK~ DYEDCON3
++ ~Tsk, tsk, Edwin... such a joker you are!  You know I came here to make sure the witch is killed in a way that will bring the most glory to Thay. Is not that right?~ EXTERN ~DENAK~ DYEDCON4

APPEND ~BEDWIN~

IF ~~ DYEDCON1
SAY ~...ready to die? Simian, who asked you?~
IF ~~ THEN DO ~SetGlobal("EdwinBetrayRW","GLOBAL",2) ActionOverride("brendan",Enemy()) ActionOverride("lasala",Enemy()) ActionOverride("diana",Enemy()) ActionOverride("denak",Enemy()) ActionOverride("edwin",LeaveParty()) ActionOverride("edwin",Enemy())~
EXIT
END

IF ~~ DYEDCON2.1
SAY ~A Red Wizard of Thay serves the glory of Thay... or his own elevation. To one who was born to unify all of Thay under his rule, it is obviously one and the same goal. No matter how pathetically inadequate you are to do my bidding, <CHARNAME>, I find my so called superiors to be inferior even to a chattering simian from a barbaric land. You will obviously need my help to destroy them... (and then I will be free to plan without constantly being scrutinized and belittled by these petty bureaucrats.)~
IF ~~ THEN DO ~AddexperienceParty(5000) SetGlobal("EdwinBetrayRW","GLOBAL",1) ActionOverride("brendan",Enemy()) ActionOverride("lasala",Enemy()) ActionOverride("diana",Enemy()) ActionOverride("denak",Enemy())~
EXIT
END

IF ~~ DYEDCON2.2
SAY ~Why, simian, is there even a question in your mind?~
IF ~~ THEN DO ~SetGlobal("EdwinBetrayRW","GLOBAL",2) ActionOverride("brendan",Enemy()) ActionOverride("lasala",Enemy()) ActionOverride("diana",Enemy()) ActionOverride("denak",Enemy()) ActionOverride("edwin",LeaveParty()) ActionOverride("edwin",Enemy())~
EXIT
END

IF ~Global("EdwinBetrayRW","GLOBAL",3)~ EDPaper
SAY ~Why, I should not even have to strain myself excessively with the paperwork... Nevron is a fool, and will swallow any likely tale... ~
IF ~~ THEN DO ~SetGlobal("EdwinBetrayRW","GLOBAL",4) AddXPObject("edwin",2000)~
EXIT
END

END

APPEND ~DENAK~

IF ~~ DYEDCON3
SAY ~I find that difficult to believe. Edwin, do prove yourself useful and help me take care of this... motley crew. ~
IF ~~ THEN DO ~SetGlobal("EdwinBetrayRW","GLOBAL",2) ActionOverride("brendan",Enemy()) ActionOverride("lasala",Enemy()) ActionOverride("diana",Enemy()) ActionOverride("denak",Enemy()) ActionOverride("edwin",LeaveParty()) ActionOverride("edwin",Enemy())~
EXIT
END

IF ~Global("EdwinBetrayRW","GLOBAL",6)~ DYEDCON5
SAY ~Quite amusing, Edwin. Once a new assignment for you has been received, I will contact you. O... and here is your reimbursement as per your last expense report, though I am still unclear as to how buying a drow pleasure slave helped you in the capture of the witch?~
IF ~~ THEN DO ~ActionOverride("brendan",EscapeArea()) ActionOverride("lasala",EscapeArea()) ActionOverride("diana",EscapeArea()) EscapeArea() SetGlobal("EdwinBetrayRW","GLOBAL",7) GiveGoldForce(1000) AddXPObject("edwin",1000)~
EXIT
END
END

CHAIN
IF ~~ THEN ~DENAK~ DYEDCON4
~Edwin, your rugged companion here awaits your answer. Do you concede to having the most pathetic sense of humor this side of the Spine of the World or will you expose <PRO_HISHER> primitive attempt at a ruse?~
== ~BEDWIN~ ~My breathtakingly clever superior can surely see that one has to elevate the spirits of his barbaric underlings? The joke was for the simians that accompany me, not your noble ears. Now, to prove our fealty, we will slay the witch in a most exemplary fashion... ~
== ~BDYNAH~ ~This is how thou repay me for my loyalty, <CHARNAME>?~
DO ~ReputationInc(-2) SetGlobal("EdwinBetrayRW","GLOBAL",5) ActionOverride("dynaheir",LeaveParty()) ActionOverride("minsc",LeaveParty()) ActionOverride("dynaheir",Enemy()) ActionOverride("minsc",Enemy())~
EXIT

ADD_STATE_TRIGGER ~DENAK~ 0 ~!InParty("edwin")~
ADD_STATE_TRIGGER ~DENAK~ 1 ~!InParty("edwin")~
ADD_STATE_TRIGGER ~DENAK~ 2 ~!InParty("edwin")~
ADD_STATE_TRIGGER ~DENAK~ 3 ~GlobalLT("EdwinBetrayRW","GLOBAL",5)~



