BEGIN P#EMMA

IF ~Global("P#EMMAFight","GLOBAL",0)InParty("KIVAN")~ THEN BEGIN EmmaQ
SAY ~Hail, travelers. That cloaked elf matches the description I was given. Are you Kivan of Shilmista?~
IF ~~ THEN EXTERN ~KIVANJ~ EMKIBigChain
END

IF ~Global("P#EMMAFight","GLOBAL",6)InParty("KIVAN")~ THEN BEGIN EmmaQ
SAY ~Hail, travelers. That cloaked elf matches the description I was given. Are you Kivan of Shilmista?~
IF ~~ THEN EXTERN ~KIVANJ~ EMKIBigChain
END

IF ~Global("P#EMMAFight","GLOBAL",0)!InParty("KIVAN")~ THEN BEGIN EmmaW
SAY ~Snowball, here! Swiftclaw, EXCUSE you!
Dread, leave the <RACE> alone!
Babe, stay, you're a good girl... Fang, stop drooling all over this good <LADYLORD>. 
<PRO_HESHE> is not our prey.~
IF ~~ THEN DO ~SetGlobal("P#EMMAFight","GLOBAL",6)~
EXIT
END

IF ~Global("P#EMMAFight","GLOBAL",2) Dead("KIVAN")~ THEN BEGIN EmmaKivDead
SAY ~So, apparently you can kill. Very good.~
IF ~~ THEN REPLY ~Are you joining me, Imanel?~ GOTO JoinNow
IF ~~ THEN REPLY ~Do I get a reward?~ GOTO EmmaReward
IF ~RACE(Player1, ELF)~ THEN REPLY ~Yep, that was fun.~ GOTO FarewellElf
IF ~!RACE(Player1, ELF)~ THEN REPLY ~Yep, that was fun.~ GOTO FarewellNotElf
END

IF ~~ THEN BEGIN JoinNow
SAY ~*Chuckles* You have done what I have planned you to do. You are of no further use. Be grateful, that I allow you to leave with your hides untouched.~
IF ~~ THEN REPLY ~Do I get a reward?~ GOTO EmmaReward
IF ~~ THEN REPLY ~Fair enough.~ GOTO FarewellNotElf
END

IF ~~ THEN BEGIN FarewellElf
SAY ~Farewell then. When you grow up, mellonamin, you just *might* become an acceptable companion for me. Good hunting.~
IF ~~ THEN DO ~ReputationInc(-4) ActionOverride("P#Emma", EscapeArea())
ActionOverride("P#WOLF01", EscapeArea())
ActionOverride("P#WOLF02", EscapeArea())
ActionOverride("P#WOLF03", EscapeArea())
ActionOverride("P#WOLF04", EscapeArea())
ActionOverride("P#WOLF05", EscapeArea())~ EXIT
END

IF ~~ THEN BEGIN FarewellNotElf
SAY ~Farewell then. Good hunting.~
IF ~~ THEN DO ~ReputationInc(-4) ActionOverride("P#Emma", EscapeArea())
ActionOverride("P#WOLF01", EscapeArea())
ActionOverride("P#WOLF02", EscapeArea())
ActionOverride("P#WOLF03", EscapeArea())
ActionOverride("P#WOLF04", EscapeArea())
ActionOverride("P#WOLF05", EscapeArea())~ EXIT
END

IF ~~ THEN BEGIN EmmaReward
SAY ~*Laughs * Speaking of rewards there was a bounty on your head as well. I think that this money is mine! You are weakened and would not put up much of a fight. By all gods, I like stupid prey!~
IF ~~ THEN DO ~ReputationInc(-4)
SetGlobal("P#EMMAFight","GLOBAL",4)
ActionOverride("P#Emma", Enemy())  ActionOverride("P#WOLF01",MoveToObject("P#Emma")) ActionOverride("P#WOLF02",MoveToObject("P#Emma"))
ActionOverride("P#WOLF03",MoveToObject("P#Emma")) ActionOverride("P#WOLF04",MoveToObject("P#Emma")) ActionOverride("P#WOLF05",MoveToObject("P#Emma"))
ActionOverride("P#WOLF01",Enemy())
ActionOverride("P#WOLF02",Enemy())
ActionOverride("P#WOLF03",Enemy())
ActionOverride("P#WOLF04",Enemy())
ActionOverride("P#WOLF05",Enemy())~ EXIT
END

