BEGIN ~SK#UNAT~
BEGIN ~SK#AMAUN~
BEGIN ~SK#HELM~

BEGIN ~SK#NEHT~

IF ~NumTimesTalkedTo(0)~ THEN BEGIN 0
  SAY ~Ho there! May I have a moment with thee?~ [SK#MEET]
  ++ ~Die, wraith!~ + 1
  ++ ~Give me one good reason why I shouldn't kill you, wraith.~ + 2
  ++ ~Sure you can, what's wrong? Besides you being dead, I mean.~ + 6
  ++ ~No you may not. I don't typically speak to the undead, and I don't plan to start now.~ + 8
  ++ ~I will give you a moment of my time. So what ails you?~ + 6
  IF ~Class(Player1,PALADIN)~ THEN REPLY ~I know a paladin when I see one, but we are not typically undead as well. What can I do to help?~ + 6
END

IF ~~ THEN BEGIN 1
  SAY ~Come and try to destroy me then, foolish one!~
  IF ~~ THEN DO ~ActionOverride("SK#Neht",Enemy())
Enemy()~ EXIT
END

IF ~~ THEN BEGIN 2
  SAY ~I wish only to speak with thee, nothing more at the moment.~
  ++ ~Then tell me what it is you want, quickly. I've got things to do.~ + 6
  ++ ~'At the moment'? Is that a threat, wraith?~ + 7
  ++ ~I don't do favors for the undead. Go away.~ + 8
END

IF ~~ THEN BEGIN 6
  SAY ~I noticed thou answered the riddles and finished off the beholders with ease, so I desire thy help to overcome what lies in the temple beyond.~
  ++ ~If I help you, what's in it for me?~ + 9
  ++ ~How do you know about the riddles and beholders?~ + 31
  ++ ~I don't help the undead.~ + 8
  ++ ~Of course I'll help, just tell me how.~ + 9
END

IF ~~ THEN BEGIN 7
  SAY ~No more of a threat than what thou hast made of it. Thou passed through the creatures and answered the riddles with ease... and I seek the aid of one such as thee.~
  ++ ~If I help you, what's in it for me?~ + 9
  ++ ~How do you know about the riddles and beholders?~ + 31
  ++ ~I don't help the undead.~ + 8
  ++ ~Of course I'll help, just tell me how.~ + 9
END

IF ~~ THEN BEGIN 8
  SAY ~Very well, but I shall leave thee with a simple warning; what lies ahead will take only a helping hand, not one which harms.~
  ++ ~What do you mean by that?~ + 15
  ++ ~Don't bother me again, wraith. If you insist on speaking to me again I'll have to kill you.~ + 17
  ++ ~Thanks for the warning. Goodbye.~ + 18
END

IF ~~ THEN BEGIN 9
  SAY ~Thou seeks what lies in the temple as much as the Eyeless One, and unlike the beholder's minions thy eyes grasped the truth in the riddles. I also seek something that is within the temple, but it is guarded by a creature I do not possess the ability to suppress.~
  IF ~~ THEN GOTO 10
END

IF ~~ THEN BEGIN 10
  SAY ~All I ask for is thy help in suppressing what guards the temple... and I shall not trouble thee further.~
  ++ ~That sounds easy enough.~ + 11
  ++ ~You ask me to help you, but you've yet to at least give me your name.~ + 13
  ++ ~I still don't see how I benefit in helping you.~ + 30
END

IF ~~ THEN BEGIN 11
  SAY ~So may I join thee for a short time?~
  ++ ~No, I'll kill whatever it is in the temple, but I'd rather not have to worry about one of my companions stabbing me in the back while doing so.~ + 8
  ++ ~You can, but only for a short time. I don't plan to stick around long.~ + 12
  ++ ~Actually, I've changed my mind. I think I'll kill you and keep whatever else is in the temple for myself.~ + 1
END

IF ~~ THEN BEGIN 12
  SAY ~Still, even if our time together is short thou should still know who I am, my <PRO_LADYLORD>.~
  IF ~~ THEN GOTO 13
END

IF ~~ THEN BEGIN 13
  SAY ~I was known as... Sir Neh'taniel in life, and once was an elvish knight. What thou sees before thee is the remains of that person.~ [SK#Neh1]
  IF ~~ THEN GOTO 19
END

IF ~~ THEN BEGIN 15
  SAY ~I have fought the creature that lies within this temple since before the Time of Troubles, yet no blow of mine has ever been able to lay the beast low. It takes spells, ones I do not possess, to bypass the temple guardian.~
  IF ~~ THEN GOTO 16
END

IF ~~ THEN BEGIN 16
  SAY ~Fare thee well... and use the knowledge I have given thee wisely.~
  IF ~~ THEN DO ~EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

IF ~~ THEN BEGIN 17
  SAY ~So be it.~
  IF ~~ THEN DO ~EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

IF ~~ THEN BEGIN 18
  SAY ~(The wraith bows to you and fades away.)~
  IF ~~ THEN DO ~EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

IF ~~ THEN BEGIN 19
  SAY ~Since the Time of Troubles began, I have helped guard this temple from wandering monsters and the followers of the Eyeless. In the past few years, far more than the usual amount of Eyeless Ones have tried to gain access to the temple... until eventually I feared their false god would try to take the other half of the device on its own.~
  IF ~~ THEN GOTO 20
END

IF ~~ THEN BEGIN 20
  SAY ~(The wraith scowls.) Despite their desire to have fewer of the living troubling them, it took some convincing to have the priests place the riddles thou hath just passed through. In truth, the riddles were in place to keep those who would use the device for personal gain away.~
  ++ ~So you automatically assumed I wouldn't use the device for personal gain just because I answered some riddles correctly?~ + 21
  ++ ~What makes you think I'm not working for the Eyeless?~ + 24
  ++ ~That's all well and good, but what is it that you actually want from the temple, if not the rift device?~ + 25
END

IF ~~ THEN BEGIN 21
  SAY ~(A small, tight smile pulls at the corners of Neh'taniel's mouth.) Power such as the rift device possesses will likely destroy thee faster than I can.~
  IF ~~ THEN GOTO 22
END

IF ~~ THEN BEGIN 22
  SAY ~Doth thy offer to join thee still stand, after all I have told thee?~
  ++ ~Of course.~ + 23
  ++ ~No, I think it's best if I try to get past the guardian on my own.~ + 8
  ++ ~Thanks for the information, now it's time for you to die.~ + 1
END

IF ~~ THEN BEGIN 23
  SAY ~My thanks.~
  IF ~~ THEN DO ~SetGlobal("SK#NehtJoined","LOCALS",1) JoinParty()~ EXIT
END

IF ~~ THEN BEGIN 24
  SAY ~Thou still hath thy eyes and attacked the beholders on the other side of the bridge. No follower of the Eyeless would have or done such a thing.~
  IF ~~ THEN GOTO 22
END

IF ~~ THEN BEGIN 25
  SAY ~I seek to speak with whom the temple was originally dedicated to.~
  ++ ~Which would be?~ + 26
  ++ ~That's all? Well, then of course you can join me.~ + 23
  ++ ~There is something fishy about all of this, best if I kill you to be on the safe side.~ + 1
END

IF ~~ THEN BEGIN 26
  SAY ~An ancient god of the sun.~
  ++ ~I was hoping you would tell me the actual name of this god.~ + 27
  ++ ~Why are you suddenly hesitant to answer?~ + 28
  ++ ~How were you able to find out that information?~ + 29
END

IF ~~ THEN BEGIN 27
  SAY ~I... am afraid I cannot. The priests spend their days defiling the temple with their thoughts, making the creature within the temple stronger. I have no wish to see the damage they would do if they spoke their curses using the deity's name.~
  IF ~~ THEN GOTO 22
END

IF ~~ THEN BEGIN 28
  SAY ~I barely know thee, so I see no reason to share more personal information.~
  IF ~~ THEN GOTO 22
END

IF ~~ THEN BEGIN 29
  SAY ~I... try to serve this god still.~
  IF ~~ THEN GOTO 22
END

IF ~~ THEN BEGIN 30
  SAY ~By helping me, thou wilt be helping thyself.~
  IF ~~ THEN GOTO 11
END

IF ~~ THEN BEGIN 31
  SAY ~I suppose I must explain... ~
  IF ~~ THEN GOTO 13
END

IF ~NumTimesTalkedTOGT(0)~ THEN BEGIN ReturnDialogue
  SAY ~Hmm... was there anything thou needed?~
  ++ ~Yes! You need to die, wraith!~ + a
  ++ ~I was wondering if you would mind joining me.~ + b
  ++ ~No, I just came by to say hello.~ + k
END

IF ~~ THEN BEGIN a
  SAY ~(The wraith sighs and draws his sword.)~
  IF ~~ THEN DO ~ActionOverride("SK#Neht",Enemy())
Enemy()~ EXIT
END

IF ~~ THEN BEGIN b
  SAY ~I would not mind. There is not much else for me to do but wait for a friend of mine to appear.~
  ++ ~You don't exactly come across as the type who has friends.~ + c
  ++ ~Who's your friend?~ + d
  ++ ~Then let's go.~ DO ~SetGlobal("SK#NehtJoined","LOCALS",1) JoinParty()~ EXIT
END

IF ~~ THEN BEGIN c
  SAY ~I suppose not.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN d
  SAY ~His name is Viduan, a lich I have known for many years.~
  ++ ~Your friend is a lich?!~ + e
  ++ ~Why are you waiting for him?~ + h
  ++ ~That's all well and good, so let's get going, shall we?~ + j
END

IF ~~ THEN BEGIN e
  SAY ~Yes, just as I am a wraith if thou noticed.~
  ++ ~Ah, yes... it is all suddenly so understandable....~ + f
  ++ ~You are the first person I have ever met who is friends with a lich.~ + f
  ++ ~That's all well and good, so let's get going, shall we?~ + j
END

IF ~~ THEN BEGIN f
  SAY ~If I am to travel with thee more often, it is likely thou wilt run into far more creatures who art friends with liches.~
  ++ ~I hope you mean the friendly kind.~ + j
  ++ ~I've changed my mind, just don't go anywhere, alright?~ + g
END

IF ~~ THEN BEGIN g
  SAY ~(He shrugs.)~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN h
  SAY ~I cannot give up trying to contact my god and Viduan may know of another temple.~
  ++ ~Seems like you have a long, boring road ahead of you.~ + g
  ++ ~What you are doing seems important, so I'll leave you alone.~ + g
  ++ ~Maybe if you travel with me, we'll find something to help you out.~ + i
END

IF ~~ THEN BEGIN i
  SAY ~That may indeed happen... and it is far better than simply waiting.~
  IF ~~ THEN GOTO j
END

IF ~~ THEN BEGIN j
  SAY ~(He smiles faintly.)~
  IF ~~ THEN DO ~SetGlobal("SK#NehtJoined","LOCALS",1) JoinParty()~ EXIT
END

IF ~~ THEN BEGIN k
  SAY ~That is... good. Hello to thee as well.~
  IF ~~ THEN EXIT
END

//*********************************************************
BEGIN ~SK#NehtP~

IF ~OR(2)
GlobalLT("chapter","GLOBAL",4)
GlobalGT("chapter","GLOBAL",5) 
Global("SK#NehtJoined","LOCALS",1)~ THEN BEGIN Kickout
SAY ~It hath been...interesting while traveling with thee. If at a later time thou hast need of me, I will be at the graveyard in Athkatla for a short time. Not in... public view, of course. Merely cast a spell which purges invisibility and thou shalt see me near some graves.~
++ ~Please rejoin the party.~ DO ~JoinParty()~ EXIT
IF ~~ GOTO Graveyard
END

IF ~GlobalGT("chapter","GLOBAL",3)
GlobalLT("chapter","GLOBAL",6) 
Global("SK#NehtJoined","LOCALS",1)~ THEN BEGIN Kickout2
SAY ~It hath been...interesting while traveling with thee.~
++ ~Please rejoin the party.~ DO ~JoinParty()~ EXIT
IF ~~ GOTO Graveyard
END

IF ~~ THEN BEGIN Graveyard
SAY ~Fare thee well, <CHARNAME>.~
IF ~!AreaCheck("AR0602")
!AreaCheck("AR0603")
!AreaCheck("AR0410")
!AreaCheck("AR0411")
!AreaCheck("AR0412")
!AreaCheck("AR0413")
!AreaCheck("AR0414")
!AreaCheck("AR1512")
!AreaCheck("AR1513")
!AreaCheck("AR1514")
!AreaCheck("AR1515")
!AreaCheck("AR1516")
!AreaCheck("AR1501")
!AreaCheck("AR1502")
!AreaCheck("AR1503")
!AreaCheck("AR1504")
!AreaCheck("AR1505")
!AreaCheck("AR1506")
!AreaCheck("AR1507")
!AreaCheck("AR1508")
!AreaCheck("AR1509")
!AreaCheck("AR1510")
!AreaCheck("AR1511")
!AreaCheck("AR2100")
!AreaCheck("AR2101")
!AreaCheck("AR2102")
!AreaCheck("AR2200")
!AreaCheck("AR2202")
!AreaCheck("AR2203")
!AreaCheck("AR2204")
!AreaCheck("AR2205")
!AreaCheck("AR2206")
!AreaCheck("AR2207")
!AreaCheck("AR2208")
!AreaCheck("AR2209")
!AreaCheck("AR2210")
!AreaCheck("AR2300")
!AreaCheck("AR2400")
!AreaCheck("AR2401")
!AreaCheck("AR2402")
!AreaCheck("AR2900")
!AreaCheck("AR2901")
!AreaCheck("AR2902")
!AreaCheck("AR2903")
!AreaCheck("AR2904")
!AreaCheck("AR2905")!AreaCheck("AR2906")~ THEN REPLY ~We'll meet you at the graveyard if we need your services again.~ DO ~SetGlobal("SK#NehtJoined","LOCALS",0)
EscapeAreaMove("AR0800",1644,1407,0)~ EXIT

IF ~!AreaCheck("AR0301")
!AreaCheck("AR0302")
!AreaCheck("AR0303")
!AreaCheck("AR0304")
!AreaCheck("AR0305")
!AreaCheck("AR0306")
!AreaCheck("AR0307")
!AreaCheck("AR0509")
!AreaCheck("AR0510")
!AreaCheck("AR0511")
!AreaCheck("AR1102")
!AreaCheck("AR1107")
!AreaCheck("AR0801")
!AreaCheck("AR0803")
!AreaCheck("AR1300")
!AreaCheck("AR1301")
!AreaCheck("AR1302")
!AreaCheck("AR1303")
!AreaCheck("AR0604")
!AreaCheck("AR0605")
!AreaCheck("AR0606")~ THEN REPLY ~Just wait here Sir Neh'taniel.  If we need you again, we'll come back for you.~ DO ~SetGlobal("SK#NehtJoined","LOCALS",0)~ EXIT
END

IF ~Global("SK#NehtJoined","LOCALS",0)~ THEN BEGIN NehtRejoin
SAY ~Shall I rejoin thee?~
++ ~Please rejoin the party.~ DO ~SetGlobal("SK#NehtJoined","LOCALS",1)
JoinParty()~ EXIT
IF ~~ THEN REPLY ~Just wait here Neh'taniel. If we need you again, we'll come back for you.~ EXIT
END


// Explanation speech after Sarie battle

CHAIN IF WEIGHT #-99 ~Global("NehtExplains","GLOBAL",1)
See(Player1)~ THEN SK#NEHTP nehtexplains
~<CHARNAME>! Thou hast no idea how glad I am to see thee, if thou came but a moment later, I'd--~
== SK#NEHTP IF ~!HasItem("SW2HOST","SK#Neht")~ THEN ~I am certain death would hath come for me a second time. So what brings thee back to Bodhi's lair?~ DO ~SetGlobal("NehtExplains","GLOBAL",2)~
== SW2HOST IF ~HasItem("SW2HOST","SK#Neht")~ THEN ~Me master woulda been singin' to da daisies fer a second time.~
== SK#NEHTP IF ~HasItem("SW2HOST","SK#Neht")~ THEN ~(Scowls at his sword before looking at you again.) So what brings thee back to Bodhi's lair?~ DO ~SetGlobal("NehtExplains","GLOBAL",2)~
END
++ ~Before I answer any of your questions, I want you to answer mine.~ + 2e
++ ~Glad to help you stay in one piece.~ + 26e
++ ~I had to get the Rhynn Lanthorn from Bodhi so I can finally get to Irenicus.~ + 7e
++ ~You knew where I was, but not why?~ + 8e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy())
Enemy()~ EXIT

APPEND SK#NEHTP
IF ~~ THEN BEGIN 2e
SAY ~Ask... I shall do my best to answer thee.~
IF ~Global("SariePlay","GLOBAL",1) CheckStatLT(Player1,14,INT)~ THEN REPLY ~Your 'help' was a little too helpful, Neh'taniel, she killed all my allies!~ GOTO 37e
++ ~What happened to you while you were gone?~ + 3e
++ ~Both Sarie and Elhan called you Lil'velkyn Chath, who are you really?~ + 13e
++ ~Sarie kept calling you 'He-Who-Made-Me', does that mean you made her undead?~ + 17e
++ ~Elhan offered a reward for killing you, why?~ + 23e
END

IF ~~ THEN BEGIN 3e
SAY ~The Guina'Kiirar managed to capture me for a brief time. (You hear Relic grumbling in the background.) When Viduan freed me and I left to find thee, he stayed behind to make sure I was not followed....~
IF ~~ THEN GOTO 4e
END

IF ~~ THEN BEGIN 4e
SAY ~I was... worried Sarie would attack thee, but thou hast seen what came of that.~
++ ~The undead girl had every opportunity to try to kill me, but she had her spawn attack you as soon as she found you, why?~ + 5e
++ ~Why would you be worried about me?~ + 11e
++ ~You know, Neh'taniel, it seems like I'm helping you more often than you are helping me.~ + 12e
++ ~Do you know why you were captured?~ + 42e
END

IF ~~ THEN BEGIN 5e
SAY ~Sarie must have been told to stay by thee if I managed to escape, since I would have tried to reach thy companions and thee first. By leaving some of her spawn to kill me, she could inform the Guina'Kiirar of where I am....~
IF ~~ THEN GOTO 6e
END

IF ~~ THEN BEGIN 6e
SAY ~She used to listen to me. I thought with my help Sarie could resist their commands, but that hath proven not to be so.~
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~Well, thank you for answering my questions. You can still travel with me, if you want.~ + 10e
++ ~I still have more questions.~ + 2e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 7e
SAY ~Thou art closer to regaining thy soul, then... dost thou still want me to help thee?~
++ ~I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~I still have more questions.~ + 2e
++ ~You can still travel with me, if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 8e
SAY ~To undead, a Bhaalspawn hath a distinctive... smell. Since thy taint is strong within thee, it was not hard to track.~
++ ~I wasn't aware I smelled quite that bad.~ + 27e
++ ~So you're saying any undead can track me down.~ + 31e
++ ~Are there any more undead 'friends' of yours I should be worried about?~ + 35e
END

IF ~~ THEN BEGIN 9e
SAY ~I understand... and hope all goes well with thee.~ 
IF ~~ THEN DO ~SetGlobal("SK#KickedOut","LOCALS",1)
EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

IF ~~ THEN BEGIN 10e 
SAY ~I do want to continue traveling with thee, there is much I must make up for.~
IF ~~ THEN DO ~JoinParty()~ EXIT
END

IF ~~ THEN BEGIN 11e
SAY ~Thou art the first alive being in a long time who hath not either run away in terror or tried to attack me. Helping thee is the least I can do.~ 
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~I still have questions.~ + 2e
++ ~Well, thank you for answering my questions. You can still travel with me, if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 12e
SAY ~I apologize for endangering thee, to do so was never my intention.~
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~I still have questions.~ + 2e
++ ~Well, thank you for answering my questions. You can still travel with me, if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 13e
SAY ~I told thee the truth... my name is Neh'taniel. Lil'velkyn Chath is the name the drow gave me when I first became undead and had no control over my actions. The drow used me as a weapon against surface elves... it was only when I became 'aware' was I able to function on my own.~ 
++ ~How long ago was this?~ + 14e
++ ~Do the drow still control you?~ + 15e
++ ~Am I going to see this 'Lil'velkyn Chath' side of you any time soon?~ + 16e
END

IF ~~ THEN BEGIN 14e
SAY ~Hundreds of years... I cannot remember the exact day.~
++ ~Go on.~ + 15e
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~Well, thank you for answering my questions. You can still travel with me, if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 15e
SAY ~No, they do not control me, but the drow would try to if they had the chance. The reason why I choose to transform into a spider instead of a drow wraith while we were in the Underdark was because of this.~
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~Well, thank you for answering my questions. You can still travel with me, if you want.~ + 10e
++ ~I still have questions.~ + 2e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 16e
SAY ~(He shakes his head.) The days when Lil'velkyn Chath killed others unknowingly are far gone.~ 
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~Well, thank you for answering my questions. You can still travel with me, if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 17e
SAY ~(He closes his eyes and nods.)~
IF ~~ THEN GOTO 18e
END

IF ~~ THEN BEGIN 18e
SAY ~When I first became aware I was undead, I refused to drain anything magical since it usually led to killing or stealing. I starved myself... and my personality began to fade until I was not strong enough to control my undead urges.~
IF ~~ THEN GOTO 19e
END

IF ~~ THEN BEGIN 19e
SAY ~I was near a cottage when I lost control.~
++ ~What happened next?~ + 20e
++ ~I think I know where this is going.~ + 20e
++ ~I've heard enough.~ + 22e
END

IF ~~ THEN BEGIN 20e
SAY ~(He shakes his head, opening his eyes again.) I shall not describe to thee the horror of realizing I slaughtered an entire family and then made them undead. Over the years only Sarie of that family managed to withstand the passage of time thus far.~
IF ~~ THEN GOTO 21e
END

IF ~~ THEN BEGIN 21e
SAY ~I have not made another wraith since.~
++ ~Despite what you've told me, I still can't trust you, Neh'taniel. I think it's best if we parted ways.~ + 9e
++ ~As long as you have control over yourself now, you can continue to travel with me if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 22e
SAY ~(He shakes his head, opening his eyes again.) It is just as well, <CHARNAME>.~
++ ~From what you've told me, I think it's best if we parted ways.~ + 10e
++ ~As long as you have control over yourself now, you can continue to travel with me if you want.~ + 10e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 23e
SAY ~I do not know who Elhan is.~
++ ~Elhan is an elf in charge of a garrison outside of Suldanessellar.~ + 24e
++ ~He offered a lot of gold, are you sure you don't know?~ + 25e
++ ~I think you are lying.~ + 25e
END

IF ~~ THEN BEGIN 24e
SAY ~Suldanessellar... now that sounds familiar to me, but I apologize... I cannot remember who it is thou speak of.~
IF ~~ THEN GOTO 25e
END

IF ~~ THEN BEGIN 25e
SAY ~If I remembered I would have told thee. (He frowns.) There is much of my past I cannot recall.~ 
++ ~You are vague, far too vague for me to trust you. I think it's best if we parted ways.~ + 9e
++ ~I knew from the first time we met you had a hard time recalling some things, so I won't hold it against you. Do you still want to help me fight Irenicus?~ + 10e
++ ~I have quite a few questions to ask you.~ + 2e
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 26e
SAY ~It is good not to have one's soul ripped to shreds by undead... I thank thee.~
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 27e
SAY ~To any who art alive, thy smell is likely not quite so bad.~
++ ~If you are trying to be funny, then you just failed.~ + 28e
++ ~I've yet to meet an undead who smelled good.~ + 30e
++ ~I have a few questions to ask you.~ + 2e
END

IF ~~ THEN BEGIN 28e
SAY ~(He shrugs, eyeing you closely.) Is there anything thou wishes to know?~
++ ~Yes, I have quite a few questions to ask you.~ + 2e
++ ~No, I've learned all I ever wanted to know about you.~ + 9e
++ ~I have just one more question; is Sarie a former girlfriend?~ + 29e
END

