//ring of human inflience

EXTEND_BOTTOM ~FORESH~ 1
IF ~CheckStatLT(Player1,17,CHR) !InParty("jaheira")~ THEN DO ~GiveItemCreate("X#RINGRO",Player1,1,0,0)~ GOTO X#RomanceForeshadow
END

EXTEND_BOTTOM ~FORESH~ 2
IF ~CheckStatLT(Player1,17,CHR)!InParty("jaheira")~ THEN DO ~GiveItemCreate("X#RINGRO",Player1,1,0,0)~ + X#RomanceForeshadow
END

EXTEND_BOTTOM ~FORESH~ 3
IF ~CheckStatLT(Player1,17,CHR) !InParty("jaheira")~ THEN DO ~GiveItemCreate("X#RINGRO",Player1,1,0,0)~ + X#RomanceForeshadow
END

APPEND ~FORESH~

IF ~~ X#RomanceForeshadow
SAY ~Ah, almost forgot! I have a trinket for you from a secret benefactory. You are young and on the road, my friend... It might well happen very soon that you'll fall in love with one of your companions. Here is a little something to help you to win a heart.~
IF ~~ THEN DO ~EscapeArea()
~ EXIT
END
END

I_C_T ~VOLTIN~ 0 X#CorVoltin
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Well met Voltine! I am Coran and you can call me... Coran. What a delightful surprise to meet another elf! And of such an exquisite beauty...~
END


I_C_T ~RIELTA~ 0 X#CoranRieltar
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~A thief does not set rules for another thief... gentleman or not. We will do what pleases us, and if you do not like it - well here is your chance to make yet another attempt on <CHARNAME>'s life. All previous assailants fell to <PRO_HISHER> hand.~
END


I_C_T ~NEMPHR~ 3 XCoran#Nemphra
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Ah, what a pity... I was hoping to see the amulet decorating that beautiful neck of yours, lady... ~
== ~NEMPHR~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Get lost already!~
END

I_C_T ~LARRIA~ 2 X#CoranLariaz
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~She does not look too good, as much as I hate to say such a thing of a lady. In fact, she looks like she is about to expire. Perhaps we can escort her to the oceanfront, <CHARNAME>? She is too beautiful to die...~
END

I_C_T ~PHEIRK~ 1 X#CoranPheirk
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~I would be damned if I'd be running small errands for a dwarf! Wait... you said the reward would be handsome? Can you give an exact number?~
== ~PHEIRK~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~If I like your work and you'd do it fast, there'd be 200 gold in it fer you.~
END

I_C_T ~LAERTA~ 0 X#CoranLaerta
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Young ladies, you have my word that the miscreant will be severely punished for disturbing your peaceful sleep. ~
END

I_C_T ~LUCKY~ 0 X#CoranLucky
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Uhm... you are indeed lucky if you are still alive among the stuff you sell. Look at this bottle! It has burned an inch deep hole around itself on a shelf! And this... er whatever it is... I swear it had winked at me!~
== ~LUCKY~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~That? That's eyes of some ladylich... or at least the gnome that sold it to me claimed that 'twas...~
END

I_C_T ~LUSSEL~ 4 X#CoranLusselyn
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~*Laughs* You are a happy man, Lusselyn... Looking at you who would not want to spend their days boozing up and chatting with amiable companions... How about we stick around for a while <CHARNAME> and spend these coins to celebrate that we are alive and to compensate to the good innkeeper for the expense of buying another jelly? ~
== ~LUSSEL~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Yer a good one, you are... ~
END

I_C_T ~NOBW8~ 3 X#CoranAreana
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Who would believe rumors once they looked into your beautiful innocent eyes, m'lady?~
== ~NOBW8~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~This is... not a light matter... I need him silenced! Please...~
END

I_C_T ~RINNIE~ 1 X#CoranRinnie
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Mmgh... so we are looking for a history of the Unicorn Run? With the title like that it could be a piquant read.~
= ~I once was told a lovely story about hunting unicorns. You see, they say that if you tie a maiden girl in the forest to an oaken trie, the unicorn would come... So that clever fellow talked a virgin to go hunt unicorns with him... Good story, that.~
DO ~SetGlobal("X#CoranUnicorn","GLOBAL",1)~
= ~I wonder if that folio tells of something similar.~
END

