EXTEND_BOTTOM C6ELHAN2 79
IF ~InParty("SK#Neht")~ THEN GOTO 0yyy
END

APPEND C6ELHAN2
IF ~Global("NehtE","LOCALS",0)~ THEN BEGIN 0yyy
SAY ~Strange... for a moment, the very air next to you blurred. Yet, now it is gone. The wind must have blown some dust into the air.~
++ ~Actually, that'd be a certain fire wraith.~ DO ~SetGlobal("NehtE","LOCALS",1)~ EXTERN ~SK#NEHTJ~ 1yyy
++ ~(Remain silent.)~ EXTERN ~C6ELHAN2~ 78
END
END

EXTEND_BOTTOM SUELHAN 6
IF ~Dead("SK#Neht")~ THEN GOTO 0xxx
END

APPEND SUELHAN
IF ~~ THEN BEGIN 0xxx
  SAY ~There have been no new sightings of Lil'velkyn Chath, I trust you bring me good news.~
  IF ~Dead("SK#Neht")~ THEN REPLY ~The wraith is dead, I killed him near Bodhi's lair.~ GOTO 1xxx
  IF ~~ THEN REPLY ~I haven't seen him.~ GOTO 5xxx
  IF ~~ THEN REPLY ~He is in this city somewhere.~ GOTO 6xxx
  IF ~~ THEN REPLY ~The wraith is dead.~ GOTO 8xxx
END

IF ~~ THEN BEGIN 1xxx
  SAY ~Word has reached me of your deed already; Chath is truly dead. The wraith would not have put up an easy fight. ~
  IF ~~ THEN DO ~GivePartyGold(100000)~ GOTO 2xxx
END

IF ~~ THEN BEGIN 2xxx
  SAY ~Here is your reward.~
  IF ~~ THEN REPLY ~Aren't you going to tell me why you wanted him killed?~ GOTO 3xxx
  IF ~~ THEN REPLY ~Thanks, it was easy.~ EXTERN SUELHAN 5
  IF ~~ THEN REPLY ~Don't I deserve a little more gold? I had a hard time killing him.~ GOTO 4xxx
END

IF ~~ THEN BEGIN 3xxx
  SAY ~You must speak with Elleseme if you want to know more about the wraith.~
  IF ~~ THEN EXTERN SUELHAN 5
END

IF ~~ THEN BEGIN 4xxx
  SAY  ~The gold I gave you is more than enough. Destroying an undead should be its own reward for the good of all.~
  IF ~~ THEN EXTERN SUELHAN 5
END

IF ~~ THEN BEGIN 5xxx
  SAY ~If you see the wraith in the city, inform me immediately.~
  IF ~~ THEN EXTERN SUELHAN 5
END

IF ~~ THEN BEGIN 6xxx
  SAY ~How did you come by this information?~
  IF ~~ THEN REPLY ~He told me.~ GOTO 7xxx
  IF ~~ THEN REPLY ~I heard rumors. ~ GOTO 5xxx
  IF ~~ THEN REPLY ~Suldanessellar would be the obvious place he would be, if as you say, he is working for Irenicus.~ GOTO 5xxx
END

IF ~~ THEN BEGIN 7xxx
  SAY ~You jest at a time which does not call for it.~
  IF ~~ THEN EXTERN SUELHAN 5
END

IF ~~ THEN BEGIN 8xxx
  SAY ~Do you have proof of this?~
  IF ~~ THEN REPLY ~No I don't, sorry about that.~ GOTO 7xxx
  IF ~~ THEN REPLY ~Yes I do, I just don't have any proof with me at the moment.~ GOTO 9xxx
END

IF ~~ THEN BEGIN 9xxx
  SAY ~Until I have proof, then I must assume Lil'velkyn Chath still exists.~
  IF ~~ THEN GOTO 5xxx
END
END