IF ~~ THEN BEGIN 29e
SAY ~(His eyes widen.) No! Sarie looks and acts like a very dangerous child, it never occurred to me to think of her in such a way. Why dost thou ask?~
++ ~Just curious, what is the relationship between you and her, then?~ + 18e
++ ~Never mind, let's go.~ + 33e
END

IF ~~ THEN BEGIN 30e
SAY ~Thou should keep those without bodies as companions more often.~
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 31e
SAY ~(He nods.)~
++ ~That isn't a pleasant thought.~ + 32e
++ ~It makes sense, since I'm constantly running into undead creatures in my travels.~ + 28e
++ ~What you said doesn't make any sense, the only undead I have following me around is you.~ + 34e
END

IF ~~ THEN BEGIN 32e
SAY ~It was not meant to be. I... feel I should help thee as much as possible, since thou could've been injured by Sarie.~
++ ~I'm sure quite a few people wouldn't know if an undead girl could go crazy.~ + 28e
++ ~You owe me nothing, Neh'taniel.~ + 6e
++ ~Just the next time you promise to send help, make sure it'd actually be helpful.~ + 33e
END

IF ~~ THEN BEGIN 33e
SAY ~Shall I take that as an offer to rejoin thee?~
++ ~Of course.~ DO ~JoinParty()~ EXIT
++ ~No.~ DO ~SetGlobal("SK#KickedOut","LOCALS",1)
EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
++ ~(Attack.)~ DO ~ActionOverride("SK#Neht",Enemy()) Enemy()~ EXIT
END

IF ~~ THEN BEGIN 34e
SAY ~Then, thou art lucky.~
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 35e
SAY ~The only one thou should worry about if I were to travel with thee would be Sarie.~ 
++ ~What's the relationship between you and Sarie, anyways?~ + 18e
++ ~Viduan isn't going to show up again?~ + 36e
++ ~There is too much about you that I don't know, so I am not sure I want you to travel with me again.~ + 2e
END

IF ~~ THEN BEGIN 36e
SAY ~He only leaves his books when forced to, it is unlikely thou wilt see him again.~
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 37e
SAY ~What did thee tell Sarie to do?~
++ ~I asked her to play one of the songs she knew.~ + 38e
++ ~I don't remember what I told her.~ + 39e
++ ~Does it matter?~ + 40e
++ ~You know what, I don't want to talk about it.~ + 41e
END

IF ~~ THEN BEGIN 38e
SAY ~Yet, thou didst not tell her who to play the song on? (He shakes his head.) If thou had not, then that is where the problem lay.~ 
IF ~~ THEN GOTO 39e
END

IF ~~ THEN BEGIN 39e
SAY ~Sarie must be given specific instructions of what thee wants her to do... otherwise she will interpret thy commands in the worst possible way.~ 
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 40e
SAY ~(Frowns.) Since thou asked, I assumed it mattered to thee.~
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 41e
SAY ~If that is thy wish....~
IF ~~ THEN GOTO 28e
END

IF ~~ THEN BEGIN 42e
SAY ~I refuse to create other fire wraiths... and through torture the remains of my personality and control can be stripped away. I would become no better than Sarie, whom the Guina'Kiirar now control completely..~
IF ~~ THEN GOTO 28e
END
END

//********************************************************************
BEGIN ~BSK#Neht~

