BEGIN ~SK#LICH~ // Don't need a separate empty file for SK#Lich
BEGIN ~SK#ALGOL~ // Had to use a GlobalGT for 0Algol

IF ~Global("HelloAlgol","LOCALS",1)
GlobalGT("HeardOfSlaveLords","GLOBAL",0)~ THEN BEGIN 0Algol
  SAY ~It's you!~
  ++ ~Die, undead thing!~ + 1Algol
  ++ ~Who?~ + 0Algol 
  ++ ~What about me?~ + 2Algol
  ++ ~I think you have me mistaken with somebody else.~ + 2Algol
  ++ ~Well... yes! That is me!~ + 2Algol
  END
  
IF ~~ THEN BEGIN 1Algol
SAY ~No, no, no! Cannot be killed here. The Master needs help. You will help him. You and ghost man, here.~
++ ~No, I already don't like you. Killing you will be much more amusing.~ + 3Algol
++ ~Tell me where your master is, and I'll consider helping.~ + 4Algol
++ ~Give me a reason why I shouldn't kill you, then.~ + 5Algol
++ ~You assume much, for a walking corpse.~ + 2Algol
END

IF ~~ THEN BEGIN 2Algol
SAY ~The Lord warned me about the <PRO_MANWOMAN> that smell of murder and the ghost man. But, but, but... things have changed. An Enforcer has come, and now it is too late. Unless, unless, unless you help.~
++ ~'Enforcer'?~ + 7Algol
++ ~Why should I help you?~ + 5Algol
++ ~Tell me where your master is, and I'll consider helping.~ + 4Algol
++ ~No, I don't trust you.~ + 3Algol
END

IF ~~ THEN BEGIN 3Algol
SAY ~No help? You now die, die, die the way the Master now dies! Ripped limb from limb!~
IF ~~ THEN DO ~SetGlobal("HelloAlgol","LOCALS",2)
ActionOverride("SK#ALGOL",Enemy())
Enemy()~ EXIT
END

IF ~~ THEN BEGIN 4Algol
SAY ~Algol not as dumb as he looks. Try, try, try again.~
++ ~Why should I help you?~ + 5Algol
++ ~Too bad, I really don't care.~ + 3Algol
END

IF ~~ THEN BEGIN 5Algol
SAY ~You hunt Master because of slaves. Master does this only for the Lady! *They* thought they killed him, but he found way to survive for the Lady. Though the Lady thinks the Master is still dead.~
IF ~~ THEN GOTO 6Algol
END

IF ~~ THEN BEGIN 6Algol
SAY ~The Lady always want a child. The Master wants perfect child for the Lady. Hired Slave Lords to find child for him. But *they* found him again!~
++ ~'They'?~ + 7Algol
++ ~No excuse. Slavery is wrong no matter the reason for it.~ + 3Algol
++ ~I guess that is a good enough reason as any.~ + 8Algol
END

IF ~~ THEN BEGIN 7Algol
SAY ~Can't say, can't say, can't say. Algol likes own hide too much. Ask again when not a fleshy.~
IF ~~ THEN GOTO 8Algol
END

IF ~~ THEN BEGIN 8Algol
SAY ~You help Master. I help you. Agreed?~
++ ~Agreed.~ + 9Algol
++ ~No, I don't agree.~ + 3Algol
END

IF ~~ THEN BEGIN 9Algol // Bells and whistles added
SAY ~I take you once. Once only! I keep eye on you for tricks!~
IF ~~ THEN DO ~SetGlobal("HelloAlgol","LOCALS",2)
ClearAllActions() 
StartCutSceneMode()
StartCutScene("SK#Lair")~ EXIT
END

IF ~Global("HelloAlgol","LOCALS",1)
Global("HeardOfSlaveLords","GLOBAL",0)~ THEN BEGIN 0Algol2
SAY ~Don't know you. Go and go away.~
IF ~~ THEN EXIT
END

CHAIN IF ~See("SK#lich")
Global("StupidGhoul","GLOBAL",0)~ THEN SK#ALGOL 0DumbAlgol
~Master! Look, look, look here! I brought more to help you!~
== SK#LICH ~Algol, you fool! I told you not to come here until the Enforcer is dealt with! By the Dead Three, you'll bring the second death of me yet!~
== SK#ALGOL ~Algol is so very sorry, master. Me was so very worried! The Lady would be upset that you dieeeed.~
== SK#LICH ~It's too late to apologize, you moronic flesh eater! You breached the wards around my crypt by coming here, and now neither of us will see my beloved wife again.~ 
END
IF ~~ THEN DO ~SetGlobal("StupidGhoul","GLOBAL",1)
ClearAllActions() 
StartCutSceneMode()
StartCutScene("arwm05")~ EXIT

APPEND SK#ALGOL // Had to add to his baf to make him leave
IF ~!See("SK#ENF")
Dead("SK#LICH")~ THEN BEGIN 1DumbAlgol
SAY ~Poor Master, lucky Algol. I go find Lady, before other Guina'Kiirar show up. Fleshies find their own way out!~
IF ~~ THEN DO ~EscapeArea()~ EXIT
END
END