BEGIN ~SK#ENF~

CHAIN IF ~Global("Enforcer","LOCALS",1)~ THEN SK#ENF 0ENF
~Well now, gaining access to your little hideout turned out far easier than I thought it would be, lich.~ DO ~SetGlobal("Enforcer","LOCALS",2)~
== SK#ENF ~Are these allies of yours, Aeldredus? Not that their help would do you much good against me.~ 
== SK#LICH ~Hardly.~
== SK#ALGOL ~Soooo sorry, Master!~
== SK#LICH ~I'm sure you are, as sorry as anyone whose main concern is preserving their own rotting skin.~
== SK#NEHTJ ~<CHARNAME>... with an Enforcer here, we should leave immediately.~
END
++ ~I have no idea what is going on.~ EXTERN ~SK#ENF~ 1ENF
++ ~Why? Things are just beginning to get interesting.~ EXTERN ~SK#ENF~ 2ENF
++ ~We came here to put an end to the slave trade, not run away at the first sign of trouble.~ EXTERN ~SK#ENF~ 3ENF
++ ~I agree, leaving seems to be a good idea.~ EXTERN ~SK#ENF~ 4ENF
++ ~We should help that lich.~ EXTERN ~SK#ENF~ 5ENF


APPEND SK#ENF
IF ~~ THEN BEGIN 1ENF
SAY ~Just as well, I might have to kill you too. Fleshies knowing too much about the undead could cause problems for my masters. Let me deal with the lich, then you and I can spend as much time as we want together.~
IF ~~ THEN DO ~StartCutSceneMode()
StartCutScene("SK#cut1")~ EXIT
END

IF ~~ THEN BEGIN 2ENF
SAY ~That's the spirit! I knew I would like you. Ever thought much about what you'd do once you died? No? Well, I suppose soon we'll find out.~
IF ~~ THEN DO ~StartCutSceneMode()
StartCutScene("SK#cut1")~ EXIT
END

IF ~~ THEN BEGIN 3ENF
SAY ~Only a fool doesn't run away from what can kill him, but I digress. Give me a moment and then we'll spend some more quality time together.~
IF ~~ THEN DO ~StartCutSceneMode()
StartCutScene("SK#cut1")~ EXIT
END

IF ~~ THEN BEGIN 4ENF
SAY ~It is now far too late for that, little fleshling. You will now stay, stay and realize just how deep the hole you have dug yourself into.~
IF ~~ THEN DO ~StartCutSceneMode()
StartCutScene("SK#cut1")~ EXIT
END

IF ~~ THEN BEGIN 5ENF
SAY ~No, you will do nothing, and by doing nothing you'll live just a few moments longer.~
IF ~~ THEN DO ~StartCutSceneMode()
StartCutScene("SK#cut1")~ EXIT
END
END

APPEND SK#ENF
IF ~Dead("SK#LICH")~ THEN BEGIN 0ENF2
SAY ~A pity he didn't put up more of a fight, but he was already weak from... my mistress's administrations. You have a delicious scent about you... <CHARNAME> is it? Such a cloying perfume of violent death that it fills me with the urge of doing something pleasant, if also rather painful, things to you.~
++ ~Take one step closer and any experience with me will be the painful sort.~ + 1ENF2
++ ~I needed information from that lich!~ + 2ENF2
++ ~All I want is an explanation of what just happened, here.~ + 3ENF2
++ ~As... charming as your offer is, I'm going to have to decline.~ + 4ENF2
END

IF ~~ THEN BEGIN 1ENF2
SAY ~Oh, now I -really- like you. Pain is such a delightful emotion. Perhaps I should keep you as a pet, though it looks like you already have an undead 'friend'. Oddly silent now, isn't he? Smart ghost.~
IF ~~ THEN GOTO 2ENF2
END

IF ~~ THEN BEGIN 2ENF2
SAY ~I'm sure if you look hard enough you'll find whatever it was you were looking for around here. Personally, this little lair to hide in isn't my preference; it needs more torture devices and less lights. To set the mood, you know.~
IF ~~ THEN EXTERN SK#NEHTJ 5ENF2
END

IF ~~ THEN BEGIN 3ENF2
SAY ~You wont get one. Figure out this mess in any way you wish, but breathe a word of what happened here to another fleshling and you'll meet a similar fate to our dead lich friend, here.~
IF ~~ THEN GOTO 2ENF2
END

IF ~~ THEN BEGIN 4ENF2
SAY ~'Charming?' You are now as unamusing as a corpse, and I'm not even the type to eat those.~
IF ~~ THEN GOTO 2ENF2
END
END


