BEGIN ~SK#SAR~

APPEND SK#SAR
IF ~Global("SarieSong","LOCALS",1)~ THEN BEGIN 0k
SAY ~(She looks in your direction, but her dull brown eyes seem to peer through you rather than at you. She smiles, but the look doesn't seem directed at you at all.) I am the Enforcer sent to help you on behalf of my master and the Guina'Kiirar. Help you, yes?~ [SK#Neh2]
  IF ~~ THEN REPLY ~Your 'master'? Who would that be?~ DO ~SetGlobal("SarieSong","LOCALS",2)~ GOTO 1k
  IF ~~ THEN REPLY ~What *are* you?~ DO ~SetGlobal("SarieSong","LOCALS",2)~ GOTO 11k
  IF ~~ THEN REPLY ~I was expecting something grander as an Enforcer.~ DO ~SetGlobal("SarieSong","LOCALS",2)~ GOTO 12k
END

IF ~~ THEN BEGIN 1k  //0k
  SAY ~My master is He-Who-Made-Me. He is Lil'velkyn Chath.~
  IF ~~ THEN REPLY ~Never heard of him.~ GOTO 2k
  IF ~~ THEN REPLY ~Elhan called Neh'taniel that, so I assume you mean him.~ GOTO 9k
  IF ~~ THEN REPLY ~Wait, are you saying that Lil'velkyn Chath killed you?~ GOTO 10k
END

IF ~~ THEN BEGIN 2k //1k
SAY ~(She tilts her head to the side, the movement strangely stiff.) You are <CHARNAME>, yes? He told me to help you and the Guina'Kiirar let me go away from home. Help you or not, the choice is yours. You do not need to understand more; only if you were dead.~
IF ~~ THEN REPLY ~What would this help entail, exactly?~ GOTO 3k
IF ~~ THEN REPLY ~I really don't need any more help, so go back to wherever you came from~ GOTO 6k
IF ~~ THEN REPLY ~If you really want to help me, then go right ahead.~ GOTO 4k
END

IF ~~ THEN BEGIN 3k
SAY ~I can make all that are in this lair sing the pretty songs that go around and around in my head.~
IF ~!CheckStatGT(Player1,14,INT)~ THEN REPLY ~Sounds good to me, go for it. I'll be right behind you... twenty miles away.~ GOTO 4k
IF ~~ THEN REPLY ~I really don't like the sound of that. Go back to your 'master' and tell him I won't be needing any help after all.~ GOTO 6k
IF ~CheckStatGT(Player1,14,INT)~ THEN REPLY ~Everyone in this lair? How about you just attack all the vampires and other minions of Bodhi? I really don't want those allied with me to be hurt. ~ GOTO 7k
END

IF ~~ THEN BEGIN 4k
SAY ~(Her hands move through the air as if touching the strings of an invisible harp. At first nothing seems to happen, but the empty air between Sarie's hands suddenly ripples like a small heat wave. While you can't hear whatever song she is playing, in the distance you faintly hear screams.~
IF ~~ DO ~ScreenShake([5.5],30)
Wait(1)
PlaySound("female2a") 
SetGlobal("SariePlay","GLOBAL",1)~ GOTO 5k
END

IF ~~ THEN BEGIN 5k
SAY ~(Once she is done playing her song, Sarie opens her eyes. Again, she seems to look through you.) There, I have done what was asked, like a good girl. All are dead or dying. I go home how.~
IF ~~ THEN DO ~UseItem("SK#Sarie",Myself)
Wait(1)
PlaySound("female2a")
GiveItemCreate("Vscroll",Player1,0,0,0)
EscapeAreaMove("AR0800",1808,1534,0)~ EXIT
END

IF ~~ THEN BEGIN 6k
SAY ~I will do so like a good girl.~
IF ~~ THEN DO ~GiveItemCreate("Vscroll",Player1,0,0,0)
EscapeAreaMove("AR0800",1808,1534,0)~ EXIT
END

IF ~~ THEN BEGIN 7k 
SAY ~(Her hands move through the air as if touching the strings of an invisible harp. At first nothing seems to happen, but the empty air between Sarie's hands suddenly ripples like a small heat wave. While you can't hear whatever song she is playing, in the distance you faintly hear screams.)~
IF ~~ THEN GOTO 8k
END

IF ~~ THEN BEGIN 8k
SAY ~There, all has been done as you asked. Only the ones you wanted are dying. I go home now.~
IF ~~ THEN DO ~UseItem("SK#Sarie",Myself)
Wait(1)
PlaySound("female2a")
GiveItemCreate("Vscroll",Player1,0,0,0)
EscapeAreaMove("AR0800",1808,1534,0)~ EXIT
END

IF ~~ THEN BEGIN 9k
SAY ~I do not know this Neh'taniel, only Lil'velkyn Chath. I am here to help.~
IF ~~ THEN REPLY ~What would this help entail, exactly?~ GOTO 3k
IF ~~ THEN REPLY ~I really don't need anymore help, so go back to where you came from.~ GOTO 6k
IF ~~ THEN REPLY ~If you really want to help me, then go right ahead.~ GOTO 4k
END

IF ~~ THEN BEGIN 10k
SAY ~(An emotion, perhaps confusion, flickers in her eyes briefly before dying.)  He made me, the Guina'Kiirar control me, and now my master cannot stop me.~
IF ~~ THEN GOTO 2k
END

IF ~~ THEN BEGIN 11k
SAY ~I am an Enforcer. I am dead. (She gives you that empty smile again.) I am here to help.~
IF ~~ THEN REPLY ~What would this help entail, exactly?~ GOTO 3k
IF ~~ THEN REPLY ~I really don't need anymore help, so go back to where you came from.~ GOTO 6k
IF ~~ THEN REPLY ~If you really want to help me, then go right ahead.~ GOTO 4k
END

IF ~~ THEN BEGIN 12k
SAY ~There are many ways to enforce the Guina'Kiirar's laws. All Enforcers are different. Help you, yes?~
IF ~~ THEN REPLY ~What would this help entail, exactly?~ GOTO 3k
IF ~~ THEN REPLY ~I really don't need anymore help, so go back to where you came from.~ GOTO 6k
IF ~~ THEN REPLY ~If you really want to help me, then go right ahead.~ GOTO 4k
END
END


CHAIN IF ~AreaCheck("SK6400") Global("NehtHOT1","GLOBAL",2)~ THEN SK#SAR Encounter
~ (Giggles.)~ [female2a] DO ~SetGlobal("NehtHOT1","GLOBAL",3)~
== SK#NEHTP ~Sarie, what art thou laughing about?~ 
== SK#Sar ~The toys died again.~
= ~(She turns her head so she can look at him and doesn't bother to hide the pity in her eyes.) You cannot hear it, but I played a song for the kitty you gave me. It died. It was funny.~
== SK#NEHTP ~I see. There is a <PRO_RACE> <PRO_MANWOMAN> by the name of <CHARNAME>. I desire thee to go to <PRO_HIMHER>, in the graveyard district of Athkatla in the nation of Amn. Play thy songs at <PRO_HISHER> bidding, but do not -- Sarie, this is most important -- do not play to <PRO_HIMHER>. I forbid it. Dost thou understand?~
== SK#Sar ~I do.~
== SK#NEHTP ~Go, then.~ DO ~EscapeArea()~
== SK#Sar ~(She picks up her harp. She runs her fingers down the strings in a simple little tune, one that will take her to Athkatla.)~ DO ~ForceSpell("SK#SARIE",DRYAD_TELEPORT)
PlaySound("EFF_M29")~
END
IF ~~ DO ~ClearAllActions() StartCutSceneMode() StartCutScene("SK#HOT2")~ EXIT

BEGIN SK#JADIS

CHAIN IF ~Global("NehtHOT1","GLOBAL",4)~ THEN sk#jadis SARIE
~Approach.~ DO ~SetGlobal("NehtHOT1","GLOBAL",5)~
== SK#Sar ~Lady, does the Guina'Kiirar want me to play a song again? That would make this a very fun day!~
== SK#JADIS ~Sarie, dear child.  We realize that your master has a task for you. Rest assured, this will not take long. Come here, we must discuss Lil'velkyn Chath.~
== SK#Sar ~(Her dull brown eyes give no hint of actually seeing the lich Jadis, despite facing her.)~
== SK#Jadis ~Your master has done a very distasteful thing. He showed poor enough taste in traveling with the living, and taking orders from them; one does not associate with food.~
= ~Heed me well, Sarie -- poor child, I fear he has neglected to teach you of etiquette and decency. When one is dead, Sarie, one accepts it. One does not cling to the living, looking for some pathetic shadow of life.~
= IF ~Gender(Player1,FEMALE)~ THEN ~Above all else, the dead never fall in love with the living, as Chath has done. Ugh! (Her outburst is echoed all around the chambers)~
== SK#Sar ~(She tilts her head to the side, but gives no other sign of actually having heard anything.)~
== SK#Jadis ~Now, you're an intelligent girl. Strong, too -- possibly strong enough not to need Chath. Perhaps that little idiot Bodhi, and her followers, are not the only ones who will be culled. Do you understand me?~
== SK#Sar ~....Yes, Lady.~
== SK#Jadis ~Good. Do as he ordered. Go to the living <PRO_RACE>, in the graveyard district of Athkatla in the nation of Amn, and play your songs at <PRO_HISHER> bidding. Then stay near <PRO_HIMHER>.~
= ~Chath will come. And when he does, show him your strength! Before you go, we have a gift for you.~
END
IF ~~ DO ~ClearAllActions() StartCutSceneMode() StartCutScene("SK#HOT3")~ EXIT
