EXTEND_BOTTOM BYLANNA 5
IF ~Global("SlumGold","GLOBAL",0)
InParty("SK#Neht")~ THEN REPLY ~I want to donate money to help the poor in the Slums.~ EXTERN ~BYLANNA~ HPP
END

EXTEND_BOTTOM BYLANNA 5 // Use the GlobalLT - otherwise option still showing
+ ~GlobalLT("HeardOfSlaveLords","GLOBAL",1)
PartyHasItem("Sacroll")~ + ~I found this scroll on one of the bodies of a person claiming to be slaver, is this what you need?~ EXTERN ~BYLANNA~ HP18
END

EXTEND_BOTTOM BYLANNA 5
+ ~Global("SlaveLNeht","GLOBAL",0)
PartyHasItem("SK#LDoc")~ + ~A lich was behind the illegal slave trade within Amn. He is now destroyed and I found these documents in his lair.~ EXTERN ~BYLANNA~ HP19
END

APPEND ~BYLANNA~
IF ~Global("SlumGold","GLOBAL",0)~ THEN BEGIN HPP
SAY ~You do? Most people choose to give money to the poor directly, though that tends to cause all kinds of problems in the long run. I am the right person to speak to about such things. How much do you want to donate?~
++ ~How will I know anything I donate will actually be used to help the poor?~ + HP1
IF ~~ THEN REPLY ~Never mind, I seem to be out of coin. Perhaps later.~ GOTO HP2
+ ~PartyGoldGT(5)~ + ~I don't have much, so five gold will do.~ + HP3
+ ~PartyGoldGT(500)~ + ~Five hundred gold it is, then.~ + HP4
+ ~PartyGoldGT(1000)~ + ~A thousand gold coins should be enough to make a difference.~ DO ~TakePartyGold(1000)
DestroyGold(1000)
SetGlobal("SlumGold","GLOBAL",1)~ GOTO HP5
END

IF ~~ THEN BEGIN HP1
SAY ~By asking the poor, of course. If the donation is large enough, they are likely to mention it.~
IF ~~ THEN REPLY ~Nevermind, I seem to be out of coin. Perhaps later.~ GOTO HP2
+ ~PartyGoldGT(5)~ + ~I don't have much, so five gold will do.~ + HP3
+ ~PartyGoldGT(500)~ + ~Five hundred gold it is, then.~ + HP4
+ ~PartyGoldGT(1000)~ + ~A thousand gold coins should be enough to make a difference.~ DO ~TakePartyGold(1000)
DestroyGold(1000)
SetGlobal("SlumGold","GLOBAL",1)~ GOTO HP5
END

IF ~~ THEN BEGIN HP2
SAY ~Then move on, citizen.~
IF ~~ THEN EXTERN ~SK#NEHTJ~ yippers
END

IF ~~ THEN BEGIN HP3
SAY ~Every little bit helps.~
IF ~~ THEN DO ~TakePartyGold(5)
DestroyGold(5)~ EXTERN ~SK#NEHTJ~ yippers2
END

IF ~~ THEN BEGIN HP4
SAY ~That will be enough to reconstruct a few of the rundown buildings in the Slums District in the next few weeks. On behalf of Amn, I thank you for your donation.~
IF ~~ THEN DO ~TakePartyGold(500)
DestroyGold(500)~ EXTERN ~SK#NEHTJ~ yippers3
END

IF ~~ THEN BEGIN HP5
SAY ~That... is certainly enough money to actually do some good for the poor. I'll be sure to tell those that live in the Slums who just made their lives a little easier.~
IF ~~ THEN GOTO HP6
END

IF ~~ THEN BEGIN HP6
SAY ~Since you seem to be both the generous and adventurous sort, I have something else you could do, if you are willing to listen.~
++ ~Which would be?~ + HP7
++ ~I'm not interested.~ EXIT
END

IF ~~ THEN BEGIN HP7
SAY ~One of my informants has brought to my attention that slavers are trying to set up a base in the Slums, if you can find this base and bring me proof as to who is behind the slavery, I'll be the one giving you a reward.~
+ ~PartyHasItem("Sacroll")~ + ~I found this scroll on one of the bodies of a person claiming to be slaver, is this what you need?~ + HP11
++ ~What kind of proof do you want?~ + HP8
++ ~And if somebody isn't trying to set up a base?~ + HP9
++ ~Wouldn't just finding and killing the slavers solve matters?~ + HP10
++ ~I've changed my mind, I really am not that interested in further helping you.~ EXIT
END