IF ~~ THEN BEGIN EMKI.PC
SAY ~You, <PRO_RACE>, you seem to be in charge of this...band. What say you?~
IF ~~ THEN REPLY ~Silversword, you have taken enough of our time with your chatter. Kivan is my friend. I will fight at his side, no matter what. His enemy is my enemy.~ GOTO WithKivan
IF ~~ THEN REPLY ~*You* can join * me *, if you wish.~ GOTO OfferJoin
IF ~~ THEN REPLY ~Oh, you require some company other than those beasts at your feet?~ GOTO AskWolves
IF ~~ THEN REPLY ~What's with all these wolves?~ GOTO AskWolves
END

IF ~~ THEN BEGIN WithKivan
SAY ~*Chuckles * Rubbish sticks together. More spoils then. I repeat my question: does anyone cherish free lifestyle in your midst? Or any lifestyle for that matter?~
IF ~~ THEN EXTERN ~KIVANJ~ KIVReact1
END

IF ~~ THEN BEGIN OfferJoin
SAY ~You are an ambitious one, aren't you? Prove me that you are worth my calling you a commander. Kill the ranger, let me see you in action.~
IF ~~ THEN REPLY ~How about we just let the ranger off the hook and you'd take his place in line? I like you much more...but I do not want others to say that I draw sword against my companions.~ GOTO LetKivanGo
IF ~~ THEN REPLY ~That goes without saying. To tell you the truth I am surprised that this whiner lived that long around me.~ GOTO WillKill
END

IF ~~ THEN BEGIN LetKivanGo
SAY ~That is not the attitude I like in my thralls...and companions, of course.  I guess today is the day you die.~
IF ~~ THEN EXTERN ~KIVANJ~ KIVReact2
END

IF ~~ THEN BEGIN WillKill
SAY ~Perfect. Let me settle myself comfortably while you commence with the slaying.~
IF ~~ THEN EXTERN ~KIVANJ~ KIVReact3
END

IF ~~ THEN BEGIN AskWolves
SAY ~My wolves are my company. However, I'm involved in all sorts of assignments, and as often as not I require someone walking on two feet and speaking Common. Of course I will not accept someone totally unknown to me into my service, so I will require you to pass a small test. Here, kill the ranger, let me see you in action.~
IF ~~ THEN REPLY ~Silversword, you have taken enough of our time with your chatter. Kivan is my friend. I will fight at his side, no matter what. His enemy is my enemy.~ GOTO WithKivan
IF ~~ THEN REPLY ~Lady, slow down. *I* am not to serve *you*. *You* can join *me*, if you wish though.~ GOTO OfferJoin
IF ~~ THEN REPLY ~How about we just let the ranger off the hook and you'd take his place in line? I like you much more...but I do not want others to say that I draw sword against my companions.~ GOTO LetKivanGo
IF ~~ THEN REPLY ~That goes without saying. To tell you the truth I am surprised that this whiner lived that long around me.~ GOTO WillKill
END

IF ~~ THEN BEGIN EM2
SAY ~Snowball, attack! Swiftclaw, FORWARD!
Dread, gut them! Babe, be a good girl and KILL! Fang, stop drooling all over this good <LADYLORD> and rip <PRO_HISHER> throat <PRO_HIMHER> already!~
IF ~~ THEN DO ~SetGlobal("P#EMMAFight","GLOBAL",1)
ActionOverride("P#Emma", Enemy())  ActionOverride("P#WOLF01",MoveToObject("P#Emma")) ActionOverride("P#WOLF02",MoveToObject("P#Emma"))
ActionOverride("P#WOLF03",MoveToObject("P#Emma")) ActionOverride("P#WOLF04",MoveToObject("P#Emma")) ActionOverride("P#WOLF05",MoveToObject("P#Emma"))
ActionOverride("P#WOLF01",Enemy())
ActionOverride("P#WOLF02",Enemy())
ActionOverride("P#WOLF03",Enemy())
ActionOverride("P#WOLF04",Enemy())
ActionOverride("P#WOLF05",Enemy())~
EXIT
END

APPEND ~KIVANJ~

IF ~~ THEN BEGIN KIVReact1
SAY ~<CHARNAME>, goth en gothamin ar' mellon en mellonamin -foe of my foe and friend of my friend - by the first sapling that rose where Shilmista now stands and by the last shadow it will cast before all things will end, I swear to give my blood for you.~
IF ~~ THEN EXTERN P#EMMA EM2
END


IF ~~ THEN BEGIN KIVReact2
SAY ~It appears that we are allies in this battle, <CHARNAME> even if reluctant ones.~
IF ~~ THEN DO ~SetGlobal("P#EMMAFight","GLOBAL",1)
ActionOverride("P#Emma", Enemy())  ActionOverride("P#WOLF01",MoveToObject("P#Emma")) ActionOverride("P#WOLF02",MoveToObject("P#Emma"))
ActionOverride("P#WOLF03",MoveToObject("P#Emma")) ActionOverride("P#WOLF04",MoveToObject("P#Emma")) ActionOverride("P#WOLF05",MoveToObject("P#Emma"))
ActionOverride("P#WOLF01",Enemy())
ActionOverride("P#WOLF02",Enemy())
ActionOverride("P#WOLF03",Enemy())
ActionOverride("P#WOLF04",Enemy())
ActionOverride("P#WOLF05",Enemy())~
EXIT
END