IF ~Global("FriendlyNeht","GLOBAL",1)
Global("1stTalk","GLOBAL",1)~ THEN BEGIN 0d
  SAY ~I sense something... other about thee, as if in part thou doth not belong to the mortal coil. If thou doth not mind, to whom dost thou claim thy parentage?~ [SK#Neh1]
++ ~You guessed correctly, but it's none of your business.~ DO ~SetGlobal("1stTalk","GLOBAL",2)~ + 1d
++ ~Gorion is my father in every way that matters. I do not know who my mother is.~ DO ~SetGlobal("1stTalk","GLOBAL",2)~ + 7d
++ ~I am a child of Bhaal, Lord of Murder, and could care less about my mother.~ DO ~SetGlobal("1stTalk","GLOBAL",2)~ + 15d
END

IF ~~ THEN BEGIN 1d
  SAY ~Indeed, there is no reason for thee to satisfy the curiosity of a wraith. If it is thy wish, I shall not bring up the subject again since it seems to pain thee.~
++ ~It doesn't bother me, I just don't want to waste my time talking about it.~ + 2d
++ ~I am constantly being asked questions about my parents and really don't want to repeat myself.~ + 5d
END

IF ~~ THEN BEGIN 2d
  SAY ~Of course, but if thou ever needs an ear to listen, or ever wishes to ask me anything... then I shall be there as much as I am able.~
++ ~It is nice of you to offer, but you are undead. The first time we talked you even admitted that you hardly feel anything any more. I don't think I'll be asking you anything anytime soon.~ + 3d
++ ~Thanks, someday I might tell you more about myself. Right now I just don't know you well enough.~ + 4d
END

IF ~~ THEN BEGIN 3d
  SAY ~Ahh... so my own words come back to haunt me. Let us continue our journey then....~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4d
  SAY ~A fair answer! Let us hope that a fair journey also awaits thee as we continue to travel together.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 5d
  SAY ~Very well, such questions about thy parentage will not be heard from me again. But allow me to say this at least.... the energy I sense from thee is old, and old things tends to be powerful... I must warn thee to take care. Such old energy doth not like to lay dormant for long....~
++ ~Your warning means nothing to me, so let us continue.~ EXIT
++ ~Thank you for the warning, but you don't need to worry about me.~ + 6d
END

IF ~~ THEN BEGIN 6d
  SAY ~I hope my worries are unnecessary. Thou art a... curiosity.~
++ ~Hope, smope. Just keep quiet!~ EXIT
++ ~Glad to be a constant source of entertainment for the undead.~ EXIT
++ ~I hope so too. It's been far too long since anyone bothered about what I felt about things.~ EXIT
END

IF ~~ THEN BEGIN 7d
  SAY ~The way thou speak makes it sound as if thou hadst a happy childhood... I am... glad.~
++ ~Why should it matter to you? I thought you weren't able to feel emotions.~ + 8d
++ ~What about your childhood?~ + 13d
END

IF ~~ THEN BEGIN 8d
  SAY ~Thou art correct, I am usually unable to feel emotions, but the more I speak with thee the more I wish to recall... It would have confused me if I was capable of that feeling.~
++ ~Yes, well... let's get going.~ EXIT
++ ~Please do not go all mushy on me.~ + 9d
++ ~Do you know why it's becoming easier to remember things by talking?~ + 12d
END

IF ~~ THEN BEGIN 9d
  SAY ~Mushy? I must have stayed too long underground... what does this word mean?~
++ ~You definitely spent too much time underground.~ + 10d
++ ~I'm certain it was around before you went underground.~ + 111d
++ ~Too much time talking to you. Let's get going.~ EXIT
++ ~A word used to describe something or someone who gets emotional.~ + 11d
END

IF ~~ THEN BEGIN 10d
SAY ~I would not be surprised if that was the case, my <PRO_LADYLORD>.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 111d
SAY ~Twas not a word I came across in... my time.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 11d
  SAY ~Ahh....~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 12d
  SAY ~I do not know. A question to ponder another day perhaps.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 13d
  SAY ~I... do not remember much of it.~
++ ~You cannot remember anything at all?~ + 14d
++ ~I don't believe it.~ + 14d
END

IF ~~ THEN BEGIN 14d
  SAY ~Now that thou mentions it... I remember one thing about my father, it had not mattered to him I was born without magic, only that he was happy to a have a Judicial Knight in the family... or was it my mother who thought thus?~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 15d
  SAY ~Aye, I recognize it now... the power that lies within thee hath Bhaal's touch. Like child, like father... more power will come unto thee. Be wary it also not lead to thy demise.~
++ ~It won't, I have a right to that power. Things are going to be different than when Bhaal had control once I gain the full extent of that power.~ + 16d
++ ~I am nothing like Bhaal. It just so happens that some of his power is mine and I will do with it what I will.~ + 16d
END

IF ~~ THEN BEGIN 16d
  SAY ~Indeed... let such strength be rightfully used....~
  IF ~~ THEN EXIT
END

CHAIN IF ~Global("AnoNehTalk","LOCALS",0)
InParty("Anomen")
See("Anomen")
!StateCheck("Anomen",STATE_SLEEPING)
!AreaType(DUNGEON)
CombatCounter(0)~ THEN BSK#NEHT nehanochain
~Anomen... how much dost becoming a knight mean to thee?~ DO ~SetGlobal("AnoNehTalk","LOCALS",1)~
== BANOMEN ~Becoming a knight means everything, it is my life's goal. Why the need to question me so, wraith?~
== BSK#NEHT ~If thou will, I would like to see how thee fares against a test I took before I became a Judicial Knight. Seeing thy eagerness to become a knight hath sparked the memory within me.~
== BANOMEN ~Go on, I know I will pass this simple test of yours.~
== BSK#NEHT ~Very well... if thy king ordered thee to kill a child, wouldst thou do it?~
== BANOMEN ~I would never agree to kill a child.~
== BSK#NEHT ~Even if, Anomen, the seers foresaw the child to be the harbinger of great evil?~
== BANOMEN ~It isn't possible for a single child to bring about this 'great evil'.~
== BSK#NEHT ~Why dost thou believe a child incapable of great evil?~
== BANOMEN ~A child cannot care for itself. It needs a guiding hand. If this hand leads the child to goodness, then no evil can come of it. This test of yours is a waste of time.~
== BSK#NEHT ~Unfortunate, for thou hath failed my simple test. Good and evil are but different ways of saying right and wrong. Neither can be defined if not by law. Laws are made by thy rulers; a true knight follows them no matter the cost. If a king's own knights do not follow his laws, then no one shall. His kingdom will fall into chaos and destruction will follow, spread by those who would take advantage of a weakened kingdom. The people who rely upon the king for protection will feel the brunt of this "great evil", all because a knight would not do his duty.~
== BANOMEN ~You have a twisted sense of honor, Sir Neh'taniel. Your test proved nothing except that your time as a wraith has blackened your thoughts. I know I am in the right.~
== BSK#NEHT ~For thy sake I hope thou art correct... what I see of the knights of this age troubles me, thou hath not the mindset to become a Judicial Knight.~
EXIT

CHAIN IF ~Global("EdwNehTalk","GLOBAL",0)
InParty("SK#NEHT")
See("SK#NEHT")
!StateCheck("SK#NEHT",STATE_SLEEPING)
!AreaType(DUNGEON)
CombatCounter(0)~ THEN BEDWIN nehedwchain
~Unless there is something which needs to be done immediately, I would rather we seek out locations of Nether Scrolls. Having such power would definitely aid me... and <CHARNAME>, in making these strolls through the lower orifice of every single monster we've come across far more worthwhile (And possibly finally rid myself of the members of this group that serve as nothing more than meat shields for the latest kobold to chew on.)~ DO ~SetGlobal("EdwNehTalk","GLOBAL",1)~
== BSK#NEHT ~Careful, mage. Nether Scrolls came from a time before thee....they were not just spoken of in frustration, but also in singed curses....Two sets of Nether Scrolls created by the greater races had been discovered....and one set lost in Myth Drannor... the second scattered across Toril. Each set of Nether Scrolls is fifty...~
== BEDWIN ~So the undead simian now wishes to prattle? (Annoying, this one.) I know of this, and your petty concerns are worthless to someone as great as I. Nether Scrolls were not meant to be used by one such as you.~
== BSK#NEHT ~Or any other besides the scrolls first creators, who are now long since dead. The Netherese gleaned a great deal from the Nether Scrolls, but even they were not able to understand all of them. Meddling with magic beyond thy ken has brought about the end of many a mage. I searched for a Nether Scroll once, and I am glad to never have found it.~
== BEDWIN ~The Nether Scrolls contain power that none but I could appreciate. (And certainly not an undead monkey) Such power awaits someone like me...like <CHARNAME> and I, and all who oppose would fall once the power of the Nether Scroll is unleashed! So spare me your syllable yappery!~
EXIT

CHAIN IF ~Global("EdwNehTalk","GLOBAL",1)
InParty("Edwin")
See("Edwin")
!StateCheck("Edwin",STATE_SLEEPING)
!AreaType(DUNGEON)
CombatCounter(0)
Gender("Edwin",FEMALE)~ THEN BSK#NEHT nehedwchain
~Who would have guessed what kind of 'Nether' the scroll thee found had referred to? Thou look... stunning... in a robe, Edwin. A pity thy nether regions will likely return to normal... eventually.~ DO ~SetGlobal("EdwNehTalk","GLOBAL",2)~
== BEDWIN ~Speak once more of my attire, and you will spend the rest of your existence as an undead frog!~
== BSK#NEHT ~Why? Doth thou need a frog prince to kiss thee to make thee feel better?~
== BEDWIN ~Another word from you (you damnable undead monkey) and we shall see how well *you* look in a robe. And I assure you, there won't be wraith friendly clothing around for you to wear when that happens!~
EXIT

CHAIN IF ~Global("NehMazTalk","GLOBAL",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("SK#Neht")
See("SK#Neht")
!StateCheck("SK#Neht",STATE_SLEEPING)~ THEN BMazzy nehmazchain
~How curious. By all rights, as an undead you are a force of negativity and evil, and should be destroyed as soon as possible to free your soul from this world, Neh'taniel.~ DO ~SetGlobal("NehMazTalk","GLOBAL",1)~
== BSK#NEHT ~Destroying me will do nothing but send me to the Hells. Staying here, on Toril, in search for a way to correct what wrongs I might have done to deserve undeath, will cause more 'good'.~
== BMAZZY ~Yet, by all accounts, you are already fallen. Less of a knight than I am.~
== BSK#NEHT ~Am I? Shall any chance of redemption be taken from me, then? What have thy prayers to Arvoreen told thee about me?~
== BMAZZY ~Nothing. She is... silent when it comes to you. If I didn't know better, it is as if Arvoreen herself is waiting for some sign before acting. This alone is what keeps me from putting an end to your undeath with a blade. For now, I will trust that <CHARNAME> made the right decision of letting you travel with <PRO_HIMHER>, though I am watching you closely.~
== BSK#NEHT ~I would expect nothing less from thee... as someone who wishes to become a full knight of thine deity.~
== BMAZZY ~In this one thing we are similar, wraith knight, but only in that.~ 
EXIT

CHAIN IF ~Global("NehMazTalk","GLOBAL",1)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("Mazzy")
See("Mazzy")
!StateCheck("Mazzy",STATE_SLEEPING)~ THEN BSK#NEHT nehmaz2chain
~Any word from thy deity yet?~ DO ~SetGlobal("NehMazTalk","GLOBAL",2)~
== BMAZZY ~No, but I do have a question for you. I sometimes wonder what it would be like to have lived in the past you were born into, Neh'taniel. Was becoming a knight easier back then?~
== BSK#NEHT ~To become a knight was nearly neigh impossible back then as well. If Amaunator's remaining followers hath not been so desperate to recruit others, I doubt I would have been accepted amongst the Judicial Knights.~
== BMAZZY ~Harsh training is something I am used to. To be everything that a knight should be, and yet to never be considered as an actual paladin by others bothers me, sometimes.~
== BSK#NEHT ~In the eyes of thy deity, thou art already a knight... and that is what matters most.~
== BMAZZY ~Indeed. Whatever others may say or think. You are... not so bad, for an undead.~ 
EXIT

CHAIN IF ~Global("NehHaeTalk","LOCALS",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("HaerDalis")
See("HaerDalis")
!StateCheck("HaerDalis",STATE_SLEEPING)~ THEN BSK#NEHT nehhaechain
~Yet again I see thee about to speak, but choose not to. Since we have traveled I have not seen thee yet contain thyself in speech.~ DO ~SetGlobal("NehHaeTalk","LOCALS",1)~
== BHAERDA ~This sparrow sings only when it is safe, not when his perch is shared with a shrike.~
== BSK#NEHT ~Thou sees me as a shrike?~
== BHAERDA ~Your song is harsh and you are known to prey upon the sparrow. All little birds must beware when a shrike is near.~
== BSK#NEHT ~I have given thee no reason to fear me, and have no reason to kill thee.~
== BHAERDA ~You will always try to mimic a sparrow's song and try to cling to what you are not. The play will end when the shrike goes into flight to decorate his tree with death. I fear the day the shrike will forget his song.~
== BSK#NEHT ~Doth not a Doomguard glorify death?~
== BHAERDA ~This sparrow knows where his flight will end and does not fear it. A sparrow fears only that the shrike will come and prolong the play.~
EXIT

CHAIN IF ~Global("NehHae2Talk","LOCALS",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("HaerDalis")
See("HaerDalis")
!StateCheck("HaerDalis",STATE_SLEEPING)~ THEN BSK#NEHT nehhae2chain
~Haer Dalis'... about thy Doomguards... wilt thou mind telling me about them?~ DO ~SetGlobal("NehHae2Talk","LOCALS",1)~
== BHAERDA ~You strike me more as a barmy Guvnor type, dear shrike. Is the Doomguard the new mask you wish to hide behind in your play?~
== BSK#NEHT ~ No, since we are such opposites, I simply wish to know my enemy more.~
== BHAERDA ~Enemies outside the stage we dance on at <CHARNAME>'s behest, perhaps. Very well, I will answer your question if you answer one mine.~
== BHAERDA ~A Doomguard believes that all the multiverse is in a state of constant decay, and that decay is... beautiful. What you had been in life, compared to what you are now brings me great joy, dear shrike, even though the danger of your roost is clear. Helping along the destruction of all is one of this sparrow's many joys.~
== BSK#NEHT ~No society would last long if they followed such beliefs.~
== BHAERDA ~No society has ever been able to defeat the decay caused by time itself, either. Now here are the new stage lines; Why do you faintly smell of Infernal?~
== BSK#NEHT ~Infernal? The last time I was admist the presence of devils and demons, I died.~
== BHAERDA ~Ah, your true feathers are showing. This scent is far more fresh. A vulture has marked you, dear shrike, and I would like to know who before we continue traveling together.~
== BSK#NEHT ~I know not who, if this is not simply one of thy jests to cause turmoil. No memory of mine remains to tell me of any devil I had spent time with.~
== BHAERDA ~You are the sort that hides behind truth, rather than lies. I believe you, shrike, but this sparrow will still keep his distance.~
EXIT

CHAIN IF ~Global("NehMinsc","LOCALS",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("SK#Neht")
See("SK#Neht")
CombatCounter(0)
!StateCheck("SK#Neht",STATE_SLEEPING)~ THEN BMinsc Neht
~You! Wraith! Boo says you smell funny.~ DO ~SetGlobal("NehMinsc","LOCALS",1)~
== BSK#NEHT ~Without a physical body, I am uncertain how I possess a scent for thy rodent to catch.~
== BMINSC ~Bah! Do not doubt his logic.~
== BSK#NEHT ~I shall... try not to.~
== BMINSC ~Good! He says that dead men always smell funny, though you'd make a good lantern as well.~
== BSK#NEHT ~Mana? Manen...? ....Nay, never mind, I do not wish to know.~
EXIT

CHAIN IF ~Global("NehMinsc2","LOCALS",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("SK#Neht")
See("SK#Neht")
CombatCounter(0)
!StateCheck("SK#Neht",STATE_SLEEPING)~ THEN BMinsc Neht
~Boo thinks you do good things for this group, dead man! There is still much evil needing a good butt kick! Demon, devils, weasels that try to eat Boo, and undead beware!~ DO ~SetGlobal("NehMinsc2","LOCALS",1)~
== BSK#NEHT ~All undead?~
== BMINSC ~All except the funny talking, dead elf kind! Boo says I need to be smacked for forgetting about you, but people keep telling me it is more a matter of being smacked too much.~
== BSK#NEHT ~ Perhaps... thou should get thy head checked, so that thee could know the truth about being hit once too many.~
== BMINSC ~No, no, no! There is no need! Though if that lisp of yours gets worse, Boo knows a good cleric.~
== BSK#NEHT ~A... noble offer, Minsc, but I must decline.~
EXIT

CHAIN IF ~Global("VicNeh4Talk","GLOBAL",0)
Global("SK#VaN","GLOBAL",1)
InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)~ THEN BSK#NEHT vicneh4chain
~Viconia... thou art doing *it* again.~ DO ~SetGlobal("VicNeh4Talk","GLOBAL",1)~
== BVICONI ~Doing what, wael? The reasoning behind your usual prattle escapes me.~
== BSK#NEHT ~By the gods, as thou oft like to remind me, I am dead! Thine eyes should not be willing to undress me so readily.~
== BVICONI ~Oh, this is delicious. The jaluk that demands I be submissive to him is blushing just from a look.~
== BSK#NEHT ~I am not–~
== BVICONI ~Compose yourself, Neh'taniel, otherwise I will be tempted to do something that will cause more than a blush on your face.~
== BSK#NEHT ~(Scowls.)~ DO ~SetGlobalTimer("SK#Vic2","GLOBAL",ONE_DAY)~
EXIT

CHAIN IF ~Global("SK#NaN","LOCALS",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("Nalia")
See("Nalia")
!StateCheck("Nalia",STATE_SLEEPING) ~ THEN BSK#NEHT nehnalchain
~I sense thy fear each time thou glances in my direction, but it seems to be not of me personally. What is it that frightens thee so?~ DO ~SetGlobal("SK#NaN","LOCALS",1)~
== BNALIA ~ I...I am sorry, Sir Neh'taniel. Your presence unnerves me, ghosts usually stay within the castle, if you get my meaning.~
== BSK#NEHT ~Such spirits stay in their castles in the hope of contacting the living, but as thou sees I have already done so.~
== BNALIA ~Yes, I have noticed that. Sir Neh'taniel, may I ask you something?~
== BSK#NEHT ~If thou wish to ask me something, then ask if it will lessen thy fear.~
== BNALIA ~No matter how much I seem to do to help my lessers, it never seems to be enough.... but here you are, someone who faces the damnation of his soul in undeath, but still manages to strive to correct what had happened to you. How do you deal with it?~
== BSK#NEHT ~A time will come when thou reaches a point when there is no choice but to accept it and strive to be who thou are. My... condition is slowly shadowing my thoughts, there is nothing that can be done but strive for a way to end it in peace.~
== BNALIA ~You mean... you have spent your entire undeath looking for a way to rest your soul? All those years... and you still kept trying? I do not think I have that kind of patience....~
== BSK#NEHT ~The only advice I can give thee is to take that which thou hast been born with to reach thy ends. Accept the inheritance of thy family and create laws of which thou perceives as better.~
== BNALIA ~How did you know...?~
== BSK#NEHT ~I also once had to make such a choice as to follow the ways of my family or not, so it is easy for me to notice the... signs. All I can tell thee is to rule as thy father ruled, set the laws that would allow thee and others a better life. ~
== BNALIA ~I... I just hope I can find the strength to do so. Do you think I could accomplish something like that, Sir Neh'taniel?~
== BSK#NEHT ~If thou hath the strength to do what thou believes is correct already, then this would be just a test of thy beliefs.~
== BNALIA ~You're... right. Thank you, Sir Neh'taniel.~
EXIT

CHAIN IF WEIGHT #-1 ~Global("SarieAttackNeht","GLOBAL",1)~ THEN BSK#Neht SarieAttack
~Sarie....~
== SK#Sar ~Hello, Lil'velkyn Chath.~
== BSK#NEHT ~(Frowns.) What art thou still here for? If thou hast helped them like I asked, then thee should be back at the city by now.~ 
== SK#SAR ~The Guina'Kiirar told me this would happen.~
== BSK#NEHT ~Sarie... what else did they tell thee to do?~
== SK#SAR ~(She tilts her head to the side, not really looking at him.)  They told me they don't need He-Who-Made-Me anymore if I am stronger.~
== BSK#NEHT ~Thou still hast much more to learn. Go back home.~
== SK#SAR ~No, they told me to try to make you go away.~
= ~Let's play a game. Your friends should be here soon, so let's see how fast they can save you.~ [female2a]
== BSK#NEHT ~Sarie! No!~ DO ~SetGlobal("SarieAttackNeht","GLOBAL",2)
JumpToPoint([1035.841])~
EXIT

APPEND PLAYER1
IF WEIGHT #-3 ~Global("NehtEnd1","GLOBAL",1)~ THEN BEGIN meff1
SAY ~(A loud voice abruptly awakens you from your sleep, and in the distance you can see the blurred form of Neh'taniel arguing with two strangers.)~
IF ~~ THEN REPLY ~(Edge closer to listen.)~ DO ~SetGlobal("NehtEnd1","GLOBAL",2)~ GOTO meff2
IF ~~ THEN REPLY ~(Go back to sleep.)~ DO ~SetGlobal("NehtEnd1","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN meff2
SAY ~(The closer you get to Neh'taniel, the more you can feel the raw power ebbing from the two strangers. One of them appears to be an old man and would have been mistaken as such if not for the faint glow surrounding him. The other is completely covered in armor with the same powerful aura surrounding him. It takes you a minute to recognize the first stranger as none other than Amaunator from the description Neh'taniel had given you, while the second stranger still remains a mystery.)~
IF ~~ THEN EXTERN ~BSK#NEHT~ meff3
END
END

CHAIN ~BSK#Neht~ meff3
~....after all this time thou offers me this?! I have been on Toril long enough to see the age I was born in turn into ashes while I remained the same! The great cities...magics...and even the laws of the very land are now dust. My homeland is now the house of demons that I could do nothing to stop! Thou comest to me now and demands that I continue to watch this decay of all that I have known and seen? To prolong this....this ‘existence'?!~
== ~SK#AMAUN~ ~....what I charge you with is the last thing you must do before you can find peace....you are my chosen and Ao has agreed. Undeath has not been able to corrupt who you are and so you have passed this part of Ao's test.~
== ~BSK#NEHT~ ~All these years....and it had been nothing but a test? Back then thou didst have the power to release me from undeath! I gave up much of what I was even when I had been alive! I had forsaken my chance to travel to the elven isle of Evermeet so that I could continue to be a Judicial Knight! I have honored thee every single day since I became a paladin, yet thou still doubted my belief in thee to test me like this?!~
== ~SK#AMAUN~ ~....if it had been my choice, my son.... I would have never tested you like this, but Ao's decisions are the laws for other gods. In the end, you would be the one to set things closer to their true neutrality and could prevent such things from happening again.~
== ~BSK#NEHT~ ~Do not try to tempt me with such strappings of power...I already know how much it would cost me....~
== ~SK#AMAUN~ ~A time will come soon when you will make your choice... hmmmm.... I fear my time... on Toril... now ends... Helm...?~
== ~SK#HELM~ ~I cannot support you here much longer, Amaunator. You have told him his last duty and time will reveal his choice.~
== ~SK#AMAUN~ ~Then... let us go....~
== ~BSK#NEHT~ ~(Neh'taniel steps toward Amaunator as if to somehow stop his leaving, but both Helm and his god fade from Toril. Finding himself suddenly alone the last of the Judicial Knights kneels on the ground. A tortured expression on his face.)~
EXIT

//***********************************************************************
BEGIN ~SK#NEHTJ~

IF ~PartyHasItem("MISC5A")
Global("Nehttrial","GLOBAL",0)~ THEN BEGIN 0a
SAY ~My <PRO_LADYLORD>....~
IF ~~ THEN DO ~SetGlobal("Nehttrial","GLOBAL",1)~ GOTO 1a
END

IF ~~ THEN BEGIN 1a
SAY ~(His shoulders sag for a moment, before he shakes his head and straightens them. Neh'taniel's voice is suddenly strong and calm, carefully neutral.)...I fear I must ask thy assistance in yet another matter.~
IF ~Global("SK#KickedOut","LOCALS",0)~ THEN REPLY ~I've already helped you once, wraith. I see no reason why I should help you again.~ GOTO 6a
IF ~~ THEN REPLY ~Which would be?~ GOTO 2a
IF ~~ THEN REPLY ~If there is anything I can do to help you out, Sir Neh'taniel, then I will.~ GOTO 3a
END

IF ~~ THEN BEGIN 2a
SAY ~It is... possible my god refuses to speak to me since there is still one more task I must do, such as ridding the land of the rift device and the Eyeless.~
IF ~~ THEN GOTO 4a
END

IF ~~ THEN BEGIN 3a
SAY ~Since my god doth not speak to me, it may be an indication that I must do something more before he does so. Perhaps to help destroy the rift device.~
IF ~~ THEN GOTO 4a

END

IF ~~ THEN BEGIN 4a
SAY ~So what say thee, my <PRO_LADYLORD>? May I continue to travel with thee to put an end to the power of the rift device and the threat of the Eyeless?~
IF ~~ THEN REPLY ~Of course you can.~ GOTO 5a
IF ~Global("SK#KickedOut","LOCALS",0)~ THEN REPLY ~I'm afraid not, Neh'taniel. You've been more of a hindrance than an actual help.~ GOTO 6a
END

IF ~~ THEN BEGIN 5a
SAY ~Then let us begin.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 6a
SAY ~I... see. If thou ever do need me, then I shall be at the graveyard. There is little I can do here on my own besides dying, I doubt I possess the strength to defeat the Eyeless single-handedly.~
IF ~~ THEN DO ~SetGlobal("SK#KickedOut","LOCALS",1)
EscapeAreaMove("AR0800",1644,1407,0) ~ EXIT
END

//death of Theshal - ghoul city under Cult of the Eyeless

IF ~Global("UndeadT","GLOBAL",1) ~ THEN BEGIN 1b
SAY ~Fighting other undead doth not trouble me, yet there is something thou must understand. There are some undead such as myself who did not choose to become what they are, and it is always a struggle to recall our former selves.~
IF ~~ DO ~SetGlobal("UndeadT","GLOBAL",2)~ GOTO 2b
END

IF ~~ THEN BEGIN 2b
SAY ~We undead may seem mindless to thee, yet we were once as much alive as thou art. Do not mock those that have tried and somewhat succeeded in regaining part of their former selves. Even if in the end thou must still destroy us.~
IF ~~ THEN EXIT
END

//Gets left behind by Amaunator in temple

IF ~AreaCheck("AR0203")
PartyHasItem("SHLD27")
Global("Nehttrial2","GLOBAL",0)~ THEN BEGIN 0c
SAY ~I have waited here for twenty years... and for nothing it seems. (Neh'taniel closes his eyes and lowers his face. Yet when he raises his face again, his green eyes shine with a darker light.) So be it, I shall find another way.~
IF ~~ THEN REPLY ~I'm not sure why you wanted to speak to Amaunator in the first place.~ DO ~SetGlobal("Nehttrial2","GLOBAL",1)~ GOTO 5c
IF ~~ THEN REPLY ~I'm sorry things haven't worked out for you.~ DO ~SetGlobal("Nehttrial2","GLOBAL",1)~ GOTO 1c
IF ~~ THEN REPLY ~In any case, I've done what I wanted to do. Nice knowing you, Neh'taniel, but I have better things to do.~ DO ~SetGlobal("Nehttrial2","GLOBAL",2)~ GOTO 13c
END

IF ~~ THEN BEGIN 1c
SAY ~I need no pity, <CHARNAME>, yet I appreciate thy concern in any case.~
IF ~~ THEN REPLY ~So what are you going to do now?~ GOTO 2c
IF ~~ THEN REPLY ~It wasn't pity at all. You are on your own now, wraith. Goodbye.~ GOTO 13c
IF ~~ THEN REPLY ~If you want, you can still travel with me.~ GOTO 3c
END

IF ~~ THEN BEGIN 2c
SAY ~I am unsure at this point.~
IF ~~ THEN REPLY ~In any case, I've done what I wanted to do. Nice knowing you, Sir Neh'taniel, but I have better things to do.~ GOTO 13c
IF ~~ THEN REPLY ~If you want, you can still travel with me. ~ GOTO 3c

END

IF ~~ THEN BEGIN 3c
SAY ~I would be honored to continue to accompany thee, <CHARNAME>, perhaps by helping thee I may also help myself.~
IF ~GlobalLT("chapter","GLOBAL",4)~ THEN REPLY ~I think you should know I'm hunting for a mage by the name of Irenicus. It could get dangerous.~ GOTO 4c
IF ~GlobalLT("chapter","GLOBAL",4)~ THEN REPLY ~I think you should know I seek to rescue a friend of mine named Imoen. It could get dangerous.~ GOTO 10cc
IF ~~ THEN REPLY ~Yes, well... let's get going.~ GOTO 11c
IF ~~ THEN REPLY ~I've changed my mind. I really can't have another tagalong with me now.~ GOTO 12c
END

IF ~~ THEN BEGIN 10cc
SAY ~All the more reason to help thee, my <PRO_LADYLORD>.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4c
SAY ~I have some experience when it comes to fighting mages, so my skills will be of good use to thee. Yet, there is also something else thou should know about me.~
IF ~~ THEN GOTO 5c
END

IF ~~ THEN BEGIN 5c
SAY ~The reason why I seek to speak to Amaunator is to end my undeath honorably, so that my soul will not be as cursed in death as it is in undeath.~
IF ~~ THEN GOTO 6c
END

IF ~~ THEN BEGIN 6c
SAY ~I fear simply destroying me will not solve matters.~
IF ~~ THEN REPLY ~You are still welcome to continue traveling with me.~ GOTO 7c
IF ~~ THEN REPLY ~Let's test that theory.~ GOTO 8c
IF ~~ THEN REPLY ~I'm not sure I can trust you now from what you've told me. Better if we go our separate ways.~ GOTO 9c
END


IF ~~ THEN BEGIN 7c
SAY ~My thanks....~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 8c
SAY ~(His eyes widen.)~
IF ~~ THEN DO ~ActionOverride("SK#Neht",Enemy())
Enemy()~ EXIT
END

IF ~~ THEN BEGIN 9c
SAY ~If thou ever needs my assistance, I can be found in the graveyard.~
IF ~~ THEN DO ~SetGlobal("SK#KickedOut","LOCALS",1)
EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

IF ~~ THEN BEGIN 10c
SAY ~(He nods.) To help thee as thou helped myself would only be just.  Yet, there is also something else thou should know about me.~
IF ~~ THEN GOTO 5c
END


IF ~~ THEN BEGIN 11c
SAY ~(The wraith salutes you with Relic.)~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 12c
SAY ~If thou ever need my assistance, I can be found in the graveyard.~
IF ~~ THEN DO ~SetGlobal("SK#KickedOut","LOCALS",1)
EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

IF ~~ THEN BEGIN 13c
SAY ~(He nods slowly.) If thou ever need my assistance, I will be at the graveyard.~
IF ~~ THEN DO ~SetGlobal("SK#KickedOut","LOCALS",1)
EscapeAreaMove("AR0800",1644,1407,0)~ EXIT
END

///Vampire Paris and Neh't talk

I_C_T VVPARIS 7 NehtVamp1
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Such petty games thou plays little one, dost thy maker know where thou art?~
== VVPARIS IF ~InParty("SK#Neht")~ THEN ~Traitor to our kind! What I do is of no concern of yours, wraith. No matter how old I sense you to be, if you plan on ruining my fun remember to mention it to my mistress.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Perhaps, if I remember thee once <CHARNAME> no longer wishes me to accompany <PRO_HIMHER>. Using thy powers other than in secret is frowned upon even in the undead havens. (Looks disgusted) Hast thou no sense? Using thy powers in the middle of the street! It matters not that it is night! Abandoning our laws will cause alarm and plummet the world into greater chaos than those who are alive could ever do. Even thou is old enough to know this!~
== VVPARIS IF ~InParty("SK#Neht")~ THEN ~Your age gives you no right to dictate to me! Fancy yourself a knight even after death do you? You smell weak to me, wraith. Is your armor the only thing that supports your backbone? Oh, but of course! You do not have one.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Sulking at being scolded continues to tell of thy own lack of control. Go back to thy mistress, and tell her of how thee nearly ruined her own games.~
END

// Anomen and Neh't drama, within a PC/Anomen romance banter

I_C_T BANOMEN 26 NehtFun
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~(He laughs softly; a chilling sound that raises goose bumps on your arms.) Thou doth have thy amusing moments, Anomen.~
== BANOMEN  IF ~InParty("SK#Neht")~ THEN ~I do not remember spitting in your direction to warrant your opinion on what <CHARNAME> and I are talking about.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Tis amusing that a squire claiming to be a champion of good brags like a drunk lost in his own fairy tale.~
== BANOMEN  IF ~InParty("SK#Neht")~ THEN ~What of your own moral standing, wraith? The only thing you can claim as champion of is death and misery.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~I have seen and done much long before thy family ever began to grow its roots. Do not try to bluff thy way to greatness, Anomen, if thou cannot understand the full concept.~
== BANOMEN  IF ~InParty("SK#Neht")~ THEN ~I wonder about your arrogance, do you really believe that a god would bother to waste time on a wraith?~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Time can destroy all hope into dust. Finding amusement in thy own blinding stupidity when thee refuse to see thy reality is something to look forward to.~
== BANOMEN  IF ~InParty("SK#Neht")~ THEN ~Bah! I shall continue this conversation again, <CHARNAME>, when we are not so rudely interrupted by one whose mind decayed so long ago.~
END

//Bodhi and Neh't

I_C_T BODHI 36 NehtVamp7
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Hast thy coven also proved... difficult for thee? I have seen vampires that claim to be thy own openly shirk the Guina'Kiirar agreement.~
== BODHI IF ~InParty("SK#Neht")~ THEN ~The Guina'Kiirar has nothing to do with the here and now. They do not dare send any of their enforcers here. *I* control all the actions of my coven, and do not need a dead Ithil'Quessir to lecture me on laws that do not apply.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~The last time I visited a  Guina'Kiirar city, four of the seven were growing restless as thou art now. A single word sent to one of them and they will seek thee out and enforce thy leash. Thou dost not remain hidden by acting so carelessly with thy coven!~
== BODHI IF ~InParty("SK#Neht")~ THEN ~<CHARNAME> sought my help since I have the power to aid <PRO_HIMHER>. Would you disrupt your leader's plans for your fool notions of undeath law, dead Ithil'Quessir?~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Thou know'st very well what will happen if a Guina'Kiirar enforcer comes to pay thee a visit! Thy own fool games will bring a more fitting end than what I could give to thee.~
END

// Neht interject into weak Amaunator

INTERJECT RIFTG03 1 AmoNeht1
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Then... what must be done, my lord god, to rid thee of it completely?~
END RIFTG03 4

INTERJECT RIFTG03 2 AmoNeht2
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Then... what must be done, my lord god, to rid thee of it completely?~
END RIFTG03 4

INTERJECT RIFTG03 3 AmoNeht3
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Then... what must be done, my lord god, to rid thee of it completely?~
END RIFTG03 4

INTERJECT RIFTG03 6 AmoNeht4
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~I have tried to make them remember thee, but to no avail. I would have reached thee sooner except I lacked the priest spells to defeat such a creature... I needed <CHARNAME>'s help....~
END RIFTG03 7

INTERJECT RIFTG03 10 AmoNeht5
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~There is still at least one other who remembers thee.~
END RIFTG03 12

INTERJECT RIFTG03 17 AmoNeht6
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~What of those that hath not abandoned thee? That still remember thy name?~
END RIFTG03 18

INTERJECT RIFTG03 24 AmoNeht7
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Yet, I am... still here, Amaunator... Hast thou not heard a single word I said? I am right in front of thee!~
END  RIFTG03 25

I_C_T2 RIFTG03 26 AmoNeht8
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Why wilt thou not say a single word to me?!~
END

//Amauna/Ghost interjects

I_C_T SHAGHO02 10 Amauna
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~It is my duty and honor to help her no matter the cost to me. I pray thee remember that, <CHARNAME>.~
END

I_C_T SHAGHO02 13 Amauna
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~It is my duty and honor to help her no matter the cost to me. I pray thee remember that, <CHARNAME>.~
END

I_C_T2 SHAGRL01 4 Nehtspeaks2
== SK#NEHTJ ~I must speak with thee, holy one, before thou go'est to the Kingdom of the Eternal Sun.~
END

I_C_T2 SHAGRL01 2 Allisnotwell
== SK#NEHTJ ~Wait! No! Illume hehtane cata imbe marda! Ata a en... cormamin niava tenna'ta elea lle au....~
= ~(He turns away from you.)~
END

//vampire interjects

INTERJECT VVTANOV 2 NehtVamp2
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~The undead of this age are... loud. I have never seen so many that exult in what they are with no care of being discovered by the living....~
END VVTANOV 6

I_C_T2 VVTANOV 3 NehtVamp5 //Neh't interjects into Tanova attacking
== SK#NEHTJ ~The hunger in her voice.... (His form dims in your sight, before regaining control of himself from his sudden lapse.)~
END

INTERJECT VVTANOV 4 NehtVamp3
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Do not run from the undead, for they are true predators... any hurried movement draws attention to thee. Once a group of undead falls into a hunting frenzy there is little I can do to help thee avoid a violent encounter.~
END VVTANOV 6

I_C_T BOANASTE 4 ValenNeht // First Arrival of Valen
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~She reeks of vampire. I would not trust her if I were thee.~
END

I_C_T SUDEMIN 2 Friend
== SUDEMIN IF ~InParty("SK#Neht")~ THEN ~Wait! That is Lil'velkyn Chath! You are allied with a monster!~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~I am no longer that, high priestess. I am free of the drow's control and wish to make amends for my past misdeeds.~
END

//First meeting Viconia

EXTEND_BOTTOM VICONI 2
IF ~Global("NehtishVic","GLOBAL",0)
InParty("SK#NEHT")~ THEN DO ~SetGlobal("NehtishVic","GLOBAL",1)~ EXTERN ~SK#NEHTJ~ MeetNV
END

APPEND SK#NEHTJ
IF ~Global("NehtishVic","GLOBAL",1)~ THEN BEGIN MeetNV
SAY ~All drow are beautiful, and this... Viconia is certainly not an exception. As long as she doth not try to kill me the rest of the way, I see no issue with her also traveling with thee.~
IF ~~ THEN DO ~SetGlobal("NehtishVic","GLOBAL",2)~ EXTERN VICONI 25
END
END

//Bodhi taunting the wraith x-many times

EXTEND_BOTTOM BODHI 1
IF ~InParty("SK#Neht")~ THEN GOTO teas
END

CHAIN IF ~Global("NehtTeas","GLOBAL",0)~ THEN BODHI teas
~Ah, but what is this? I can sense you among these others, old one. Why do you stay with these... mortal rabble my dear, dead Ithil'Quessir? I can sense your hunger for them; a need that is much akin to my own.  They fear us, dead Ithil'Quessir, just as cattle should fear the predators. Becoming attached to your food is foolish, Lil'vel–.~ DO ~SetGlobal("NehtTeas","GLOBAL",1)~
== SK#NEHTJ ~I am not... that... anymore, Bodhi, just as the name thou takest now is not real.~
== BODHI ~A shame, you used to be so much more fun.~
= ~Tell me, dead Ithil'Quessir, how many years has it been since you felt joy? How much time has passed since your god and kin abandoned you just as mine did? You welcomed your true calling once, and you were glorious.~
== SK#NEHTJ ~Those days... are dead now, and I will not lose myself into madness again.~
== BODHI ~Would it be so bad to accept what you are? You did once.~
== SK#NEHTJ ~To... accept what I am now would be to exist without despair or hopelessness, and no longer have to watch even the strongest of emotions slip through my fingers and fall into emptiness. I know of no way to stop it...~
=  ~I cannot accept what fate has given me any more than thou hast.~
== BODHI ~You know nothing about my fate, wraith. We are alike only in that we are predators.~
END BODHI 2

INTERJECT BODHI 74 NehtVamp8
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~This is... good. Ridding Amn of at least some rogues is an honorable task, though I must wonder what will happen if by doing so paves the way for whatever vile, alternate purposes Bodhi has planned. The only lawful deed out of all of this is an opportunity to remove the stealing vermin plaguing the city.~
END BODHI 77

INTERJECT BODHI2 4 NehtVamp9
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~From what I know of this vampire from old... she has a way with words, <CHARNAME>, be wary of anything she tells thee.~
END BODHI2 5

INTERJECT BODHIAMB 6 NehtVamp11
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Not if I have any say in the matter, Bodhi. We *will* meet thee again, and it shall be to cut out thy black heart!~
END BODHIAMB 7

EXTEND_BOTTOM C6BODHI 20
IF ~!Dead("SK#Neht")~ THEN EXTERN C6BODHI Bodhirantings
END

APPEND C6BODHI
IF ~~ THEN BEGIN Bodhirantings
SAY ~I see not Neh'taniel with you now, but do you think their precious queen will show him any mercy once he is discovered?! They quickly label any *elf* who is unlike them as Exiled as I am!~
IF ~~ THEN GOTO Bodhirantings2
END

IF ~~ THEN BEGIN Bodhirantings2
SAY ~How little you know! Yet you still claim some distorted view of righteousness?! Elhan would kill you simply because of whom you called ally!~
IF ~~ THEN GOTO 21
END
END

EXTEND_BOTTOM PPBODHI4 7
IF ~InParty("SK#Neht")~ THEN GOTO TauntNeht
END

CHAIN IF ~GLOBAL("TauntNeht","GLOBAL",0)~ THEN PPBODHI4 TauntNeht
~The same failing you all have, I suppose. Especially in... oh... what does your companion call himself now? "Neh'taniel"?~ DO ~SetGlobal("TauntNeht","GLOBAL",1)~
== SK#NEHTJ ~Thou know'st very well what my name is!~
== PPBODHI4 ~Yet you are known by so many... other... names, weak one. I shall take great pleasure in seeing you play fleshling with the Bhaalspawn... only to turn on <PRO_HIMHER> to feed.  Yes, this will all be fun to watch.~
END PPBODHI4 8

I_C_T BODHI 6 MightAsWell
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~As much as I detest Bodhi, I would rather we work with her than Shadow Thieves. Especially... if it would mean weakening the hold these rogues have on the city.~
== BODHI IF ~InParty("SK#Neht")~ THEN ~Why, your sentiments almost made me feel warm on the inside... Neh'taniel.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Perhaps setting thee on fire shall help thee feel warmer, since thou art having trouble with that.~
== BODHI IF ~InParty("SK#Neht")~ THEN ~Oh no, your attempts at playing with the living would be far more amusing to me, so please go on and continue to do so.~
END


//************************************************************************
// Shade Lord drama

APPEND SK#NEHTJ
IF ~AreaCheck("AR1404")
Global("DFounder","GLOBAL",1)~ THEN BEGIN DivineFind
SAY ~This... this was all once holy ground.~
++ ~(Leave him alone.)~ DO ~SetGlobal("DFounder","GLOBAL",2)~ EXIT
++ ~Why do you say that?~ + 1m
++ ~With the way all the shadows move on their own, I doubt these woods were in any way holy.~ + 2m
END

IF ~~ THEN BEGIN 1m
SAY ~As within any temple, the very... feel of it, a small part of the land... rejects my presence here, and yet... I am unsure if I can explain it well enough to thee. To someone who art still alive.~
++ ~Try to, especially if it might help warn me of anything we'll run into while here.~ + 2m
++ ~I am not an imbecile, Neh'taniel, if you can explain it I'm sure I'll understand.~ + 3m
++ ~Then say nothing at all right now, I have a feeling that the less noise we make here, the less trouble I'll have to deal with.~ + 4m
END

IF ~~ THEN BEGIN 2m
SAY ~The forest... smells... of age, <CHARNAME>. Long ago, something here was once blessed by the divine, but the remains of what was holy hath been reduced by the darkness here to where I cannot sense... what the source of that divinity was. ~
= ~Polluted by undeath.... I feel somewhat at home here, which means tis likely there are more undead in the area. The town of Imnesvale may hath hinted wolves to be the problem, but no living creature could survive here for long.~
IF ~~ THEN DO ~SetGlobal("DFounder","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 3m
SAY ~Very well.~
IF ~~ THEN GOTO 2m
END

IF ~~ THEN BEGIN 4m
SAY ~(He nods, eyeing the trees around him.)~
IF ~~ THEN DO ~SetGlobal("DFounder","GLOBAL",2)~ EXIT
END


//after talking to Anath

IF ~Global("NowayAmo","GLOBAL",1)~ THEN BEGIN NotaAmauna
SAY ~It cannot be a temple once dedicated to Amaunator.~
++ ~Since you worship Amaunator, if you say it wasn't a temple dedicated to him, then of course I'll believe you.~ + 1n
++ ~I don't think the werewolf lied, Anath does not have a reason to.~ + 2n
++ ~Maybe, I am currently finding it hard to tell of who between you is telling the truth.~ + 3n
END

IF ~~ THEN BEGIN 1n
SAY ~(He doesn't look relieved about your belief in him. If anything, he appears even more tense.)~
IF ~~ THEN DO ~SetGlobal("NowayAmo","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 2n
SAY ~Thou art correct.~
++ ~You can't have it both ways; either there isn't a temple of Amaunator and she lied, or there is one and she told the truth.~ + 4n
++ ~You are confusing me. I don't see how both of you could be telling the truth.~ + 5n
++ ~Will you please make up your mind?~ + 4n
++ ~We don't have time to stand around and debate this, Neh'taniel.~ + 6n

END

IF ~~ THEN BEGIN 3n
SAY ~Thou doth not believe me?~
++ ~I do believe you, most of the time, but I really don't think Anath lied.~ + 4n
++ ~Does it really matter? We have little time to stand around and argue. Let's go.~ + 6n
++ ~You sound more like you are trying to convince yourself that there really isn't a temple, then trying to convince me.~ + 7n
END

IF ~~ THEN BEGIN 4n
SAY ~(You hear the beginnings of anger in his voice.) I cannot bring myself to believe her. Dost thou not understand what it means for me, if she spoke truth?~
= ~I, who hath dedicated as much as my being as possible to Amaunator, could not sense the presence of one of his temples. It means I am well and truly forgotten by him! Or worse, <CHARNAME>, I am indeed shunned by him!~
= ~Yet... yet to believe a falsehood when I sense the truth is told breaks a law by my god that I hold dear. I am damned either way.~
IF ~~ THEN DO ~SetGlobal("NowayAmo","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 5n
SAY ~ I fear I am also confusing myself.~
IF ~~ THEN DO ~SetGlobal("NowayAmo","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 6n
SAY ~This... this matters a great deal to me, but by thy tone I know it doth not matter to thee, and so I shall not explain further.~
IF ~~ THEN DO ~SetGlobal("NowayAmo","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 7n
SAY ~Do I...?~
IF ~~ THEN GOTO 4n
END

//Neht sees the crystal

IF ~AreaCheck("AR1404")
Global("ActivateCrystal","AR1404",2)~ THEN BEGIN NhtSee
SAY ~(You find him staring at the crystal, though he doesn't walk towards it. His eyes are glowing faintly, and his mouth is reduced to a thin line on his face.)~
++ ~I would think seeing the crystal still work would make you happy.~ + 1mm
++ ~What's wrong now?~ + 2mm
++ ~(Ignore him.)~ DO ~SetGlobal("NehtCrystal","GLOBAL",1)~ EXIT
++ ~If you keep slowing me down, I'm going to have to leave you behind.~ + 3mm
END

IF ~~ THEN BEGIN 1mm
SAY ~I will be happy only when Amaunator's light once more completely illuminates his holy ground.~
IF ~~ THEN DO ~SetGlobal("NehtCrystal","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN 2mm
SAY ~....~
++ ~Answer me!~ + 4mm
++ ~(Leave him alone.)~ DO ~SetGlobal("NehtCrystal","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN 3mm
SAY ~Very well. If I am to be left behind for bothering thee, then I will rid my god's temple of the Shade Lord alone.~
IF ~~ THEN DO ~SetGlobal("NehtCrystal","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN 4mm
SAY ~(He finally turns to look in your direction, though you realize he isn't really looking at *you* at all.)~
IF ~~ THEN GOTO 5mm
END

IF ~~ THEN BEGIN 5mm
SAY ~I implore thee, <CHARNAME>, to help rid the Sun Lord's temple of its taint.... If not for Imnesvale's or my sake, then that for a god who has been treated ill.~
IF ~~ THEN DO ~SetGlobal("NehtCrystal","GLOBAL",1)~ EXIT
END

//after answering the questions within Shade Lord Lair

IF ~AreaCheck("AR1401")
Global("NehtStatue","GLOBAL",1)~ THEN BEGIN NehtStatue2
SAY ~Well done, <CHARNAME>.~
++ ~Thank you. The temple is full of hints in figuring out the correct answers, so it was easy.~ + 1p
++ ~Why didn't you help me? If you just told me the answers, we could have moved on faster.~ + 2p
++ ~In all the time we have traveled together, I don't recall you doing any of the rituals the statue says.~ + 3p
++ ~Thank you. Despite all the hints in the temple, giving the correct answers for the rituals was difficult for me.~ + 4p
END

IF ~~ THEN BEGIN 1p
SAY ~I am glad it was easy for thee. It hath been a long time since I heard any of the rituals spoken by others correctly.~
IF ~~ THEN DO ~SetGlobal("NehtStatue","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 2p
SAY ~It was not my test to take.~
IF ~~ THEN DO ~SetGlobal("NehtStatue","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 3p
SAY ~Those forms of the Morning, Noontide, and Dusk Rituals were meant more to gather enough faith to uphold the seal once chaining the Shade Lord. Ever since the... Time of Troubles, the faith of others is the only way to measure a god's power. My own rituals to the Sun Lord are done while thee sleep.~
IF ~~ THEN DO ~SetGlobal("NehtStatue","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN 4p
SAY ~Yet, thou hast done well despite any difficulty. I could not simply give the answers to thee, since it would be a form of... cheating thee out of learning them on thy own.~
IF ~~ THEN DO ~SetGlobal("NehtStatue","GLOBAL",2)~ EXIT
END

//death of Merella

IF ~Global("ShadeGone","GLOBAL",1)~ THEN BEGIN ShadeGone2
SAY ~'The road once walked cannot be walked again,
As the sun grows dim upon it,
Each pebble, each stone, now worn smooth by feet a thousand times over,
Will fade to memory.

Shadows may stretch along the road,
Yet do not fear the path awaiting thee,
The shadows are long only because of the glorious light at the end.
May the Sun Lord guide thee to thy final resting place.' ~
IF ~~ THEN GOTO 1q
END

IF ~~ THEN BEGIN 1q
SAY ~(He looks away from Merella's remains to the forest around him, and nods. The wraith finally turns and smiles at you.) A task done well by thee indeed, <CHARNAME>. For this alone I will be forever grateful.~
IF ~~ THEN DO ~SetGlobal("ShadeGone","GLOBAL",2)~ EXIT
END


//Oh no! Clerics!

IF ~AreaCheck("AR0900")
Global("SK#Notliked","GLOBAL",1)
InParty("SK#Neht")~ THEN BEGIN Notliked
SAY ~Sen faeg!~
IF ~~ THEN GOTO Notliked1
END

IF ~~ THEN BEGIN Notliked1
SAY ~Ai... why cannot I remember the right words in Common...? I... I apologize for my lapse. I do not recall these temples being here when I first went underground, and I fear it will mean trouble for the both of us, <CHARNAME>.~
++ ~I've never seen you be so nervous you talked funnier than usual.~ + Notliked2
++ ~Why will there be trouble?~ + Notliked3
++ ~I am certain you are just over-reacting.~ + Notliked4
++ ~There is nothing to apologize for. What troubles you?~ + Notliked5
END

IF ~~ THEN BEGIN Notliked2
SAY ~What doth thou find so odd about the way I speak? No matter... thou art distracting me from explaining something important.~
IF ~~ THEN GOTO Notliked3
END

IF ~~ THEN BEGIN Notliked3
SAY ~Clerics, or any of those who feel strongly against the undead, will attack me on sight. While I can cloud the minds of others enough so most cannot see me, clerics and paladins will still be able to sense my presence. If I continue traveling with thee, thou wilt likely be attacked as well.~
++ ~Seems a little too aggressive on their part to attack you on sight.~ + Notliked6
++ ~Killing a few clerics and paladins along the way doesn't trouble me.~ + Notliked7
++ ~I don't want to be attacked wherever there happens to be a cleric.~ + Notliked8
++ ~Have you ever clouded my mind?~ + Notliked9
END

IF ~~ THEN BEGIN Notliked4
SAY ~For thy sake I hope so.~
IF ~~ THEN GOTO Notliked3
END

IF ~~ THEN BEGIN Notliked5
SAY ~My very presence at thy side may cause a great deal of trouble for thee.~
IF ~~ THEN GOTO Notliked3
END

IF ~~ THEN BEGIN Notliked6
SAY ~I am unsure of how things are now, but a deity may ask one's followers to destroy all undead one comes across. Most clerics feel destroying undead will rid the world of negative energy, no matter if one of my kind is sentient or no.~
IF ~~ THEN GOTO Notliked8
END

IF ~~ THEN BEGIN Notliked7
SAY ~(He frowns at you.)~
IF ~~ THEN GOTO Notliked8
END

IF ~~ THEN BEGIN Notliked8
SAY ~If there comes a time when my presence becomes unbearable, then simply tell me to leave thy group and I shall. It doth not bother me if I must leave thy side for being useless.~
IF ~~ THEN DO ~SetGlobal("SK#Notliked","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN Notliked9
SAY ~No. When we first met, my goal was to gain thy attention, not to hide from it.~
IF ~~ THEN GOTO Notliked8
END

// Mazzy & Neh't drama re defacing the altar

IF ~~ THEN BEGIN SK#MazzyNo
SAY ~Such a thing cannot be allowed, <CHARNAME>. It is sacrilege.~
IF ~~ THEN GOTO SK#MazzyNo1
END

IF ~~ THEN BEGIN SK#MazzyNo1
SAY ~The Shade Lord was not destroyed only to defile Amaunator's altar in a different way.~
++ ~Making the altar a monument to Mazzy's fallen comrades is a good thing. I don't understand why you have a problem with it.~ DO ~SetGlobal("SK#MazzyNo","GLOBAL",1)~ EXTERN MAZZYJ SK#MazzyNo2
++ ~It doesn't matter what you 'allow'. If Mazzy wants to honor her comrades, then she shall.~ DO ~SetGlobal("SK#MazzyNo","GLOBAL",1)~ EXTERN MAZZYJ SK#MazzyNo2
++ ~Amaunator isn't worshiped by anyone other than you, Neh'taniel. The Sun Lord is long dead.~ GOTO SK#MazzyNo3
++ ~You are right, it is wrong to further mark an altar dedicated to a god, no matter what state it is in.~ GOTO SK#MazzyNo4
END

IF ~~ THEN BEGIN SK#MazzyNo3
SAY ~Not long ago thou stood before the avatar of Amaunator. He may not be strong as... as when the Netherese still ruled, but he is not dead. Did his light not help thee destroy the Shade Lord's shadows? It is words like thine own which reduced the Sun Lord to the state he is now in.~
IF ~~ THEN DO ~SetGlobal("SK#MazzyNo","GLOBAL",1)~ EXTERN ~MAZZYJ~ SK#MazzyNo2
END


IF ~~ THEN BEGIN SK#MazzyNo4
SAY ~My thanks. Amaunator may be weak, <CHARNAME>, but as his presence within the temple thou found me showed, he is not dead.~
IF ~~ THEN DO ~SetGlobal("SK#MazzyNo","GLOBAL",1)~ EXTERN ~MAZZYJ~ SK#MazzyNo2
END
END

//Relic speaks in temple

CHAIN IF ~Global("RelicNehto1","GLOBAL",1)
AreaCheck("AR1401")~THEN SK#NEHTJ Defiled
~The very walls reek of defilement.~ DO ~SetGlobal("RelicNehto1","GLOBAL",2)~
== SW2HOST ~Jus' needs a bloody dragon ta make dings perkier down here for ye.~
== SK#NEHTJ ~Thou thinkest so? I recall circumstances much worse than this, with far less company.~
== SW2HOST ~Aye, dere was a dragon in dat one too. Whatever ye do, ye bedder not get me stuck in a scaly arse again. While I dun got a nose, I dun want anodder of dose 'circumstances'.~ DO ~DestroySelf()~
== SK#NEHTJ ~(A faint smile crosses the wraith's features.)~
EXIT

//Spider love? - takes place in the Underdark - added a sound for the spider

CHAIN IF ~InParty("SK#Neht")
See("SK#UNAT")
Global("SpiderLove","LOCALS",0)~ THEN SK#NEHTJ SpiderLove
~Away with thee!~ DO ~SetGlobal("SpiderLove","LOCALS",1)~
== SK#UNAT ~(Emits a whistling sound.)~ [gam_23]
== SK#NEHTJ ~I have no wish to perform... spiderly mating customs.... Now away!~ [wspid02]
== SK#UNAT ~(Rubs two front legs together.)~ DO ~MoveToObjectFollow("SK#Neht")~
== SK#NEHTJ ~(Squeaks.)~ DO ~Recoil()~
EXIT

//more Shade Lord drama

CHAIN IF WEIGHT #-1 ~Global("NehtTalk","GLOBAL",0)
IsValidForPartyDialog("SK#Neht")~ THEN SHADEL Hi_There
~I sense undeath among you. How odd of you to bring one of my own kind against me.~ DO ~SetGlobal("NehtTalk","GLOBAL",1)~
== SK#NEHTJ ~I claim more kinship to the sun then to the shadow, Shade Lord.~
== SHADEL ~Then you are a follower of the one who imprisoned me, I see. You are as good as dead already.~
== SK#NEHTJ ~Enough of thy words! By all the faith that remains within me, thou shalt return to the nothingness thou sprung from!~
== SHADEL ~There is no power in your words, wraith.~
END SHADEL 6

APPEND C6ELHAN2
IF WEIGHT #-999 ~Global("ElhanFinishedSpeaking","GLOBAL",1)
See(Player1)
Global("Neht_Warn","GLOBAL",1)~ THEN BEGIN WARNING
SAY ~Another warning before you go; there are rumors of sightings of a wraith that walks around in daylight. You need not know anything more than this wraith's name: Lil'velkyn Chath.~ 
= ~For this wraith to appear and disappear much like Irenicus has, it is too much of a coincidence to not suspect that they are in league with each other. If you can find and kill Lil'velkyn Chath, and bring me proof of his death, the queen will reward you with 100,000 gold.~
IF ~~ THEN REPLY ~(Say nothing.)~ DO ~SetGlobal("Neht_Warn","GLOBAL",2)~ GOTO 2x
IF ~~ THEN REPLY ~There must be more than one wraith who walks around during the day. A wraith named Neh'taniel used to travel with me, but he seemed decent enough for an undead.~ DO ~SetGlobal("Neht_Warn","GLOBAL",2)~ GOTO 3x
IF ~~ THEN REPLY ~The only wraith I know of that walks around in the light is named Neh'taniel. If you offer the same amount of coin in killing him, then the deed is as good as done.~ DO ~SetGlobal("Neht_Warn","GLOBAL",2)~ GOTO 3x
IF ~~ THEN REPLY ~You've been completely rude to me. Even if I did know where that wraith was, I won't hunt him down for you. I'll do what I can to get the Lanthorn, but nothing else.~ DO ~SetGlobal("Neht_Warn","GLOBAL",2)~ GOTO 4x
END

IF ~~ THEN BEGIN 2x
  SAY ~Though I still do not trust you enough to explain fully why my queen wants Lil'velkyn Chath to be destroyed,  know that this wraith is a vile creature. Since you now hunt Bodhi, you might run into him. Keep my warning in mind.~
IF ~~ EXIT 
END

IF ~~ THEN BEGIN 3x
  SAY ~They are one and the same. Do not be fooled by whatever false disguise he might have shown you. He has killed many innocents and is prone to do so again. To travel with such a creature does not bode well of your judgement.  If you had not just proved you did not work for Irenicus, I would also suspect you are helping the wraith.~
  IF ~~ THEN GOTO 2x
END

IF ~~ THEN BEGIN 4x
  SAY ~Do whatever you want with my warning, but do not compromise the elves while doing so.~
IF ~~ EXIT
END
END

//Neht running into Elhan

APPEND SK#NEHTJ
IF WEIGHT #-1 ~Global("NehtE","LOCALS",1)
InParty("SK#Neht")~ THEN BEGIN 1yyy
SAY ~Bauglir! I thought thee an ally!~
IF ~~ THEN DO ~LeaveParty()
ActionOverride("SK#Neht",Enemy())
Enemy()~ EXIT
END

//Running into Ellesime

IF WEIGHT #-1 ~InParty("SK#Neht")
Global("ElleNeht","GLOBAL",1)~ THEN BEGIN UhohElle
SAY ~(With Ellesime gone, Neh'taniel fades back within sight, looking troubled over very narrowly being spotted by the queen.) We must indeed hurry.~
IF ~~ THEN DO ~SetGlobal("ElleNeht","GLOBAL",2)~ EXIT
END
END

//Ellesime interject

INTERJECT SUELLEAP 3 AlmostSpotNeht
== SUELLEAP IF ~InParty("SK#Neht")~ THEN ~Is there something behind you? I thought I saw a pair of green eyes... no, they are gone now. Jon is making me see enemies wherever I turn!~
END SUELLEAP 4

//Slayer Evilness

INTERJECT PLAYER1 0 UhohBhaal
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Easy there, <CHARNAME>. No harm will come of thee for taking a short break.~
END PLAYER1 3

INTERJECT PLAYER1 2 UhohBhaal2
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~The expression on thy face.... I am here for thee, merely tell me what must be done.~
END
++ ~(Ignore him.)~ EXTERN PLAYER1 4
++ ~Do you know of a way to control it, at least temporarily?~ EXTERN ~SK#NEHTJ~ UhohBhaal3
++ ~Help me kill Bodhi and Irenicus, that is all I want.~ EXTERN ~SK#NEHTJ~ UhohBhaal4
++ ~All I want right now is to get out of here.~ EXTERN ~SK#NEHTJ~ UhohBhaal5

APPEND SK#NEHTJ
IF ~~ THEN BEGIN UhohBhaal3
SAY ~The taint within thee is far stronger than my own undead nature. At best I may help suppress this new twist to thine own taint for a moment, for the next time, so that thou can regain control on thy own.~
IF ~~ THEN GOTO UhohBhaal6
END

IF ~~ THEN BEGIN  UhohBhaal6

SAY ~It is the best I can do for thee.~
IF ~~ THEN EXTERN PLAYER1 4
END

IF ~~ THEN BEGIN UhohBhaal4
SAY ~(He nods, his eyes glowing softer than before.)~
IF ~~ THEN EXTERN PLAYER1 4
END

IF ~~ THEN BEGIN UhohBhaal5
SAY ~For Bodhi to appear, we must be close to the exit.~
IF ~~ THEN EXTERN PLAYER1 4

END
END

//Wellyn

INTERJECT WELLYN 7 Wellyn
== SK#NEHTJ ~If only all undead simply need'st a small toy to find peace.~
END WELLYN 8

//Kangaxx

INTERJECT HLSKULL 4 KangRelic
== SW2HOST IF ~Global("RelicKang","GLOBAL",1)~ THEN ~Ye know, when undead dings dat float around try ta talk to ye, yer supposed ta run away.~ DO ~SetGlobal("RelicKang","GLOBAL",2) DestroySelf()~
END HLSKULL 5

I_C_T2 HLSKULL 8 NehtKang
== SK#NEHTJ ~There is likely a reason as to why Kangaxx rent asunder into parts in the first place, my <PRO_LADYLORD>. I would not put much worth into his weak promises of power and wealth, if I were thee.~
END

//Gaal

INTERJECT GAAL 19 NehtGaal
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~One such as he will die soon, by us or whom he calls master. That is always the end of the path he chose to walk.~
END GAAL 20

I_C_T2 GAAL 23 Die_Gaal // Added by Diana - I'm sure Neht is pissed off at the Beholder's cultists 
== SK#NEHTJ IF ~InParty("SK#NEHT")~ THEN ~Die with thy false god, priest!~
END

//Tree of Life

INTERJECT PLAYER1 33 SK#TreeofLife
== PLAYER1 IF ~InParty("SK#Neht")~ THEN ~Neh'taniel, the undead knight with a talking sword that expresses more emotion than he does. The wraith is still as tortured about finding a way to end his undeath honorably as when you first met him, yet follows you into battle without complaint. Is he willing to risk himself one more time on your behalf?~
END
++ ~This has never been your fight, Neh'taniel. I know you still want to search for a way to speak to Amaunator. There's no need to risk giving up any chance of doing so....~ EXTERN SK#NehtJ risk
++ ~Irenicus has shown time and again of being a powerful mage, perhaps even too powerful for you to risk draining energy from. You do not have to help me fight him, Neh'taniel.~ EXTERN SK#NehtJ power
++ ~Just one more magic user for you to fight and drain the energy from for me, Neh'taniel. Will you be able to do it?~ EXTERN SK#NehtJ ready

APPEND SK#NEHTJ
IF ~~ THEN BEGIN risk
SAY ~What honor would I have left, if I left thee to fight an enemy alone? It is because of thee I was able to move about Amn without having to hide my every movement. I owe thee much, and cannot leave thy side in good conscience.~
COPY_TRANS PLAYER1 33
END

IF ~~ THEN BEGIN power
SAY ~It is more of a question of what is not worth the risk for. There is no need to worry, <CHARNAME>, I have not abandoned thee in the past, and make no plans of doing so now.~
COPY_TRANS PLAYER1 33
END

IF ~~ THEN BEGIN ready
SAY ~One more mage indeed. There hath never been a mage as of yet who resisted the effects of being touched by one of my kind, and Irenicus is no different. Lead on, <CHARNAME>, and I will surely follow.~
COPY_TRANS PLAYER1 33
END
END

//Neht hates rain

APPEND SK#NEHTJ
IF ~!AreaType(DUNGEON)
InParty("SK#Neht")
Global("HateRain2","GLOBAL",2)~ THEN BEGIN RainHate
SAY ~Rain... how I hate thee.~
++ ~What's so wrong about rain?~ DO ~SetGlobal("HateRain2","GLOBAL",3)~ GOTO RH1
++ ~I didn't know you can sense weather types.~ DO ~SetGlobal("HateRain2","GLOBAL",3)~ GOTO RH2
++ ~I adore the rain.~ DO ~SetGlobal("HateRain2","GLOBAL",3)~ GOTO RH3
++ ~Aye, I hate it too.~ DO ~SetGlobal("HateRain2","GLOBAL",3)~ GOTO RH4
END

IF ~~ THEN BEGIN RH1
SAY ~As a being made partially of fire, I feel'st every droplet which passes through me. It quickly becomes... annoying!~
++ ~Calm down there, Neh'taniel, it is just rain.~ + RH5
++ ~This can't be the first time you've been rained on.~ + RH6
++ ~Everyone else is just as miserable as you are, so please be quiet.~ + RH7
++ ~Will it harm you?~ + RH8
END

IF ~~ THEN BEGIN RH2
SAY ~As any other form of undead can, <CHARNAME>. Such as a vampire who instinctively knows when the sun will rise and set. For me... it is the strength of heat and cold, with cold and water being far more harmful.~

++ ~What did you do the last time you were rained on?~ + RH9
++ ~This can't be the first time you've been rained on.~ + RH6
++ ~Everyone else is just as miserable as you are, so please be quiet.~ + RH7
++ ~How harmful?~ + RH8
END

IF ~~ THEN BEGIN RH3
SAY ~One would think the up welling of mud alone would hath bothered thee as thou walk'st.~
++ ~Comes with the territory of being an adventurer.~ + RH10
++ ~This can't be the first time you've been rained on.~ + RH6
++ ~Everyone else is just as miserable as you are, so please be quiet.~ + RH7
++ ~Is rain actually harmful to you?~ + RH8
END

IF ~~ THEN BEGIN RH4
SAY ~When I lived, I... am fairly certain it did not bother me. But now... rain is something to hate, or any another combination of water and cold.~
++ ~We could stay at an inn until the rain lets up.~ + RH11
++ ~This can't be the first time you've been rained on.~ + RH6
++ ~Everyone else is just as miserable as you are, so please be quiet.~ + RH7
++ ~You complain, but the weather doesn't seem to be actually harmful to you.~ + RH8
END

IF ~~ THEN BEGIN RH5
SAY ~Tis not simply just rain, <CHARNAME>.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN RH6
SAY ~Tis not, nor was any other time it rained since I died to ever be pleasant.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN RH7
SAY ~(The wraith snarls silently.)~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN RH8
SAY ~Nay, tis merely an extreme annoyance. My apologies... over my behavior... let us just continue on.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN RH9
SAY ~I stayed within an abandoned cottage.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN RH10
SAY ~There are some who never wanted the existence of an adventurer.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN RH11
SAY ~Truly? Nothing would please me more at the moment.~
IF ~~ THEN EXIT
END

END

//Getting on the boat 
// Saemon

INTERJECT PPSAEM 44 NehtBoat
== PPSAEM IF ~InParty("SK#Neht")~ THEN ~Proper supplies are already aboard, of course. A few magical trinkets to keep your undead companion from eating the crew. Have to keep the morale high for this voyage, after all.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Fear not, I hath no inclinations to feed on thy crew. Draining the energy from wands shall be... enough.~
== PPSAEM IF ~InParty("SK#Neht")~ THEN ~I'd rather you stay below decks, as well. Just so my crew wouldn't have to worry about a change in inclinations.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Below decks is... fine. Tis less likely I will not be splashed by water this way....~
END PPSAEM 45

I_C_T2 PPSAEM 4 NehtBoat2
== PPSAEM IF ~InParty("SK#Neht")~ THEN ~Proper supplies are already aboard, of course. A few magical trinkets to keep your undead companion from eating the crew. Have to keep the morale high for this voyage, after all.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Fear not, I hath no inclinations to feed on thy crew. Draining the energy from wands shall be... enough.~
== PPSAEM IF ~InParty("SK#Neht")~ THEN ~I'd rather you stay below decks, as well. Just so my crew wouldn't have to worry about a change in inclinations.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Below decks is... fine. Tis less likely I will not be splashed by water this way....~
== PPBODHI3 IF ~InParty("SK#Neht")~ THEN ~There is plenty we can do below decks, wraith, try not to look so glum about being in my company.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~(Sighs.)~
END

//Getting off the boat

I_C_T PPSAEM 14 OffBoatB
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~No more... water.... Never shall I travel by boat again. By the gods, if I had been splashed just one more time...I... I would have....~
== PPSAEM IF ~InParty("SK#Neht")~ THEN ~Nearly set the entire ship on fire? Well, you almost did, and I'll need compensation for the damage you did do at a later time.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Of course... simply... give me a moment away from all of that... *water*.~
END

I_C_T PPSAEM 53 OffBoatR
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~No more... water.... Never shall I travel by boat again. By the gods, if I had been splashed just one more time...I... I would have....~
== PPSAEM IF ~InParty("SK#Neht")~ THEN ~Nearly set the entire ship on fire? Well, you almost did, and I'll need compensation for the damage you did do at a later time.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Of course... simply... give me a moment away from all of that... *water*. Twas all a most... unpleasant experience....~
END

//on a ship again?!

INTERJECT PPSAEM2 19 OnAgainish
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Taking the portal seems far less treacherous to me than the words of one who hath betrayed thee once already.~
END
++ ~Your advice has nothing to do with your distaste about water, then?~ EXTERN ~SK#NEHTJ~ OnAgain1
++ ~Why don't you think the portal is trapped?~ EXTERN ~SK#NEHTJ~ OnAgain2
++ ~I don't trust him either, but taking the portal seems like a bad idea.~ EXTERN ~SK#NEHTJ~ OnAgain3

APPEND SK#NEHTJ
IF ~~ THEN BEGIN OnAgain1
SAY ~(Sighs.) May Amaunator help me... but it does.~
IF ~~ THEN EXTERN PPSAEM2 20
END

IF ~~ THEN BEGIN OnAgain2
SAY ~Irenicus left in a... hurry. He would not have time to trap the portal.~
IF ~~ THEN EXTERN PPSAEM2 20
END

IF ~~ THEN BEGIN OnAgain3
SAY ~Whatever thy choice, I shall... follow it. Another trip across the sea, or no.~
IF ~~ THEN EXTERN PPSAEM2 20
END
END

//Sinking boat

INTERJECT PPSAEM3 51 Fishmen
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~As long as the boat doth not sink the rest of the way... without any land in sight... nor any way to escape this vessel.... Ai, rhach pan lim adanath!~
END PPSAEM3 52

//finding oneself underwater interjects

INTERJECT SAHKNG01 8 KingFish
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Help to these... giant talking fish is more likely along the lines of becoming food.~

END SAHKNG01 12

INTERJECT SAHKNG01 9 KingFish1
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~I am... tempted to see them try to eat a wraith. It is usually the other way around.~
END SAHKNG01 12

INTERJECT SAHKNG01 10 KingFish2
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Perhaps... no, whatever may be quicker in escaping this place. Being underwater.... (The wraith manages to grow even paler again.)~
END SAHKNG01 12

INTERJECT SAHKNG01 11 KingFish3
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~In this situation, where we are... trapped... so... so very far underwater, twould not be the best thing to lie.~
END SAHKNG01 12

INTERJECT SAHPR1 9 Trapped
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Trapped in a thin cage of air, and then dragged... hundreds of feet underwater doth not comes across as something... friendly to do to a fire wraith.~
END SAHPR1 10

//finding oneself underwater on rest

APPEND SK#NEHTJ
IF ~AreaCheck("AR2300")
InParty("SK#Neht")
Global("WaterCity","GLOBAL",1)~ THEN BEGIN WaterCity
SAY ~(As you prepare for yet another day, you notice how Neh'taniel is hunched down on himself, both hands wrapped around the hilt of his weapon. Very carefully not looking at his surroundings.)~
++ ~(Ignore him.)~ EXIT
++ ~You look a little ill, Neh'taniel.~ + WaterCity1
++ ~I'm still surprised that water bothers you so much~ + WaterCity2
++ ~We shouldn't be down here for much longer.~ + WaterCity3
END

IF ~~ THEN BEGIN WaterCity1
SAY ~We are nowhere near warmth, <CHARNAME>. All I can sense here is cold... and far too much moisture. Being trapped under the ocean is a very... a nightmarish experience for me. I fear if I stray too far from thy side in this place, dying the rest of the way is a likely possibility.~
IF ~~ THEN DO ~SetGlobal("WaterCity","GLOBAL",2)~ GOTO WaterCity4
END

IF ~~ THEN BEGIN WaterCity2
SAY ~I survive off of heat... and the essence of others. There is little of that here. I can only fight off all this... moisture for so long, before dissipating into nothingness. The only heat here is what lies in the bodies of thy group.~
IF ~~ THEN DO ~SetGlobal("WaterCity","GLOBAL",2)~ GOTO WaterCity4
END

IF ~~ THEN BEGIN WaterCity3
SAY ~Good... that is... very good. These fish men doth not come across as creatures I can easily feed from, since they are always drenched in water. Being here, with hundreds... thousands of miles of water of above us, is... a very trying experience.~
IF ~~ THEN DO ~SetGlobal("WaterCity","GLOBAL",2)~ GOTO WaterCity4
END

IF ~~ THEN BEGIN WaterCity4
SAY ~No temple of Amaunator, abandoned or no, is anywhere near here. Even if he listened, I doubt any of my prayers will reach him from this place.~
IF ~~ THEN EXIT
END
END

//How Irenicus got to the wraith

I_C_T2 PPIRENI2 2 WraithIreni
== PPIRENI2 IF ~InParty("SK#Neht")~ THEN ~A corrupted wand drained to make a wraith more malleable. It was so very easy to capture you all.~
END

//Bad Yoshimo!

I_C_T YOSHJ 113 BadYoshi
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~I thought thee trusted <CHARNAME>! To turn against us all like this... marks thee as the worst kind of rogue.~
END

INTERJECT YOSHIMOX 1 WraithYoshi
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Thou should'st told us about the Geas, there are ways it could hath been removed. With difficulty, but tis not impossible.~
END YOSHIMOX 2

INTERJECT_COPY_TRANS YOSHIMOX 4 WraithYoshi2
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Thou should'st told us about the Geas, there are ways it could hath been removed. With difficulty, but tis not impossible.~
END

//Relic +3 in Firkraag Lair

CHAIN IF WEIGHT #-1 ~AreaCheck("AR1203")
Global("RelicDragon","GLOBAL",1)~ THEN SW2HOST RFirk
~Fer once, I'd like ta meet a pack o' rabid squirrels at de arse-end of a dungeon, instead'a fat lizard. Dat'd be interesting.~
DO ~SetGlobal("RelicDragon","GLOBAL",2)~
== SK#NEHTJ ~Yet far more dangerous.~
== SW2HOST ~(Snort.)~ DO ~DestroySelf()~
EXIT

//In Hell

I_C_T PLAYER1 25 NehtInHell
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~I heard thy voice calling me, as we all were dying, and I knew thou were in trouble... so I... I turned back and found thee here.~
= ~Being around thee certainly seems hazardous to one's continued existence, but... being here is surely not so bad as.... Allow me a moment to think of a situation worse than the current one....~
END

//*********************************************************************
//before running into Elhan – added him casting invisibility

APPEND SK#NEHTJ
IF ~AreaCheck("AR2500")
Global("TakingCareNeht","LOCALS",1)~ THEN BEGIN NoAsking
SAY ~This is... where thou art supposed to meet Elhan?~
++ ~Aye, not very far from the entrance to the Underdark.~ + NoAsking1
++ ~Nay, we're just taking a stroll through the woods.~ + NoAsking2
++ ~I'm not sure.~ + NoAsking3
END

IF ~~ THEN BEGIN NoAsking1
SAY ~Far better for me to put in more effort in concealing my presence for now, then.~
IF ~~ THEN DO ~ApplySpell(Myself,WIZARD_IMPROVED_INVISIBILITY)~ GOTO NoAsking4
END

IF ~~ THEN BEGIN NoAsking2
SAY ~A jest on thy part, perhaps, though ill said. This part of the forest carries the... thick smell of elves.~
IF ~~ THEN GOTO NoAsking4
END

IF ~~ THEN BEGIN NoAsking3
SAY ~Tis likely, this part of the forest seems riddled with elves.~
IF ~~ THEN GOTO NoAsking4
END

IF ~~ THEN BEGIN NoAsking4
SAY ~(The wraith fades from sight, but you cannot help but think Neh'taniel is still somewhere nearby.)~
IF ~~ THEN EXIT
END
END

//Gotta fight Irenicus

INTERJECT HELLJON 5 DyingJ
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~To think I hath problems staying dead.~
END HELLJON 6

//Leaving party after Irenicus

APPEND SK#NEHTJ
IF ~Global("NehtBye","GLOBAL",1)~ THEN BEGIN ByeNeht
SAY ~Once Irenicus is defeated, I shall need to leave thy side immediately.~
++ ~But why?~ + BN1
++ ~You seem to think Irenicus will be easily defeated.~ + BN2
++ ~I'm not in the mood to talk right now.~ + BN3
++ ~I want you to stay afterwards, Neh'taniel.~ + BN4
++ ~Where are you going?~ + BN5
END

IF ~~ THEN BEGIN BN1
SAY ~Thou wilt likely be returning to Suldanesselar, and I will not risk the chance of being discovered there a second time.~
IF ~~ THEN GOTO BN5
END

IF ~~ THEN BEGIN BN2
SAY ~Through our travels I hath seen thy prowess in battle, and know that thou art more than capable. With allies at thy side, Irenicus' defeat is all but certain.~
IF ~~ THEN GOTO BN5
END

IF ~~ THEN BEGIN BN3
SAY ~Very well.~
IF ~~ THEN DO ~SetGlobal("NehtBye","GLOBAL",2)
RestParty()~ EXIT
END

IF ~~ THEN BEGIN BN4
SAY ~(Smiles.) Thy words warm me, but there are other things I must do still.~
IF ~~ THEN GOTO BN5
END

IF ~~ THEN BEGIN BN5
SAY ~I... recently learned something about myself. Something that requires me to walk a path that is no longer on Toril. I am unsure if I will be able to return.~
++ ~Does this have anything to do with those avatars visiting you several nights ago?~ GOTO BN6
++ ~Go ahead and leave, then. I doubt I'll want your help afterwards.~ GOTO BN3
+ ~Alignment(Player1,MASK_EVIL)~ + ~The best of luck to you.~ GOTO BN7
+ ~Alignment(Player1,MASK_GOOD)~ + ~The best of luck to you.~ GOTO BN77
++ ~What do you mean by that?~ GOTO BN777
END

IF ~~ THEN BEGIN BN6
SAY ~ That... I was at my weakest, back then. 'Tis no longer important.~
IF ~Gender(Player1,FEMALE)~ THEN GOTO BN8
IF ~Gender(Player1,MALE)~ THEN GOTO BN9
END

IF ~~ THEN BEGIN BN7
SAY ~My thanks, may Amaunator's light--no, I can no longer bring myself to say his name as a blessing. As we had traveled together, my actions hath shown to me the folly of trying to do 'good' in my current state.~
IF ~Gender(Player1,FEMALE)~ THEN GOTO BN8
IF ~Gender(Player1,MALE)~ THEN GOTO BN9
END

IF ~~ THEN BEGIN BN77
SAY ~My thanks, may Amaunator's light continue to guide us both along the ways of true righteousness. Thy actions hath proven to me as we traveled together the good that can still be done in this world, and what I must do to continue to do so.~
IF ~Gender(Player1,FEMALE)~ THEN GOTO BN8
IF ~Gender(Player1,MALE)~ THEN GOTO BN9
END

IF ~~ THEN BEGIN BN777
SAY ~The answers I seek and... the answer I must give, now reside in the Planes.~
IF ~Gender(Player1,FEMALE)~ THEN GOTO BN8
IF ~Gender(Player1,MALE)~ THEN GOTO BN9
END

IF ~~ THEN BEGIN BN8
SAY ~While I will be unable to help thee immediately after defeating Irenicus, know that I shall do my best to return if my assistance is needed again. I... have something for thee.~
++ ~Why are you giving me a gift?~ + BN10
++ ~Thank you.~ DO ~GiveItemCreate("SK#ROMR",Player1,0,0,0)~ GOTO BN11
++ ~No, I don't want any gift from you.~ + BN3
END

IF ~~ THEN BEGIN BN9
SAY ~While I will be unable to help thee immediately after defeating Irenicus, I shall do my best to return if thou ever need my aid again.~
IF ~~ THEN DO ~SetGlobal("NehtBye","GLOBAL",2)
RestParty()~ EXIT

END

IF ~~ THEN BEGIN BN10
SAY ~It is... for something that may hath been, that could possibly still be. This is... a duplicate of the ring I own, that I asked Cromwell to make while we were in Athkatla. Simply... something that I want thee to have, that came from me. I cannot explain better.~
++ ~A ring is too nice of a gift to accept, Neh'taniel.~ + BN3
++ ~I can't accept the ring, Neh'taniel. I'm in a relationship with someone, and I don't want anyone to get the wrong idea by accepting your gift.~ + BN3
++ ~Thank you.~ DO ~GiveItemCreate("SK#ROMR",Player1,0,0,0)~ + BN11
++ ~A gift from you is something I'll treasure and accept gladly.~ DO ~GiveItemCreate("SK#ROMR",Player1,0,0,0)~ + BN12
END

IF ~~ THEN BEGIN BN11
SAY ~(The wraith nods and disappears from your sight for the time being.)~
IF ~~ THEN DO ~SetGlobal("NehtBye","GLOBAL",2)
RestParty()~ EXIT
END

IF ~~ THEN BEGIN BN12
SAY ~Thy words honor me, my lady.(He smiles, disappearing from your sight for the time being.)~
IF ~~ THEN DO ~SetGlobal("NehtBye","GLOBAL",2)~ EXIT
END
END

//Shall I read to you?

APPEND SK#NEHTJ
IF ~Global("ReadToPC","GLOBAL",1)~ THEN BEGIN ReadingTime
SAY ~(By now, you have noticed that while the rest of the group sleeps, one member does not. Neh'taniel doesn't do much more than remove some of his armor and take out his journal. He spends the majority of the time you rest writing in it with an odd quill, until you and the rest of the group wakes up, such as presently.)~
++ ~(Leave him alone.)~ EXIT
++ ~Why do you never sleep?~ + RT1
++ ~What are you writing, there?~ + RT2
++ ~I don't think I have ever seen that quill before.~ + RT3
++ ~(Watch him.)~ + RT4
END

IF ~~ THEN BEGIN RT1
SAY ~Unlike some forms of undead... wraiths do not have the luxury of sleeping... of dreaming. If my energy ever grows low, than I merely drain the energy from... something.~
IF ~~ THEN GOTO RT5
END

IF ~~ THEN BEGIN RT2
SAY ~My thoughts and the events of the day. I have no wish to forget them... as is the case, more oft then not.~
IF ~~ THEN GOTO RT5
END

IF ~~ THEN BEGIN RT3
SAY ~A gift from... someone. As long as it is near me, it doth not run dry. Someone I knew thought it would be a great gift... though I cannot remember who....~
IF ~~ THEN GOTO RT5
END


IF ~~ THEN BEGIN RT4
SAY ~(A spill of long, black hair covers most of his face, creating at least the illusion of seclusion as he writes in his journal. Eventually he does notice your gaze, focusing the twin pinpoints of green light from his eyes onto your face.)~
IF ~~ THEN GOTO RT5
END

IF ~~ THEN BEGIN RT5

SAY ~Is it time for us to go?~
++ ~The others are not awake yet, so you have a little more time.~ + RT6
++ ~Aye, past time we get going.~ DO ~SetGlobal("ReadToPC","GLOBAL",2)~ EXIT
++ ~May I see what you are writing?~ + RT7
END

IF ~~ THEN BEGIN RT6
SAY ~(He nods.) I... usually do not have an audience when I write.... Dost thou wish to read it?~
++ ~Nay, I'll leave you alone.~ DO ~SetGlobal("ReadToPC","GLOBAL",2)~ EXIT
++ ~Aye, I want to know more about you.~ + RT8
++ ~I am interested in your journal, but I would not like to invade your privacy.~ + RT9
END

IF ~~ THEN BEGIN RT7
SAY ~Of course thou can. While I do not have the stamina to translate all of my journal for thee, an entry or two as we travel together would not be too much.~
IF ~~ THEN DO ~SetGlobal("ReadToPC","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN RT8
SAY ~It is no trouble... over the years there hath been the problem of too much privacy, rather than the lack of such. Every so often I will translate a section or two for thee.~

IF ~~ THEN DO ~SetGlobal("ReadToPC","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN RT9
SAY ~Perhaps by reading to thee, I will relearn things about myself. As we continue to travel together, I will translate an entry every so often.~
IF ~~ THEN DO ~SetGlobal("ReadToPC","GLOBAL",2)~ EXIT
END
END

//Lathander Heratic

APPEND SK#NEHTJ
IF ~Global("NehtSeeHera","LOCALS",1)~ THEN BEGIN LaHe1
SAY ~(His eyes begin to glow softly.) That man by the fountain... mayhap... he is speaking about Amaunator.~
IF ~~ THEN DO ~SetGlobal("NehtSeeHera","LOCALS",2)~ EXIT
END
END

APPEND SK#NEHTJ
IF ~Global("NehtSStatue","LOCALS",1)~ THEN BEGIN NehStatu1
SAY ~I would like to see these statues, if thou has the time to spare, <CHARNAME>.~
++ ~Any reason why you want to see the statues?~ + NS1
++ ~If your ego gets any bigger, you'll burst.~ + NS2
++ ~I don't see why we can't, I want to see them too.~ + NS3
++ ~We can't spare the time, perhaps later.~ + NS4
END

IF ~~ THEN BEGIN NS1
SAY ~It is... a first to have a statue erected of myself. While I have done my best to remain unseen in this town, I cannot help but wonder if, just maybe....~
IF ~~ THEN GOTO NS4
END

IF ~~ THEN BEGIN NS2
SAY ~This is not a matter of pride, I assure thee, but one of curiosity.~
IF ~~ THEN GOTO NS4
END

IF ~~ THEN BEGIN NS3
SAY ~In the future, when the people of this town die off, these statues may remain. A lore master might stumble across the ruins and know who we were, that we... existed. Trademeet has done us a great honor.~
IF ~~ THEN GOTO NS4
END

IF ~~ THEN BEGIN NS4
SAY ~(He shakes his head.) I have spoken too much, let us carry on.~
IF ~~ THEN DO ~SetGlobal("NehtSStatue","LOCALS",2)~ EXIT
END
END



//Innkeeper at Imnesvale

INTERJECT UHINN01 16 UmarWitch
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~He reeks of lies.~
== UHINN01 IF ~InParty("SK#Neht")~ THEN ~W-what?! W-who said that?!~
== UHINN02 IF ~InParty("SK#Neht")~ THEN ~Ha! Didna hear a thing other than ye blowin' yer own horn. Ye shoulda seen yerself jump just now, Vince! Bet ye jus' scared yerself.~
== UHINN01 IF ~InParty("SK#Neht")~ THEN ~I heard a voice, an' twasn't me own! Stop yer laughin'! Tis the last time I'm gunna warn ye ta keep quiet, ye stupid boy.~
END UHINN01 17 

//Daar in Imnesvale

I_C_T JUGDAR01 8 DaarNeht
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Long ago, I was once akin to Daar, though the woman I cared for wanted nothing to do with me. If thou truly wish'st to help him, first learn if his lady truly returns his feelings.~
END

I_C_T2 JUGDAR01 11 DaarNeht1
== SK#NEHTJ ~At least now one love story shall have a happy ending.~
END

I_C_T2 JUGDAR01 15 DaarNeht2
== SK#NEHTJ ~At least now one love story shall have a happy ending.~
END

//Mook

INTERJECT MOOK 15 WarnMook
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Away from him, Mook! He is a vampire!~
END

//Sassar

INTERJECT SASSAR 8 SassWarn
== SASSAR IF ~!InParty("SK#Neht")~ THEN ~Besides smaller beholders, there is a ghost that kills anyone trying to take the artifact. I fear the spirit has set up some kind of trap that requires sight in order to escape from, and no doubt that is why Gaal picked you to travel in the lower depths.~
END SASSAR 9

// Cernd

I_C_T2 CERND 0 NegaCerd
== CERND IF ~InParty("SK#Neht")~ THEN ~How strange, I sense a force of negative energy near you, but see nothing, which tells me that you claim friendship with far more nefarious beings than merchants.~
END

//Skinner

I_C_T2 TRSKIN03 1 DeadSense
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~One of my kind, if better at hiding than I am, is near. 'Tis better if thou do not agree so easily with this fleshling's desires.~
END

I_C_T2 TRSKIN03 4 DeadSense2
== TRSKIN03 IF ~InParty("SK#Neht")~ THEN ~I was warned beforehand about the wraith you travel with, and your life as well as his treachery against his own kind ends here!~
END

I_C_T2 TRSKIN03 7 DeadSense4
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Even with that man dead, I still sense a force of undead nearby. I... am sorry, <CHARNAME>, for being unable to locate its very location. It knows that I am here, which makes it the better at hiding from me.~
END

I_C_T2 TRSKIN03 10 DeadSense1
== TRSKIN03 IF ~InParty("SK#Neht")~ THEN ~I was warned beforehand about the wraith you travel with, and your life as well as his treachery against his own kind ends here!~
END

I_C_T2 TRSKIN03 12 DeadSense3
== TRSKIN03 IF ~InParty("SK#Neht")~ THEN ~I was warned beforehand about the wraith you travel with, and your life as well as his treachery against his own kind ends here!~
END

//Faldorn

I_C_T2 CEFALDOR 2 DruidHate
== CEFALDOR IF ~InParty("SK#Neht")~ THEN ~You reek of undeath, and such unholy power will not work against me, here.~
END

//Diseased One

INTERJECT RIFTM01 0 RiftNeht
== RIFTM01 IF ~InParty("SK#Neht")~ THEN ~Oh, its you again, Neh'taniel. If you are so bored to feel the need to talk to me, there should be a beholder wandering around somewhere for you to kill.~
== SK#NEHTJ ~I have already given up trying to have a decent conversation with thee a long time ago, Diseased One.~
== RIFTM01 ~As if that friend of yours, Viduan, wasn't enough to be pestered by. Not that it did anyone any good.~
== SK#NEHTJ ~There is... another who wishes to speak with thee.~
== RIFTM01 ~Is that so? I suppose I should get to repeating the usual tedious announcement about myself.~
END RIFTM01 6

//Adalon

I_C_T2 UDSILVER 9 ADragon
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~In thy company,<CHARNAME>, we seem to be constantly running into the scaled kind. How many doth it make, now? Surely this cannot be healthy....~
END

INTERJECT UDSILVER 53 SpiderNeht
== UDSILVER IF ~InParty("SK#Neht")~ THEN ~Masking the undead required a different kind of illusion, but wraith spiders are often seen and admired by the drow you will be dealing with.~
= ~It will raise less questions than a drow wraith moving about openly.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~My thanks....~
END UDSILVER 35

//Ellesime: Where did the wraith go?

INTERJECT SUELLE2 4 ByeNeht2
== SUELLE2 IF ~Global("NehtBye","GLOBAL",2)~ THEN ~A pity you could not have also dealt with Lil'velkyn Chath, since several of my men reported sightings of him in the city. Though, this problem is more a matter for us, then for someone who has already risked much.~
END SUELLE2 5

INTERJECT SUELLE2 7 ByeNeht2
== SUELLE2 IF ~Global("NehtBye","GLOBAL",2)~ THEN ~A pity you could not have also dealt with Lil'velkyn Chath, since several of my men reported sightings of him in the city. Though, this problem is more a matter for us, then for someone who has already risked much.~
END SUELLE2 8

//handmaiden of lolth

I_C_T UDDROW35 1 blessed
== UDDROW35 IF ~InParty("SK#Neht")~ THEN ~May you continue to be blessed with the presence of Lolth's holy creature!~
END

I_C_T UDDROW35 0 blessed2
== UDDROW35 IF ~InParty("SK#Neht")~ THEN ~Do not think so highly of yourself simply because one of Lolth's holy creatures is with you!~
END

INTERJECT UDIMRAE 2 blessed3
== UDIMRAE IF ~InParty("SK#Neht")~ THEN ~You may currently walk with a blessing of Lolth beside you, but the Spider Queen is known to have her children feed on the unworthy without warning.~
= ~A spider at your side means nothing more than that you are favored... at the moment.~
END UDIMRAE 3

INTERJECT DADROW17 0 bleed4
== DADROW17 IF ~InParty("SK#Neht")~ THEN ~Fail me in this task, and the holy spider at your side will feed on your flesh next!~
END DADROW17 1

//Sola notices the spider

I_C_T UDSOLA01 1 bleed5
== UDSOLA01 IF ~InParty("SK#Neht")~ THEN ~Many may see you as blessed by one of Lolth's creatures, but it does not change that you are a foreigner.~
END

I_C_T UDSOLA01 18 bleed6
== UDSOLA01 IF ~InParty("SK#Neht")~ THEN ~It is becoming apparent to me of just why a spider follows <PRO_HIMHER> around so much. Veldrin makes so many mistakes <PRO_HESHE> is likely to become its next snack.~
END

I_C_T UDSOLA01 30 bleed7
== UDSOLA01 IF ~InParty("SK#Neht")~ THEN ~Perhaps, if your spider manages to not wander off, Lolth will favor the recovery of the eldest daughter as well.~
END

I_C_T UDSOLA01 129 bleed8
== UDSOLA01 IF ~InParty("SK#Neht")~ THEN ~Your spider is an odd one, Veldrin, in that I sense no evil from it. If I did, I would be more fearful in speaking to you thus.~
END

//Neht doesn't like working for the Shadow Thieves

INTERJECT GAELAN 53 NoST
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~The Shadowmaster? Thou expect me to work with thieves?! I... cannot agree to this, <CHARNAME>. Helping thee rescue thy friend is one thing, but lowering ourselves to work with those who think nothing of breaking the law to be quite another.~
== GAELAN IF ~InParty("SK#Neht")~ THEN  ~Do ye really believe some upright 'n noble lout is going to help <CHARNAME> when yer type is traveling with <PRO_HIMHER>?~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~There is much difference between a wrong forced onto a being, and a being who chooses to do wrong. I foresee no good in accepting help from thieves!~
END
+ ~Class(Player1,THIEF_ALL)~ + ~Then what about me? I've been known to dabble in the rogue arts as well.~ EXTERN ~SK#NEHTJ~ NoST2
++ ~As long as you travel with me, you have to follow my decisions, Neh'taniel.~ EXTERN ~SK#NEHTJ~ NoST3
++ ~Considering the lack of options I have, working with this Aran is the lesser of the two evils.~ EXTERN ~SK#NEHTJ~ NoST4

++ ~Then leave, if my methods offend you so much.~ EXTERN ~SK#NEHTJ~ NoST5
+ ~CheckStatGT(Player1,13,CHR)~ + ~Nobody is asking you to steal, Neh'taniel. Consider this an opportunity to see the inner workings of an enemy.~ EXTERN ~SK#NEHTJ~ NoST6
+ ~!CheckStatGT(Player1,13,CHR)~ + ~Nobody is asking you to steal, Neh'taniel. Consider this an opportunity to see the inner workings of an enemy.~ EXTERN ~SK#NEHTJ~ NoST7

APPEND SK#NEHTJ
IF ~~ THEN BEGIN NoST2
SAY ~While I find thy ways to be petty, thou hast not done much more than cause minor annoyances to law. Joining an organization of thieves known for disrupting order within a city is... too much.~
IF ~~ THEN GOTO NoST5
END

IF ~~ THEN BEGIN NoST3
SAY ~That is true, yet even leaders make mistakes. In choosing to work with thieves, thy reasoning is faulty.~
IF ~~ THEN GOTO NoST5
END

IF ~~ THEN BEGIN NoST4
SAY ~I would trust another undead's word than I would someone who routinely breaks the law.~
IF ~~ THEN GOTO NoST5
END

IF ~~ THEN BEGIN NoST5
SAY ~My offer to help thee was genuine, but I will not do so at the cost of my own morality.~
IF ~~ THEN DO ~SetGlobal("SK#NehtJoined","LOCALS",0)
EscapeAreaMove("AR0800",1644,1407,0)~ EXTERN ~GAELAN~ 65
END

IF ~~ THEN BEGIN NoST6
SAY ~Thou hast a good point.... Very well, I will continue to help thee. Simply... do not expect me to participate in anything rogue-like.~
IF ~~ THEN EXTERN ~GAELAN~ 65
END

IF ~~ THEN BEGIN NoST7
SAY ~Thou art not exactly the most wise when it comes to making decisions, <CHARNAME>.~
IF ~~ THEN GOTO NoST5
END
END

// Jan's intro

I_C_T2 TRAX 10 UnlawfulPC
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~(Frowns.) That... could hath been handled better by thee.~
END

I_C_T2 JAN 13 UnlawfulPC2
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~He broke the law, I see no reason why thou should help him.~
END

// Aran's task to go kill Bodhi

I_C_T2 ARAN 14 KillVamp
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~To go to the graveyard with wooden stakes... thou now face something that I am of use against.~
END

//Underdark stuff

INTERJECT DADROW26 2 hungryspider
== DADROW26 IF ~InParty("SK#Neht")~ THEN ~Your own child of Lolth can partake if it wishes, though it doesn't seem particularly hungry.~
END
++ ~Spiders are always hungry, isn't that right, o' holy one?~ EXTERN ~SK#NEHTJ~ hungryspider2
++ ~My spider is currently suffering from indigestion, he tried to eat a troll earlier.~ EXTERN ~SK#NEHTJ~ hungryspider2
++ ~My spider is too fat to go around killing things. I'll come back once it loses some weight.~ EXTERN ~SK#NEHTJ~  hungryspider2

APPEND SK#NEHTJ
IF ~~ THEN BEGIN hungryspider2
SAY ~(The said spider does its best to scowl at you with a mouth full of pincers.)~ [wspid01]
IF ~~ THEN EXIT
END
END

I_C_T UDDUER01 1 DSee
== UDDUER01 IF ~InParty("SK#Neht")~ THEN ~Especially if there happens to be an influx of surfacers traveling with undead.~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~What-~
== UDDUER01 IF ~InParty("SK#Neht")~ THEN ~Well, look at that, it even knows how to speak. Patterns of heat reveal all here, fire wraith, ye'll have a harder time hiding yerself in the Underdark. But none of my business.~
END

I_C_T UDSVIR03 0 UndeadTravel2
== UDSVIR03 IF ~InParty("SK#Neht")~ THEN ~Traveling with undead as well, by the looks of it. Never thought I'd see another fire wraith in my lifetime. A bad omen, if I ever needed another one.~
END

I_C_T UDDROW16 1 Spiderbattle
== UDDROW16 IF ~InParty("SK#Neht")~ THEN ~You can even have your pet spider join in, if the holy one so wishes.~
END

EXTEND_BOTTOM UDDROW10 1
IF ~InParty("SK#Neht")~ THEN REPLY ~Just one tale then; have you ever heard of fire wraiths?~ EXTERN ~UDDROW10~ Chath
END

APPEND UDDROW10
IF ~~ THEN BEGIN Chath
SAY ~Fire wraiths? I do have some knowledge regarding them, and I suppose I can continue to sit and repeat myself just one more time, since it is such an odd request.~
IF ~~ THEN GOTO Chath2
END

IF ~~ THEN BEGIN Chath2
SAY ~They are a rare breed of undead, and captured to be trained as House pets whenever possible. They are good weapons to use against surface elves, the last I heard. The only one I personally know about managed to escape from the House which controlled it a long time ago. Back when I was rash, I suppose.~
IF ~~ THEN GOTO Chath3
END

IF ~~ THEN BEGIN Chath3
SAY ~It was called Lil'velkyn Chath, the Unseen Fire, and destroyed a great many lives before somebody freed the wraith from its House's control. I know who did the freeing, of course, but we Khalazza must keep our secrets.~
IF ~~ THEN GOTO 3
END
END

// Desharik

EXTEND_BOTTOM PPDESH 12
IF ~InParty("SK#Neht")
Global("NehtBoo","GLOBAL",0)~ THEN REPLY ~I see dead people. Really, I do! Especially ones with bad lisps. Neh'taniel, scare Desharik here by saying 'Boo!'.~ EXTERN ~SK#NEHTJ~ Boo
END

CHAIN IF ~~ THEN SK#NEHTJ Boo
~"Boo?" That is the best thou can think'st of to get us into the Asylum?!~ DO ~SetGlobal("NehtBoo","GLOBAL",1)~
== MINSCJ IF ~InParty("Minsc")~ THEN ~Boo? What about Boo?~
== PPDESH IF ~InParty("Minsc")~ THEN ~Is that man talking to a hamster?~
== SK#NEHTJ IF ~InParty("Minsc")~ THEN ~There is no need for thee to worry about Minsc. This is... actually one of his better days....~
== PPDESH ~Where is that strange voice coming from?~
== SK#NEHTJ ~I do not speak strangely! There is -nothing- wrong with my accent. Thou should know many people spoke thusly when I was alive!~
END
IF ~~ THEN REPLY ~See? I see and hear dead people with bad lisps.~ EXTERN ~PPDESH~ 18
IF ~InParty("Minsc")~ THEN REPLY ~See? Not only do disembodied voices with bad lisps follow me around, but people who talk to hamsters as well.~ EXTERN ~PPDESH~ 14
IF ~~ THEN REPLY ~Come on, Neh'taniel! Do it for the mission! Just say 'Boo' and scare him.~ EXTERN ~SK#NEHTJ~ Boo2

APPEND SK#NEHTJ
IF ~~ THEN BEGIN Boo2
SAY ~(Sighs.) Boo.~
IF ~~ THEN EXTERN ~PPDESH~ 17
END
END

//Uh oh Underdark

APPEND SK#NEHTJ
IF ~Global("UhohUnderdark","LOCALS",1)~ THEN BEGIN UDD
SAY ~This is... not good.~
++ ~That is the understatement of the year.~ + UDD1
++ ~Where are we?~ + UDD1
++ ~Besides the whole being surrounded by darkness, why is this not a good thing?~ + UDD2
++ ~Stop complaining, things could be worse.~ + UDD3
++ ~I take it you've been here before.~ + UDD4
END

IF ~~ THEN BEGIN UDD1
SAY ~The Underdark... of all the places I hath visited, this would be the last I ever wanted to return to. As surfacers, the best we could look forward to is to become slaves for the illithid or drow, if not outright killed.~
IF ~~ THEN GOTO UDD2
END

IF ~~ THEN BEGIN UDD2
SAY ~I was... kept... in the Underdark long enough to learn some of the drow language, but anything more than simple sentences is beyond me. Simply... we should seek allies as soon as possible, though keep in mind these same allies will likely turn against us.~
++ ~When were you last here?~ + UDD4
++ ~What happened to you in the Underdark?~ + UDD4
++ ~I think you are exaggerating.~ + UDD3
++ ~I'll keep your advice in mind as we move about, here.~ EXIT
END

IF ~~ THEN BEGIN UDD3
SAY ~It seems for thee, thou must learn things the hard way.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN UDD4
SAY ~This place... makes me recall painful memories I would rather forget. I apologize, <CHARNAME>, but I would rather not explain my... time in the Underdark to thee.~
IF ~~ THEN EXIT
END
END

//Jarlaxle

EXTEND_BOTTOM JARLAXLE 16
IF ~InParty("SK#Neht")~ THEN EXTERN ~JARLAXLE~ Goodslaves
END

APPEND JARLAXLE
IF ~~ THEN BEGIN Goodslaves
SAY ~I know that a Bhaalspawn and a fire wraith will sell particularly well as slaves, at the very least.~
IF ~~ THEN GOTO 17
END
END

//Tanner

EXTEND_TOP TANNER 7
IF ~InParty("SK#Neht")~ THEN EXTERN ~TANNER~ USimi
END

APPEND TANNER
IF ~~ THEN BEGIN USimi
SAY ~You disappoint me. I heard rumors that you travel with undead, and thought we'd be of likened mind. I see that is not the case.~
IF ~~ THEN GOTO 20
END
END

//In Gov Building

APPEND SK#NEHTJ
IF ~Global("GoodMemory","LOCALS",1)~ THEN BEGIN GoodMem
SAY ~This hall... and the memories it inspires; I've sorely missed this. The murmurs of nobles, magistrates, and soldiers discussing what next needs to be done in the city. Seeing scribes constantly at work writing down any new laws and contracts....~
IF ~~ THEN DO ~SetGlobal("GoodMemory","LOCALS",2)~ GOTO GM1
END

IF ~~ THEN BEGIN GM1
SAY ~In the past, I... would stand next to them, with the favor from my god in suggesting what laws would bring about the most order. Mine was the shield that protected Law, my blade the one used to enforce Order when necessary.... I was... I belonged here, and had purpose.~
IF ~~ THEN GOTO GM2
END

IF ~~ THEN BEGIN GM2
SAY ~<CHARNAME>, I knowest this to be an odd request, but would thou mind speaking to some of the people here? I cannot do so myself, without causing alarm. Or, perhaps to just the woman in armor standing in front of the stone seat, there.~
++ ~No, there are more important things we need to do.~ EXIT
++ ~Since we are already here, I don't see why I couldn't talk to the people here.~ + GM3
++ ~Randomly walking up to nobles to talk to them doesn't seem to be a smart thing to do.~ + GM4
+ ~Gender(Player1,FEMALE)~ + ~Speaking to the man at the end of the hall seems to be a better idea.~ + GM5
+ ~Gender(Player1,MALE)~ + ~Talk to the woman standing there? She is certainly one of the more attractive nobles here.~ + GM6
END

IF ~~ THEN BEGIN GM3
SAY ~(Smiles.) My thanks, <CHARNAME>.~
++ ~You're welcome.~ EXIT
++ ~Let's just get this over with.~ EXIT
++ ~Anything in mind I should ask them?~ + GM7
END

IF ~~ THEN BEGIN GM4
SAY ~(Frowns.) I can see how that... could cause problems. Since we are new to Athkatla, we cannot ask direct questions about the more... complicated inner workings. A simple test then, to see just how much the woman actually cares about the city.~
IF ~~ THEN GOTO GM7
END

IF ~~ THEN BEGIN GM5
SAY ~(He looks directly into your eyes for a moment, before slowly smirking.) There is no need for thee to worry about where my eyes may wander to.~
IF ~~ THEN GOTO GM7
END

IF ~~ THEN BEGIN GM6
SAY ~My thoughts exactly, my <LADYLORD>. I see no reason why we cannot make this as enjoyable as possible.~
IF ~~ THEN GOTO GM7
END

IF ~~ THEN BEGIN GM7
SAY ~Tell the woman thou wish to donate money to help the poor. There is no need to actually give money, I... simply wish to see her reaction.~
IF ~~ THEN EXIT
END
END


APPEND SK#NEHTJ
IF ~Global("SK#NoHelp","LOCALS",0)
Global("HeardOfSlaveLords","GLOBAL",2)~ THEN BEGIN NoHelp
SAY ~(Sighs.) Things... could have turned out better. While I understand thy desire to concentrate only on thy current problems, 'twould hath been nice to do the city some good, as well.~
IF ~~ THEN DO ~SetGlobal("SK#NoHelp","LOCALS",1)~ EXIT
END

IF ~Global("SK#NoHelp","LOCALS",0)
AreaCheck("AR1002")
Global("HeardOfSlaveLords","GLOBAL",1)~ THEN BEGIN Helpish
SAY ~To do the work of a city again... I have not been this happy in years.~
IF ~~ THEN DO ~SetGlobal("SK#NoHelp","LOCALS",1)~ EXIT
END
END

APPEND SK#NEHTJ
IF ~Global("SlumGold2","LOCALS",1)~ THEN BEGIN PCHelpsPoor
SAY ~Thy donation given to Lady Bylanna will no doubt be reflected in the poor, here. Speak with them, if thou wishest.~
IF ~~ THEN REPLY ~You don't seem to thrilled about my good deed.~ GOTO PCH1
IF ~~ THEN REPLY ~I'll go talk to the poor just to see if they actually did receive anything.~ GOTO PCH2
IF ~~ THEN REPLY ~I'm not interested in talking to the poor.~ GOTO PCH3
END

IF ~~ THEN BEGIN PCH1
SAY ~Some... good... may come of thy deed, but 'tis merely a dent in this depravity.~
IF ~~ THEN DO ~SetGlobal("SlumGold2","LOCALS",2)~ EXIT
END

IF ~~ THEN BEGIN PCH2
SAY ~(He nods and fades back out of sight.)~
IF ~~ THEN DO ~SetGlobal("SlumGold2","LOCALS",2)~ EXIT
END

IF ~~ THEN BEGIN PCH3
SAY ~Then there should hath been no desire for thee to give anything to them in the first place.~
IF ~~ THEN DO ~SetGlobal("SlumGold2","LOCALS",2)~ EXIT
END
END

//Slave lord

I_C_T HLSION 3 BadSL
== HLKETTA ~Of course, my dear. We should try not to make as much of a mess as with that guard.~
== HLSION IF ~InParty("SK#Neht")~ THEN ~We'll just get our sponsor to clean up the mess. He'll be happy with <CHARNAME> and <PRO_HISHER> pet ghost destroyed.~
END



//Spider biting drow

I_C_T2 DADROW6 1 BiteDrow1
== SK#NEHTJ ~(Hiss.)~ [wspid01]
== DADROW6 ~Ouch! It bit me! My apologies, holy one, for nearly stepping on you.~ [drmen105]
END

I_C_T2 DADROW6 2 BiteDrow2
== SK#NEHTJ ~(Hiss.)~ [wspid01]
== DADROW6 ~Ouch! It bit me! My apologies, holy one, for nearly stepping on you.~ [drmen105]
END

I_C_T2 DADROW6 5 BiteDrow3
== SK#NEHTJ ~(Hiss.)~ [wspid01]
== DADROW6 ~Ouch! It bit me! My apologies, holy one, for nearly stepping on you.~ [drmen105]
END

I_C_T2 DADROW6 6 BiteDrow4
== SK#NEHTJ ~(Hiss.)~ [wspid01]
== DADROW6 ~Ouch! It bit me! My apologies, holy one, for nearly stepping on you.~ [drmen105]
END

I_C_T2 DADROW6 7 BiteDrow5 
== DADROW6 ~Almost got away, what with that ankle bite the holy one gave me. Lolth must not have meant the chase to be easy.~
END


//Enforcer

CHAIN IF ~Global("Enforcer","LOCALS",2)~ THEN SK#NEHTJ 5ENF2
~If thou art done, here....~ DO ~SetGlobal("Enforcer","LOCALS",3)~
== SK#ENF ~How rude! But very well, I know when I am not wanted. By the way, <CHARNAME>, once you grow tired of "Neh'taniel's" presence, feel free to look me up sometime in the next millennia. Such a delicious scent....~ DO ~CreateVisualEffectObject("spsumgte","SK#ENF")
Wait(2)
DestroySelf()~ EXIT

APPEND SK#NEHTJ
IF ~Dead("SK#LICH")
!See("SK#ENF")
!See("SK#ALGOL")
AreaCheck("SK5401")
Global("Enf_Gone","LOCALS",0)~ THEN BEGIN GoneEnforcer
SAY ~Finally gone....~
++ ~So what do we do now?~ + 1GE
++ ~I want to get out of here.~ + 2GE
++ ~Tell me more about these Enforcers.~ + 3GE
++ ~You were scared of that Enforcer, weren't you?~ + 4GE
++ ~You know more about what happened here, don't you?~ + 5GE
END

IF ~~ THEN BEGIN 1GE
SAY ~Do as the Enforcer suggested; find the information we sought here, and leave. I... doubt we will be able to return here once thou art done looking.~
IF ~~ DO ~SetGlobal("Enf_Gone","LOCALS",1)~ EXIT
END

IF ~~ THEN BEGIN 2GE
SAY ~(Nods.) That is for the best, though we... should look around here for anything about the slave trade, first.~
IF ~~ DO ~SetGlobal("Enf_Gone","LOCALS",1)~ EXIT
END

IF ~~ THEN BEGIN 3GE
SAY ~They are the worst and most twisted of undead, controlled by powers even more fell. Neither of us would hath been able to stand long against him, if it came to a fight. That is all thee need to know.~
++ ~You know more about what happened here, don't you?~ + 5GE
END

IF ~~ THEN BEGIN 4GE
SAY ~Things.. could hath turned very ugly, very quickly for ourselves.~
++ ~Tell me more about these Enforcers.~ + 3GE
++ ~You know more about what happened here, don't you?~ + 5GE
END

IF ~~ THEN BEGIN 5GE
SAY ~(The wraith eyes you for a moment, before nodding.) Aeldredus made the mistake of falling in love with the living, which... is highly frowned upon. When... this attraction went too far, other... undead took him and tortured the memories of his beloved out of him.~
IF ~~ THEN GOTO 6GE
END

IF ~~ THEN BEGIN 6GE
SAY ~Aeldredus must have escaped before the memory loss was complete, only to now be found again.... We should leave this place soon, <CHARNAME>.~
IF ~~ DO ~SetGlobal("Enf_Gone","LOCALS",1)~ EXIT
END
END

//*************************************************************************
CHAIN IF WEIGHT #-99 ~InParty("SK#Neht")
!StateCheck("SK#Neht",STATE_SLEEPING)
CombatCounter(0)
!AreaType(DUNGEON)
Global("SK#VaN","GLOBAL",0)~ THEN BVICONI vicnehtchain
~Ugh, the very sight of you gives me a headache.~ DO ~SetGlobal("SK#VaN","GLOBAL",1)~
== BSK#NEHT ~I would have believed thee, Viconia, if thou did not stare so intently at regions lower than my face.~
== BVICONI ~Do not flatter yourself, jaluk. No matter if you are pleasing to the eye, the fact you are undead would revolt any drow.~
== BSK#NEHT ~Tis interesting that thou say 'would revolt any drow', but not 'all' or 'is'.~
== BVICONI ~A pathetic attempt, waela elghinyrr darhiir, to try to trap me in my own words. The very idea of you touching me is sickening.~
== BSK#NEHT ~Thy mind doth not seem to lie as easily as thy tongue. For all thy talk of the prowess of the drow, I have yet to see thee use thy tongue for other than barbed words. I am not one to trap others, but to dominate.~
== BVICONI ~You could not dominate a kul'gobuss, wael. If any will be dominating between us, it will be me. I will have you screaming for mercy once I am done with you.~
== BSK#NEHT ~We shall see, my dark lady.~
EXIT

CHAIN IF WEIGHT #-88 ~InParty("SK#Neht")
!StateCheck("SK#Neht",STATE_SLEEPING)
Global("SK#VaN2","GLOBAL",0)
Global("VicNeh4Talk","GLOBAL",1)~ THEN BVICONI vicneh2chain
~I have heard everyone's droll life story but yours, Neh'taniel. Or haven't you done much more than wallow in the dried husks of your food?~ DO ~SetGlobal("SK#VaN2","GLOBAL",1)~
== BSK#NEHT ~It would take... weeks if not months to recount my existence. If thou wish'st to hear tales, then go speak to a bard.~
== BVICONI ~I am finally able to touch a nerve despite your lack of a body. Undead are not known to shy from anything grisly, though please withhold from foaming at the mouth whenever you describe something you've eaten.~
== BSK#NEHT ~What could thee possibly want to know from a wraith? The many battles I fought? The places I visited? Or perhaps even one of the many things I hath failed to accomplish?~
== BVICONI ~If I wanted to hear any foolish tales of supposed bravery I would speak to a living knight. Have you ever lost your precious control, jaluk? That is what I want to know.~
== BSK#NEHT ~Several times... the Mori'Quessir even gave me a special name from what I hath done, but press for any details, Viconia, and it shall become twice.~
== BVICONI ~So you do have a backbone.... somewhere. But do not start sulking on me now, wraith, such looks will not endear yourself to me.~
== BSK#NEHT ~Then what would endear myself to thee, my dark lady?~
== BVICONI ~Show me more of that fire of yours, Neh'taniel, perhaps then the more fiery side of yourself could be put into good use.~
== BSK#NEHT ~I could not be any other way.~
EXIT

CHAIN IF WEIGHT #-77 ~InParty("SK#Neht")
!StateCheck("SK#Neht",STATE_SLEEPING)
CombatCounter(0)
!AreaType(DUNGEON)
Global("SK#VaN3","GLOBAL",0)
Global("VicNeh5Talk","GLOBAL",1)~ THEN BVICONI vicneh3chain
~Must you scare away every single jaluk we come across, fire wraith? I would not mind the occasional chat with another male without you glowering over my shoulder.~ DO ~SetGlobal("SK#VaN3","GLOBAL",1)~
== BSK#NEHT ~Truly, Viconia? Thee try to distract me with thy form every time I begin to speak to another female besides thyself.~
== BVICONI ~Ha! Any jalil draws your eyes, and she doesn't even have to be alive. The innocent act fools no one.~
== BSK#NEHT ~I was not aware thou had'st so much interest in whom my eyes do fall upon. Ssinssriggin ussta 'urn z'ress?~
== BVICONI ~Insolent, presumptuous har'elghinyrr jaluk! You have as much subtlety as rothe. If you were not ancient Ilythirri, I would not have given you a second glance.~
== BSK#NEHT ~Hm... so thou hath been watching, but thy harsh words are making the heat in my hands die anyway.~
== BVICONI ~As it should, jaluk. Some day I will get around to killing you, even though you are useful at times.~
== BSK#NEHT ~Doth thou now imply more quality time with thy mouth?  So tempting... tis truly too bad I am incorporeal.~
== BVICONI ~There are ways to get around that obstacle.~
EXIT

CHAIN IF ~InParty("SK#Neht")
CombatCounter(0)
Global("Collarstuff","GLOBAL",0)
Global("SK#VaN3","GLOBAL",1)
See("JAHABOAM")~ THEN VICONIJ collarspeak
~That appears to be a xukuth collar. Garish and hardly unique.~ DO ~SetGlobal("Collarstuff","GLOBAL",1)~
== DSHOP02 ~What's that? Erm, if you look closely at its metal backing and this here, it is the handle of an invisible leash. Press this and the animal gets a mild – a very mild – shock. Brings the rowdiest beast to heel.~
== VICONIJ ~I know what it is, wael. It is used to inspire....passion, in an unwilling male vith rothe. I will buy it.~
== DSHOP02 ~A-a drow collar? Uh, yes, they can also chain zif roof.... You will not regret buying this collar, miss. The collar, you see, expands or contracts to fit any size throat…er, I did say that was for dogs, miss?~
== VICONIJ ~I heard you. Come here, Neh'taniel, my vith rothe.~
== DSHOP02 ~Now see here, miss, I don't hold.... who? What?!~
== SK#NEHTJ ~If thou wishes to have a pet then put it on thy merchant, but it will not be forced onto me, my dark lady.~
== VICONIJ ~Ahh, chaining you will be pleasant indeed, my rothe. But no matter, I'll teach you the pleasures the leash can be in time. The drow are skilled when it comes to certain spells.~
== SK#NEHTJ ~Were it not those pleasures of the leash that made thee leave thy underground realm? Tis good thou hath bought thine own collar, I shall find it...useful.~
EXIT

CHAIN IF ~Global("VicNeh5Talk","GLOBAL",0)
CombatCounter(0)
!AreaType(DUNGEON)
InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("Collarstuff","GLOBAL",1)~ THEN BSK#NEHT vicneh5chain
~Beautiful....~ DO ~SetGlobal("VicNeh5Talk","GLOBAL",1)~
== BVICONI ~What is it now, jaluk?~
== BSK#NEHT ~Nothing but the view.~
== BVICONI ~(Sighs.) Is this to be yet another of your bumbling attempts at 'courting'?~
== BSK#NEHT ~Nay, now would thee step out of the way so I may see better?~
== BVICONI ~I am going to need more than a xukuth collar, but a gag as well to keep your words more respectful. (Moves aside.)~
== BSK#NEHT ~Now whom is now being presumptuous? My thanks on moving so I can gain a better view of thy profile.~
== BVICONI ~A gag made out of water to stuff down your throat would do nicely. I do believe your first 'lesson' in the proper way to treat jalil will begin once we are alone.~
== BSK#NEHT ~(Raises an eyebrow.)~
EXIT

CHAIN IF ~Global("LastVicNeht","LOCALS",0)
CombatCounter(0)
InParty("Viconia")
See("Viconia")
!StateCheck("Viconia",STATE_SLEEPING)
Global("VicNeh5Talk","GLOBAL",1)~ THEN BSK#NEHT lastofVicNeht
~Viconia-~ DO ~SetGlobal("LastVicNeht","LOCALS",1)~
== BVICONI ~Do not speak to me, wael. I already grow tired of your pathetic attempts to draw my attention.~
== BSK#NEHT ~This sudden change in thee is... odd. What have I done to–~
== BVICONI ~Have you now lost your ability to hear? You were amusing for a time, but that was all.~
== BSK#NEHT ~Man sen siniath?! I do not understand this change in thee.~
== BVICONI ~You forget your place, jaluk. Did you think I was honestly attracted to you? You, with your inability to speak any tongue properly. Or perhaps you thought I would swoon with desire over your corpse pallor and empty, sunken eyes.~
= ~No woman would willingly be with you.~
EXIT

//***************** Click ME! I say stuff! *******************************
  APPEND SK#NEHTJ
  IF ~IsGabber(Player1)
  CombatCounter(0)~ THEN BEGIN Nehtclicky
SAY ~What is thy wish?~

IF ~RandomNum(4,1)~ THEN REPLY ~How are you?~ + HU1
IF ~RandomNum(4,2)~ THEN REPLY ~How are you?~ + HU2
IF ~RandomNum(4,3)~ THEN REPLY ~How are you?~ + HU3
IF ~RandomNum(4,4)~ THEN REPLY ~How are you?~ + HU4
IF ~Global("WorkingForBodhi","GLOBAL",1)
GlobalLT("Chapter","GLOBAL",4)~ THEN REPLY ~What do you think about our new allies?~ + HU22
IF ~Global("WorkingForAran","GLOBAL",1)
GlobalLT("Chapter","GLOBAL",4)~ THEN REPLY ~What do you think about our new allies?~ + HU23
IF ~AreaCheck("AR1600")
Global("TakeSaemonRoute","GLOBAL",1)~ THEN REPLY ~What do you think about Saemon's offer?~ + HU24
IF ~AreaCheck("AR1600")
!Global("TakeSaemonRoute","GLOBAL",1)~ THEN REPLY ~Any advice on where to go in Brynnlaw?~ + HU25
IF ~AreaCheck("AR0300")~ THEN REPLY ~Any fondness for the Docks?~ + HU40
IF ~AreaCheck("AR0400")
Alignment(Player1,MASK_EVIL)~ THEN REPLY ~Look at all the poor running around, here. I bet most of them have fleas.~ + HU41
IF ~AreaCheck("AR0400")
Alignment(Player1,MASK_GOOD)~ THEN REPLY ~Look at all these poor people. I wish I could do something for them.~ + HU42
IF ~AreaCheck("AR0400")
Alignment(Player1,MASK_LCNEUTRAL)~ THEN REPLY ~These slums smell pretty badly. A pity things are like this, but every city having at least one run down area is inevitable.~ + HU43
IF ~AreaCheck("AR0410")~ THEN REPLY ~Ever run into these kind of magical machines before?~ + HU44
IF ~AreaCheck("AR0500")~ THEN REPLY ~You are looking a little paler than usual, which is really saying something.~ + HU45
IF ~OR(4)
AreaCheck("AR0404")
AreaCheck("AR0701")
AreaCheck("AR0705")
AreaCheck("AR0711")~ THEN REPLY ~Sewers are usually hiding spots for undead, but you don't look at all confortable here.~ + HU47
IF ~AreaCheck("AR0700")~ THEN REPLY ~Being around all these people without being attacked must be new for you.~ + HU46
IF ~AreaCheck("AR0800")~ THEN REPLY ~Have any 'friends' living here?~ + HU48
IF ~AreaCheck("AR0900")~ THEN REPLY ~The Temple District can't be healthy for you.~ + HU49
IF ~AreaCheck("AR1000")~ THEN REPLY ~If your eyes start glowing any brighter, somebody is bound to notice you, here.~ + HU50
IF ~AreaCheck("AR1100")~ THEN REPLY ~Being in a small village like this should be easier for you to be out in the open than a city, correct?~ + HU51
IF ~AreaCheck("AR1200")~ THEN REPLY ~Can you sense anything odd about Windspear Hills?~ + HU52
IF ~AreaCheck("AR1300")~ THEN REPLY ~I think I just saw a troll wandering around on the battlements, there.~ + HU53

IF ~AreaCheck("AR1900")~ THEN REPLY ~Not just clerics and paladins, but you have to worry about druids wanting to destroy you on sight too, right?~ + HU54
IF ~AreaCheck("AR2000")~ THEN REPLY ~Isn't it odd to build a trading town practically in the middle of nowhere?~ + HU55
IF ~AreaCheck("AR1500")~ THEN REPLY ~Any thoughts on Spellhold?~ + HU26
IF ~AreaCheck("AR1512")~ THEN REPLY ~Do you have any advice about our current situation?~ + HU27
IF ~AreaCheck("AR1516")~ THEN REPLY ~So what do you think we should do?~ + HU28
IF ~AreaCheck("AR2300")~ THEN REPLY ~Neh'taniel, are you going to be alright being surrounded by all this water?~ + HU29
IF ~AreaCheck("AR2100")~ THEN REPLY ~Happen to have any advice about the Underdark?~ + HU30
IF ~AreaCheck("AR2200")~ THEN REPLY ~Liking Ust' Natha as a spider so far?~ + HU31
IF ~GlobalGT("Chapter","GLOBAL",6)~ THEN REPLY ~Elhan and the other elves certainly seem to have something against you.~ + HU32
IF ~AreaCheck("AR2800")~ THEN REPLY ~Are you going to be alright helping me in Suldanesslar?~ + HU33
IF ~AreaCheck("AR2900")~ THEN REPLY ~Know anything about the Nine Hells?~ + HU34
IF ~~ THEN REPLY ~Do you remember how you became undead?~ + HU5
IF ~~ THEN REPLY ~Can you tell me more about Relic?~ + HU21
IF ~~ THEN REPLY ~Why did you choose to become a knight?~ + HU35
IF ~Global("Chapter","GLOBAL",2)~ THEN REPLY ~Can you tell me more about Amaunator?~ + HU6
IF ~Global("Chapter","GLOBAL",3)~ THEN REPLY ~Can you tell me more about Amaunator?~ + HU7
IF ~Global("Chapter","GLOBAL",4)~ THEN REPLY ~Can you tell me more about Amaunator?~ + HU8
IF ~Global("Chapter","GLOBAL",5)~ THEN REPLY ~Can you tell me more about Amaunator?~ + HU10
IF ~Global("Chapter","GLOBAL",6)~ THEN REPLY ~Can you tell me more about Amaunator?~ + HU12
IF ~Global("Chapter","GLOBAL",7)~ THEN REPLY ~Can you tell me more about Amaunator?~ + HU13
IF ~GlobalLT("Chapter","GLOBAL",6)~ THEN REPLY ~Can you tell me more about Viduan?~ + HU15
IF ~GlobalGT("Chapter","GLOBAL",6)~ THEN REPLY ~Can you tell me more about Viduan?~ + HU16
IF ~GlobalGT("Chapter","GLOBAL",6)~ THEN REPLY ~Can you tell me more about Sarie?~ + HU17
IF ~GlobalGT("Chapter","GLOBAL",6)~ THEN REPLY ~Can you tell me more about the Guina'Kiirar?~ + HU18
IF ~Global("StupidGhoul","GLOBAL",1)
GlobalLT("Chapter","GLOBAL",6)~ THEN REPLY ~Can you tell me more about the Guina'Kiirar?~ + HU19
IF ~Global("KaoNeht","LOCALS",2)~ THEN REPLY ~Are you sure you don't know someone named Kaoemeth?~ + HU39
IF ~~ THEN REPLY ~All the other paladins I've come across are both law abiding and rightuous, but you don't exactly fit that description.~ + HU36
IF ~Global("NoVicNeht","GLOBAL",0)
InParty("Viconia")
Gender(Player1,FEMALE)~ THEN REPLY ~I want you to stop flirting with Viconia.~ + HU37
IF ~Global("NoVicNeht","GLOBAL",0)
InParty("Viconia")
Gender(Player1,MALE)~ THEN REPLY ~I want you to stop flirting with Viconia.~ + HU38
END

IF ~~ THEN BEGIN HU1
SAY ~The urge to feed is strong while surrounded by so many of the living, but I am... managing.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU2
SAY ~As long as it doth not rain, or snow, or any other liquid form of hell keeps itself from landing on me, then I am content.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU3
SAY ~I am well, it is... nice to move about at least somewhat openly again.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU4
SAY ~Much has changed since I was last here. Every where I look, I see what was before. Like the buildings themselves possess their own ghosts that seek my attention.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU5
SAY ~I remember... someone's laughter as Amaunator's final blessing began to leave me. Seeing the towers of Ascalhorn burn and the walls about me crumble. The feeling of my skin burning.... (He turns away from you, not wanting to speak further.)~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU6
SAY ~(His eyes flare a brighter green, obviously happy about the interest.) Amaunator is an ancient Netherese god of the sun, order, law, and to a lesser extent of time itself. He is a deity of pure Law, unclouded with bias towards what is good and evil.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU7
SAY ~Thou wish to know more? Very well....  When the Netherese Empire fell, the survivors blamed Amaunator, despite Mystryl being the one in charge of magic. This... began his slow dying from neglect.~ 
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU8
SAY ~The few who still worshiped Amaunator tried to recruit as many followers as possible, even ones that before the fall of Netheril would not have made good candidates, such as... I....~
IF ~~ THEN GOTO HU9
END

IF ~~ THEN BEGIN HU9
SAY ~The Sun Priests' efforts to revive the faith... failed. There... was not enough followers of Amaunator to make him an active deity once more, and what truly faithful remained found their prayers being answered less often.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU10
SAY ~The branch of Amaunator's faithful who were monks, the Brotherhood of the Sun, chose to abandon the Sun Lord to worship Lathander instead. They... call themselves the Order of the Sun Soul, now....~
IF ~~ THEN GOTO HU11
END

IF ~~ THEN BEGIN HU11
SAY ~Before I went underground to the temple where thou found me, I heard rumors that these monks claim Lathander is the reincarnated Amaunator, though this strikes me more as them seeking a justification for their actions....~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU12
SAY ~There was... also an organization of knights known as the Syndicate of Celestial and Righteous Lawmakers, which held a smaller branch within it, called Judicial Knights. I... doth not know what happened to my brothers. They became even more lost in the passage of time than Amaunator had.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU13
SAY ~All novice followers of Amaunator were taught thus; ‘Learn the law and live it; obey its every letter and clause, for in knowledge of the intricacies of law lies freedom to act with righteous impunity. Keep track of the decisions of thy superiors so that the body of precedent continues to grow and the unity of purpose of the rulings of Amaunator is made manifest to all. Serve thy superiors faithfully, and they will reward thee faithfully; shirk thy duty and find the harsh hand of reproof.'~
IF ~~ THEN GOTO HU14
END

IF ~~ THEN BEGIN HU14
SAY ~(He turns away from you, and you get the feeling he won't tell you anymore about this subject.)~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU15
SAY ~He is a friend of mine -- the only friend I hath known both in life and undeath.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU16
SAY ~I know thee well enough now to tell thee more.... Viduan was one of the survivors of the fall of the Netherese Empire, who turned to lichdom to survive the ages. After I died, he became a member of the Guina'Kiirar, though grew bored of that position before long. His home is now a mage tower whose location is known to only a few. I could not have asked for a better friend.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU17
SAY ~When I first became undead, I had very little control of myself. I... have vague memories of attacking her home, turning her entire family into undead. Sarie... was the only survivor once the Guina'Kiirar took hold of her. I have tried my best to free her from their grasp, but with little success. She hates and fears me still, with good reason to.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU18
SAY ~This is... a subject none but those who are also undead should be aware of.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU19
SAY ~(He frowns at you, but nods after a moment.) Thou hast earned my trust. The Guina'Kiirar is... an organization of undead that rule from the ruins of a fallen Netherese city underground. Their strength is great enough to reach out to other undead to make them bend to their will. This strength comes from the Guina'Kiirar's elite force of undead called Enforcers, who deal with those that may pose a risk to them.~
IF ~~ THEN GOTO HU20
END

IF ~~ THEN BEGIN HU20
SAY ~If thou ever comes across an Enforcer, than run... and then keep running. They are undead with weapons that are as bizarre as they are powerful, with the twisted mind frame to match.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU21
SAY ~Relic's story is one even I do not know fully. He has always appeared as a weapon battered by weather, and left neglected until I found him in a storage room of an Amaunatori temple.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU22
SAY ~To have to choose between working for rogues or vampires.... Thou made the correct choice in picking the vampires. With Shadow Thieves as our enemies, there shall be a lot less rogues around to continue to corrupt Amn's laws.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU23
SAY ~To do the work of thieves... we should avoid breaking the law as much as possible. To do what they want... goes against everything I have been taught.~
IF ~~ THEN EXIT
END 

IF ~~ THEN BEGIN HU24
SAY ~Saemon hath proven to be untrustworthy, yet... I shall abide by thy choice, even though I do not agree with it. Thou art our leader, after all.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU25
SAY ~Perhaps we should speak directly to the ruler of this island to gain what we wish. I believe that is the best route before thee.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU26
SAY ~(He glances around at his surroundings uneasily.)The wards around Spellhold are thick, too thick for even someone not bound by a body to leave easily. Let us... try not to be the next permanent residents of this place.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU27
SAY ~We should leave here quickly, not simply because of Bodhi's promise to hunt us, but of thy worsening condition. I am... worried about thee.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU28
SAY ~Simply... realize that while thou can possibly recruit the inmates to help thee, there may be sound reasons for why they ended up in Spellhold in the first place. Their use to thee might be... limited.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU29
SAY ~These... walking, lizard, fish men... things that talk... I wonder how resistant they are to fire. (He goes back to glaring at all the moisture around him.)~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU30
SAY ~Treat everything here as thy potential enemy. Take no kind words from others at face value, more than likely 'tis a trap of some kind. I would also tell thee to avoid drow at all costs, but meeting them seems inevitable. Surfacers are nothing more than possible playthings or objects to be killed by the denizens here.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU31
SAY ~I apologize, <CHARNAME>, but for both our sakes I cannot... speak much here. The attention it would draw would be only the worst kind.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU32
SAY ~Many a death was caused by me, when I was controlled by the drow.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU33
SAY ~Remaining unnoticed will not be easy, but I shall be fine. It is thou and regaining thy soul that we need to focus on.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU34
SAY ~Not much. This... part of Hell seems to be of thy own creation.... Whatever hauntings in thy mind may take form here, so be careful.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU35
SAY ~At the lowest point when I was alive, I lost... the will to do anything, and saw no hope in my future. A Sun Priest of Amaunator showed me a reason, a greater goal in life not bound by the body, and I took it. Amaunator's will became my own, and I did not look back.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU36
SAY ~'All law is useful.' What is thought as 'good' and 'evil' changes for every person. Yet, when others follow the laws of their respective lands, there is peace and order. There is no higher goal to strive for than that, and so that is the path I follow. The distinction between good and evil is so slim it doth not matter. If a society manages itself well with its laws, then there is no true ‘evil' there.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU37
SAY ~Why do my words with Viconia bother thee?~
IF ~~ THEN EXTERN BVICONI NoRomNeht
END


IF ~~ THEN BEGIN HU38
SAY ~Viconia shall speak to whomever she wishes, just as I will.~
IF ~~ THEN EXTERN BVICONI NoRomNeht2
END

IF ~~ THEN BEGIN HU39
SAY ~I truly do not possess any memory of him. Kaoemeth... mentioned Viduan, I shall have to speak to my lich friend about this when next I see him.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU40
SAY ~No. The air is thick with sea water, and this may as well be the nesting grounds of thieves. I would be happy to leave here as soon as possible.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU41
SAY ~Unless Amn has a law to enforce it, tis best if thou do not give any resident here coin in front of others. That... may start a mob after thee, and will then have more to worry about then gaining fleas.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU42
SAY ~If thou wish to help them, then give thy coin to Amn's official charity service. There... should be someone in the Government District for thee to speak to.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU43

SAY ~Thou hast the right of it. As wretched these people's lives are, without them there would be no one willing to do the less... appealing work within a city.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU44
SAY ~Nay, while my... father--No, 'twas my mother--who was a mage, I was never allowed within her laboratory. The person who designed this sphere was a great mage indeed.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU45
SAY ~The smell of death is thick. Fresh death.... I can nearly hear the torturous cries of those that died here. Something happened here... that was not pleasent.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU46
SAY ~It is indeed. While invisible to them, I can... pretend, at little, that I am still alive. I.. miss being able to walk up to one of the living without inspiring fear or hatred.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU47
SAY ~I prefer... dryer places.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU48
SAY ~(He frowns at you.) Perhaps thou should wander into the crypts and find out for thyself.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU49
SAY ~In life I would have liked walking down these streets, but now such a thing would lead only to my destruction. We should leave here quickly.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU50
SAY ~This... Government District; the embodiment of a city's law resides here. A long time has passed since I was last in such a setting. Could we.. explore, <CHARNAME> ? Perhaps visit the council building.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU51
SAY ~Villages may have less people than cities, but they are ones more likely to wield pitchforks.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU52
SAY ~This place... is thick with the smell of dragon.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU53
SAY ~Trolls shall pose no problem for thee with a fire wraith at thy side.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU54
SAY ~Thou art correct. (The wraith glances around at his surroundings, grimacing.) Though druids who prefer living in swamps I find just as equally... trying on the nerves.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN HU55
SAY ~It is indeed... unless Trademeet stands between two major cities, though wild animals seem to find this place fonder than the local merchant, currently.~ 
IF ~~ THEN EXIT
END
END

CHAIN IF ~~ THEN BVICONI NoRomNeht
~Isn't it obvious, jaluk? You pay far more attention to me than you do to her, and <CHARNAME> is jealous.~ DO ~SetGlobal("NoVicNeht","GLOBAL",1)~
== BSK#NEHT ~Is... this true, <CHARNAME>? It did not occur to me thou would-~
== BVICONI ~You are blind as well as dead, Neh'taniel. A hopeless case that is better off left to her to deal with, than me.~
== BSK#NEHT ~If that is all I ever was to thee, than it is indeed best not to speak to each other further.~
== BVICONI ~Ha! If you thought you meant anything more, than you truly are a fool, waess dobluth.~
== BSK#NEHT ~(Snarls.) Elg'caress.~
EXIT

CHAIN IF ~~ THEN BVICONI NoRomNeht2
~The similarity of rothe fighting amongst themselves and you two does little to amuse me. If you wish to gain my attention, then earn it.~ DO ~SetGlobal("NoVicNeht","GLOBAL",1)~
== BSK#NEHT ~I must somehow 'earn' thy attention, now?~
== BVICONI ~Did you forget what you are? What you were, waess? Of course you must do more if you want any reaction from me besides spitting in your general direction.~
== BSK#NEHT ~(Hisses.) She is all thine, <CHARNAME>.~
EXIT

//**************************************************************************

BEGIN ~SW2HOST~
IF ~True()~ THEN BEGIN 0
  SAY ~(Neh'taniel holds out Relic so that you can speak to it. The runes on the sword glow brightly when it senses you near, the light playing across the blade in greeting.) Well met <CHARNAME>! Was dere anyding me master and I can do fer ye?~
  IF ~~ THEN REPLY ~You're certainly more cheerful ever since you've been upgraded.~ GOTO 1
  IF ~~ THEN REPLY ~Can you tell me anything more about your master's past?~ GOTO 2
  IF ~Gender(Player1,FEMALE)~ THEN REPLY ~Can you tell me more about Araniel?~ EXTERN SW2HOST 3
  IF ~~ THEN REPLY ~Do you know much about the Underdark? Any idea of what and what not to do there?~ GOTO 4
  IF ~~ THEN REPLY ~Can you give me any advice in how to kill deadly creatures?~ GOTO 5
END

IF ~~ THEN BEGIN 1
  SAY ~Noddin like gettin' banged along dem edges ta make ye aware of what's 'round ye again.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 2
  SAY ~I can't say much else about me master, <PRO_GIRLBOY>, if ye want ta know more den tis best if ye ask 'em yerself.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4
  SAY ~O' course I know 'bout de Underdark! Tis one o' de places me master and I visited way back when. What did ye want to know 'bout it?~
  IF ~~ THEN REPLY ~Tell me more about the drow.~ GOTO 4a
  IF ~~ THEN REPLY ~What are the dangers in the Underdark?~ GOTO 4b
  IF ~~ THEN REPLY ~I hear that most of the residents of the Underdark are evil. Are there any good races there?~ GOTO 4c
  IF ~~ THEN REPLY ~Which gods and goddesses watch over the Underdark?~ GOTO 4d
  IF ~~ THEN REPLY ~What kind of magic is in the Underdark?~ GOTO 4e
  IF ~~ THEN REPLY ~Not much really, better if we just move along.~ GOTO 6
END

IF ~~ THEN BEGIN 4a
  SAY ~Dem drow are sneaky liddle bastards; more of a mind ta trick ye into doing someding stupid or taking yer life if deir bored enough. De females rule o'er de males, and dey like ta use deir whips on 'em a lot too. Unless ye can dink like a drow, I'd stay away from 'em.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4b
  SAY ~What ye really should o' asked is what *isn't* dangerous in de Underdark. De place crawls wid traps and creatures who never see de sun--and wid good reason too. Even de drow don't often travel drough de Underdark alone. Yer likely ta gain de attention o' someding ye won't like.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4c
  SAY ~O' course dere is! Ye got yer svirfneblin dat like ta get friendly digging at piles o' dirt. Dem svirfneblin are a suspecious type, but if ye can win 'em over den dier a good ally ta have. Anodder race ye might run into are dem duergar, who are enemies o' de svirfneblin. While duergar are usually not as friendly as de svirfneblin, dey make de better magical stuff.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4d
  SAY ~De only Underdark deities I'm familiar wid is dose drow ones. Ye got Ghaunadaur, who rules over all dem giant goos ye come 'cross. Den there is Kiaransalee, who rules o'er undead and vengence. Selvetarm, who is Lolth's whipping boy when it comes to a baddle. Vhaeraun, who is Lolth's son and wants ta expand his reign o'er all half-drow as well. Eilistraee, who is Lolth's daughter and likes ta always dance and sing. Den o' course ye got Lolth, who likes her own eight-legged company an' who is de strongest o' de Underdark deities.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 4e
  SAY ~Underdark magic is strong, yet it's useless once ye get on de surface. If yer in de Underdark go right ahead an' use it, but don't get depended on it if ye plan on wanting ta see sunlight again.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 5
  SAY ~I never liked dem liches, dey were too spell happy if ye know what I mean. To kill dem liches ye have to get alot'o space 'tween dem and ye, let 'em waste deir spells against de air all dey want. Only get close to kill 'em once dey run outa spells. If ye can, use dose dispelling arrows since dey work wonders. Any creature out dere ye wanted ta know about?~
  IF ~~ THEN REPLY ~Tell me more about how to kill liches.~ GOTO 5a
  IF ~~ THEN REPLY ~Any advice on fighting dragons?~ GOTO 5b
  IF ~~ THEN REPLY ~How can you kill demons?~ GOTO 5c
  IF ~~ THEN REPLY ~Do you know an easy way to kill illithids?~ GOTO 5d
  IF ~~ THEN REPLY ~What is the best way to kill vampires?~ GOTO 5e
  IF ~~ THEN REPLY ~No, that's all I want to know right now.~ GOTO 6
END

IF ~~ THEN BEGIN 5a
  SAY ~Eh? Ye want ta know more about dose casting creepy crawlies? Let me dink on dat some more... (The sword spends so much time thinking that it falls asleep.)~ [guarr01]
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 5b
  SAY ~Pesky overgrown lizards, all of 'em. De dragons yer more likely ta have trouble with are dem gold and red lizards. Dey like deir enemies toasty and tend to like ta squish em 'tween deir toes whenever dey can. Me advice is ta make alot'o friends of the high fire and magic resistance kind, like me master. Besides dat, get 'em giant lizards jumpin around with yer ice an' dispel arrows with a good dosage of magic missiles.~
  IF ~~ THEN EXIT


END

IF ~~ THEN BEGIN 5c
  SAY ~I'll tell ye now, me master and I do not fare too well against de demons. Ye need to hit em with weapons stronger den me and better ta get yer spell happy types casten resist fear all de time. Demons are scary little buggers.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 5d
  SAY ~If ye ever have ta get in a tentacle tango with dem brain suckers, don't send any of yer idiot fighters to attack first. Dey need all de brain cells they got left widdout a brain sucker eating the rest. If ye can, blast de brains suckers wid yer area effect spells. Just make sure ye don't blast yer own idiot fighters.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 5e
  SAY ~De fanged fools don't like ta take deir baths and use dem toothpicks. Just splash some of dat blessed water on dem and watch em become even smellier den before. With dem toothpicks just forget where deir mouth is and hit the heart. Don't go resten in deir covens if ye haven't stuck a tooth pick in the fanged fools to kill 'em, dey got a nasty habit of comin back.~
  IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN 6
  SAY ~Den get ye gone!~
  IF ~~ THEN EXIT
END

CHAIN IF ~~ THEN SW2HOST 3
~Why? Ye trying ta snuggle up to me master now? (The sword flashes brightly, and if you didn't know better you'd think Relic was laughing.) I'll tell ye exactly what y-~
== SK#NEHTJ IF ~InParty("SK#Neht")~ THEN ~Relic! Don't....~
== SW2HOST  IF ~InParty("SK#Neht")~ THEN ~Alright, me master, I'll keep *dat* liddle secret ta meself.~
EXIT

CHAIN IF WEIGHT #0 ~Global("UpgradeRelic","GLOBAL",2)
Global("CromwellRelic2","GLOBAL",0)~ THEN SW2HOST swordattack
~(The runes on the sword glow briefly after Cromwell has repaired it.)~
== WSMITH01 ~Not all the damage to the sword be removed, but enough to make it more useful when ye swing at something.~ DO ~SetGlobal("CromwellRelic2","GLOBAL",1)~
== SW2HOST ~Ye fergot a spot! Methinks me master woulda found me more useful den dat bloody hammer ye keep tryin' ta swing ‘round! I demand me money back!~
== WSMITH01 ~Ye had so much rust in yer mouth ye should be glad ye can talk at all!~
== SW2HOST ~Me mouth don't rust, ye bloody hammer waving tinkerer! Almighty smithy, meet me shiny arse!~
== WSMITH01 ~There be never such an ungrateful piece of metal!~
== SW2HOST ~Watch it dere, tinkerer, ye jus' made me sharp n' shiny.~
== WSMITH01 ~By the Soul Forger, if that sword gets any more dents in it, I willna be sharpenin' it again!~
EXIT

//************************************************************
// Mazzy / CHARNAME / NEHT

ADD_TRANS_TRIGGER MAZZYJ 1 ~!InParty("SK#NEHT")~

EXTEND_BOTTOM MAZZYJ 1
IF ~InParty("SK#Neht")
    Global("SK#MazzyNo","GLOBAL",0)~ THEN EXTERN ~SK#NEHTJ~ SK#MazzyNo
END

APPEND MAZZYJ 
IF ~AreaCheck("AR1400")
Global("SK#MazzyNo","GLOBAL",1)~ THEN BEGIN SK#MazzyNo2
SAY ~The wraith is right, your grace. I forgot myself in my grief. I wouldn't allow anyone to make marks onto an altar dedicated to the deity I worship, if I were in his place.~
IF ~~ THEN DO ~SetGlobal("SK#MazzyNo","GLOBAL",2)
SetGlobal("MazzyComment","AR1400",2)~ EXIT
END
END

// Mazzy/Shade Lord/NEHT - Shade Lord

ADD_TRANS_TRIGGER MAZZYJ 63 ~!InParty("SK#NEHT")~

EXTEND_BOTTOM MAZZYJ 63
IF ~InParty("SK#NEHT")
    Global("NehtTalk","GLOBAL",0)~ THEN EXTERN ~SHADEL~ Hi_There
END

EXTEND_BOTTOM VVMADMAN 6 //crazy rogue

IF ~InParty("SK#Neht")~ THEN DO ~ActionOverride("VVMADMAN",EscapeArea())~ EXTERN SK#NEHTJ crazyrogue0
END

APPEND SK#NEHTJ
IF ~~ THEN BEGIN crazyrogue0
SAY ~Hm... 'watch thy friends and watch thy death'....~
++ ~Don't tell me you're going to repeat all of what the rogue said, this is a bad time for you to lose control over yourself.~ GOTO crazyrogue1
++ ~Did the rogue's words have any special meaning to you?~ GOTO crazyrogue2
++ ~It's just the ramblings of a madman, we can't waste time on this.~ GOTO crazyrogue3
END

IF ~~ THEN BEGIN crazyrogue1
SAY ~I believe it is a special warning for thee, perhaps against those thou travels with.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN crazyrogue2
SAY ~I have heard of this... sometime in the past... were they my words? No, of course not. The undead have their own communities and the powerful oft make themselves known to each other.~
IF ~~ THEN GOTO crazy1
END

IF ~~ THEN BEGIN crazy1
SAY  ~I am not one of those, especially not now, though I am one of the oldest surviving undead. I know of two cities where every being died and became undead. They could not escape at first... forced to feed off of themselves. When visiting one of these places I heard of an elven woman who sought to become undead. (He shakes his head, looking at you.) I apologize, <CHARNAME>, for my wandering thoughts.... let us continue on.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN crazyrogue3
SAY ~Madman or not, he risked himself to warn thee, but if thou will not pay attention to him, then any additional warning from me will come to naught.~
IF ~~ THEN EXIT
END
END

//******************************************************************************
// Give the wraith a chance to leave before the priests attack so we can do quests

APPEND SK#NEHTJ
IF ~AreaCheck("AR0605")
Global("Cant_Pass_QUAYLE","LOCALS",1)~ THEN BEGIN QUAYLE
SAY ~I fear this 'Quayle' must be a priest. (Sighs.) Most likely he will attack thee because of me.  I will await thee outside the tent.~
IF ~~ THEN DO ~SetGlobal("Cant_Pass_QUAYLE","LOCALS",2)
ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)
EscapeAreaMove("AR0700",3192,1578,0)~ EXIT
END
END

I_C_T2 NALIAMES 4 Not_Welcome // Nalia's father's funeral in graveyard
== SK#NEHTJ IF ~InParty("SK#NEHT")~ THEN ~I doubt the priest and mourners will welcome my presence.  I will await thee here.~
DO ~ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)~
END

I_C_T2 PIRMUR10 7 Golin // After Claire's rescue - Golin is an elven priest
== SK#NEHTJ IF ~InParty("SK#Neht") Global("Neht_Golin","LOCALS",0)~ THEN ~Thy friend... Is this 'Golin' a priest or an elf?~ DO ~SetGlobal("Neht_Golin","LOCALS",1)~
== PIRMUR10 IF ~InParty("SK#NEHT")~ THEN ~Y-yes... He is both, Sir.~ 
== SK#NEHTJ IF ~InParty("SK#NEHT")~ THEN ~(Sighs.) Once more I must leave thy group lest thee come to harm. I will await thee at the Vulgar Monkey.~
DO ~ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)
EscapeAreaMove("AR1600",2007,1660,0)~
END

I_C_T2 PIRMUR10 9 Golin1
== SK#NEHTJ IF ~InParty("SK#Neht") GLOBAL("SK#NEHT_Golin","GLOBAL",0)~ THEN ~Thy friend... Is this 'Golin' a priest or an elf?~ DO ~SetGlobal("Neht_Golin","GLOBAL",1)~
== PIRMUR10 IF ~InParty("SK#Neht")~ THEN ~Y-yes... He is both, Sir.~ 
== SK#NEHTJ IF ~InParty("SK#NEHT")~ THEN ~(Sighs.) Once more I must leave thy group lest thee come to harm.  I will await thee at the Vulgar Monkey.~
DO ~ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)
EscapeAreaMove("AR1600",2007,1660,0)~
END

//***************************************************************************
//slayer--woke up – added cutscene for more dramatic effect

ADD_TRANS_TRIGGER PLAYER1 7 ~!InParty("SK#NEHT")~

EXTEND_BOTTOM PLAYER1 7
IF ~InParty("SK#Neht")
    Global("SK#DRAIN","GLOBAL",0)~ THEN DO ~ClearAllActions()
 StartCutSceneMode() StartCutScene("Neht_Hlp")~ EXIT
END

APPEND PLAYER1
IF WEIGHT #-2 ~Global("SK#DRAIN","GLOBAL",1)~ THEN After_Drain
SAY ~(A burst of heat overwhelms you, and the pain that had been growing within your body lessens. You see Neh'taniel standing near you as you struggle to focus on him, watching as he draws his hand away from your body.)~ 
= ~(He steps away from you, once you are able to push away even more of the darkness on your own.)~
IF ~~ DO ~SetGlobal("SK#DRAIN","GLOBAL",2)~ EXTERN SK#NEHTJ Drain0
END
END

APPEND SK#NEHTJ
IF ~~ THEN Drain0
SAY ~Thou art well?~
++ ~Yes, thank you.~ GOTO drainage
++ ~What did you do?~ GOTO drainage1
++ ~No, I am not alright.~ GOTO drainage2
++ ~Let's just continue traveling.~ EXIT
END

IF ~~ THEN drainage
SAY ~Thou art welcome. Above all, I am here to be of use.~
IF ~~ THEN GOTO drainage1
END

IF ~~ THEN drainage1
SAY ~I merely drained some of the energy within thee, so thou can control the Slayer better.~
++ ~I did not give you permission to drain energy from me!~ + drainage3
++ ~Couldn't there have been a different way for you to help?~ + drainage4
++ ~Whatever it takes to control this new form of mine better.~ + drainage5
++ ~Whatever it takes in keeping me from hurting others.~ + drainage5
END

IF ~~ THEN drainage2
SAY ~Perhaps in time thou wilt be able to control thy new form without any help. The lack of control should only be non-existent the first few times....~
IF ~~ THEN GOTO drainage1
END

IF ~~ THEN drainage3
SAY ~The next time thou lose control and attack me, then I will also return thy favor.~
IF ~~ THEN EXIT
END

IF ~~ THEN drainage4
SAY ~I fear there is not. The only way for thee to gain full control is to take thy soul back from Irenicus.~
IF ~~ THEN EXIT
END

IF ~~ THEN drainage5
SAY ~Of course.~
IF ~~ THEN EXIT
END
END

APPEND SK#NEHTJ
IF ~Global("Cant_Pass_LUST","LOCALS",1)~ THEN Lust_Chambers
SAY ~I cannot enter with thee...~
++ ~Why not? You could always watch the action.~ + L_C2
++ ~Well, you can always look up your 'girlfriend' while we're busy.~ + L_C3
END

IF ~~ L_C2
SAY ~I sense too many priestesses within the area... I could be discovered.~
++ ~We'll just try to be as anonymous as possible, then.~ EXIT
++ ~Then wait here. We'll return after we've finished.~ DO ~SetGlobal("Cant_Pass_LUST","LOCALS",2)
ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)~ EXIT
END

IF ~~ L_C3
SAY ~(Neht scowls at you.)~ [wspid01]
IF ~~ DO ~SetGlobal("Cant_Pass_LUST","LOCALS",2)
ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)~ EXIT
END

IF ~Global("Cant_Pass","LOCALS",1)~ THEN BEGIN Lolth_Temple
SAY ~I cannot enter with thee...~
++ ~Why not?  Spiders are revered here.~ + Temple
END

IF ~~ THEN Temple
SAY ~The Matron Mother is very powerful... as are the priestesses therein.~
~The risk of my capture is too great.  I will await thee here.~
++ ~Alright.  We'll return for you.~ DO ~SetGlobal("Cant_Pass","LOCALS",2)
ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
SetGlobal("SK#NehtJoined","LOCALS",0)~ EXIT
END

IF ~~ THEN STEIN
SAY ~Disturber of the dead. . . now thou shalt join us!~
IF ~~ THEN EXTERN STEIN 5
END
END

EXTEND_BOTTOM STEIN 1
IF ~InParty("SK#NEHT")~ THEN EXTERN SK#NEHTJ STEIN
END

EXTEND_BOTTOM SHAAVA01 0 
IF ~IsGabber("SK#NEHT")~ THEN GOTO Morn
END

EXTEND_BOTTOM SHAAVA01 7
IF ~IsGabber("SK#NEHT")~ THEN EXTERN Shaava01 Noon
END

EXTEND_BOTTOM SHAAVA01 14
IF ~IsGabber("SK#NEHT")~ THEN EXTERN Shaava01 Eve
END

APPEND SHAAVA01
IF ~~ THEN BEGIN Morn
SAY ~Faithful one, thou already knowest the rituals. Someone else must answer.~
IF ~~ EXIT
END

IF ~~ THEN BEGIN Noon
SAY ~Faithful one, thou already knowest the rituals. Someone else must answer.~
IF ~~ EXIT
END

IF ~~ THEN BEGIN Eve
SAY ~Faithful one, thou already knowest the rituals. Someone else must answer.~
IF ~~ EXIT
END
END

//Bylanna in gov district stuff

APPEND SK#NEHTJ
IF ~~ THEN BEGIN yippers
SAY ~Her surprised reaction, followed by quick indifference about thee not donating... doth not speak well of the condition of Athkatla's laws.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN yippers2
SAY ~Five gold is the amount most in passing would give, perhaps with a larger donation she would respond better.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN yippers3
SAY ~Reeking of indifference despite the large amount of gold... the City of Coin is aptly named, if all the worse for it.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN yippers4
SAY ~This... is an opportunity to be active in upholding laws again. A trip to the Slums, perhaps?~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN yippers5
SAY ~Her disdain would hath formed into a dagger and stabbed us, if it could.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN yippers6
SAY ~She is in the right, when it comes to problems such as this... a long term solution is better than the shorter one. Shall we go to the Slums?~
IF ~~ THEN EXIT
END
END

APPEND SK#NEHTJ // Didn't trigger if interrupted by other mods
IF ~AreaCheck("AR0907")
PartyHasItem("Sicroll")
Global("DeadSLords","LOCALS",1)~ THEN BEGIN LichHunt
SAY ~The name written in the scroll thou found... 'Aeldredus'. It is the name of a lich that turned against a powerful group of undead and was destroyed. His servant, Algol, should still exist... we should visit the Graveyard District at night, since that is the likeliest of places Algol would call home.~
IF ~~ THEN DO ~SetGlobal("DeadSLords","LOCALS",2)~ EXIT
END
END

APPEND SK#NEHTJ
IF WEIGHT #-1 ~Global("SlaveLNeht","GLOBAL",2)~ THEN BEGIN SlaveLNeht
SAY ~Thou hast accomplished a great thing there, <CHARNAME>, a thing I am honored to have been part of.~
++ ~All we did is wander around for information; that is certainly not enough to get riled up about. ~ + SLN1
++ ~Helping the city means nothing. I was just doing all this for the loot.~ + SLN2
++ ~I like helping others, and am glad slavery will no longer trouble Athkatla.~ + SLN3
++ ~What of the 'Lady' that Algol and Aeldredus kept mentioning?~ + SLN4
++ ~Yes, well, let's just move on.~ + SLN5
END

IF ~~ THEN BEGIN SLN1
SAY ~Not all battles are ones which require swords, but words. We would hath all died quite horribly if we fought the Enforcer, instead of letting him do his... task.~
IF ~~ THEN DO ~SetGlobal("SlaveLNeht","GLOBAL",3)~ EXIT
END

IF ~~ THEN BEGIN SLN2
SAY ~(Frowns.) Not the noblest of desires... but it is the end result which matters most.~
IF ~~ THEN DO ~SetGlobal("SlaveLNeht","GLOBAL",3)~ EXIT
END

IF ~~ THEN BEGIN SLN3
SAY ~I am glad we travel together.~
IF ~~ THEN DO ~SetGlobal("SlaveLNeht","GLOBAL",3)~ EXIT
END

IF ~~ THEN BEGIN SLN4
SAY ~She will live the rest of her life without knowing what truly happened to her love. It is... worrying of what Algol might do when he finds her, but I believe Aeldredus made certain she would be safe, no matter what happened to him.~
IF ~Gender(Player1,FEMALE)~ THEN REPLY ~Have you ever thought much of love?~ + SLN5
IF ~~ THEN REPLY ~Time to move on, then.~ DO ~SetGlobal("SlaveLNeht","GLOBAL",3)~ EXIT
END

IF ~~ THEN BEGIN SLN5
SAY ~Of course, my Lady. Constantly.~
IF ~~ THEN DO ~SetGlobal("SlaveLNeht","GLOBAL",3)~ EXIT
END
END