I_C_T ~CORDYR~ 1 X#CoranCordyr
== ~CoranJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Sirens' hunt is a cruel quest - listening to their sweet singing, and knowing for true that they but lure men to spill blood that boiled at the first sighting of them. *Sighs* I can never quite believe that it is their intent. Maybe one day I should stop resisting and find out for myself.~
== ~SAFANJ~ IF ~InParty("Safana") InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~I was told that my mother was a siren...~
== ~CoranJ~ IF ~InParty("Safana") InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Knowing you, I am inclined to believe this tale, temptress. I wish I knew how your father... er... never mind. ~
END

I_C_T ~DESRET~ 0 X#CoranDesreta
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~*Raises his brow* I was not aware that they now call it *entropy* in Baldur's Gate... I was away for too long perhaps.~
END

I_C_T ~FABER~ 0 X#CoranFaber
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~A telltale! He reminds me of my sister Ameniela... Mama! Coran had slipped away from the window and had been hunting all night! Papa! Coran was kissing Enivien Maervik's daughter... Quite inconvenient. We will have to watch our backs now.~
== ~FABER~ IF ~InParty("Coran")~ THEN ~Guaaards!~
END

I_C_T ~CANTIC~ 0 X#CoranCanticle
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Enslaving a bard to do digging? This Davaeorn has a brain the size of walnut! Worry not, troubadour, we are here to set you all free and kill Davaeorn.~
== ~CANTIC~ IF ~InParty("Coran")~ THEN ~If you break us free... I would sing a song of you, even if I would not be able to speak after that ever again.~
END

I_C_T ~TAXEK~ 2 X#Taxek
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Is *that* all?~
DO ~SetGlobal("X#CoranTaxek","GLOBAL",1)~
== ~TAXEK~ IF ~InParty("Coran")~ THEN ~Yes sir. Not to be offencive or anything like that but your house aren't much...~
END

I_C_T ~FORTHE~ 2 X#CoranForthel
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~You need material for a ballad? You have asked the right person! Look at this noble looking heroic <PRO_LADYLORD>! Every day with <PRO_HIMHER> can be made into a song, and a week - into an epic!~
== ~CoranJ~ IF ~InParty("Coran") Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1)~ THEN ~*quietly* and every night into a song...~
== ~FORTHE~ IF ~InParty("Coran")~ THEN ~Well, give me at least one...~
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Gladly. Just a few days ago, we worked on stopping the iron shortages and chased the bandits out of the bowels of Toril... Or as close to its bowels as I ever intend to be. ~
== ~FORTHE~ IF ~InParty("Coran")~ THEN ~Are you telling me you have been to the Underdark?~
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Er... pretty much. There we were assaulted by vicious -~
== ~FORTHE~ IF ~InParty("Coran")~ THEN ~Drow?! I knew they were involved! Nothing evil... make it just 'nothing'... happens on the face of Toril, without a drow or two involved!~
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Er... yes, drow everywhere, skulking in shadows, shooting those poisonous darts of theirs.... and their women so voluptuous and evil that you fall in love with them quicker than they kill you, and take it from me, they do it quite speedily...~
== ~VICONJ~ IF ~InParty("Coran") InParty("Viconia")~ THEN ~*quietly* I'd be glad to demonstrate the killing part to you, stupid darthiir...~
== ~CORANJ~ IF ~InParty("Coran") InParty("Viconia")~ THEN ~*quietly* Then drop your hood and do it... I wonder how long you'd live after the Flaming Fist learns whom we shelter?~
== ~VICONJ~ IF ~InParty("Coran") InParty("Viconia")~ THEN ~Wretched surfacer!~
== ~FORTHE~ IF ~InParty("Coran")~ THEN ~What a splendid tale!~
DO ~GiveGoldForce("10")~
END

