BEGIN ~SK#VIDU~
BEGIN ~SK#VIDUJ~

CHAIN IF ~Global("RelicVidu2","LOCALS",0)
!PartyHasItem("SW2HOST")
InParty("SK#Neht")~THEN SK#VIDU introhelp
~Hmph! It took thee long enough to get here!~
DO ~SetGlobal("RelicVidu2","LOCALS",1)~
== SK#NEHTJ ~Viduan! What brings thee here?~
== SK#VIDU ~I was about to get to that.~
END
++ ~I wouldn't mind finding out as well.~ EXTERN SK#VIDU 2xyz 
++ ~Viduan? Funny name for a lich.~ EXTERN SK#VIDU 5xyz
++ ~Do you know this lich, Neh'taniel?~ EXTERN SK#VIDU 8xyz
++ ~I have the distinct feeling I am missing something.~ EXTERN SK#VIDU 2xyz

CHAIN IF ~Global("RelicVidu2","LOCALS",0)
PartyHasItem("SW2HOST")
InParty("SK#Neht")~THEN SK#VIDU introhelp
~Hmph! It took thee long enough to get here!~
DO ~SetGlobal("RelicVidu2","LOCALS",1)~
== SW2HOST ~Dun twist yer rodded undergarments in a knot, ye cantrip cracker, me an' me master go where we bloody well please!~
== SK#VIDU ~Thou were *supposed* to meet me in the Graveyard! Not in the middle of an elf battle!~
== SW2HOST ~Ye can't expect me master to wait fur yer rodded arse forever, *yer* da one who's late!~
== SK#VIDU ~My comments were not directed to *thee*! When they are, my words would be addressed to a cranky, rusty piece of scrap metal!~
== SW2HOST ~Yer callin' *me* cranky?! Why--~
== SK#NEHTJ ~Viduan! What brings thee here?~
== SW2HOST ~(Grumbles.)~ DO ~DestroySelf()~
== SK#VIDU ~I was about to get to that.~
END
++ ~I wouldn't mind finding out as well.~ EXTERN SK#VIDU 2xyz 
++ ~Viduan? Funny name for a lich.~ EXTERN SK#VIDU 5xyz
++ ~Do you know this lich, Neh'taniel?~ EXTERN SK#VIDU 8xyz
++ ~I have the distinct feeling I am missing something.~ EXTERN SK#VIDU 2xyz

CHAIN IF ~~ THEN SK#VIDU 8xyz
~Of course he knows me. (Snorts.)~
== SK#NEHTJ ~He is a friend of mine, <CHARNAME>.~
== SK#VIDU ~A friend who needs thy help.~
END
IF ~~ THEN REPLY ~Help with what?~ EXTERN SK#VIDU 2xyz
IF ~~ THEN REPLY ~Whatever it is, my answer is no.~ EXTERN SK#VIDU 7xyz
IF ~~ THEN REPLY ~Sure I'll help, just tell me what it is.~ EXTERN SK#VIDU 2xyz

CHAIN IF ~~ THEN SK#VIDU 7xyz
~(Snorts) Neh'taniel, does this fleshling speak for thee, now?~
== SK#NEHTJ ~In all matters that concern <PRO_HIMHER>, aye.~
== SK#VIDU ~This doth not concern a Bhaalspawn, my words are only for Neh'taniel.~
END SK#VIDU 3xyz

CHAIN IF ~~ THEN SK#VIDU 3xyz
~(Finishes unrolling a scroll.) Now, where was I? Oh, yes... now why the Guina'Kiirar would insist I give this message to thee personally I doth not know.~
== SK#NEHTJ ~I would think no item is so powerful the Guina'Kiirar could not use it.~
== SK#VIDU ~If the Netherese still reigned in the sky, perhaps, but not now.~
== SK#VIDU ~*They* have come across a magical item too dangerous for even them to use safely and do not want anyone else using it; an item made partially of fire. Since no typical wraith can drain it, the Guina'Kiirar wants thee to.~
== SK#NEHTJ ~(He nods, turning to face you.) We are almost free from the Underdark, <CHARNAME>, but are no closer to confronting Irenicus or Bodhi; we only vaguely know where they are. Would thou mind if I leave thee for a short time? There is little I could help thee with at this point.~
END
++ ~I think your leaving would be a bad idea.~ EXTERN ~SK#NEHTJ~ NehtVidu5
++ ~I'm not holding you back, Neh'taniel, go if you want.~ EXTERN ~SK#NEHTJ~ NehtVidu6

APPEND SK#VIDU
IF ~~ THEN BEGIN 2xyz
SAY ~(The lich takes out a scroll from a sleeve of his robes.)~
IF ~~ THEN REPLY ~(Attack him.)~ DO ~ReallyForceSpell(Myself,DRYAD_TELEPORT)
Wait(1)
DestroySelf()~ EXIT
IF ~~ THEN REPLY ~(Remain silent.)~ GOTO 3xyz
IF ~~ THEN REPLY ~That better not be a spell scroll.~ GOTO 4xyz
END

IF ~~ THEN BEGIN 4xyz
SAY ~(The lich glares at you.) It is not a spell scroll.~
IF ~~ THEN GOTO 3xyz
END

IF ~~ THEN BEGIN 5xyz
SAY ~It is a Netherese name for a lich, thou would be wise to remember it.~
IF ~~ THEN GOTO 3xyz
END
END

// Neht dialog with Player1 after the long Viduan conversation

APPEND SK#NEHTJ
IF ~~ THEN BEGIN NehtVidu5
SAY ~If I do not go to drain the item now, then thee may have more to worry about than a vampire and a mage running off with thy divinity. I joined thy group to help thee, not to make things even more difficult.~
IF ~~ THEN GOTO NehtVidu7
END

IF ~~ THEN BEGIN NehtVidu6
SAY ~I will return to thy side once I am done, if thou wish.~
IF ~~ THEN GOTO NehtVidu7
END   

IF ~~ THEN BEGIN NehtVidu7
SAY ~Since I am leaving thee so suddenly, I can send... an ally of mine to help thee. This ally, a wraith much like myself, will follow thy orders to the letter.~
++ ~Sounds good, so who and where is this 'ally' of yours?~ + NehtVidu8
++ ~While I might trust you, I don't trust any of your friends. I can manage on my own till you come back.~ + NehtVidu9
++ ~You've been acting increasingly strange the longer we travel together. I don't trust you, Neh'taniel, especially not under the current circumstances.~ + NehtVidu10
END

IF ~~ THEN BEGIN NehtVidu8
SAY ~Her name is Sarie. A... bard of no small amount of skill. There is no need to go out and look for her, she will find thee.~
IF ~~ THEN GOTO NehtVidu11
END

IF ~~ THEN BEGIN NehtVidu9
SAY ~(Nods.) So be it.~
IF ~~ THEN GOTO NehtVidu11
END

IF ~~ THEN BEGIN NehtVidu10
SAY ~I shall keep that in mind the next time thou turns into the Slayer.~
IF ~~ THEN GOTO NehtVidu11
END

IF ~~ THEN BEGIN NehtVidu11
SAY ~Fare thee well, <CHARNAME>... until we meet again.~
IF ~~ THEN DO ~SetGlobal("Sarie_Help","GLOBAL",1)
ChangeAIScript("",DEFAULT)
SetLeavePartyDialogueFile()
LeaveParty()
EscapeArea()~ EXIT
END
END
