BEGIN ~SK#NOBLE~

IF ~NumTimesTalkedTo(0)
Global("Greed","LOCALS",0)~ THEN BEGIN craw1
SAY ~My mummsy simply *had* to kick me out of the house without a coin. It wasn't *my* fault the chambermaid got pregnant! Oh, what am I to do?!~
IF ~~ THEN GOTO craw2
END

IF ~~ THEN BEGIN craw2
SAY ~I suppose I could sell this trinket of mine, since it is growing incredibly dull to have around.~
++ ~What item are you talking about?~ + craw3
++ ~Why don't you just go back home?~ + craw4
++ ~How is a pregnant chambermaid not your fault?~ + craw5 
END

IF ~~ THEN BEGIN craw3
SAY ~Oh, this little bottle here. It'll give you things for a price. You look like the adventuring sort, and so should have a few spare coins.... I'll sell my trinket to you for a little gold. How does 50,000 sound?~
++ ~You call that a little gold?!~ + craw6
++ ~No thank you.~ + craw7
IF ~PartyGoldGT(50000)~ THEN REPLY ~I can pay that price of yours.~ DO ~TakePartyGold(49999)
DestroyGold(50000)~ GOTO craw8
END

IF ~~ THEN BEGIN craw4
SAY ~Humph! You mean why it is I don't submit to indignity! With enough coin I suppose I can buy my own estate, and need not return to mummsy, but I'll have to sell this trinket of mine, to do so.~
++ ~What trinket are you talking about?~ + craw3
++ ~I'll leave you to your... grief, then.~ EXIT
END

IF ~~ THEN BEGIN craw5
SAY ~She lied. For all I know, all the chambermaid has growing under her skirt is a  melon. Say... do you want to buy this trinket of mine? If you do, I'll have just enough to buy my own estate *without* mummsy.~
++ ~What trinket are you talking about?~ + craw3
++ ~I'll leave you to your... grief, then.~ EXIT
END

IF ~~ THEN BEGIN craw6
SAY ~Well, yes. It is less than half the price I offered to the last adventurer who wanted to buy.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN craw7
SAY ~(Sigh.) Very well, speak to me again when you can pay my price. Just don't tell mummsy.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN craw8
SAY ~Oh! How very kind of you.~
IF ~~ THEN DO ~GiveItemCreate("SK#NYM",Player1,0,0,0)
SetGlobal("Greed","LOCALS",1)~ EXIT
END

IF ~!NumTimesTalkedTo(0)
Global("Greed","LOCALS",0)~ THEN BEGIN ReturnCraw
SAY ~Back so soon? Perhaps you want to buy my little trinket now?~
++ ~What item are you talking about?~ + recraw1
++ ~No, just saying hello.~ + recraw2
END

IF ~~ THEN BEGIN recraw1
SAY~ Why, this little bottle can come to life, that'll give you and buy other different trinkets for a price. I'll sell the bottle to you for 50,000 gold.~
++ ~No thank you.~ EXIT
IF ~PartyGoldGT(49999)~ THEN REPLY ~I can pay that price of yours.~ DO ~TakePartyGold(49999)
DestroyGold(49999)~ GOTO recraw3
END

IF ~~ THEN BEGIN recraw2
SAY ~Oh! Well, hello.~
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN recraw3
SAY ~*Do* have fun with it.~
IF ~~ THEN DO ~GiveItemCreate("SK#NYM",Player1,0,0,0)
SetGlobal("Greed","LOCALS",1)~ EXIT
END

IF ~!NumTimesTalkedTo(0)
Global("Greed","LOCALS",1)~ THEN BEGIN crawness
SAY ~Shoo! Don't expect me to buy it back.~
IF ~~ THEN EXIT
END