I_C_T ~COKSMTH~ 0 X#CoranPeter
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~A fellow huntsman of wyverns, I presume?~ 
== ~COKSMTH~ IF ~InParty("Coran")~ THEN ~A huntsman, yes. But I have no interest in these... wyverns. I am here for... er... caves.~
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Really? And I could have sworn that this faint acidic smell on your cloak is the same that their poison leaves...~
= ~So you are not going to kill the pair? I am not surprised. *Nobody* around here is buying wyvern trophies... I know that for a fact! ~
= ~Er... how long you are going to stay in this cave anyway?~
== ~COKSMTH~ IF ~InParty("Coran")~ THEN ~For some time... My er... spelunking takes time...~
END

INTERJECT_COPY_TRANS ~SLAVLEAD~ 0 X#CoranRill
== ~CoranJ~ IF ~InParty("Coran")~ THEN ~Of course we can help you out! As they say - take from the rich, give to the poor and do not forget yourself....~
END

I_C_T ~SONNER~ 4 X#CoranSonner
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~The three of you cannot win favor with one lady? Mine, I alone can win three ladies in the same amount of time!~
== ~SONNER~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~You try it then, mate. Only she's no lady, she's a bitch, like her Queen...~
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~<CHARNAME>, the men who call woman a bitch are not worthy of our help...~
END

EXTEND_BOTTOM ~BRILLA~ 0
IF ~IsValidForPartyDialog("Coran") Gender(Player1,FEMALE) !InParty("Skie")~ EXTERN ~CoranJ~ X#CoranBrilla2
END

I_C_T ~BRILLA~ 0 X#CoranBrilla1
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1,MALE)~ THEN ~Remember what I told you? With noblewomen it's boldness that scores. Smile, you rascal!~
END

I_C_T ~ABELA~ 7 X#CoranAbela2
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~You are free, my woodland beauty. Care to celebrate the joyous occasion in a cozy inn? Or in a lovely grotto which you call your home... where is it by the way? Abela?~
== ~ABELA~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~*Abela throws a weighting glance at Coran, but then jerks her eyes away and sighs.~
END

I_C_T ~ABELA~ 4 X#CoranAbela1
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~You are free, my woodland beauty. Care to celebrate the joyous occasion in a cozy inn? Or in a lovely grotto which you call your home... where is it by the way? Abela?~
== ~ABELA~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~*Abela throws a weighting glance at Coran, but then jerks her eyes away and sighs.~
END

I_C_T ~POE~ 15 X#CoranPoe
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Bard, your ballad brought to my mind a story of Elf-King Echtellion and the Songstress Inga Highwing.~
== ~POE~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~ I would fancy to hear this tale, Master Elf.~
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~There is a small settlement of Belgarden in Cormyr, on the lands that now are claimed by humans but of old they were Elven. One cruel battle was fought there thousands of years ago, ere the Crown Wars. And in it the fairest and mightiest Elf King Echtellion was slain in some noble fashion, of course.~
= ~To commemorate him, Alaundalion, the artist carved a statue to put on his grave. He was said to be in love with Echtellion's sister and therefore to please her, he did her bidding and made the statue very lifelike, against the Elven tradition - for we all know that Elves have little talent for the exact depicting of the features, as they ever try to capture the spirit.~
= ~The sister of the King, wise Ogneda, was enamoured with Alaundalion's work, and she quite often came to honor her brother and lay flowers by the statue's feet. It is believed that Ogneda later became mad, convincing herself, that the dead stone was her brother. The magic was strong in her, and added by her insanity, she turned into a banshee.~
= ~The centuries had passed, and even the Elves with their long memories now have little recall of King Echtellion and his deeds. Yet the statue stood, as whole as it was on the day of its carving. Many a person came throughout the years to see the monument and went away in wonder.~
= ~Inga the Highwing stayed.~
= ~The image of the long-dead King captivated her so much, that she wanted to know all there is about him. She pieced together, what shreds of lore she could find, but that was an unsatisfactory harvest. In her love for the King, Inga wrote her own songs about him, and came every day at the sunrise to his statue to sing to his stone image.~
= ~One night, when she was in the middle of a particularly moving ballad, o, wonder! The statue had stepped down from the column at which it stood and walked over to Inga. Echtellion lived again!~
= ~The small crowd that gathered round went so quiet that a snowflake's fall would have broken that silence. Echtellion's voice seemed not to go hoarse with disuse and the whole gathering had hearkened to the words he said to Inga Highwing:~
= ~"Seldarine have mercy on me! You wail worst than my sister!"~
== ~POE~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Wh-what?~
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~Do not despair, bard. Bad poetry has the power to turn the stone to flesh and raise dead... ~
= ~Now, <CHARNAME>, were you going to say something?~
END


