BEGIN ~SK#KAO~


CHAIN IF ~Global("KaoNeht","LOCALS",1)
InParty("SK#Neht")~THEN SK#KAO introhelp
~Well, well, so the great <CHARNAME> has finally graced this pathetic town with <PRO_HISHER> presence. Come to solve everybody else's problems once again, have you?~
DO ~SetGlobal("KaoNeht","LOCALS",2)~
== SK#NEHTJ ~Watch thy tongue, mage. I doth not take kindly to thee speaking ill of <CHARNAME>.~
== SK#KAO ~*You* I am too angry to even look at, considering who it is you chose to travel with after all this time. I had to learn of your whereabouts from Viduan!~
END
++ ~(Remain silent.)~ EXTERN SK#NEHTJ ih1
++ ~What is wrong?~ EXTERN SK#KAO ih4
++ ~I don't like people being rude to me, let's just cut out his tongue.~ EXTERN SK#KAO ih2
+ ~Gender(Player1,FEMALE)~ + ~I can defend myself, you know.~ EXTERN SK#NEHTJ ih3
+ ~Gender(Player1,MALE)~ + ~I can defend myself, you know.~ EXTERN SK#NEHTJ ih33
++ ~Both of you are acting like fools, what is actually the matter?~ EXTERN SK#KAO ih4
++ ~What could you have possibly done to earn somebody's ire *this* time, Neh'taniel?~ EXTERN SK#KAO ih5

APPEND SK#NEHTJ
IF ~~ THEN BEGIN ih1
SAY ~Why art thou angry with me? Viduan never mentioned thee to me, and I certainly doth not remember thee.~
IF ~~ THEN EXTERN SK#KAO ih5
END

IF ~~ THEN BEGIN ih3
SAY ~My lady, thou art worthy of respect. Please do not take my words harshly, I know thou art a strong woman. Yet I cannot stand by and do nothing against such behavior, either.~
IF ~~ THEN EXTERN SK#KAO ih5
END

IF ~~ THEN BEGIN ih33
SAY ~I could not simply stand by and allow someone to not be treated with the respect they deserve.~
IF ~~ THEN EXTERN SK#KAO ih5
END

IF ~~ THEN BEGIN ih6
SAY ~If I had known him, I would have written it in my journal, unless.... (He shakes his head.) What he said worries me greatly, but let us continue.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN ih7
SAY ~An enemy which shall be dealt with quickly when he appears again.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN ih8
SAY ~Some things cannot be helped, <CHARNAME>. I told thee before that if my presence becomes too troublesome, then I will leave thy side.~
IF ~~ THEN EXIT
END
END

CHAIN IF ~~ THEN SK#KAO ih2
~Such an effort would be useless, I assure you.~
== SK#NEHTJ ~Thou possess no form of undeath, of that I am certain. Yet, there is some strange, feeling about-~
END SK#KAO ih5

CHAIN IF ~~ THEN SK#KAO ih4
~Nothing you should ever be a part of. Your lack of intelligence has been noted.~
== SK#NEHTJ ~Spit out thy reason, mage. <CHARNAME> and I hath far better things to do than listen to thy insults.~
END SK#KAO ih5

CHAIN IF ~~ THEN SK#KAO ih5
~You really do not remember about.... No, of course you do not, you wouldn't be traveling with your current company if you did.~
== SK#NEHTJ ~(Frowns.) If I had truly known thee, then I apologize for not remembering. Though that doth not excuse thee of insulting anyone I travel with.~
== SK#KAO ~How much has your state taken over your mind, melm--Neh'taniel?~
== SK#NEHTJ ~....It doth not concern thee.~
== SK#KAO ~It does indeed, and I will make you remember. Not now perhaps, but someday soon.~ DO ~EscapeArea()~
END
++ ~What was that about?~ EXTERN SK#NEHTJ ih6
++ ~Great, yet another enemy hounding us.~ EXTERN SK#NEHTJ ih7
++ ~You really do need to keep your problems to yourself.~ EXTERN SK#NEHTJ ih8
++ ~We've wasted far too much time here, let's go.~ EXIT


  
  
  
  




  