IF ~~ THEN BEGIN HP8
SAY ~Preferably some kind of written document signed by the person allowing them to set up in the Slums. Best of luck to you on this, don't be surprised if things turn bloody.~
IF ~~ THEN EXTERN ~SK#NEHTJ~ yippers4
END

IF ~~ THEN BEGIN HP9
SAY ~Then neither of us receive anything for our efforts.~
IF ~~ THEN EXTERN ~SK#NEHTJ~ yippers5
END

IF ~~ THEN BEGIN HP10
SAY ~No, since it leaves the door open for more slavers to arrive and sell slaves to whoever to sponsoring their base. I am more interested in a long term solution, here.~
IF ~~ THEN EXTERN ~SK#NEHTJ~ yippers6
END

IF ~~ THEN BEGIN HP11
SAY ~You've been busy in the Slums, I see. Fair enough if no harm was done, though in the future I'd keep the random slaughtering of the lawless to a minimum, or you'll be the one visiting a jail cell.~
IF ~Global("HeardOfSlaveLords","GLOBAL",0)~ THEN GOTO HP12
END

IF ~~ THEN BEGIN HP12
SAY ~Still, you have the city's thanks in acquiring this information, but without knowing an exact location within the Temple District, I can't have my guards entering temples and homes at random.~
++ ~I want a reward, for giving you that information.~ GOTO HP14
++ ~What else can I do?~ DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",1)~ GOTO HP13
++ ~Good luck with that.~ DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",1)~ EXIT
++ ~I have no more interest in this.~ DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",2)~ EXIT
END

IF ~~ THEN BEGIN HP13
SAY ~I'm sure you are aware of the current troubles in the streets at night, that have been keeping the city guard's hands full. The Cowled Wizards will not be able to help much, either. I need you and your allies, since you've proven to be trustworthy enough, to accompany what guards I can spare for a 'patrol check' of the district.~
++ ~Isn't this all a little too rushed?~ + HP15
++ ~A good enough plan, I'll go meet your 'patrollers' in the Temple District.~ + HP16
++ ~That doesn't sound like a good plan.~ + HP17
++ ~Where should I meet these guards?~ + HP16
END

IF ~~ THEN BEGIN HP14
SAY ~I wish you joy of it.~
IF ~~ THEN DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",2)
GiveItemCreate("SK#AMU",Player1,0,0,0)~ EXIT
END

IF ~~ THEN BEGIN HP15
SAY ~No, not in light of this information. An unnanounced sweep through a district, especially in these times, is perfectly legal.~
++ ~Good enough, I'll go meet your 'patrollers' in the Temple District.~ + HP16
++ ~That doesn't sound like a good plan.~ + HP17
++ ~Where should I meet these guards?~ + HP16
END

IF ~~ THEN BEGIN HP16
SAY ~One of my men will confront you in the Temple District once they have been able to pinpoint the location of the Slave Lords.~
IF ~~ THEN DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",1)~ EXIT
END

IF ~~ THEN BEGIN HP17
SAY ~It is a good enough plan that can be made in such short notice. Your constant questioning of my decision means I doubt you'll be as useful as I thought you'd be. Here is a reward for your help so far; I do not need your assistance.~
IF ~~ THEN DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",2)
GiveItemCreate("SK#AMU",Player1,0,0,0)~ EXIT
END

IF ~~ THEN BEGIN HP18
SAY ~You have the city's thanks in acquiring this information, but without knowing an exact location within the Temple District, I can't have my guards entering temples and homes at random.~
++ ~I want a reward, for giving you that information.~ GOTO HP14
++ ~What else can I do?~ DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",1)
TakePartyItem("Sacroll")~ GOTO HP13
++ ~Good luck with that.~ DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",1)
TakePartyItem("Sacroll")~ EXIT
++ ~I have no more interest in this.~ DO ~SetGlobal("HeardOfSlaveLords","GLOBAL",2)
TakePartyItem("Sacroll")~ EXIT
END

IF ~~ THEN BEGIN HP19
SAY ~These are exactly the documents needed to put an end to the slave trade within the city. By doing this, you have marked yourselves as true heroes of Amn. Since you have proven yourselves to not be a danger to the city, you now have the right to use magic in its streets.~
IF ~~ THEN DO ~SetGlobal("SlaveLNeht","GLOBAL",1)
TakePartyItem( "SK#LDoc")
ReputationInc(2)
SetGlobal("KnowsCowledBribe","LOCALS",1)
SetGlobal("BribedCowled","GLOBAL",1)~ EXIT
END
END