EXTEND_BOTTOM SHOAL 0
IF ~!Dead("Coran") InParty("Coran")~ THEN DO ~SetGlobal("CSKCCIV","GLOBAL",1)~ EXIT
END

EXTEND_BOTTOM ~FCOOK2~ 0
IF ~IsValidForPartyDialog("Coran")~ EXTERN ~BCORAN~ X#CoranCook
END

CHAIN 
IF ~~ THEN ~BCORAN~ X#CoranCook
~Er... m'lady, it seems that your romantic ideals were badly effected by your prolonged stay among the rough thugs, miners and hobgoblins. ~
== ~FCOOK2~ ~Aye, but shag is still a shag. You're a bit flimsy for me liking, but if you want some-~
== ~BCORAN~ IF ~Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1)~ THEN ~Would that I could, m'lady. But alas, my heart does not belong to me any longer. And I am afraid that the one who holds it would bleed it should I -~
== ~FCOOK2~ IF ~Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1)~ THEN ~Your ladylove would chop you into sauerkraut, if you stray, that's what you mean... o, well. Maybe another time. *winks* ~
== ~BCORAN~ IF ~OR(2) !Global("CoranMatch","GLOBAL",1) Global("CoranRomanceInactive","GLOBAL",1)~ THEN ~Should I have the time, I would have shown you the difference, m'lady... what is your name?~
END
IF ~Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1)~ THEN EXIT
+ ~OR(2) !Global("CoranMatch","GLOBAL",1) Global("CoranRomanceInactive","GLOBAL",1)~ + ~Cooooran! Must I pry you loose from *every* skirt?~ EXTERN ~CORANJ~ X#CoranCook1
+ ~OR(2) !Global("CoranMatch","GLOBAL",1) Global("CoranRomanceInactive","GLOBAL",1)~ + ~But you do not. So the littl' bird's name is irrelevant. Now let us go.~ + X#CoranCook2
+ ~Gender(Player1, MALE) OR(2) !Global("CoranMatch","GLOBAL",1) Global("CoranRomanceInactive","GLOBAL",1)~ + ~Excuse me kindly, gentle lady, but I must steal my comrade from you...~ EXTERN ~FCOOK2~ X#CoranCook3

INTERJECT_COPY_TRANS ~BGWILLIA~ 4 ManyInt1
== ~CORANJ~ IF ~Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1) InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE) Global("CoranLover","GLOBAL",1)~ THEN ~You don't even have to turn your back on her now for that to happen.~
== ~AJANTJ~ IF ~InParty("ajantis") Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1) InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE) Global("CoranLover","GLOBAL",1)~ THEN ~Coran?! What you mumbling about?~
== ~CORANJ~ IF ~Global("CoranMatch","GLOBAL",1) !Global("CoranRomanceInactive","GLOBAL",1) InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE) Global("CoranLover","GLOBAL",1)~ THEN ~Oh, nothing, my brave knight.~
END

INTERJECT_COPY_TRANS ~BGWILLIA~ 5 ManyInt2
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE)~ THEN ~A lark in naught but a cloak around her waste...~
== ~XANJ~ IF ~InParty("xan") InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE)~ THEN ~Coran.. *sighs* CORAN!~
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE)~ THEN ~Oh... did I drift off?~
END

INTERJECT_COPY_TRANS ~JESSUP~ 1 ManyInt3
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE) Class(Player1, THIEF_ALL)~ THEN ~Once a cute thief, always a cute thief.~
== ~IMOEN2~ IF ~InParty("imoen2") InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE) Class(Player1, THIEF_ALL)~ THEN ~Heya! <CHARNAME> is not the only cute thief in this party, thank ya very much!~
END