IF ~~ THEN BEGIN KIVReact3
SAY ~Nothing hurts more than betrayal. You had my friendship, now you wish to have my head? Come; try to take it off my shoulders then.~
IF ~~ THEN DO ~LeaveParty()
ActionOverride("KIVAN",Enemy())
SetGlobal("P#EMMAFight","GLOBAL",2)~
EXIT
END

END

CHAIN3 ~KIVANJ~ EMKIBigChain
~I am.~
== P#EMMA ~Short and to the point.~
= ~My name is Imanel Silversword.~
= ~I am in a mood for a pleasant conversation, but Tazok mentioned that it was your wife who did all the talking, not you. *Sigh*~
= ~Tazok is a friend of mine, if you failed to understand the subtlety of my hint.~
== ~KIVANJ~ ~You have my bow.~
== P#EMMA ~Oh, yes, Tazok would not know what to do with your bow, it being elven made and enchanted for only elves to use. So I have it now. It is a sweet weapon, Kivan.~
= ~I like it.~
== ~KIVANJ~ ~Deheriana gave me this bow for our wedding. If there is a drop of honor left in you, you will return it to me, oath-breaker.~
== P#EMMA ~Oath-breaker? I can see that you have some sense of humor. I like it in men.~
= ~At least I hope that's what it is. Or are you indeed one of those pathetic creatures who take the ranger's vows seriously?~
== ~KIVANJ~ ~I pity those who foreswore, not those who kept to their word.~
== P#EMMA ~No sense of humor then?~
= ~How disappointing! Well, let us talk business then, shall we? I have a generous heart and I am in need of men. The blasted fools I traveled with got themselves killed when you sacked our camp. * Shrugs * What do you expect of Na'N'Tel'Quess-barely persons? You are an Elf at least.~
= ~I am inclined to give you a chance - I will take you under my protective wing and teach you what life is all about, Kivan. ~
== ~KIVANJ~ ~I will not ally myself with your cause.~
== P#EMMA ~Oh, do not you understand that your second option is a gravestone with your name on it? That slow, eh?~
= ~I was paid for the task of returning your head to Tazok.  I intend to *fulfill my vow*, if you do not give me a reason to spare you.~
= ~Refuse my offer and there would be no revenge for your pitiful Deheriana. If you take it... I'll help you to backstab Tazok. After all he would be insisting that I cut that lovely throat of yours with all the brutal stubbornness of his lesser race.~
= ~When the prospect of payback is equal, I ally myself with the cutest side, and you have that advantage over Tazok, Kivan.~
= ~Hmmm...if you wash some.~
== ~KIVANJ~ IF ~Dead("TAZOK")~ THEN ~Tazok is no more, Silversword.~
== P#EMMA IF ~Dead("TAZOK")~ THEN ~Naive as well... Delicious! No, Kivan, Tazok is not dead. Tazok is serving a leader of the Iron Throne, and he brought him back to life.~
= ~There is a lesson for you in that - masters sometimes give treats to the dogs that serve well.~
== ~KIVANJ~ ~I will not ally myself with your cause.~
== P#EMMA ~Oh, not the *same* words again! Do not make a mistake of taking me lightly, mellonamin.~
== ~KIVANJ~ ~I dread a day when I call someone like you a friend, but I do not underestimate you. You look like quite an accomplished murderer, Imanel Silversword.~
== P#EMMA ~Then you choose death.~
= ~ *Sighs* And I was even going to offer you back that bow...after we would have found a better one.~
= ~I cannot go around forever with a bow which has "mela en' coiamin Kivan" inscribed all over it. "My beloved Kivan..." -and that's not the worst of it.~
= ~I wonder why your little wife did not use parchment to write all this nonsense down and give to you? Ah, I know! She was sure that the bow would never leave your hands...~
= ~How touching.~
== ~KIVANJ~ ~Kinslaying is not something I wish to do, Imanel. Allow me to escort you to the Flaming Fist's quarters or to any other authorities you would wish to surrender to. There might be yet a chance for you to redeem yourself.~
== P#EMMA ~Kivan, you are a fool, and you are soon to be a dead fool. Does anyone among you have brain? Join me, and we shall have loads of gold and fun together.~
= ~The imbecile ranger, of course, will have to be killed….~
DO ~CreateItem("P#BOW",0,0,0)~
END  P#EMMA EMKI.PC