INTERJECT_COPY_TRANS ~JESSUP~ 2 ManyInt4
== ~XanJ~ IF ~IsValidForPartyDialogue("Xan") Gender(Player1, FEMALE)~ THEN ~*Whispers* <CHARNAME>, me being a Greycloak of Evereska... I do have a spare cloak... if you wish to borrow it one day...~
== ~CORANJ~ IF ~InParty("coran") IsValidForPartyDialogue("Xan") Gender(Player1, FEMALE)~ THEN ~Xan... I heard that!~
END

INTERJECT_COPY_TRANS ~BGWILLIA~ 8 ManyInt5
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE)~ THEN ~<CHARNAME>, you need to show this carefree side of yourself more now. It would surely help reduce... tension.~
== ~XANJ~ IF ~InParty("xan") InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING) Gender(Player1, FEMALE)~ THEN ~Our chances of survival is meager as is, and it would only aggravate us all even worst if our leader decides to drop her weapons and attire in the middle of the battle... Moreover, while <CHARNAME> is fair of face, I have very little confidence that her revealing herself in such a way, would have a blinding effect on our enemies, such as from a spell that a dryad could place on her foes...~
END

I_C_T ~TAMOKO~ 20 CoranTamoko
== ~CORANJ~ IF ~InParty("coran") !Dead("coran") !StateCheck("coran",STATE_SLEEPING)~ THEN ~*Whistles quietly* What a woman! Your brother must be something out of an ordinary to inspire such deep feelings!~
END

APPEND CORANJ


// Coran, Shoal Kiss - Male
IF WEIGHT #-2 ~Global("CSKMale","GLOBAL",1)~ THEN CSKMale1
SAY ~He is not the first to fail because of a woman’s kiss.~
IF ~~ THEN DO ~SetGlobal("CSKMale","GLOBAL",2)~ EXIT
END

// Coran, Shoal Kiss - Female
IF WEIGHT #-2 ~Global("CSKFemale","GLOBAL",1)~ THEN CSKFemale1
SAY ~Who knew that a sisterly kiss has such poison?~
IF ~~ THEN DO ~SetGlobal("CSKFemale","GLOBAL",2)~ EXIT
END

// Coran, Shoal Kiss, Coran's Comment
IF WEIGHT #-2 ~Global("CSKCC","GLOBAL",1)~ THEN CSKCC1
SAY ~I accepted death gladly, for I have known the moment of pure happiness in your embrace, my lady.~
IF ~~ THEN DO ~SetGlobal("CSKCC","GLOBAL",2)~ EXIT
END

// Coran, Entry to Baldur’s Gate
IF WEIGHT #-2 ~Global("CEBG","GLOBAL",1)~ THEN CEBG1
SAY ~Ah, I love this city!~
IF ~~ THEN DO ~SetGlobal("CEBG","GLOBAL",2)~ EXIT
END

//Coran Halfling Brewery FW4003
IF WEIGHT #-2  ~Global("X#CoranHB","GLOBAL",1)~ THEN BEGIN X#CoranHB
SAY ~I have heard that halfling's ales are most delectable. Care to join me and ascertain or disprove this claim, <CHARNAME>?~
++ ~Perhaps later on, Coran~ DO ~SetGlobal("X#CoranHB","GLOBAL",2)~ + X#CoranHB1
++ ~No, you will have to drink alone. Though with your talents I doubt not that you'd find yourself company.~ DO ~SetGlobal("X#CoranHB","GLOBAL",2)~ + X#CoranHB2
++ ~We have not come here for the meads and ales, Coran!~ DO ~SetGlobal("X#CoranHB","GLOBAL",2)~ + X#CoranHB3
END

IF ~~ X#CoranHB1
SAY ~Ah, nothing is better than an even in a genteel company by the fireplace after slaughtering a ghost or two... ~
IF ~~ THEN EXIT
END

IF ~~ X#CoranHB2
SAY ~But I wanted to drink with a nice person... on the second thought that eliminates you!~
IF ~~ THEN EXIT
END

IF ~~ X#CoranHB3
SAY ~No, but now that we found it... I say it is worthwhile to try it!~
IF ~~ THEN EXIT
END

//Natasha
IF WEIGHT #-2  ~Global("X#CoranNatasha","GLOBAL",1)~ THEN BEGIN CoranNatasha1
SAY ~Just another cold body... but what a body! Makes me feel sad looking at it that such magnificence going to waste. *Sighs*~
= ~And an odd ball too... why not hurl lightening and fireballs at me after I have talked to her and made for an exit as every other woman does? This way nobody gets hurt... unless there is sentient furniture in the rooms...~
IF ~~ THEN DO ~SetGlobal("X#CoranNatasha","GLOBAL",2)~ EXIT
END

//CoranTaxek

IF WEIGHT #-2  ~Global("X#CoranTaxek","GLOBAL",2)~ THEN BEGIN CoranTaxek2
SAY ~That's the easiest money I have made! But I must admit that I dislike stealing what was already rightfully stolen... If a thief can cross a thief, what kind of world is it?~
IF ~~ THEN DO ~SetGlobal("X#CoranTaxek","GLOBAL",3)~ EXIT
END

//Coran Unicorn

IF WEIGHT #-2  ~Global("X#CoranUnicorn","GLOBAL",2)~ THEN BEGIN CoranUnik1
SAY ~Alas, this Unicorn Run is indeed a history scroll... And a boring one at that! Just listen: ~
= ~Bards and sages pass down the tale that the headwaters of the Unicorn Run are, in truth, the Font of Life, and a cradle of fecundity.  Each natural race is said to have emerged from the womb of Chauntea onto Toril at the river's source, and then traveled down the Unicorn Run to the outside world.~
= ~Oh, well, could have been worst! If I see another "History of the North" I'd go mad, I swear! It is in every house we enter - was it given away for free by the author in this region? Or did he promise a reward to anyone who manages to read it cover to cover?~
IF ~~ THEN DO ~SetGlobal("X#CoranUnicorn","GLOBAL",3)~ EXIT
END

//CoranCook
IF ~~ X#CoranCook1
SAY ~Just the ones that are wrapped around a pair of exquisitely shapely legs...~
++ ~Yes, yes, I know that with you it's what under the skirts that counts.~ + X#CoranCook4
++ ~Lady, do show him your legs, so we can get moving finally.~ EXTERN ~FCOOK2~ X#CoranCook5
++ ~O, the variable life of an adventurer! One minute I slaughter hobgoblins, another I receive lessons in seduction. And all in the same mine. ~ + X#CoranCook6
END

IF ~~ X#CoranCook4
SAY ~Ah, you are too down to Toril my friend for the one so young. You should be still dreaming of chaste kisses and moonlit walks...~
++ ~You were just like that in my age, no doubt.~ EXIT
END

IF ~~ X#CoranCook6
SAY ~Is not that wonderful?~
IF ~~ THEN EXTERN ~BCORAN~ X#CoranCook2
END

//Coran Durlyle Aftermath

IF WEIGHT #-2 ~Global("X#CoranDur","GLOBAL",3)~ THEN BEGIN X#CoDurlyleAfter
SAY ~Nobody calls my ladylove a bitch -~
++ ~He is gone, you silly boy.~ DO ~SetGlobal("X#CoranDur","GLOBAL",4)~ + X#CODAfter1
++ ~Oh, Coran, Coran... did he hurt you, my heart?~ DO ~SetGlobal("X#CoranDur","GLOBAL",4)~ + X#CODAfter2
++ ~Dear me, and I thought that you were wiser than to pick fights with the guys bigger than yourself...~ DO ~SetGlobal("X#CoranDur","GLOBAL",4)~ + X#CODAfter3
END

IF ~~ X#CODAfter1
SAY ~Well... Er... Coward!~
IF ~~ THEN EXIT
END

IF ~~ X#CODAfter2
SAY ~*Touches his jaw* Not so bad, but you'd have to be careful when kissing me. The bastard broke my lip. I wonder how he managed to put a hit in so quickly?~
IF ~~ THEN EXIT
END

IF ~~ X#CODAfter3
SAY ~Er... he was... impetuous with his sweet songs and wanton glances. He was *ogling* you! ~
++ ~*Start laughing* He is not the only one who does such things, Coran... I know an elf from Tethyr -~ + X#CODAfter4
++ ~Oh, really? How awful!~ + X#CODAfter5
++ ~*Sigh* Let us just go, Coran.~ EXIT
END

IF ~~ X#CODAfter4
SAY ~*Sheepishly* Oh... I guess you are right. But you do not mind it... when it's coming from me, right?~
IF ~~ THEN EXIT
END

IF ~~ X#CODAfter5
SAY ~It was! *Touches his jaw* I wonder how he managed to put a hit in so quickly?~
IF ~~ THEN EXIT
END

// Coran, Entry to Durlag’s Tower - TOTSC!
IF WEIGHT #-1 ~Global("CEDT","GLOBAL",1)~ THEN CEDT1
SAY ~This place shall be an ultimate test of my skills! Dwarven traps against the nimbleness of elven hands! If I loose I die, if I win - there is a treasure waiting! What a thrill!~
IF ~~ THEN DO ~SetGlobal("CEDT","GLOBAL",2)~ EXIT
END

// Coran, Sighting The Dragon Skeleton TOTSC!
IF WEIGHT #-2 ~Global("CSTDS","GLOBAL",1)~ THEN CSTDS1
SAY ~It is enormous...look at it! I have never seen a dragon of that size. I bet it is one of the ancient ones...I guess it died of old age. I wonder what they would pay for his scalp at the Hall of Wonders?~
IF ~~ THEN DO ~SetGlobal("CSTDS","GLOBAL",2)~ EXIT
END



END

CHAIN
IF ~~ THEN ~BCORAN~ X#CoranCook2
~Good <DAYNIGHT>, lovely. We met and we part, like two fireflies on a windy night...~
== ~FCOOK2~ ~*Giggles*~
EXIT

CHAIN 
IF ~~ THEN ~FCOOK2~ X#CoranCook3
~Seems that our mine now attracts the gentle-borns... I better do something about my hairdo... and buy new shoes.~
EXIT

CHAIN 
IF ~~ THEN ~FCOOK2~ X#CoranCook5
~I have not had that much fun in ages! Here ya go!~
== ~BCORAN~ ~Uhm... <CHARNAME>, I'll catch up with you later... much later...~
DO ~LeaveParty() EscapeArea() ActionOverride("fcook2", EscapeArea())~
EXIT

CHAIN
IF ~~ THEN ~CORANJ~ X#CoranBrilla2
~*quietly* Let me handle this, <CHARNAME>...~
= ~O, Ladylove, the rumors that Lady Brilla Silvershield is the most beautiful Lady in Baldur's Gate reached my ears and I came here to -~
== ~BRILLA~ ~Was it all over the town? O... ~
== ~CORANJ~ ~The rumors lie, m'lady...~
== ~BRILLA~ ~Wh-what?!~
== ~CORANJ~ ~*after a dramatic pause* You are the loveliest woman in the world... ~
== ~BRILLA~ ~Thank you kindly...~
== ~CORANJ~ ~May I have a privilege of kissing your slender elegant fingers?~
== ~BRILLA~ ~Certainly...~
= ~Wait! I think I know you! I saw you at Lady's Berayat's Estate, the very evening when her diamond-and-star sapphires necklace went missing...~
= ~*Giggles* Serves her right too, the way she was parading it at every occasion!~
== ~CORANJ~ ~Lady Berayat? Oh... diamond-and-star sapphires? Horse-faced girl?~
== ~BRILLA~ ~You were awfully friendly with her...~
== ~CORANJ~ ~I must have been blinded by your beauty... ~
== ~BRILLA~ ~*Giggles* But you said you have never seen me before, Elf?~
== ~CORANJ~ ~Er... I lied. Ever since that evening I was hoping to see you again... I er... even called my comrades to help me to find you...~
== ~BRILLA~ ~How romantic!~
== ~CORANJ~ ~I shall serenade you tonight at midnight, m'lady.~
== ~BRILLA~ ~I will be waiting...~
DO ~GiveItemCreate("RING18","Coran",1,0,0)  EscapeArea()~
EXIT

